qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 string STR_PLAYER = "player";
  83 string STR_SPECTATOR = "spectator";
  84 string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if not(IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void GameLogEcho(string s)
 111 {
 112     string fn;
 113     float matches;
 114
 115     if (autocvar_sv_eventlog_files)
 116     {
 117         if (!logfile_open)
 118         {
 119             logfile_open = TRUE;
 120             matches = autocvar_sv_eventlog_files_counter + 1;
 121             cvar_set("sv_eventlog_files_counter", ftos(matches));
 122             fn = ftos(matches);
 123             if (strlen(fn) < 8)
 124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 126             logfile = fopen(fn, FILE_APPEND);
 127             fputs(logfile, ":logversion:3\n");
 128         }
 129         if (logfile >= 0)
 130         {
 131             if (autocvar_sv_eventlog_files_timestamps)
 132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 133             else
 134                 fputs(logfile, strcat(s, "\n"));
 135         }
 136     }
 137     if (autocvar_sv_eventlog_console)
 138     {
 139         print(s, "\n");
 140     }
 141 }
 142
 143 void GameLogInit()
 144 {
 145     logfile_open = 0;
 146     // will be opened later
 147 }
 148
 149 void GameLogClose()
 150 {
 151     if (logfile_open && logfile >= 0)
 152     {
 153         fclose(logfile);
 154         logfile = -1;
 155     }
 156 }
 157
 158 float spawnpoint_nag;
 159 void relocate_spawnpoint()
 160 {
 161     // nudge off the floor
 162     setorigin(self, self.origin + '0 0 1');
 163
 164     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 165     if (trace_startsolid)
 166     {
 167         vector o;
 168         o = self.origin;
 169         self.mins = PL_MIN;
 170         self.maxs = PL_MAX;
 171         if (!move_out_of_solid(self))
 172             objerror("could not get out of solid at all!");
 173         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 174         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 175         print(" ", ftos(self.origin_y - o_y));
 176         print(" ", ftos(self.origin_z - o_z), "'\n");
 177         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 178         {
 179             if (!spawnpoint_nag)
 180                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 181             spawnpoint_nag = 1;
 182         }
 183         else
 184         {
 185             setorigin(self, o);
 186             self.mins = self.maxs = '0 0 0';
 187             objerror("player spawn point in solid, mapper sucks!\n");
 188             return;
 189         }
 190     }
 191
 192     self.use = spawnpoint_use;
 193     self.team_saved = self.team;
 194     if (!self.cnt)
 195         self.cnt = 1;
 196
 197     if (have_team_spawns != 0)
 198         if (self.team)
 199             have_team_spawns = 1;
 200     have_team_spawns_forteam[self.team] = 1;
 201
 202     if (autocvar_r_showbboxes)
 203     {
 204         // show where spawnpoints point at too
 205         makevectors(self.angles);
 206         entity e;
 207         e = spawn();
 208         e.classname = "info_player_foo";
 209         setorigin(e, self.origin + v_forward * 24);
 210         setsize(e, '-8 -8 -8', '8 8 8');
 211         e.solid = SOLID_TRIGGER;
 212     }
 213 }
 214
 215 #define strstr strstrofs
 216 /*
 217 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 218 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 219 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 220 // BE CONSTANT OR strzoneD!
 221 float strstr(string haystack, string needle, float offset)
 222 {
 223         float len, endpos;
 224         string found;
 225         len = strlen(needle);
 226         endpos = strlen(haystack) - len;
 227         while(offset <= endpos)
 228         {
 229                 found = substring(haystack, offset, len);
 230                 if(found == needle)
 231                         return offset;
 232                 offset = offset + 1;
 233         }
 234         return -1;
 235 }
 236 */
 237
 238 float NUM_NEAREST_ENTITIES = 4;
 239 entity nearest_entity[NUM_NEAREST_ENTITIES];
 240 float nearest_length[NUM_NEAREST_ENTITIES];
 241 entity findnearest(vector point, .string field, string value, vector axismod)
 242 {
 243     entity localhead;
 244     float i;
 245     float j;
 246     float len;
 247     vector dist;
 248
 249     float num_nearest;
 250     num_nearest = 0;
 251
 252     localhead = find(world, field, value);
 253     while (localhead)
 254     {
 255         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 256             dist = localhead.oldorigin;
 257         else
 258             dist = localhead.origin;
 259         dist = dist - point;
 260         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 261         len = vlen(dist);
 262
 263         for (i = 0; i < num_nearest; ++i)
 264         {
 265             if (len < nearest_length[i])
 266                 break;
 267         }
 268
 269         // now i tells us where to insert at
 270         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 271         if (i < NUM_NEAREST_ENTITIES)
 272         {
 273             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 274             {
 275                 nearest_length[j + 1] = nearest_length[j];
 276                 nearest_entity[j + 1] = nearest_entity[j];
 277             }
 278             nearest_length[i] = len;
 279             nearest_entity[i] = localhead;
 280             if (num_nearest < NUM_NEAREST_ENTITIES)
 281                 num_nearest = num_nearest + 1;
 282         }
 283
 284         localhead = find(localhead, field, value);
 285     }
 286
 287     // now use the first one from our list that we can see
 288     for (i = 0; i < num_nearest; ++i)
 289     {
 290         traceline(point, nearest_entity[i].origin, TRUE, world);
 291         if (trace_fraction == 1)
 292         {
 293             if (i != 0)
 294             {
 295                 dprint("Nearest point (");
 296                 dprint(nearest_entity[0].netname);
 297                 dprint(") is not visible, using a visible one.\n");
 298             }
 299             return nearest_entity[i];
 300         }
 301     }
 302
 303     if (num_nearest == 0)
 304         return world;
 305
 306     dprint("Not seeing any location point, using nearest as fallback.\n");
 307     /* DEBUGGING CODE:
 308     dprint("Candidates were: ");
 309     for(j = 0; j < num_nearest; ++j)
 310     {
 311         if(j != 0)
 312                 dprint(", ");
 313         dprint(nearest_entity[j].netname);
 314     }
 315     dprint("\n");
 316     */
 317
 318     return nearest_entity[0];
 319 }
 320
 321 void spawnfunc_target_location()
 322 {
 323     self.classname = "target_location";
 324     // location name in netname
 325     // eventually support: count, teamgame selectors, line of sight?
 326 }
 327
 328 void spawnfunc_info_location()
 329 {
 330     self.classname = "target_location";
 331     self.message = self.netname;
 332 }
 333
 334 string NearestLocation(vector p)
 335 {
 336     entity loc;
 337     string ret;
 338     ret = "somewhere";
 339     loc = findnearest(p, classname, "target_location", '1 1 1');
 340     if (loc)
 341     {
 342         ret = loc.message;
 343     }
 344     else
 345     {
 346         loc = findnearest(p, target, "###item###", '1 1 4');
 347         if (loc)
 348             ret = loc.netname;
 349     }
 350     return ret;
 351 }
 352
 353 string formatmessage(string msg)
 354 {
 355         float p, p1, p2;
 356         float n;
 357         vector cursor;
 358         entity cursor_ent;
 359         string escape;
 360         string replacement;
 361         p = 0;
 362         n = 7;
 363
 364         WarpZone_crosshair_trace(self);
 365         cursor = trace_endpos;
 366         cursor_ent = trace_ent;
 367
 368         while (1) {
 369                 if (n < 1)
 370                         break; // too many replacements
 371
 372                 n = n - 1;
 373                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 374                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 375
 376                 if (p1 < 0)
 377                         p1 = p2;
 378
 379                 if (p2 < 0)
 380                         p2 = p1;
 381
 382                 p = min(p1, p2);
 383
 384                 if (p < 0)
 385                         break;
 386
 387                 replacement = substring(msg, p, 2);
 388                 escape = substring(msg, p + 1, 1);
 389
 390                 if (escape == "%")
 391                         replacement = "%";
 392                 else if (escape == "\\")
 393                         replacement = "\\";
 394                 else if (escape == "n")
 395                         replacement = "\n";
 396                 else if (escape == "a")
 397                         replacement = ftos(floor(self.armorvalue));
 398                 else if (escape == "h")
 399                         replacement = ftos(floor(self.health));
 400                 else if (escape == "l")
 401                         replacement = NearestLocation(self.origin);
 402                 else if (escape == "y")
 403                         replacement = NearestLocation(cursor);
 404                 else if (escape == "d")
 405                         replacement = NearestLocation(self.death_origin);
 406                 else if (escape == "w") {
 407                         float wep;
 408                         wep = self.weapon;
 409                         if (!wep)
 410                                 wep = self.switchweapon;
 411                         if (!wep)
 412                                 wep = self.cnt;
 413                         replacement = W_Name(wep);
 414                 } else if (escape == "W") {
 415                         if (self.items & IT_SHELLS) replacement = "shells";
 416                         else if (self.items & IT_NAILS) replacement = "bullets";
 417                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 418                         else if (self.items & IT_CELLS) replacement = "cells";
 419                         else replacement = "batteries"; // ;)
 420                 } else if (escape == "x") {
 421                         replacement = cursor_ent.netname;
 422                         if (replacement == "" || !cursor_ent)
 423                                 replacement = "nothing";
 424                 } else if (escape == "s")
 425                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 426                 else if (escape == "S")
 427                         replacement = ftos(vlen(self.velocity));
 428
 429                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 430                 p = p + strlen(replacement);
 431         }
 432         return msg;
 433 }
 434
 435 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 436         return (value == 0) ? FALSE : TRUE;
 437 }
 438
 439 /*
 440 =============
 441 GetCvars
 442 =============
 443 Called with:
 444   0:  sends the request
 445   >0: receives a cvar from name=argv(f) value=argv(f+1)
 446 */
 447 void GetCvars_handleString(string thisname, float f, .string field, string name)
 448 {
 449         if (f < 0)
 450         {
 451                 if (self.field)
 452                         strunzone(self.field);
 453                 self.field = string_null;
 454         }
 455         else if (f > 0)
 456         {
 457                 if (thisname == name)
 458                 {
 459                         if (self.field)
 460                                 strunzone(self.field);
 461                         self.field = strzone(argv(f + 1));
 462                 }
 463         }
 464         else
 465                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 466 }
 467 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 468 {
 469         GetCvars_handleString(thisname, f, field, name);
 470         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 471                 if (thisname == name)
 472                 {
 473                         string s;
 474                         s = func(strcat1(self.field));
 475                         if (s != self.field)
 476                         {
 477                                 strunzone(self.field);
 478                                 self.field = strzone(s);
 479                         }
 480                 }
 481 }
 482 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 483 {
 484         if (f < 0)
 485         {
 486         }
 487         else if (f > 0)
 488         {
 489                 if (thisname == name)
 490                         self.field = stof(argv(f + 1));
 491         }
 492         else
 493                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 494 }
 495 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 496 {
 497         if (f < 0)
 498         {
 499         }
 500         else if (f > 0)
 501         {
 502                 if (thisname == name)
 503                 {
 504                         if(!self.field)
 505                         {
 506                                 self.field = stof(argv(f + 1));
 507                                 if(!self.field)
 508                                         self.field = -1;
 509                         }
 510                 }
 511         }
 512         else
 513         {
 514                 if(!self.field)
 515                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 516         }
 517 }
 518 float w_getbestweapon(entity e);
 519 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 520 {
 521         string o;
 522         o = W_FixWeaponOrder_ForceComplete(wo);
 523         if(self.weaponorder_byimpulse)
 524         {
 525                 strunzone(self.weaponorder_byimpulse);
 526                 self.weaponorder_byimpulse = string_null;
 527         }
 528         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 529         return o;
 530 }
 531 void GetCvars(float f)
 532 {
 533         string s = string_null;
 534
 535         if (f > 0)
 536                 s = strcat1(argv(f));
 537
 538         get_cvars_f = f;
 539         get_cvars_s = s;
 540
 541         MUTATOR_CALLHOOK(GetCvars);
 542
 543         Notification_GetCvars();
 544
 545         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 546         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 547         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 548         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 549         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 556         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 557         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 558         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 559         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 560         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 561         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 562         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 563         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 564         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 565         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 566         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 567         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 568
 569         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 570         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 571
 572         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 573         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 574         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 575         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 576         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 577
 578         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 579         if (f > 0)
 580         {
 581                 if (s == "cl_weaponpriority")
 582                         self.switchweapon = w_getbestweapon(self);
 583                 if (s == "cl_allow_uidtracking")
 584                         PlayerStats_AddPlayer(self);
 585         }
 586 }
 587
 588 // decolorizes and team colors the player name when needed
 589 string playername(entity p)
 590 {
 591     string t;
 592     if (teamplay && !intermission_running && p.classname == "player")
 593     {
 594         t = Team_ColorCode(p.team);
 595         return strcat(t, strdecolorize(p.netname));
 596     }
 597     else
 598         return p.netname;
 599 }
 600
 601 vector randompos(vector m1, vector m2)
 602 {
 603     vector v;
 604     m2 = m2 - m1;
 605     v_x = m2_x * random() + m1_x;
 606     v_y = m2_y * random() + m1_y;
 607     v_z = m2_z * random() + m1_z;
 608     return  v;
 609 }
 610
 611 //#NO AUTOCVARS START
 612
 613 float g_pickup_shells;
 614 float g_pickup_shells_max;
 615 float g_pickup_nails;
 616 float g_pickup_nails_max;
 617 float g_pickup_rockets;
 618 float g_pickup_rockets_max;
 619 float g_pickup_cells;
 620 float g_pickup_cells_max;
 621 float g_pickup_fuel;
 622 float g_pickup_fuel_jetpack;
 623 float g_pickup_fuel_max;
 624 float g_pickup_armorsmall;
 625 float g_pickup_armorsmall_max;
 626 float g_pickup_armorsmall_anyway;
 627 float g_pickup_armormedium;
 628 float g_pickup_armormedium_max;
 629 float g_pickup_armormedium_anyway;
 630 float g_pickup_armorbig;
 631 float g_pickup_armorbig_max;
 632 float g_pickup_armorbig_anyway;
 633 float g_pickup_armorlarge;
 634 float g_pickup_armorlarge_max;
 635 float g_pickup_armorlarge_anyway;
 636 float g_pickup_healthsmall;
 637 float g_pickup_healthsmall_max;
 638 float g_pickup_healthsmall_anyway;
 639 float g_pickup_healthmedium;
 640 float g_pickup_healthmedium_max;
 641 float g_pickup_healthmedium_anyway;
 642 float g_pickup_healthlarge;
 643 float g_pickup_healthlarge_max;
 644 float g_pickup_healthlarge_anyway;
 645 float g_pickup_healthmega;
 646 float g_pickup_healthmega_max;
 647 float g_pickup_healthmega_anyway;
 648 float g_pickup_ammo_anyway;
 649 float g_pickup_weapons_anyway;
 650 float g_weaponarena;
 651 WEPSET_DECLARE_A(g_weaponarena_weapons);
 652 float g_weaponarena_random;
 653 float g_weaponarena_random_with_laser;
 654 string g_weaponarena_list;
 655 float g_weaponspeedfactor;
 656 float g_weaponratefactor;
 657 float g_weapondamagefactor;
 658 float g_weaponforcefactor;
 659 float g_weaponspreadfactor;
 660
 661 WEPSET_DECLARE_A(start_weapons);
 662 WEPSET_DECLARE_A(start_weapons_default);
 663 WEPSET_DECLARE_A(start_weapons_defaultmask);
 664 float start_items;
 665 float start_ammo_shells;
 666 float start_ammo_nails;
 667 float start_ammo_rockets;
 668 float start_ammo_cells;
 669 float start_ammo_fuel;
 670 float start_health;
 671 float start_armorvalue;
 672 WEPSET_DECLARE_A(warmup_start_weapons);
 673 WEPSET_DECLARE_A(warmup_start_weapons_default);
 674 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 675 float warmup_start_ammo_shells;
 676 float warmup_start_ammo_nails;
 677 float warmup_start_ammo_rockets;
 678 float warmup_start_ammo_cells;
 679 float warmup_start_ammo_fuel;
 680 float warmup_start_health;
 681 float warmup_start_armorvalue;
 682 float g_weapon_stay;
 683
 684 entity get_weaponinfo(float w);
 685
 686 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 687 {
 688         var float i = weaponinfo.weapon;
 689         var float d = 0;
 690
 691         if (!i)
 692                 return 0;
 693
 694         if (g_lms || g_ca || allguns)
 695         {
 696                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 697                         d = TRUE;
 698                 else
 699                         d = FALSE;
 700         }
 701         else if (g_cts)
 702                 d = (i == WEP_SHOTGUN);
 703         else if (g_nexball)
 704                 d = 0; // weapon is set a few lines later
 705         else
 706                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 707
 708         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 709                 d |= (i == WEP_HOOK);
 710         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 711                 d = 0;
 712
 713         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 714
 715         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 716
 717         // bit order in t:
 718         // 1: want or not
 719         // 2: is default?
 720         // 4: is set by default?
 721         if(t < 0)
 722                 t = 4 | (3 * d);
 723         else
 724                 t |= (2 * d);
 725
 726         return t;
 727 }
 728
 729 void readplayerstartcvars()
 730 {
 731         entity e;
 732         float i, j, t;
 733         string s;
 734
 735         // initialize starting values for players
 736         WEPSET_CLEAR_A(start_weapons);
 737         WEPSET_CLEAR_A(start_weapons_default);
 738         WEPSET_CLEAR_A(start_weapons_defaultmask);
 739         start_items = 0;
 740         start_ammo_shells = 0;
 741         start_ammo_nails = 0;
 742         start_ammo_rockets = 0;
 743         start_ammo_cells = 0;
 744         start_health = cvar("g_balance_health_start");
 745         start_armorvalue = cvar("g_balance_armor_start");
 746
 747         g_weaponarena = 0;
 748         WEPSET_CLEAR_A(g_weaponarena_weapons);
 749
 750         s = cvar_string("g_weaponarena");
 751         if (s == "0" || s == "")
 752         {
 753                 if(g_lms || g_ca)
 754                         s = "most";
 755         }
 756
 757         if (s == "0" || s == "")
 758         {
 759                 // no arena
 760         }
 761         else if (s == "off")
 762         {
 763                 // forcibly turn off weaponarena
 764         }
 765         else if (s == "all")
 766         {
 767                 g_weaponarena = 1;
 768                 g_weaponarena_list = "All Weapons";
 769                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 770                 {
 771                         e = get_weaponinfo(j);
 772                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 773                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 774                 }
 775         }
 776         else if (s == "most")
 777         {
 778                 g_weaponarena = 1;
 779                 g_weaponarena_list = "Most Weapons";
 780                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 781                 {
 782                         e = get_weaponinfo(j);
 783                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 784                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 785                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 786                 }
 787         }
 788         else if (s == "none")
 789         {
 790                 g_weaponarena = 1;
 791                 g_weaponarena_list = "No Weapons";
 792         }
 793         else
 794         {
 795                 g_weaponarena = 1;
 796                 t = tokenize_console(s);
 797                 g_weaponarena_list = "";
 798                 for (i = 0; i < t; ++i)
 799                 {
 800                         s = argv(i);
 801                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 802                         {
 803                                 e = get_weaponinfo(j);
 804                                 if (e.netname == s)
 805                                 {
 806                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 807                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 808                                         break;
 809                                 }
 810                         }
 811                         if (j > WEP_LAST)
 812                         {
 813                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 814                         }
 815                 }
 816                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 817         }
 818
 819         if(g_weaponarena)
 820                 g_weaponarena_random = cvar("g_weaponarena_random");
 821         else
 822                 g_weaponarena_random = 0;
 823         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 824
 825         if (g_weaponarena)
 826         {
 827                 g_minstagib = 0; // incompatible
 828                 g_pinata = 0; // incompatible
 829                 g_weapon_stay = 0; // incompatible
 830                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 831                 if(!(g_lms || g_ca))
 832                         start_items |= IT_UNLIMITED_AMMO;
 833         }
 834         else if (g_minstagib)
 835         {
 836                 g_pinata = 0; // incompatible
 837                 g_weapon_stay = 0; // incompatible
 838                 g_bloodloss = 0; // incompatible
 839                 start_health = 100;
 840                 start_armorvalue = 0;
 841                 WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
 842                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 843                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 844
 845                 if (g_minstagib_invis_alpha <= 0)
 846                         g_minstagib_invis_alpha = -1;
 847         }
 848         else
 849         {
 850                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 851                 {
 852                         e = get_weaponinfo(i);
 853                         float w = want_weapon("g_start_weapon_", e, FALSE);
 854                         if(w & 1)
 855                                 WEPSET_OR_AW(start_weapons, i);
 856                         if(w & 2)
 857                                 WEPSET_OR_AW(start_weapons_default, i);
 858                         if(w & 4)
 859                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 860                 }
 861         }
 862
 863         if(!cvar("g_use_ammunition"))
 864                 start_items |= IT_UNLIMITED_AMMO;
 865
 866         if(cvar("g_nexball"))
 867                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 868
 869         if(g_minstagib)
 870         {
 871                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 872                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 873         }
 874         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 875         {
 876                 start_ammo_rockets = 999;
 877                 start_ammo_shells = 999;
 878                 start_ammo_cells = 999;
 879                 start_ammo_nails = 999;
 880                 start_ammo_fuel = 999;
 881         }
 882         else
 883         {
 884                 if(g_lms || g_ca)
 885                 {
 886                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 887                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 888                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 889                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 890                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 891                 }
 892                 else
 893                 {
 894                         start_ammo_shells = cvar("g_start_ammo_shells");
 895                         start_ammo_nails = cvar("g_start_ammo_nails");
 896                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 897                         start_ammo_cells = cvar("g_start_ammo_cells");
 898                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 899                 }
 900         }
 901
 902         if (g_lms || g_ca)
 903         {
 904                 start_health = cvar("g_lms_start_health");
 905                 start_armorvalue = cvar("g_lms_start_armor");
 906         }
 907
 908         if (inWarmupStage)
 909         {
 910                 warmup_start_ammo_shells = start_ammo_shells;
 911                 warmup_start_ammo_nails = start_ammo_nails;
 912                 warmup_start_ammo_rockets = start_ammo_rockets;
 913                 warmup_start_ammo_cells = start_ammo_cells;
 914                 warmup_start_ammo_fuel = start_ammo_fuel;
 915                 warmup_start_health = start_health;
 916                 warmup_start_armorvalue = start_armorvalue;
 917                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 918                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
 919                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
 920
 921                 if (!g_weaponarena && !g_minstagib && !g_ca)
 922                 {
 923                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 924                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 925                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 926                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 927                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 928                         warmup_start_health = cvar("g_warmup_start_health");
 929                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 930                         WEPSET_CLEAR_A(warmup_start_weapons);
 931                         WEPSET_CLEAR_A(warmup_start_weapons_default);
 932                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
 933                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 934                         {
 935                                 e = get_weaponinfo(i);
 936                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
 937                                 if(w & 1)
 938                                         WEPSET_OR_AW(warmup_start_weapons, i);
 939                                 if(w & 2)
 940                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
 941                                 if(w & 4)
 942                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
 943                         }
 944                 }
 945         }
 946
 947         if (g_jetpack)
 948                 start_items |= IT_JETPACK;
 949
 950         MUTATOR_CALLHOOK(SetStartItems);
 951
 952         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
 953         {
 954                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 955                 start_items |= IT_FUEL_REGEN;
 956                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 957                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 958         }
 959
 960         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 961         {
 962                 e = get_weaponinfo(i);
 963                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
 964                         weapon_action(i, WR_PRECACHE);
 965         }
 966
 967         start_ammo_shells = max(0, start_ammo_shells);
 968         start_ammo_nails = max(0, start_ammo_nails);
 969         start_ammo_cells = max(0, start_ammo_cells);
 970         start_ammo_rockets = max(0, start_ammo_rockets);
 971         start_ammo_fuel = max(0, start_ammo_fuel);
 972
 973         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 974         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 975         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 976         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 977         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 978 }
 979
 980 float g_bugrigs;
 981 float g_bugrigs_planar_movement;
 982 float g_bugrigs_planar_movement_car_jumping;
 983 float g_bugrigs_reverse_spinning;
 984 float g_bugrigs_reverse_speeding;
 985 float g_bugrigs_reverse_stopping;
 986 float g_bugrigs_air_steering;
 987 float g_bugrigs_angle_smoothing;
 988 float g_bugrigs_friction_floor;
 989 float g_bugrigs_friction_brake;
 990 float g_bugrigs_friction_air;
 991 float g_bugrigs_accel;
 992 float g_bugrigs_speed_ref;
 993 float g_bugrigs_speed_pow;
 994 float g_bugrigs_steer;
 995
 996 float sv_autotaunt;
 997 float sv_taunt;
 998
 999 string GetGametype(); // g_world.qc
