qcsrc/server/monsters/lib/monsters.qc

   1 // TODO: clean up this file?
   2
   3 void M_Item_Touch ()
   4 {
   5         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   6         {
   7                 Item_Touch();
   8                 self.think = SUB_Remove;
   9                 self.nextthink = time + 0.1;
  10         }
  11 }
  12
  13 void monster_item_spawn()
  14 {
  15         self.monster_delayedattack();
  16
  17         self.think = monster_item_spawn;
  18         self.nextthink = time + 0.1;
  19         self.gravity = 1;
  20         self.velocity = randomvec() * 175 + '0 0 325';
  21         self.touch = M_Item_Touch;
  22
  23         SUB_SetFade(self, time + 5, 1);
  24 }
  25
  26 void Monster_DropItem (string itype, string itemsize)
  27 {
  28         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  29         entity e = spawn();
  30
  31         setorigin(e, org);
  32
  33         switch(itype)
  34         {
  35                 case "armor":
  36                 {
  37                         switch(itemsize)
  38                         {
  39                                 case "mega": e.monster_delayedattack = spawnfunc_item_armor_large; break;
  40                                 case "large": e.monster_delayedattack = spawnfunc_item_armor_big; break;
  41                                 case "medium": e.monster_delayedattack = spawnfunc_item_armor_medium; break;
  42                                 case "small": e.monster_delayedattack = spawnfunc_item_armor_small; break;
  43                                 default: break;
  44                         }
  45                         break; // break here?
  46                 }
  47                 case "health":
  48                 {
  49                         switch(itemsize)
  50                         {
  51                                 case "mega": e.monster_delayedattack = spawnfunc_item_health_mega; break;
  52                                 case "large": e.monster_delayedattack = spawnfunc_item_health_large; break;
  53                                 case "medium": e.monster_delayedattack = spawnfunc_item_health_medium; break;
  54                                 case "small": e.monster_delayedattack = spawnfunc_item_health_small; break;
  55                                 default: break;
  56                         }
  57                         break; // break here?
  58                 }
  59                 case "ammo":
  60                 {
  61                         switch(itemsize)
  62                         {
  63                                 case "shells": e.monster_delayedattack = spawnfunc_item_shells; break;
  64                                 case "cells": e.monster_delayedattack = spawnfunc_item_cells; break;
  65                                 case "rockets": e.monster_delayedattack = spawnfunc_item_rockets; break;
  66                                 case "bullets":
  67                                 case "nails": e.monster_delayedattack = spawnfunc_item_bullets; break;
  68                                 default: break;
  69                         }
  70                         break;
  71                 }
  72                 default: break;
  73         }
  74
  75         if(g_minstagib)
  76                 e.monster_delayedattack = spawnfunc_item_minst_cells;
  77
  78         e.think = monster_item_spawn;
  79         e.nextthink = time + 0.1;
  80 }
  81
  82 void monsters_setframe(float _frame)
  83 {
  84         if(self.frame == _frame)
  85                 return;
  86
  87         self.anim_start_time = time;
  88         self.frame = _frame;
  89         self.SendFlags |= MSF_ANIM;
  90 }
  91
  92 float monster_isvalidtarget (entity targ, entity ent)
  93 {
  94         if(!targ || !ent)
  95                 return FALSE; // this check should fix a crash
  96
  97         if(time < game_starttime)
  98                 return FALSE; // monsters do nothing before the match has started
  99
 100         WarpZone_TraceLine(ent.origin, targ.origin, MOVE_NORMAL, ent);
 101
 102         if(vlen(targ.origin - ent.origin) >= ent.target_range)
 103                 return FALSE; // enemy is too far away
 104
 105         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 106         if(trace_ent != targ)
 107                 return FALSE; // we can't see the enemy
 108
 109         if(targ.takedamage == DAMAGE_NO)
 110                 return FALSE; // enemy can't be damaged
 111
 112         if(targ.items & IT_INVISIBILITY)
 113                 return FALSE; // enemy is invisible
 114
 115         if(IS_SPEC(targ) || IS_OBSERVER(targ))
 116                 return FALSE; // enemy is a spectator
 117
 118         if not(targ.vehicle_flags & VHF_ISVEHICLE) // vehicles dont count as alive?
 119         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
 120                 return FALSE; // enemy/self is dead
 121
 122         if(targ.monster_owner == ent || ent.monster_owner == targ)
 123                 return FALSE; // enemy owns us, or we own them
 124
 125         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 126         if(targ.flags & FL_NOTARGET)
 127                 return FALSE; // enemy can't be targetted
 128
 129         if not(autocvar_g_monsters_typefrag)
 130         if(targ.BUTTON_CHAT)
 131                 return FALSE; // no typefragging!
 132
 133         if not(IsDifferentTeam(targ, ent))
 134                 return FALSE; // enemy is on our team
 135
 136         return TRUE;
 137 }
 138
 139 entity FindTarget (entity ent)
 140 {
 141         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 142         entity e;
 143
 144         for(e = world; (e = findflags(e, monster_attack, TRUE)); )
 145         if(monster_isvalidtarget(e, ent))
 146                 return e;
 147
 148         return world;
 149 }
 150
 151 void MonsterTouch ()
 152 {
 153         if(other == world)
 154                 return;
 155
 156         if(self.enemy != other)
 157         if not(other.flags & FL_MONSTER)
 158         if(monster_isvalidtarget(other, self))
 159                 self.enemy = other;
 160 }
 161
 162 void monster_sound(string msound, float sound_delay, float delaytoo)
 163 {
 164         if(delaytoo && time < self.msound_delay)
 165                 return; // too early
 166
 167         if(msound == "")
 168                 return; // sound doesn't exist
 169
 170         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTN_NORM);
 171
 172         self.msound_delay = time + sound_delay;
 173 }
 174
 175 void monster_precachesounds(entity e)
 176 {
 177         precache_sound(e.msound_idle);
 178         precache_sound(e.msound_death);
 179         precache_sound(e.msound_attack_melee);
 180         precache_sound(e.msound_attack_ranged);
 181         precache_sound(e.msound_sight);
 182         precache_sound(e.msound_pain);
 183 }
 184
 185 void monster_melee (entity targ, float damg, float er, float deathtype, float dostop)
 186 {
 187         float bigdmg, dot, rdmg = damg * random();
 188
 189         if (self.health <= 0)
 190                 return;
 191         if (targ == world)
 192                 return;
 193
 194         if(dostop)
 195         {
 196                 self.velocity_x = 0;
 197                 self.velocity_y = 0;
 198                 self.state = MONSTER_STATE_ATTACK_MELEE;
 199                 self.SendFlags |= MSF_MOVE;
 200         }
 201
 202         makevectors (self.angles);
 203         dot = normalize (targ.origin - self.origin) * v_forward;
 204
 205         bigdmg = rdmg * self.scale;
 206
 207         if(dot > er)
 208                 Damage(targ, self, self, bigdmg * monster_skill, deathtype, targ.origin, normalize(targ.origin - self.origin));
 209 }
 210
 211 void Monster_CheckDropCvars (string mon)
 212 {
 213         if not(self.candrop)
 214                 return; // forced off
 215
 216         string dropitem;
 217         string dropsize;
 218
 219         dropitem = cvar_string(strcat("g_monster_", mon, "_drop"));
 220         dropsize = cvar_string(strcat("g_monster_", mon, "_drop_size"));
 221
 222         monster_dropitem = dropitem;
 223         monster_dropsize = dropsize;
 224         MUTATOR_CALLHOOK(MonsterDropItem);
 225         dropitem = monster_dropitem;
 226         dropsize = monster_dropsize;
 227
 228         if(autocvar_g_monsters_forcedrop)
 229                 Monster_DropItem(autocvar_g_monsters_drop_type, autocvar_g_monsters_drop_size);
 230         else if(dropitem != "")
 231                 Monster_DropItem(dropitem, dropsize);
 232         else
 233                 Monster_DropItem("armor", "medium");
 234 }
 235
 236 void ScaleMonster (float scle, vector min_s, vector max_s)
 237 {
 238         // this should prevent monster from falling through floor when scale changes
 239         self.scale = scle;
 240         setsize(self, min_s * scle, max_s * scle);
 241         setorigin(self, self.origin + ('0 0 30' * scle));
 242         self.SendFlags |= MSF_SIZE | MSF_MOVE;
 243 }
 244
 245 void Monster_CheckMinibossFlag ()
 246 {
 247         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 248                 return;
 249
 250         if(self.spawnflags & MONSTERFLAG_GIANT)
 251                 return; // 1 size modifier at a time
 252
 253         float r = random() * 4, chance = random() * 100;
 254
 255         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 256         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 257         {
 258                 self.health += autocvar_g_monsters_miniboss_healthboost;
 259                 ScaleMonster(1.5, self.mins, self.maxs);
 260                 self.flags |= MONSTERFLAG_MINIBOSS;
 261                 if not(self.weapon)
 262                         self.weapon = WEP_NEX;
 263
 264                 if (r < 2 || self.team == NUM_TEAM_2)
 265                 {
 266                         self.strength_finished = -1;
 267                         self.effects |= (EF_FULLBRIGHT | EF_BLUE);
 268                 }
 269                 else if (r >= 1 || self.team == NUM_TEAM_1)
 270                 {
 271                         self.invincible_finished = -1;
 272                         self.effects |= (EF_FULLBRIGHT | EF_RED);
 273                 }
 274                 else
 275                         self.effects |= (EF_FULLBRIGHT | EF_RED | EF_BLUE);
 276
 277                 if not(self.team)
 278                         self.colormod = randomvec();
 279         }
 280 }
 281
 282 float Monster_CanRespawn(entity ent)
 283 {
 284         other = ent;
 285         if(MUTATOR_CALLHOOK(MonsterRespawn))
 286                 return TRUE; // enabled by a mutator
 287
 288         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 289                 return FALSE;
 290
 291         if not(autocvar_g_monsters_respawn)
 292                 return FALSE;
 293
 294         return TRUE;
 295 }
 296
 297 void Monster_Fade ()
 298 {
 299         if(Monster_CanRespawn(self))
 300         {
 301                 self.monster_respawned = TRUE;
 302                 self.netname = ""; // needed to fix sprite (TODO: fix!)
 303                 self.think = self.monster_spawnfunc;
 304                 self.nextthink = time + self.respawntime;
 305                 if(self.respawnflags & MONSTER_RESPAWN_DEATHPOINT)
 306                 {
 307                         self.pos1 = self.origin;
 308                         self.pos2 = self.angles;
 309                 }
 310                 setorigin(self, self.pos1);
 311                 self.angles = self.pos2;
 312                 self.health = self.max_health; // TODO: check if resetting to max_health is wise here
 313                 return;
 314         }
 315         self.think = SUB_Remove;
 316         self.nextthink = time + 4;
 317         SUB_SetFade(self, time + 3, 1);
 318 }
 319
 320 float Monster_CanJump (vector vel)
 321 {
 322         if(self.state)
 323                 return FALSE; // already attacking
 324         if not(self.flags & FL_ONGROUND)
 325                 return FALSE; // not on the ground
 326         if(self.health <= 0)
 327                 return FALSE; // called when dead?
 328         if(time < self.attack_finished_single)
 329                 return FALSE; // still attacking
 330
 331         vector old = self.velocity;
 332
 333         self.velocity = vel;
 334         tracetoss(self, self);
 335         self.velocity = old;
 336         if (trace_ent != self.enemy)
 337                 return FALSE;
 338
 339         return TRUE;
 340 }
 341
 342 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 343 {
 344         if(!Monster_CanJump(vel))
 345                 return FALSE;
 346
 347         monsters_setframe(anm);
 348         self.state = MONSTER_STATE_ATTACK_LEAP;
 349         self.touch = touchfunc;
 350         self.origin_z += 1;
 351         self.velocity = vel;
 352         self.flags &~= FL_ONGROUND;
 353
 354         self.attack_finished_single = time + anim_finished;
 355
 356         return TRUE;
 357 }
 358
 359 float GenericCheckAttack ()
 360 {
 361         // checking attack while dead?
 362         if (self.health <= 0 || self.enemy == world)
 363                 return FALSE;
 364
 365         if(self.monster_delayedattack && self.delay != -1)
 366         {
 367                 if(time < self.delay)
 368                         return FALSE;
 369
 370                 self.monster_delayedattack();
 371         }
 372
 373         if (time < self.attack_finished_single)
 374                 return FALSE;
 375
 376         if(self.attack_melee)
 377         if(vlen(self.enemy.origin - self.origin) <= 100 * self.scale)
 378         {
 379                 monster_sound(self.msound_attack_melee, 0, FALSE); // no delay for attack sounds
 380                 self.attack_melee(); // don't wait for nextthink - too slow
 381                 return TRUE;
 382         }
 383
 384         // monster doesn't have a ranged attack function, so stop here
 385         if not(self.attack_ranged)
 386                 return FALSE;
 387
 388         // see if any entities are in the way of the shot
 389         if not(findtrajectorywithleading(self.origin, '0 0 0', '0 0 0', self.enemy, 800, 0, 2.5, 0, self))
 390                 return FALSE;
 391
 392         if(self.attack_ranged())
 393         {
 394                 monster_sound(self.msound_attack_ranged, 0, FALSE); // no delay for attack sounds
 395                 return TRUE;
 396         }
 397
 398         return FALSE;
 399 }
 400
 401 void monster_use ()
 402 {
 403         if (self.enemy)
 404                 return;
 405         if (self.health <= 0)
 406                 return;
 407
 408         if(!monster_isvalidtarget(activator, self))
 409                 return;
 410
 411         self.enemy = activator;
 412 }
 413
 414 float trace_path(vector from, vector to)
 415 {
 416         vector dir = normalize(to - from) * 15, offset = '0 0 0';
 417         float trace1 = trace_fraction;
 418
 419         offset_x = dir_y;
 420         offset_y = -dir_x;
 421         traceline (from+offset, to+offset, TRUE, self);
 422
 423         traceline(from-offset, to-offset, TRUE, self);
 424
 425         return ((trace1 < trace_fraction) ? trace1 : trace_fraction);
 426 }
 427
 428 .float last_trace;
 429 vector monster_pickmovetarget(entity targ)
 430 {
 431         // enemy is always preferred target
 432         if(self.enemy)
 433         {
 434                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 435                 self.last_trace = time + 0.1;
 436                 return self.enemy.origin;
 437         }
 438         if(targ)
 439         {
 440                 self.monster_movestate = MONSTER_MOVE_WANDER;
 441                 self.last_trace = time + 0.5;
 442                 return targ.origin;
 443         }
 444
 445         switch(self.monster_moveflags)
 446         {
 447                 case MONSTER_MOVE_OWNER:
 448                 {
 449                         self.monster_movestate = MONSTER_MOVE_OWNER;
 450                         self.last_trace = time + 0.3;
 451                         if(self.monster_owner && self.monster_owner.classname != "monster_swarm")
 452                                 return self.monster_owner.origin;
 453                 }
 454                 case MONSTER_MOVE_WANDER:
 455                 {
 456                         self.monster_movestate = MONSTER_MOVE_WANDER;
 457                         self.last_trace = time + 2;
 458
 459                         self.angles_y = random() * 500;
 460                         makevectors(self.angles);
 461                         return self.origin + v_forward * 600;
 462                 }
 463                 case MONSTER_MOVE_SPAWNLOC:
 464                 {
 465                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 466                         self.last_trace = time + 2;
 467                         return self.pos1;
 468                 }
 469                 default:
 470                 case MONSTER_MOVE_NOMOVE:
 471                 {
 472                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 473                         self.last_trace = time + 2;
 474                         return self.origin;
 475                 }
 476         }
 477 }
 478
 479 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 480 {
 481         if(self.target)
 482                 self.goalentity = find(world, targetname, self.target);
 483
 484         entity targ;
 485
 486         if(self.frozen)
 487         {
 488                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 489                 self.health = max(1, self.max_health * self.revive_progress);
 490
 491                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 492
 493                 movelib_beak_simple(stopspeed);
 494
 495                 self.velocity = '0 0 0';
 496                 self.enemy = world;
 497                 self.nextthink = time + 0.1;
 498
 499                 if(self.revive_progress >= 1)
 500                         Unfreeze(self); // wait for next think before attacking
 501
 502                 return; // no moving while frozen
 503         }
 504
 505         if(self.flags & FL_SWIM)
 506         {
 507                 if(self.waterlevel < WATERLEVEL_WETFEET)
 508                 {
 509                         if(time >= self.last_trace)
 510                         {
 511                                 self.last_trace = time + 0.4;
 512
 513                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 514                                 self.angles = '90 90 0';
 515                                 if(random() < 0.5)
 516                                 {
 517                                         self.velocity_y += random() * 50;
 518                                         self.velocity_x -= random() * 50;
 519                                 }
 520                                 else
 521                                 {
 522                                         self.velocity_y -= random() * 50;
 523                                         self.velocity_x += random() * 50;
 524                                 }
 525                                 self.velocity_z += random() * 150;
 526                         }
 527
 528
 529                         self.movetype = MOVETYPE_BOUNCE;
 530                         //self.velocity_z = -200;
 531
 532                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 533
 534                         return;
 535                 }
 536                 else
 537                 {
 538                         self.angles = '0 0 0';
 539                         self.movetype = MOVETYPE_WALK;
 540                 }
 541         }
 542
 543         if(gameover || time < game_starttime)
 544         {
 545                 runspeed = walkspeed = 0;
 546                 monsters_setframe(manim_idle);
 547                 movelib_beak_simple(stopspeed);
 548                 return;
 549         }
 550
 551         targ = self.goalentity;
 552
 553         monster_target = targ;
 554         monster_speed_run = runspeed;
 555         monster_speed_walk = walkspeed;
 556         MUTATOR_CALLHOOK(MonsterMove);
 557         targ = monster_target;
 558         runspeed = monster_speed_run;
 559         walkspeed = monster_speed_walk;
 560
 561         if(IsDifferentTeam(self.monster_owner, self))
 562                 self.monster_owner = world;
 563
 564         if not(monster_isvalidtarget(self.enemy, self))
 565                 self.enemy = world; // check enemy each think frame?
 566
 567         if not(self.enemy)
 568         {
 569                 self.enemy = FindTarget(self);
 570                 if(self.enemy)
 571                         monster_sound(self.msound_sight, 0, FALSE);
 572         }
 573
 574         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 575                 self.state = 0;
 576
 577         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 578         if(time >= self.last_trace || self.enemy) // update enemy instantly
 579                 self.moveto = monster_pickmovetarget(targ);
 580
 581         if not(self.enemy)
 582                 monster_sound(self.msound_idle, 5, TRUE);
 583
 584         vector angles_face = vectoangles(self.moveto - self.origin);
 585         vector owner_face = vectoangles(self.monster_owner.origin - self.origin);
 586         vector enemy_face = vectoangles(self.enemy.origin - self.origin);
 587
 588         if(self.state != MONSTER_STATE_ATTACK_LEAP)
 589         {
 590                 self.angles_y = angles_face_y;
 591                 self.v_angle = self.angles;
 592         }
 593
 594         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 595         {
 596                 self.state = 0;
 597                 self.touch = MonsterTouch;
 598         }
 599
 600         v_forward = normalize(self.moveto - self.origin);
 601
 602         float l = vlen(self.moveto - self.origin);
 603         float t1 = trace_path(self.origin+'0 0 10', self.moveto+'0 0 10');
 604         float t2 = trace_path(self.origin-'0 0 15', self.moveto-'0 0 15');
 605
 606         if(t1*l-t2*l>50 && (t1*l > 100 || t1 > 0.8))
 607         if(self.flags & FL_ONGROUND)
 608                 movelib_jump_simple(100);
 609
 610         if(vlen(self.origin - self.moveto) > 64 * self.scale)
 611         {
 612                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 613                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 614                 else
 615                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 616                 if(time > self.pain_finished)
 617                 if(time > self.attack_finished_single)
 618                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 619         }
 620         else
 621         {
 622                 movelib_beak_simple(stopspeed);
 623                 if(time > self.attack_finished_single)
 624                 if(time > self.pain_finished)
 625                 if (vlen(self.velocity) <= 30)
 626                 {
 627                         monsters_setframe(manim_idle);
 628                         if(self.enemy)
 629                                 self.angles_y = enemy_face_y;
 630                         else
 631                                 self.angles_y = ((self.monster_owner) ? owner_face_y : self.pos2_y); // reset looking angle now?
 632                 }
 633         }
 634
 635         if(self.enemy && self.checkattack)
 636                 self.checkattack();
 637
 638         self.SendFlags |= MSF_ANG;
 639         self.SendFlags |= MSF_MOVE;
 640 }
 641
 642 void monsters_setstatus()
 643 {
 644         self.stat_monsters_total = monsters_total;
 645         self.stat_monsters_killed = monsters_killed;
 646 }
 647
 648 void Monster_Appear()
 649 {
 650         self.enemy = activator;
 651         self.spawnflags &~= MONSTERFLAG_APPEAR;
 652         self.monster_spawnfunc();
 653 }
 654
 655 float Monster_CheckAppearFlags(entity ent)
 656 {
 657         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 658                 return FALSE;
 659
 660         ent.think = func_null;
 661         ent.nextthink = -1;
 662         ent.use = Monster_Appear;
 663         ent.flags = FL_MONSTER; // set so this monster can get butchered
 664
 665         return TRUE;
 666 }
 667
 668 void monsters_reset()
 669 {
 670         setorigin(self, self.pos1);
 671         self.angles = self.pos2;
 672
 673         self.health = self.max_health;
 674         self.velocity = '0 0 0';
 675         self.enemy = world;
 676         self.goalentity = world;
 677         self.attack_finished_single = 0;
 678         self.moveto = self.origin;
 679
 680         WaypointSprite_UpdateHealth(self.sprite, self.health);
 681 }
 682
 683 float monster_send(entity to, float sf)
 684 {
 685         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 686         WriteByte(MSG_ENTITY, sf);
 687         if(sf & MSF_SETUP)
 688         {
 689             WriteByte(MSG_ENTITY, self.monsterid);
 690
 691             WriteCoord(MSG_ENTITY, self.origin_x);
 692             WriteCoord(MSG_ENTITY, self.origin_y);
 693             WriteCoord(MSG_ENTITY, self.origin_z);
 694
 695             WriteAngle(MSG_ENTITY, self.angles_x);
 696             WriteAngle(MSG_ENTITY, self.angles_y);
 697
 698                 WriteByte(MSG_ENTITY, self.scale);
 699                 WriteByte(MSG_ENTITY, self.skin);
 700     }
 701
 702         if(sf & MSF_SIZE)
 703         {
 704                 WriteByte(MSG_ENTITY, self.scale);
 705
 706                 WriteCoord(MSG_ENTITY, self.mins_x);
 707             WriteCoord(MSG_ENTITY, self.mins_y);
 708             WriteCoord(MSG_ENTITY, self.mins_z);
 709
 710                 WriteCoord(MSG_ENTITY, self.maxs_x);
 711             WriteCoord(MSG_ENTITY, self.maxs_y);
 712             WriteCoord(MSG_ENTITY, self.maxs_z);
 713         }
 714
 715     if(sf & MSF_ANG)
 716     {
 717         WriteShort(MSG_ENTITY, rint(self.angles_x));
 718         WriteShort(MSG_ENTITY, rint(self.angles_y));
 719     }
 720
 721     if(sf & MSF_MOVE)
 722     {
 723         WriteShort(MSG_ENTITY, rint(self.origin_x));
 724         WriteShort(MSG_ENTITY, rint(self.origin_y));
 725         WriteShort(MSG_ENTITY, rint(self.origin_z));
 726
 727         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 728         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 729         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 730
 731         WriteShort(MSG_ENTITY, rint(self.angles_y));
 732     }
 733
 734     if(sf & MSF_ANIM)
 735     {
 736         WriteCoord(MSG_ENTITY, self.anim_start_time);
 737         WriteByte(MSG_ENTITY, self.frame);
 738     }
 739
 740     if(sf & MSF_STATUS)
 741     {
 742                 WriteByte(MSG_ENTITY, self.skin);
 743
 744         WriteByte(MSG_ENTITY, self.team);
 745
 746         if(self.health <= 0)
 747             WriteByte(MSG_ENTITY, 0);
 748         else
 749             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 750     }
 751
 752         return TRUE;
 753 }
 754
 755 void monster_link(void() spawnproc)
 756 {
 757     Net_LinkEntity(self, TRUE, 0, monster_send);
 758     self.think      = spawnproc;
 759     self.nextthink  = time;
 760 }
 761
 762 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 763 {
 764         self.health -= damage;
 765
 766         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 767
 768         if(self.health <= -100) // 100 health until gone?
 769         {
 770                 Violence_GibSplash(self, 1, 0.5, attacker);
 771
 772                 self.think = SUB_Remove;
 773                 self.nextthink = time + 0.1;
 774         }
 775 }
 776
 777 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 778 {
 779         if(self.frozen && deathtype != DEATH_KILL)
 780                 return;
 781
 782         if(time < self.pain_finished && deathtype != DEATH_KILL)
 783                 return;
 784
 785         if((ignore_turrets && !(attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET)) || !ignore_turrets)
 786         if(monster_isvalidtarget(attacker, self))
 787                 self.enemy = attacker;
 788
 789         if(deathtype != DEATH_KILL)
 790                 damage *= self.armorvalue;
 791
 792         self.health -= damage;
 793
 794         if(self.sprite)
 795                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 796
 797         self.dmg_time = time;
 798
 799         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 800                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 801
 802         self.velocity += force * self.damageforcescale;
 803
 804         if(deathtype != DEATH_DROWN)
 805         {
 806                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 807                 if (damage > 50)
 808                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 809                 if (damage > 100)
 810                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 811         }
 812
 813         if(self.health <= 0)
 814         {
 815                 if(self.sprite)
 816                 {
 817                         // Update one more time to avoid waypoint fading without emptying healthbar
 818                         WaypointSprite_UpdateHealth(self.sprite, 0);
 819                 }
 820
 821                 if(deathtype == DEATH_KILL)
 822                         self.candrop = FALSE; // killed by mobkill command
 823
 824                 activator = attacker;
 825                 other = self.enemy;
 826                 self.target = self.target2;
 827                 self.target2 = "";
 828                 SUB_UseTargets();
 829
 830                 self.monster_die();
 831
 832                 frag_attacker = attacker;
 833                 frag_target = self;
 834                 MUTATOR_CALLHOOK(MonsterDies);
 835
 836                 self.SendFlags |= MSF_MOVE;
 837
 838                 if(self.health <= -100) // check if we're already gibbed
 839                 {
 840                         Violence_GibSplash(self, 1, 0.5, attacker);
 841
 842                         self.think = SUB_Remove;
 843                         self.nextthink = time + 0.1;
 844                 }
 845         }
 846
 847         self.SendFlags |= MSF_STATUS;
 848 }
 849
 850 // used to hook into monster post death functions without a mutator
 851 void monster_hook_death()
 852 {
 853         WaypointSprite_Kill(self.sprite);
 854
 855         if(self.weaponentity)
 856         {
 857                 remove(self.weaponentity);
 858                 self.weaponentity = world;
 859         }
 860
 861         monster_sound(self.msound_death, 0, FALSE);
 862
 863         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 864                 monsters_killed += 1;
 865
 866         if(self.candrop && self.weapon)
 867                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 868
 869         if(IS_CLIENT(self.realowner))
 870                 self.realowner.monstercount -= 1;
 871
 872         self.event_damage       = monsters_corpse_damage;
 873         self.solid                      = SOLID_CORPSE;
 874         self.takedamage         = DAMAGE_AIM;
 875         self.enemy                      = world;
 876         self.movetype           = MOVETYPE_TOSS;
 877
 878         totalspawned -= 1;
 879 }
 880
 881 // used to hook into monster post spawn functions without a mutator
 882 void monster_hook_spawn()
 883 {
 884         if not(self.monster_respawned)
 885                 Monster_CheckMinibossFlag();
 886
 887         self.max_health = self.health;
 888         self.pain_finished = self.nextthink;
 889         self.anim_start_time = time;
 890
 891         monster_precachesounds(self);
 892
 893         if(self.team)
 894         {
 895                 //self.colormod = Team_ColorRGB(self.team);
 896                 //self.glowmod = self.colormod;
 897                 self.colormap = 1024 + (self.team - 1) * 17;
 898                 self.colormod = '1 1 1';
 899                 self.glowmod = Team_ColorRGB(self.team);
 900                 self.monster_attack = TRUE;
 901         }
 902         else
 903                 self.colormod = self.glowmod = '1 1 1';
 904
 905         // TODO: fix this...
 906         if (self.target)
 907         {
 908                 self.target2 = self.target;
 909                 self.goalentity = find(world, targetname, self.target);
 910         }
 911
 912         self.sprite_height *= self.scale; // do this after setting the monster's scale
 913
 914         if(autocvar_g_monsters_healthbars)
 915         {
 916                 WaypointSprite_Spawn(self.message, 0, 600, self, '0 0 1' * self.sprite_height, world, 0, self, sprite, FALSE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 917                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 918                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 919         }
 920
 921         self.message = self.oldmessage;
 922
 923         monster_sound(self.msound_spawn, 0, FALSE);
 924
 925         MUTATOR_CALLHOOK(MonsterSpawn);
 926
 927         self.SendFlags = MSF_SETUP;
 928 }
 929
 930 float monster_initialize(string  net_name, float mon_id,
 931                                                  vector  min_s,
 932                                                  vector  max_s,
 933                                                  float   nodrop,
 934                                                  void() dieproc,
 935                                                  void() spawnproc)
 936 {
 937         if not(autocvar_g_monsters)
 938                 return FALSE;
 939
 940         // support for quake style removing monsters based on skill
 941         if(monster_skill <= autocvar_g_monsters_skill_easy && (self.spawnflags & MONSTERSKILL_NOTEASY)) { return FALSE; }
 942         if(monster_skill == autocvar_g_monsters_skill_normal && (self.spawnflags & MONSTERSKILL_NOTMEDIUM)) { return FALSE; }
 943         if(monster_skill == autocvar_g_monsters_skill_hard && (self.spawnflags & MONSTERSKILL_NOTHARD)) { return FALSE; }
 944         if(monster_skill == autocvar_g_monsters_skill_insane && (self.spawnflags & MONSTERSKILL_NOTINSANE)) { return FALSE; }
 945         if(monster_skill >= autocvar_g_monsters_skill_nightmare && (self.spawnflags & MONSTERSKILL_NOTNIGHTMARE)) { return FALSE; }
 946
 947         if(self.netname == "")
 948         {
 949                 if(net_name != "" && IS_PLAYER(self.realowner))
 950                         net_name = strzone(sprintf("%s^7's %s", self.realowner.netname, net_name));
 951                 self.netname = ((net_name == "") ? self.classname : net_name);
 952                 self.oldmessage = self.message;
 953                 self.message = strzone(strdecolorize(self.netname));
 954         }
 955
 956         if(autocvar_g_monsters_giants_only)
 957                 self.spawnflags |= MONSTERFLAG_GIANT;
 958
 959         if not(self.scale)
 960                 self.scale = 1;
 961
 962         if(self.spawnflags & MONSTERFLAG_GIANT && !autocvar_g_monsters_nogiants)
 963                 self.scale = 5;
 964
 965         if(self.team && !teamplay)
 966                 self.team = 0;
 967
 968         self.flags = FL_MONSTER;
 969
 970         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 971         if not(self.monster_respawned)
 972                 monsters_total += 1;
 973
 974         ScaleMonster(self.scale, min_s, max_s);
 975
 976         self.takedamage                 = DAMAGE_AIM;
 977         self.bot_attack                 = TRUE;
 978         self.iscreature                 = TRUE;
 979         self.teleportable               = TRUE;
 980         self.damagedbycontents  = TRUE;
 981         self.monsterid                  = mon_id;
 982         self.damageforcescale   = 0.003;
 983         self.monster_die                = dieproc;
 984         self.event_damage               = monsters_damage;
 985         self.touch                              = MonsterTouch;
 986         self.use                                = monster_use;
 987         self.solid                              = SOLID_BBOX;
 988         self.movetype                   = MOVETYPE_WALK;
 989         self.delay                              = -1; // used in attack delay code
 990         monsters_spawned           += 1;
 991         self.enemy                              = world;
 992         self.velocity                   = '0 0 0';
 993         self.moveto                             = self.origin;
 994         self.pos2                               = self.angles;
 995         self.reset                              = monsters_reset;
 996         self.candrop                    = TRUE;
 997         self.view_ofs                   = '0 0 1' * self.maxs_z;
 998
 999         if not(self.ticrate)
1000                 self.ticrate = autocvar_g_monsters_think_delay;
1001
1002         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1003
1004         if not(self.armorvalue)
1005                 self.armorvalue = 1; // multiplier
1006
1007         if not(self.target_range)
1008                 self.target_range = autocvar_g_monsters_target_range;
1009
1010         if not(self.respawntime)
1011                 self.respawntime = autocvar_g_monsters_respawn_delay;
1012
1013         if not(self.monster_moveflags)
1014                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1015
1016         if(autocvar_g_nodepthtestplayers)
1017                 self.effects |= EF_NODEPTHTEST;
1018
1019         if(autocvar_g_fullbrightplayers)
1020                 self.effects |= EF_FULLBRIGHT;
1021
1022         if not(nodrop)
1023         {
1024                 setorigin(self, self.origin);
1025                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1026                 setorigin(self, trace_endpos);
1027         }
1028
1029         self.pos1 = self.origin;
1030
1031         monster_link(spawnproc);
1032
1033         return TRUE;
1034 }