1000 void readlevelcvars(void)
1001 {
1002         g_minstagib = cvar("g_minstagib");
1003
1004         // load ALL the mutators
1005         if(cvar("g_dodging"))
1006                 MUTATOR_ADD(mutator_dodging);
1007         if(cvar("g_spawn_near_teammate"))
1008                 MUTATOR_ADD(mutator_spawn_near_teammate);
1009         if(cvar("g_physical_items"))
1010                 MUTATOR_ADD(mutator_physical_items);
1011         if(cvar("g_touchexplode"))
1012                 MUTATOR_ADD(mutator_touchexplode);
1013         if(cvar("g_riflearena"))
1014                 MUTATOR_ADD(mutator_riflearena);
1015         if(!g_minstagib)
1016         {
1017                 if(cvar("g_invincible_projectiles"))
1018                         MUTATOR_ADD(mutator_invincibleprojectiles);
1019                 if(cvar("g_new_toys"))
1020                         MUTATOR_ADD(mutator_new_toys);
1021                 if(cvar("g_nix"))
1022                         MUTATOR_ADD(mutator_nix);
1023                 if(cvar("g_rocket_flying"))
1024                         MUTATOR_ADD(mutator_rocketflying);
1025                 if(cvar("g_vampire"))
1026                         MUTATOR_ADD(mutator_vampire);
1027                 if(cvar("g_superspectate"))
1028                         MUTATOR_ADD(mutator_superspec);
1029         }
1030
1031         // is this a mutator? is this a mode?
1032         if(cvar("g_sandbox"))
1033                 MUTATOR_ADD(sandbox);
1034
1035         if(cvar("sv_allow_fullbright"))
1036                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1037
1038     g_bugrigs = cvar("g_bugrigs");
1039     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1040     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1041     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1042     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1043     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1044     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1045     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1046     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1047     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1048     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1049     g_bugrigs_accel = cvar("g_bugrigs_accel");
1050     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1051     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1052     g_bugrigs_steer = cvar("g_bugrigs_steer");
1053
1054         sv_clones = cvar("sv_clones");
1055         sv_foginterval = cvar("sv_foginterval");
1056         g_cloaked = cvar("g_cloaked");
1057     if(g_cts)
1058         g_cloaked = 1; // always enable cloak in CTS
1059         g_jump_grunt = cvar("g_jump_grunt");
1060         g_footsteps = cvar("g_footsteps");
1061         g_grappling_hook = cvar("g_grappling_hook");
1062         g_jetpack = cvar("g_jetpack");
1063         g_midair = cvar("g_midair");
1064         g_norecoil = cvar("g_norecoil");
1065         g_bloodloss = cvar("g_bloodloss");
1066         sv_maxidle = cvar("sv_maxidle");
1067         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1068         sv_autotaunt = cvar("sv_autotaunt");
1069         sv_taunt = cvar("sv_taunt");
1070
1071         inWarmupStage = cvar("g_warmup");
1072         g_warmup_limit = cvar("g_warmup_limit");
1073         g_warmup_allguns = cvar("g_warmup_allguns");
1074         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1075
1076         if ((g_race && g_race_qualifying == 2) || g_arena || g_assault || cvar("g_campaign"))
1077                 inWarmupStage = 0; // these modes cannot work together, sorry
1078
1079         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1080         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1081         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1082         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1083         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1084         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1085         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1086         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1087         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1088         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1089         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1090         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1091         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1092         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1093
1094         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1095         g_weaponratefactor = cvar("g_weaponratefactor");
1096         g_weapondamagefactor = cvar("g_weapondamagefactor");
1097         g_weaponforcefactor = cvar("g_weaponforcefactor");
1098         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1099
1100         g_pickup_shells = cvar("g_pickup_shells");
1101         g_pickup_shells_max = cvar("g_pickup_shells_max");
1102         g_pickup_nails = cvar("g_pickup_nails");
1103         g_pickup_nails_max = cvar("g_pickup_nails_max");
1104         g_pickup_rockets = cvar("g_pickup_rockets");
1105         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1106         g_pickup_cells = cvar("g_pickup_cells");
1107         g_pickup_cells_max = cvar("g_pickup_cells_max");
1108         g_pickup_fuel = cvar("g_pickup_fuel");
1109         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1110         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1111         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1112         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1113         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1114         g_pickup_armormedium = cvar("g_pickup_armormedium");
1115         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1116         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1117         g_pickup_armorbig = cvar("g_pickup_armorbig");
1118         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1119         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1120         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1121         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1122         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1123         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1124         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1125         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1126         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1127         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1128         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1129         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1130         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1131         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1132         g_pickup_healthmega = cvar("g_pickup_healthmega");
1133         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1134         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1135
1136         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1137         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1138
1139         g_pinata = cvar("g_pinata");
1140
1141     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1142     if(!g_weapon_stay)
1143         g_weapon_stay = cvar("g_weapon_stay");
1144
1145         if not(inWarmupStage && !g_ca)
1146                 game_starttime = cvar("g_start_delay");
1147
1148         readplayerstartcvars();
1149 }
1150
1151 //#NO AUTOCVARS END
1152
1153 // Sound functions
1154 string precache_sound (string s) = #19;
1155 float precache_sound_index (string s) = #19;
1156
1157 #define SND_VOLUME      1
1158 #define SND_ATTENUATION 2
1159 #define SND_LARGEENTITY 8
1160 #define SND_LARGESOUND  16
1161
1162 float sound_allowed(float dest, entity e)
1163 {
1164     // sounds from world may always pass
1165     for (;;)
1166     {
1167         if (e.classname == "body")
1168             e = e.enemy;
1169         else if (e.realowner && e.realowner != e)
1170             e = e.realowner;
1171         else if (e.owner && e.owner != e)
1172             e = e.owner;
1173         else
1174             break;
1175     }
1176     // sounds to self may always pass
1177     if (dest == MSG_ONE)
1178         if (e == msg_entity)
1179             return TRUE;
1180     // sounds by players can be removed
1181     if (autocvar_bot_sound_monopoly)
1182         if (clienttype(e) == CLIENTTYPE_REAL)
1183             return FALSE;
1184     // anything else may pass
1185     return TRUE;
1186 }
1187
1188 #ifdef COMPAT_XON010_CHANNELS
1189 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1190 void sound(entity e, float chan, string samp, float vol, float atten)
1191 {
1192     if (!sound_allowed(MSG_BROADCAST, e))
1193         return;
1194     builtin_sound(e, chan, samp, vol, atten);
1195 }
1196 #else
1197 #undef sound
1198 void sound(entity e, float chan, string samp, float vol, float atten)
1199 {
1200     if (!sound_allowed(MSG_BROADCAST, e))
1201         return;
1202     sound7(e, chan, samp, vol, atten, 0, 0);
1203 }
1204 #endif
1205
1206 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1207 {
1208     float entno, idx;
1209
1210     if (!sound_allowed(dest, e))
1211         return;
1212
1213     entno = num_for_edict(e);
1214     idx = precache_sound_index(samp);
1215
1216     float sflags;
1217     sflags = 0;
1218
1219     atten = floor(atten * 64);
1220     vol = floor(vol * 255);
1221
1222     if (vol != 255)
1223         sflags |= SND_VOLUME;
1224     if (atten != 64)
1225         sflags |= SND_ATTENUATION;
1226     if (entno >= 8192 || chan < 0 || chan > 7)
1227         sflags |= SND_LARGEENTITY;
1228     if (idx >= 256)
1229         sflags |= SND_LARGESOUND;
1230
1231     WriteByte(dest, SVC_SOUND);
1232     WriteByte(dest, sflags);
1233     if (sflags & SND_VOLUME)
1234         WriteByte(dest, vol);
1235     if (sflags & SND_ATTENUATION)
1236         WriteByte(dest, atten);
1237     if (sflags & SND_LARGEENTITY)
1238     {
1239         WriteShort(dest, entno);
1240         WriteByte(dest, chan);
1241     }
1242     else
1243     {
1244         WriteShort(dest, entno * 8 + chan);
1245     }
1246     if (sflags & SND_LARGESOUND)
1247         WriteShort(dest, idx);
1248     else
1249         WriteByte(dest, idx);
1250
1251     WriteCoord(dest, o_x);
1252     WriteCoord(dest, o_y);
1253     WriteCoord(dest, o_z);
1254 }
1255 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1256 {
1257     vector o;
1258
1259     if (!sound_allowed(dest, e))
1260         return;
1261
1262     o = e.origin + 0.5 * (e.mins + e.maxs);
1263     soundtoat(dest, e, o, chan, samp, vol, atten);
1264 }
1265 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1266 {
1267     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1268 }
1269 void stopsoundto(float dest, entity e, float chan)
1270 {
1271     float entno;
1272
1273     if (!sound_allowed(dest, e))
1274         return;
1275
1276     entno = num_for_edict(e);
1277
1278     if (entno >= 8192 || chan < 0 || chan > 7)
1279     {
1280         float idx, sflags;
1281         idx = precache_sound_index("misc/null.wav");
1282         sflags = SND_LARGEENTITY;
1283         if (idx >= 256)
1284             sflags |= SND_LARGESOUND;
1285         WriteByte(dest, SVC_SOUND);
1286         WriteByte(dest, sflags);
1287         WriteShort(dest, entno);
1288         WriteByte(dest, chan);
1289         if (sflags & SND_LARGESOUND)
1290             WriteShort(dest, idx);
1291         else
1292             WriteByte(dest, idx);
1293         WriteCoord(dest, e.origin_x);
1294         WriteCoord(dest, e.origin_y);
1295         WriteCoord(dest, e.origin_z);
1296     }
1297     else
1298     {
1299         WriteByte(dest, SVC_STOPSOUND);
1300         WriteShort(dest, entno * 8 + chan);
1301     }
1302 }
1303 void stopsound(entity e, float chan)
1304 {
1305     if (!sound_allowed(MSG_BROADCAST, e))
1306         return;
1307
1308     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1309     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1310 }
1311
1312 void play2(entity e, string filename)
1313 {
1314     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1315     msg_entity = e;
1316     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1317 }
1318
1319 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1320 .float spamtime;
1321 float spamsound(entity e, float chan, string samp, float vol, float atten)
1322 {
1323     if (!sound_allowed(MSG_BROADCAST, e))
1324         return FALSE;
1325
1326     if (time > e.spamtime)
1327     {
1328         e.spamtime = time;
1329         sound(e, chan, samp, vol, atten);
1330         return TRUE;
1331     }
1332     return FALSE;
1333 }
1334
1335 void play2team(float t, string filename)
1336 {
1337     entity head;
1338
1339     if (autocvar_bot_sound_monopoly)
1340         return;
1341
1342     FOR_EACH_REALPLAYER(head)
1343     {
1344         if (head.team == t)
1345             play2(head, filename);
1346     }
1347 }
1348
1349 void play2all(string samp)
1350 {
1351     if (autocvar_bot_sound_monopoly)
1352         return;
1353
1354     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1355 }
1356
1357 void PrecachePlayerSounds(string f);
1358 void precache_playermodel(string m)
1359 {
1360         float globhandle, i, n;
1361         string f;
1362
1363         if(substring(m, -9,5) == "_lod1")
1364                 return;
1365         if(substring(m, -9,5) == "_lod2")
1366                 return;
1367         precache_model(m);
1368         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1369         if(fexists(f))
1370                 precache_model(f);
1371         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1372         if(fexists(f))
1373                 precache_model(f);
1374
1375         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1376         if (globhandle < 0)
1377                 return;
1378         n = search_getsize(globhandle);
1379         for (i = 0; i < n; ++i)
1380         {
1381                 //print(search_getfilename(globhandle, i), "\n");
1382                 f = search_getfilename(globhandle, i);
1383                 PrecachePlayerSounds(f);
1384         }
1385         search_end(globhandle);
1386 }
1387 void precache_all_playermodels(string pattern)
1388 {
1389         float globhandle, i, n;
1390         string f;
1391
1392         globhandle = search_begin(pattern, TRUE, FALSE);
1393         if (globhandle < 0)
1394                 return;
1395         n = search_getsize(globhandle);
1396         for (i = 0; i < n; ++i)
1397         {
1398                 //print(search_getfilename(globhandle, i), "\n");
1399                 f = search_getfilename(globhandle, i);
1400                 precache_playermodel(f);
1401         }
1402         search_end(globhandle);
1403 }
1404
1405 void precache()
1406 {
1407     // gamemode related things
1408     precache_model ("models/misc/chatbubble.spr");
1409
1410 #ifdef TTURRETS_ENABLED
1411     if (autocvar_g_turrets)
1412         turrets_precash();
1413 #endif
1414
1415     // Precache all player models if desired
1416     if (autocvar_sv_precacheplayermodels)
1417     {
1418         PrecachePlayerSounds("sound/player/default.sounds");
1419         precache_all_playermodels("models/player/*.zym");
1420         precache_all_playermodels("models/player/*.dpm");
1421         precache_all_playermodels("models/player/*.md3");
1422         precache_all_playermodels("models/player/*.psk");
1423         precache_all_playermodels("models/player/*.iqm");
1424     }
1425
1426     if (autocvar_sv_defaultcharacter)
1427     {
1428         string s;
1429         s = autocvar_sv_defaultplayermodel_red;
1430         if (s != "")
1431             precache_playermodel(s);
1432         s = autocvar_sv_defaultplayermodel_blue;
1433         if (s != "")
1434             precache_playermodel(s);
1435         s = autocvar_sv_defaultplayermodel_yellow;
1436         if (s != "")
1437             precache_playermodel(s);
1438         s = autocvar_sv_defaultplayermodel_pink;
1439         if (s != "")
1440             precache_playermodel(s);
1441         s = autocvar_sv_defaultplayermodel;
1442         if (s != "")
1443             precache_playermodel(s);
1444     }
1445
1446     if (g_footsteps)
1447     {
1448         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1449         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1450     }
1451
1452     // gore and miscellaneous sounds
1453     //precache_sound ("misc/h2ohit.wav");
1454     precache_model ("models/hook.md3");
1455     precache_sound ("misc/armorimpact.wav");
1456     precache_sound ("misc/bodyimpact1.wav");
1457     precache_sound ("misc/bodyimpact2.wav");
1458     precache_sound ("misc/gib.wav");
1459     precache_sound ("misc/gib_splat01.wav");
1460     precache_sound ("misc/gib_splat02.wav");
1461     precache_sound ("misc/gib_splat03.wav");
1462     precache_sound ("misc/gib_splat04.wav");
1463     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1464     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1465     precache_sound ("misc/null.wav");
1466     precache_sound ("misc/spawn.wav");
1467     precache_sound ("misc/talk.wav");
1468     precache_sound ("misc/teleport.wav");
1469     precache_sound ("misc/poweroff.wav");
1470     precache_sound ("player/lava.wav");
1471     precache_sound ("player/slime.wav");
1472
1473     precache_model ("models/sprites/0.spr32");
1474     precache_model ("models/sprites/1.spr32");
1475     precache_model ("models/sprites/2.spr32");
1476     precache_model ("models/sprites/3.spr32");
1477     precache_model ("models/sprites/4.spr32");
1478     precache_model ("models/sprites/5.spr32");
1479     precache_model ("models/sprites/6.spr32");
1480     precache_model ("models/sprites/7.spr32");
1481     precache_model ("models/sprites/8.spr32");
1482     precache_model ("models/sprites/9.spr32");
1483     precache_model ("models/sprites/10.spr32");
1484
1485     // common weapon precaches
1486         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1487     precache_sound ("weapons/weapon_switch.wav");
1488     precache_sound ("weapons/weaponpickup.wav");
1489     precache_sound ("weapons/unavailable.wav");
1490     precache_sound ("weapons/dryfire.wav");
1491     if (g_grappling_hook)
1492     {
1493         precache_sound ("weapons/hook_fire.wav"); // hook
1494         precache_sound ("weapons/hook_impact.wav"); // hook
1495     }
1496
1497     if(autocvar_sv_precacheweapons)
1498     {
1499         //precache weapon models/sounds
1500         float wep;
1501         wep = WEP_FIRST;
1502         while (wep <= WEP_LAST)
1503         {
1504             weapon_action(wep, WR_PRECACHE);
1505             wep = wep + 1;
1506         }
1507     }
1508
1509     precache_model("models/elaser.mdl");
1510     precache_model("models/laser.mdl");
1511     precache_model("models/ebomb.mdl");
1512
1513 #if 0
1514     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1515
1516     if (!self.noise && self.music) // quake 3 uses the music field
1517         self.noise = self.music;
1518
1519     // plays music for the level if there is any
1520     if (self.noise)
1521     {
1522         precache_sound (self.noise);
1523         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1524     }
1525 #endif
1526 }
1527
1528 // WARNING: this kills the trace globals
1529 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1530 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1531
1532 #define INITPRIO_FIRST              0
1533 #define INITPRIO_GAMETYPE           0
1534 #define INITPRIO_GAMETYPE_FALLBACK  1
1535 #define INITPRIO_FINDTARGET        10
1536 #define INITPRIO_DROPTOFLOOR       20
1537 #define INITPRIO_SETLOCATION       90
1538 #define INITPRIO_LINKDOORS         91
1539 #define INITPRIO_LAST              99
1540
1541 .void(void) initialize_entity;
1542 .float initialize_entity_order;
1543 .entity initialize_entity_next;
1544 entity initialize_entity_first;
1545
1546 void make_safe_for_remove(entity e)
1547 {
1548     if (e.initialize_entity)
1549     {
1550         entity ent, prev = world;
1551         for (ent = initialize_entity_first; ent; )
1552         {
1553             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1554             {
1555                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1556                 // skip it in linked list
1557                 if (prev)
1558                 {
1559                     prev.initialize_entity_next = ent.initialize_entity_next;
1560                     ent = prev.initialize_entity_next;
1561                 }
1562                 else
1563                 {
1564                     initialize_entity_first = ent.initialize_entity_next;
1565                     ent = initialize_entity_first;
1566                 }
1567             }
1568             else
1569             {
1570                 prev = ent;
1571                 ent = ent.initialize_entity_next;
1572             }
1573         }
1574     }
1575 }
1576
1577 void objerror(string s)
1578 {
1579     make_safe_for_remove(self);
1580     builtin_objerror(s);
1581 }
1582
1583 .float remove_except_protected_forbidden;
1584 void remove_except_protected(entity e)
1585 {
1586         if(e.remove_except_protected_forbidden)
1587                 error("not allowed to remove this at this point");
1588         builtin_remove(e);
1589 }
1590
1591 void remove_unsafely(entity e)
1592 {
1593     if(e.classname == "spike")
1594         error("Removing spikes is forbidden (crylink bug), please report");
1595     builtin_remove(e);
1596 }
1597
1598 void remove_safely(entity e)
1599 {
1600     make_safe_for_remove(e);
1601     builtin_remove(e);
1602 }
1603
1604 void InitializeEntity(entity e, void(void) func, float order)
1605 {
1606     entity prev, cur;
1607
1608     if (!e || e.initialize_entity)
1609     {
1610         // make a proxy initializer entity
1611         entity e_old;
1612         e_old = e;
1613         e = spawn();
1614         e.classname = "initialize_entity";
1615         e.enemy = e_old;
1616     }
1617
1618     e.initialize_entity = func;
1619     e.initialize_entity_order = order;
1620
1621     cur = initialize_entity_first;
1622     prev = world;
1623     for (;;)
1624     {
1625         if (!cur || cur.initialize_entity_order > order)
1626         {
1627             // insert between prev and cur
1628             if (prev)
1629                 prev.initialize_entity_next = e;
1630             else
1631                 initialize_entity_first = e;
1632             e.initialize_entity_next = cur;
1633             return;
1634         }
1635         prev = cur;
1636         cur = cur.initialize_entity_next;
1637     }
1638 }
1639 void InitializeEntitiesRun()
1640 {
1641     entity startoflist;
1642     startoflist = initialize_entity_first;
1643     initialize_entity_first = world;
1644     remove = remove_except_protected;
1645     for (self = startoflist; self; self = self.initialize_entity_next)
1646     {
1647         self.remove_except_protected_forbidden = 1;
1648     }
1649     for (self = startoflist; self; )
1650     {
1651         entity e;
1652         var void(void) func;
1653         e = self.initialize_entity_next;
1654         func = self.initialize_entity;
1655         self.initialize_entity_order = 0;
1656         self.initialize_entity = func_null;
1657         self.initialize_entity_next = world;
1658         self.remove_except_protected_forbidden = 0;
1659         if (self.classname == "initialize_entity")
1660         {
1661             entity e_old;
1662             e_old = self.enemy;
1663             builtin_remove(self);
1664             self = e_old;
1665         }
1666         //dprint("Delayed initialization: ", self.classname, "\n");
1667         if(func)
1668             func();
1669         else
1670         {
1671             eprint(self);
1672             backtrace(strcat("Null function in: ", self.classname, "\n"));
1673         }
1674         self = e;
1675     }
1676     remove = remove_unsafely;
1677 }
1678
1679 .float uncustomizeentityforclient_set;
1680 .void(void) uncustomizeentityforclient;
1681 void UncustomizeEntitiesRun()
1682 {
1683     entity oldself;
1684     oldself = self;
1685     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1686         self.uncustomizeentityforclient();
1687     self = oldself;
1688 }
1689 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1690 {
1691     e.customizeentityforclient = customizer;
1692     e.uncustomizeentityforclient = uncustomizer;
1693     e.uncustomizeentityforclient_set = !!uncustomizer;
1694 }
1695
1696 .float nottargeted;
1697 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1698
1699 void() SUB_Remove;
1700 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1701 {
1702     vector mi, ma;
1703
1704     if (e.classname == "")
1705         e.classname = "net_linked";
1706
1707     if (e.model == "" || self.modelindex == 0)
1708     {
1709         mi = e.mins;
1710         ma = e.maxs;
1711         setmodel(e, "null");
1712         setsize(e, mi, ma);
1713     }
1714
1715     e.SendEntity = sendfunc;
1716     e.SendFlags = 0xFFFFFF;
1717
1718     if (!docull)
1719         e.effects |= EF_NODEPTHTEST;
1720
1721     if (dt)
1722     {
1723         e.nextthink = time + dt;
1724         e.think = SUB_Remove;
1725     }
1726 }
1727
1728 void adaptor_think2touch()
1729 {
1730     entity o;
1731     o = other;
1732     other = world;
1733     self.touch();
1734     other = o;
1735 }
1736
1737 void adaptor_think2use()
1738 {
1739     entity o, a;
1740     o = other;
1741     a = activator;
1742     activator = world;
1743     other = world;
1744     self.use();
1745     other = o;
1746     activator = a;
1747 }
1748
1749 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1750 {
1751         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1752                 self.projectiledeathtype |= HITTYPE_SPLASH;
1753         adaptor_think2use();
1754 }
1755
1756 // deferred dropping
1757 void DropToFloor_Handler()
1758 {
1759     builtin_droptofloor();
1760     self.dropped_origin = self.origin;
1761 }
1762
1763 void droptofloor()
1764 {
1765     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1766 }
1767
1768
1769
1770 float trace_hits_box_a0, trace_hits_box_a1;
1771
1772 float trace_hits_box_1d(float end, float thmi, float thma)
1773 {
1774     if (end == 0)
1775     {
1776         // just check if x is in range
1777         if (0 < thmi)
1778             return FALSE;
1779         if (0 > thma)
1780             return FALSE;
1781     }
1782     else
1783     {
1784         // do the trace with respect to x
1785         // 0 -> end has to stay in thmi -> thma
1786         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1787         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1788         if (trace_hits_box_a0 > trace_hits_box_a1)
1789             return FALSE;
1790     }
1791     return TRUE;
1792 }
1793
1794 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1795 {
1796     end -= start;
1797     thmi -= start;
1798     thma -= start;
1799     // now it is a trace from 0 to end
1800
1801     trace_hits_box_a0 = 0;
1802     trace_hits_box_a1 = 1;
1803
1804     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1805         return FALSE;
1806     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1807         return FALSE;
1808     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1809         return FALSE;
1810
1811     return TRUE;
1812 }
1813
1814 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1815 {
1816     return trace_hits_box(start, end, thmi - ma, thma - mi);
1817 }
1818
1819 float SUB_NoImpactCheck()
1820 {
1821         // zero hitcontents = this is not the real impact, but either the
1822         // mirror-impact of something hitting the projectile instead of the
1823         // projectile hitting the something, or a touchareagrid one. Neither of
1824         // these stop the projectile from moving, so...
1825         if(trace_dphitcontents == 0)
1826         {
1827                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1828                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1829                 checkclient();
1830         }
1831     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1832         return 1;
1833     if (other == world && self.size != '0 0 0')
1834     {
1835         vector tic;
1836         tic = self.velocity * sys_frametime;
1837         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1838         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1839         if (trace_fraction >= 1)
1840         {
1841             dprint("Odd... did not hit...?\n");
1842         }
1843         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1844         {
1845             dprint("Detected and prevented the sky-grapple bug.\n");
1846             return 1;
1847         }
1848     }
1849
1850     return 0;
1851 }
1852
1853 #define SUB_OwnerCheck() (other && (other == self.owner))
1854
1855 void RemoveGrapplingHook(entity pl);
1856 void W_Crylink_Dequeue(entity e);
1857 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1858 {
1859         if(SUB_OwnerCheck())
1860                 return TRUE;
1861         if(SUB_NoImpactCheck())
1862         {
1863                 if(self.classname == "grapplinghook")
1864                         RemoveGrapplingHook(self.realowner);
1865                 else if(self.classname == "spike")
1866                 {
1867                         W_Crylink_Dequeue(self);
1868                         remove(self);
1869                 }
1870                 else
1871                         remove(self);
1872                 return TRUE;
1873         }
1874         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1875                 UpdateCSQCProjectile(self);
1876         return FALSE;
1877 }
1878 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1879
1880 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1881 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1882
1883 void URI_Get_Callback(float id, float status, string data)
1884 {
1885         if(url_URI_Get_Callback(id, status, data))
1886         {
1887                 // handled
1888         }
1889         else if (id == URI_GET_DISCARD)
1890         {
1891                 // discard
1892         }
1893         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1894         {
1895                 // sv_cmd curl
1896                 Curl_URI_Get_Callback(id, status, data);
1897         }
1898         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1899         {
1900                 // online ban list
1901                 OnlineBanList_URI_Get_Callback(id, status, data);
1902         }
1903         else
1904         {
1905                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1906         }
1907 }
1908
1909 string uid2name(string myuid) {
1910         string s;
1911         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1912
1913         // FIXME remove this later after 0.6 release
1914         // convert old style broken records to correct style
1915         if(s == "")
1916         {
1917                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1918                 if(s != "")
1919                 {
1920                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1921                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1922                 }
1923         }
1924
1925         if(s == "")
1926                 s = "^1Unregistered Player";
1927         return s;
1928 }
1929
1930 float race_readTime(string map, float pos)
1931 {
1932         string rr;
1933         if(g_cts)
1934                 rr = CTS_RECORD;
1935         else
1936                 rr = RACE_RECORD;
1937
1938         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1939 }
1940
1941 string race_readUID(string map, float pos)
1942 {
1943         string rr;
1944         if(g_cts)
1945                 rr = CTS_RECORD;
1946         else
1947                 rr = RACE_RECORD;
1948
1949         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1950 }
1951
1952 float race_readPos(string map, float t) {
1953         float i;
1954         for (i = 1; i <= RANKINGS_CNT; ++i)
1955                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1956                         return i;
1957
1958         return 0; // pos is zero if unranked
1959 }
1960
1961 void race_writeTime(string map, float t, string myuid)
1962 {
1963         string rr;
1964         if(g_cts)
1965                 rr = CTS_RECORD;
1966         else
1967                 rr = RACE_RECORD;
1968
1969         float newpos;
1970         newpos = race_readPos(map, t);
1971
1972         float i, prevpos = 0;
1973         for(i = 1; i <= RANKINGS_CNT; ++i)
1974         {
1975                 if(race_readUID(map, i) == myuid)
1976                         prevpos = i;
1977         }
1978         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1979                 for (i = prevpos; i > newpos; --i) {
1980                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1981                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1982                 }
1983         } else { // player has no ranked record yet
1984                 for (i = RANKINGS_CNT; i > newpos; --i) {
1985                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1986                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1987                 }
1988         }
1989
1990         // store new time itself
1991         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1992         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1993 }
1994
1995 string race_readName(string map, float pos)
1996 {
1997         string rr;
1998         if(g_cts)
1999                 rr = CTS_RECORD;
2000         else
2001                 rr = RACE_RECORD;
2002
2003         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2004 }
2005
2006 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2007 {
2008     float m, i;
2009     vector start, org, delta, end, enddown, mstart;
2010     entity sp;
2011
2012     m = e.dphitcontentsmask;
2013     e.dphitcontentsmask = goodcontents | badcontents;
2014
2015     org = world.mins;
2016     delta = world.maxs - world.mins;
2017
2018     start = end = org;
2019
2020     for (i = 0; i < attempts; ++i)
2021     {
2022         start_x = org_x + random() * delta_x;
2023         start_y = org_y + random() * delta_y;
2024         start_z = org_z + random() * delta_z;
2025
2026         // rule 1: start inside world bounds, and outside
2027         // solid, and don't start from somewhere where you can
2028         // fall down to evil
2029         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2030         if (trace_fraction >= 1)
2031             continue;
2032         if (trace_startsolid)
2033             continue;
2034         if (trace_dphitcontents & badcontents)
2035             continue;
2036         if (trace_dphitq3surfaceflags & badsurfaceflags)
2037             continue;
2038
2039         // rule 2: if we are too high, lower the point
2040         if (trace_fraction * delta_z > maxaboveground)
2041             start = trace_endpos + '0 0 1' * maxaboveground;
2042         enddown = trace_endpos;
2043
2044         // rule 3: make sure we aren't outside the map. This only works
2045         // for somewhat well formed maps. A good rule of thumb is that
2046         // the map should have a convex outside hull.
2047         // these can be traceLINES as we already verified the starting box
2048         mstart = start + 0.5 * (e.mins + e.maxs);
2049         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2050         if (trace_fraction >= 1)
2051             continue;
2052         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2053         if (trace_fraction >= 1)
2054             continue;
2055         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2056         if (trace_fraction >= 1)
2057             continue;
2058         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2059         if (trace_fraction >= 1)
2060             continue;
2061         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2062         if (trace_fraction >= 1)
2063             continue;
2064
2065         // rule 4: we must "see" some spawnpoint
2066         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2067                 if(checkpvs(mstart, sp))
2068                         break;
2069         if(!sp)
2070         {
2071                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2072                         if(checkpvs(mstart, sp))
2073                                 break;
2074                 if(!sp)
2075                         continue;
2076         }
2077
2078         // find a random vector to "look at"
2079         end_x = org_x + random() * delta_x;
2080         end_y = org_y + random() * delta_y;
2081         end_z = org_z + random() * delta_z;
2082         end = start + normalize(end - start) * vlen(delta);
2083
2084         // rule 4: start TO end must not be too short
2085         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2086         if (trace_startsolid)
2087             continue;
2088         if (trace_fraction < minviewdistance / vlen(delta))
2089             continue;
2090
2091         // rule 5: don't want to look at sky
2092         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2093             continue;
2094
2095         // rule 6: we must not end up in trigger_hurt
2096         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2097             continue;
2098
2099         break;
2100     }
2101
2102     e.dphitcontentsmask = m;
2103
2104     if (i < attempts)
2105     {
2106         setorigin(e, start);
2107         e.angles = vectoangles(end - start);
2108         dprint("Needed ", ftos(i + 1), " attempts\n");
2109         return TRUE;
2110     }
2111     else
2112         return FALSE;
2113 }
2114
2115 float zcurveparticles_effectno;
2116 vector zcurveparticles_start;
2117 float zcurveparticles_spd;
2118
2119 void endzcurveparticles()
2120 {
2121         if(zcurveparticles_effectno)
2122         {
2123                 // terminator
2124                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2125         }
2126         zcurveparticles_effectno = 0;
2127 }
2128
2129 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2130 {
2131         spd = bound(0, floor(spd / 16), 32767);
2132         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2133         {
2134                 endzcurveparticles();
2135                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2136                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2137                 WriteShort(MSG_BROADCAST, effectno);
2138                 WriteCoord(MSG_BROADCAST, start_x);
2139                 WriteCoord(MSG_BROADCAST, start_y);
2140                 WriteCoord(MSG_BROADCAST, start_z);
2141                 zcurveparticles_effectno = effectno;
2142                 zcurveparticles_start = start;
2143         }
2144         else
2145                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2146         WriteCoord(MSG_BROADCAST, end_x);
2147         WriteCoord(MSG_BROADCAST, end_y);
2148         WriteCoord(MSG_BROADCAST, end_z);
2149         WriteCoord(MSG_BROADCAST, end_dz);
2150         zcurveparticles_spd = spd;
2151 }
2152
2153 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2154 {
2155         float end_dz;
2156         vector vecxy, velxy;
2157
2158         vecxy = end - start;
2159         vecxy_z = 0;
2160         velxy = vel;
2161         velxy_z = 0;
2162
2163         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2164         {
2165                 endzcurveparticles();
2166                 trailparticles(world, effectno, start, end);
2167                 return;
2168         }
2169
2170         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2171         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2172 }
2173
2174 void write_recordmarker(entity pl, float tstart, float dt)
2175 {
2176     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2177
2178     // also write a marker into demo files for demotc-race-record-extractor to find
2179     stuffcmd(pl,
2180              strcat(
2181                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2182                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2183 }
2184
2185 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2186 {
2187         switch(algn)
2188         {
2189                 default:
2190                 case 3: // right
2191                         break;
2192
2193                 case 4: // left
2194                         vecs_y = -vecs_y;
2195                         break;
2196
2197                 case 1:
2198                         if(allowcenter) // 2: allow center handedness
2199                         {
2200                                 // center
2201                                 vecs_y = 0;
2202                                 vecs_z -= 2;
2203                         }
2204                         else
2205                         {
2206                                 // right
2207                         }
2208                         break;
2209
2210                 case 2:
2211                         if(allowcenter) // 2: allow center handedness
2212                         {
2213                                 // center
2214                                 vecs_y = 0;
2215                                 vecs_z -= 2;
2216                         }
2217                         else
2218                         {
2219                                 // left
2220                                 vecs_y = -vecs_y;
2221                         }
2222                         break;
2223         }
2224         return vecs;
2225 }
2226
2227 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2228 {
2229         string s;
2230         vector v;
2231
2232         if (autocvar_g_shootfromeye)
2233         {
2234                 if (visual)
2235                 {
2236                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2237                         else { vecs_y = 0; vecs_z -= 2; }
2238                 }
2239                 else
2240                 {
2241                         vecs_y = 0;
2242                         vecs_z = 0;
2243                 }
2244         }
2245         else if (autocvar_g_shootfromcenter)
2246         {
2247                 vecs_y = 0;
2248                 vecs_z -= 2;
2249         }
2250         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2251         {
2252                 v = stov(s);
2253                 if (y_is_right)
2254                         v_y = -v_y;
2255                 if (v_x != 0)
2256                         vecs_x = v_x;
2257                 vecs_y = v_y;
2258                 vecs_z = v_z;
2259         }
2260         else if (autocvar_g_shootfromclient)
2261         {
2262                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2263         }
2264         return vecs;
2265 }
2266
2267 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2268 {
2269         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2270 }
2271
2272
2273 void attach_sameorigin(entity e, entity to, string tag)
2274 {
2275     vector org, t_forward, t_left, t_up, e_forward, e_up;
2276     float tagscale;
2277
2278     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2279     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2280     t_forward = v_forward * tagscale;
2281     t_left = v_right * -tagscale;
2282     t_up = v_up * tagscale;
2283
2284     e.origin_x = org * t_forward;
2285     e.origin_y = org * t_left;
2286     e.origin_z = org * t_up;
2287
2288     // current forward and up directions
2289     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2290                 e.angles = AnglesTransform_FromVAngles(e.angles);
2291         else
2292                 e.angles = AnglesTransform_FromAngles(e.angles);
2293     fixedmakevectors(e.angles);
2294
2295     // untransform forward, up!
2296     e_forward_x = v_forward * t_forward;
2297     e_forward_y = v_forward * t_left;
2298     e_forward_z = v_forward * t_up;
2299     e_up_x = v_up * t_forward;
2300     e_up_y = v_up * t_left;
2301     e_up_z = v_up * t_up;
2302
2303     e.angles = fixedvectoangles2(e_forward, e_up);
2304     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2305                 e.angles = AnglesTransform_ToVAngles(e.angles);
2306         else
2307                 e.angles = AnglesTransform_ToAngles(e.angles);
2308
2309     setattachment(e, to, tag);
2310     setorigin(e, e.origin);
2311 }
2312
2313 void detach_sameorigin(entity e)
2314 {
2315     vector org;
2316     org = gettaginfo(e, 0);
2317     e.angles = fixedvectoangles2(v_forward, v_up);
2318     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2319                 e.angles = AnglesTransform_ToVAngles(e.angles);
2320         else
2321                 e.angles = AnglesTransform_ToAngles(e.angles);
2322     setorigin(e, org);
2323     setattachment(e, world, "");
2324     setorigin(e, e.origin);
2325 }
2326
2327 void follow_sameorigin(entity e, entity to)
2328 {
2329     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2330     e.aiment = to; // make the hole follow bmodel
2331     e.punchangle = to.angles; // the original angles of bmodel
2332     e.view_ofs = e.origin - to.origin; // relative origin
2333     e.v_angle = e.angles - to.angles; // relative angles
2334 }
2335
2336 void unfollow_sameorigin(entity e)
2337 {
2338     e.movetype = MOVETYPE_NONE;
2339 }
2340
2341 entity gettaginfo_relative_ent;
2342 vector gettaginfo_relative(entity e, float tag)
2343 {
2344     if (!gettaginfo_relative_ent)
2345     {
2346         gettaginfo_relative_ent = spawn();
2347         gettaginfo_relative_ent.effects = EF_NODRAW;
2348     }
2349     gettaginfo_relative_ent.model = e.model;
2350     gettaginfo_relative_ent.modelindex = e.modelindex;
2351     gettaginfo_relative_ent.frame = e.frame;
2352     return gettaginfo(gettaginfo_relative_ent, tag);
2353 }
2354
2355 .float scale2;
2356
2357 float modeleffect_SendEntity(entity to, float sf)
2358 {
2359         float f;
2360         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2361
2362         f = 0;
2363         if(self.velocity != '0 0 0')
2364                 f |= 1;
2365         if(self.angles != '0 0 0')
2366                 f |= 2;
2367         if(self.avelocity != '0 0 0')
2368                 f |= 4;
2369
2370         WriteByte(MSG_ENTITY, f);
2371         WriteShort(MSG_ENTITY, self.modelindex);
2372         WriteByte(MSG_ENTITY, self.skin);
2373         WriteByte(MSG_ENTITY, self.frame);
2374         WriteCoord(MSG_ENTITY, self.origin_x);
2375         WriteCoord(MSG_ENTITY, self.origin_y);
2376         WriteCoord(MSG_ENTITY, self.origin_z);
2377         if(f & 1)
2378         {
2379                 WriteCoord(MSG_ENTITY, self.velocity_x);
2380                 WriteCoord(MSG_ENTITY, self.velocity_y);
2381                 WriteCoord(MSG_ENTITY, self.velocity_z);
2382         }
2383         if(f & 2)
2384         {
2385                 WriteCoord(MSG_ENTITY, self.angles_x);
2386                 WriteCoord(MSG_ENTITY, self.angles_y);
2387                 WriteCoord(MSG_ENTITY, self.angles_z);
2388         }
2389         if(f & 4)
2390         {
2391                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2392                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2393                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2394         }
2395         WriteShort(MSG_ENTITY, self.scale * 256.0);
2396         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2397         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2398         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2399         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2400
2401         return TRUE;
2402 }
2403
2404 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2405 {
2406         entity e;
2407         float sz;
2408         e = spawn();
2409         e.classname = "modeleffect";
2410         setmodel(e, m);
2411         e.frame = f;
2412         setorigin(e, o);
2413         e.velocity = v;
2414         e.angles = ang;
2415         e.avelocity = angv;
2416         e.alpha = a;
2417         e.teleport_time = t1;
2418         e.fade_time = t2;
2419         e.skin = s;
2420         if(s0 >= 0)
2421                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2422         else
2423                 e.scale = -s0;
2424         if(s2 >= 0)
2425                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2426         else
2427                 e.scale2 = -s2;
2428         sz = max(e.scale, e.scale2);
2429         setsize(e, e.mins * sz, e.maxs * sz);
2430         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2431 }
2432
2433 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2434 {
2435         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2436 }
2437
2438 float randombit(float bits)
2439 {
2440         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2441                 return bits;
2442
2443         float n, f, b, r;
2444
2445         r = random();
2446         b = 0;
2447         n = 0;
2448
2449         for(f = 1; f <= bits; f *= 2)
2450         {
2451                 if(bits & f)
2452                 {
2453                         ++n;
2454                         r *= n;
2455                         if(r <= 1)
2456                                 b = f;
2457                         else
2458                                 r = (r - 1) / (n - 1);
2459                 }
2460         }
2461
2462         return b;
2463 }
2464
2465 float randombits(float bits, float k, float error_return)
2466 {
2467         float r;
2468         r = 0;
2469         while(k > 0 && bits != r)
2470         {
2471                 r += randombit(bits - r);
2472                 --k;
2473         }
2474         if(error_return)
2475                 if(k > 0)
2476                         return -1; // all
2477         return r;
2478 }
2479
2480 void randombit_test(float bits, float iter)
2481 {
2482         while(iter > 0)
2483         {
2484                 print(ftos(randombit(bits)), "\n");
2485                 --iter;
2486         }
2487 }
2488
2489 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2490 {
2491         if(halflifedist > 0)
2492                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2493         else if(halflifedist < 0)
2494                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2495         else
2496                 return 1;
2497 }
2498
2499
2500
2501
2502 #ifdef RELEASE
2503 #define cvar_string_normal builtin_cvar_string
2504 #define cvar_normal builtin_cvar
2505 #else
2506 string cvar_string_normal(string n)
2507 {
2508         if not(cvar_type(n) & 1)
2509                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2510         return builtin_cvar_string(n);
2511 }
2512
2513 float cvar_normal(string n)
2514 {
2515         return stof(cvar_string_normal(n));
2516 }
2517 #endif
2518 #define cvar_set_normal builtin_cvar_set
2519
2520 void defer_think()
2521 {
2522     entity oself;
2523
2524     oself           = self;
2525     self            = self.owner;
2526     oself.think     = SUB_Remove;
2527     oself.nextthink = time;
2528
2529     oself.use();
2530 }
2531
2532 /*
2533     Execute func() after time + fdelay.
2534     self when func is executed = self when defer is called
2535 */
2536 void defer(float fdelay, void() func)
2537 {
2538     entity e;
2539
2540     e           = spawn();
2541     e.owner     = self;
2542     e.use       = func;
2543     e.think     = defer_think;
2544     e.nextthink = time + fdelay;
2545 }
2546
2547 .string aiment_classname;
2548 .float aiment_deadflag;
2549 void SetMovetypeFollow(entity ent, entity e)
2550 {
2551         // FIXME this may not be warpzone aware
2552         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2553         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2554         ent.aiment = e; // make the hole follow bmodel
2555         ent.punchangle = e.angles; // the original angles of bmodel
2556         ent.view_ofs = ent.origin - e.origin; // relative origin
2557         ent.v_angle = ent.angles - e.angles; // relative angles
2558         ent.aiment_classname = strzone(e.classname);
2559         ent.aiment_deadflag = e.deadflag;
2560 }
2561 void UnsetMovetypeFollow(entity ent)
2562 {
2563         ent.movetype = MOVETYPE_FLY;
2564         PROJECTILE_MAKETRIGGER(ent);
2565         ent.aiment = world;
2566 }
2567 float LostMovetypeFollow(entity ent)
2568 {
2569 /*
2570         if(ent.movetype != MOVETYPE_FOLLOW)
2571                 if(ent.aiment)
2572                         error("???");
2573 */
2574         if(ent.aiment)
2575         {
2576                 if(ent.aiment.classname != ent.aiment_classname)
2577                         return 1;
2578                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2579                         return 1;
2580         }
2581         return 0;
2582 }
2583
2584 float isPushable(entity e)
2585 {
2586         if(e.iscreature)
2587                 return TRUE;
2588         if(e.pushable)
2589                 return TRUE;
2590         switch(e.classname)
2591         {
2592                 case "body":
2593                 case "droppedweapon":
2594                 case "keepawayball":
2595                 case "nexball_basketball":
2596                 case "nexball_football":
2597                         return TRUE;
2598                 case "bullet": // antilagged bullets can't hit this either
2599                         return FALSE;
2600         }
2601         if (e.projectiledeathtype)
2602                 return TRUE;
2603         return FALSE;
2604 }