qcsrc/server/monsters/lib/monsters.qc

   1 // TODO: clean up this file?
   2
   3 void M_Item_Touch ()
   4 {
   5         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   6         {
   7                 Item_Touch();
   8                 self.think = SUB_Remove;
   9                 self.nextthink = time + 0.1;
  10         }
  11 }
  12
  13 void monster_item_spawn()
  14 {
  15         self.monster_delayedattack();
  16
  17         self.think = SUB_Remove;
  18         self.nextthink = time + 5;
  19         self.gravity = 1;
  20         self.velocity = randomvec() * 175 + '0 0 325';
  21         self.touch = M_Item_Touch;
  22
  23         SUB_SetFade(self, time + 5, 1);
  24 }
  25
  26 void Monster_DropItem (string itype, string itemsize)
  27 {
  28         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  29         entity e = spawn();
  30
  31         setorigin(e, org);
  32
  33         switch(itype)
  34         {
  35                 case "armor":
  36                 {
  37                         switch(itemsize)
  38                         {
  39                                 case "mega": e.monster_delayedattack = spawnfunc_item_armor_large; break;
  40                                 case "large": e.monster_delayedattack = spawnfunc_item_armor_big; break;
  41                                 case "medium": e.monster_delayedattack = spawnfunc_item_armor_medium; break;
  42                                 case "small": e.monster_delayedattack = spawnfunc_item_armor_small; break;
  43                         }
  44                         break; // break here?
  45                 }
  46                 case "health":
  47                 {
  48                         switch(itemsize)
  49                         {
  50                                 case "mega": e.monster_delayedattack = spawnfunc_item_health_mega; break;
  51                                 case "large": e.monster_delayedattack = spawnfunc_item_health_large; break;
  52                                 case "medium": e.monster_delayedattack = spawnfunc_item_health_medium; break;
  53                                 case "small": e.monster_delayedattack = spawnfunc_item_health_small; break;
  54                         }
  55                         break; // break here?
  56                 }
  57                 case "ammo":
  58                 {
  59                         switch(itemsize)
  60                         {
  61                                 case "shells": e.monster_delayedattack = spawnfunc_item_shells; break;
  62                                 case "cells": e.monster_delayedattack = spawnfunc_item_cells; break;
  63                                 case "rockets": e.monster_delayedattack = spawnfunc_item_rockets; break;
  64                                 case "bullets":
  65                                 case "nails": e.monster_delayedattack = spawnfunc_item_bullets; break;
  66                         }
  67                         break;
  68                 }
  69         }
  70
  71         if(g_minstagib)
  72                 e.monster_delayedattack = spawnfunc_item_minst_cells;
  73
  74         e.think = monster_item_spawn;
  75         e.nextthink = time + 0.1;
  76 }
  77
  78 void monsters_setframe(float _frame)
  79 {
  80         if(self.frame == _frame)
  81                 return;
  82
  83         self.anim_start_time = time;
  84         self.frame = _frame;
  85         self.SendFlags |= MSF_ANIM;
  86 }
  87
  88 float monster_isvalidtarget (entity targ, entity ent)
  89 {
  90         if(!targ || !ent)
  91                 return FALSE; // someone doesn't exist
  92
  93         if(time < game_starttime)
  94                 return FALSE; // monsters do nothing before the match has started
  95
  96         WarpZone_TraceLine(ent.origin, targ.origin, MOVE_NORMAL, ent);
  97
  98         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  99                 return FALSE; // enemy is too far away
 100
 101         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 102         if(trace_ent != targ)
 103                 return FALSE; // we can't see the enemy
 104
 105         if(targ.takedamage == DAMAGE_NO)
 106                 return FALSE; // enemy can't be damaged
 107
 108         if(targ.items & IT_INVISIBILITY)
 109                 return FALSE; // enemy is invisible
 110
 111         if(IS_SPEC(targ) || IS_OBSERVER(targ))
 112                 return FALSE; // enemy is a spectator
 113
 114         if not(targ.vehicle_flags & VHF_ISVEHICLE) // vehicles dont count as alive?
 115         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
 116                 return FALSE; // enemy/self is dead
 117
 118         if(targ.monster_owner == ent || ent.monster_owner == targ)
 119                 return FALSE; // enemy owns us, or we own them
 120
 121         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 122         if(targ.flags & FL_NOTARGET)
 123                 return FALSE; // enemy can't be targetted
 124
 125         if not(autocvar_g_monsters_typefrag)
 126         if(targ.BUTTON_CHAT)
 127                 return FALSE; // no typefragging!
 128
 129         if not(IsDifferentTeam(targ, ent))
 130                 return FALSE; // enemy is on our team
 131
 132         return TRUE;
 133 }
 134
 135 entity FindTarget (entity ent)
 136 {
 137         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 138         entity e;
 139
 140         for(e = world; (e = findflags(e, monster_attack, TRUE)); )
 141         if(monster_isvalidtarget(e, ent))
 142                 return e;
 143
 144         return world;
 145 }
 146
 147 void MonsterTouch ()
 148 {
 149         if(other == world)
 150                 return;
 151
 152         if(self.enemy != other)
 153         if not(other.flags & FL_MONSTER)
 154         if(monster_isvalidtarget(other, self))
 155                 self.enemy = other;
 156 }
 157
 158 void monster_sound(string msound, float sound_delay, float delaytoo)
 159 {
 160         if(delaytoo && time < self.msound_delay)
 161                 return; // too early
 162
 163         if(msound == "")
 164                 return; // sound doesn't exist
 165
 166         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTN_NORM);
 167
 168         self.msound_delay = time + sound_delay;
 169 }
 170
 171 void monster_precachesounds(entity e)
 172 {
 173         precache_sound(e.msound_idle);
 174         precache_sound(e.msound_death);
 175         precache_sound(e.msound_attack_melee);
 176         precache_sound(e.msound_attack_ranged);
 177         precache_sound(e.msound_sight);
 178         precache_sound(e.msound_pain);
 179 }
 180
 181 void monster_setupsounds(string mon)
 182 {
 183         if(self.msound_idle == "") self.msound_idle = strzone(strcat("monsters/", mon, "_idle.wav"));
 184         if(self.msound_death == "") self.msound_death = strzone(strcat("monsters/", mon, "_death.wav"));
 185         if(self.msound_pain == "") self.msound_pain = strzone(strcat("monsters/", mon, "_pain.wav"));
 186         if(self.msound_attack_melee == "") self.msound_attack_melee = strzone(strcat("monsters/", mon, "_melee.wav"));
 187         if(self.msound_attack_ranged == "") self.msound_attack_ranged = strzone(strcat("monsters/", mon, "_attack.wav"));
 188         if(self.msound_sight == "") self.msound_sight = strzone(strcat("monsters/", mon, "_sight.wav"));
 189 }
 190
 191 void monster_melee (entity targ, float damg, float er, float deathtype, float dostop)
 192 {
 193         float bigdmg, dot, rdmg = damg * random();
 194
 195         if (self.health <= 0)
 196                 return;
 197         if (targ == world)
 198                 return;
 199
 200         if(dostop)
 201         {
 202                 self.velocity_x = 0;
 203                 self.velocity_y = 0;
 204                 self.state = MONSTER_STATE_ATTACK_MELEE;
 205                 self.SendFlags |= MSF_MOVE;
 206         }
 207
 208         makevectors (self.angles);
 209         dot = normalize (targ.origin - self.origin) * v_forward;
 210
 211         bigdmg = rdmg * self.scale;
 212
 213         if(dot > er)
 214                 Damage(targ, self, self, bigdmg * monster_skill, deathtype, targ.origin, normalize(targ.origin - self.origin));
 215 }
 216
 217 void Monster_CheckDropCvars (string mon)
 218 {
 219         if not(self.candrop)
 220                 return; // forced off
 221
 222         string dropitem;
 223         string dropsize;
 224
 225         dropitem = cvar_string(strcat("g_monster_", mon, "_drop"));
 226         dropsize = cvar_string(strcat("g_monster_", mon, "_drop_size"));
 227
 228         monster_dropitem = dropitem;
 229         monster_dropsize = dropsize;
 230         MUTATOR_CALLHOOK(MonsterDropItem);
 231         dropitem = monster_dropitem;
 232         dropsize = monster_dropsize;
 233
 234         if(autocvar_g_monsters_forcedrop)
 235                 Monster_DropItem(autocvar_g_monsters_drop_type, autocvar_g_monsters_drop_size);
 236         else if(dropitem != "")
 237                 Monster_DropItem(dropitem, dropsize);
 238         else
 239                 Monster_DropItem("armor", "medium");
 240 }
 241
 242 void ScaleMonster (float scle, vector min_s, vector max_s)
 243 {
 244         // this should prevent monster from falling through floor when scale changes
 245         self.scale = scle;
 246         setsize(self, min_s * scle, max_s * scle);
 247         setorigin(self, self.origin + ('0 0 30' * scle));
 248         self.SendFlags |= MSF_SIZE | MSF_MOVE;
 249 }
 250
 251 void Monster_CheckMinibossFlag ()
 252 {
 253         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 254                 return;
 255
 256         if(self.spawnflags & MONSTERFLAG_GIANT)
 257                 return; // 1 size modifier at a time
 258
 259         float chance = random() * 100;
 260
 261         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 262         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 263         {
 264                 self.health += autocvar_g_monsters_miniboss_healthboost;
 265                 ScaleMonster(1.5, self.mins, self.maxs);
 266                 self.flags |= MONSTERFLAG_MINIBOSS;
 267                 if not(self.weapon)
 268                         self.weapon = WEP_NEX;
 269         }
 270 }
 271
 272 float Monster_CanRespawn(entity ent)
 273 {
 274         other = ent;
 275         if(MUTATOR_CALLHOOK(MonsterRespawn))
 276                 return TRUE; // enabled by a mutator
 277
 278         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 279                 return FALSE;
 280
 281         if not(autocvar_g_monsters_respawn)
 282                 return FALSE;
 283
 284         return TRUE;
 285 }
 286
 287 void Monster_Fade ()
 288 {
 289         if(Monster_CanRespawn(self))
 290         {
 291                 self.monster_respawned = TRUE;
 292                 self.think = self.monster_spawnfunc;
 293                 self.nextthink = time + self.respawntime;
 294                 self.deadflag = DEAD_RESPAWNING;
 295                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 296                 {
 297                         self.pos1 = self.origin;
 298                         self.pos2 = self.angles;
 299                 }
 300                 self.event_damage = func_null;
 301                 self.takedamage = DAMAGE_NO;
 302                 setorigin(self, self.pos1);
 303                 self.angles = self.pos2;
 304                 self.health = self.max_health; // TODO: check if resetting to max_health is wise here
 305
 306                 self.SendFlags |= MSF_MOVE;
 307                 self.SendFlags |= MSF_STATUS;
 308
 309                 return;
 310         }
 311         SUB_SetFade(self, time + 3, 1);
 312 }
 313
 314 float Monster_CanJump (vector vel)
 315 {
 316         if(self.state)
 317                 return FALSE; // already attacking
 318         if not(self.flags & FL_ONGROUND)
 319                 return FALSE; // not on the ground
 320         if(self.health <= 0)
 321                 return FALSE; // called when dead?
 322         if(time < self.attack_finished_single)
 323                 return FALSE; // still attacking
 324
 325         vector old = self.velocity;
 326
 327         self.velocity = vel;
 328         tracetoss(self, self);
 329         self.velocity = old;
 330         if (trace_ent != self.enemy)
 331                 return FALSE;
 332
 333         return TRUE;
 334 }
 335
 336 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 337 {
 338         if(!Monster_CanJump(vel))
 339                 return FALSE;
 340
 341         monsters_setframe(anm);
 342         self.state = MONSTER_STATE_ATTACK_LEAP;
 343         self.touch = touchfunc;
 344         self.origin_z += 1;
 345         self.velocity = vel;
 346         self.flags &~= FL_ONGROUND;
 347
 348         self.attack_finished_single = time + anim_finished;
 349
 350         return TRUE;
 351 }
 352
 353 float GenericCheckAttack ()
 354 {
 355         // checking attack while dead?
 356         if (self.health <= 0)
 357                 return FALSE;
 358
 359         // reset delays when we have no enemy
 360         if not(self.enemy)
 361         {
 362                 self.monster_delayedattack = func_null;
 363                 self.delay = -1;
 364         }
 365
 366         if(self.monster_delayedattack && self.delay != -1)
 367         {
 368                 if(time < self.delay)
 369                         return FALSE;
 370
 371                 self.monster_delayedattack();
 372         }
 373
 374         if (time < self.attack_finished_single)
 375                 return FALSE;
 376
 377         if(self.attack_melee)
 378         if(vlen(self.enemy.origin - self.origin) <= 100 * self.scale)
 379         {
 380                 monster_sound(self.msound_attack_melee, 0, FALSE); // no delay for attack sounds
 381                 self.attack_melee(); // don't wait for nextthink - too slow
 382                 return TRUE;
 383         }
 384
 385         // monster doesn't have a ranged attack function, so stop here
 386         if not(self.attack_ranged)
 387                 return FALSE;
 388
 389         // see if any entities are in the way of the shot
 390         if not(findtrajectorywithleading(self.origin, '0 0 0', '0 0 0', self.enemy, 800, 0, 2.5, 0, self))
 391                 return FALSE;
 392
 393         if(self.attack_ranged())
 394         {
 395                 monster_sound(self.msound_attack_ranged, 0, FALSE); // no delay for attack sounds
 396                 return TRUE;
 397         }
 398
 399         return FALSE;
 400 }
 401
 402 void monster_use ()
 403 {
 404         if (self.enemy)
 405                 return;
 406         if (self.health <= 0)
 407                 return;
 408
 409         if(!monster_isvalidtarget(activator, self))
 410                 return;
 411
 412         self.enemy = activator;
 413 }
 414
 415 float trace_path(vector from, vector to)
 416 {
 417         vector dir = normalize(to - from) * 15, offset = '0 0 0';
 418         float trace1 = trace_fraction;
 419
 420         offset_x = dir_y;
 421         offset_y = -dir_x;
 422         traceline (from+offset, to+offset, TRUE, self);
 423
 424         traceline(from-offset, to-offset, TRUE, self);
 425
 426         return ((trace1 < trace_fraction) ? trace1 : trace_fraction);
 427 }
 428
 429 .float last_trace;
 430 vector monster_pickmovetarget(entity targ)
 431 {
 432         // enemy is always preferred target
 433         if(self.enemy)
 434         {
 435                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 436                 self.last_trace = time + 0.1;
 437                 return self.enemy.origin;
 438         }
 439         if(targ)
 440         {
 441                 self.monster_movestate = MONSTER_MOVE_WANDER;
 442                 self.last_trace = time + 0.5;
 443                 return targ.origin;
 444         }
 445
 446         switch(self.monster_moveflags)
 447         {
 448                 case MONSTER_MOVE_OWNER:
 449                 {
 450                         self.monster_movestate = MONSTER_MOVE_OWNER;
 451                         self.last_trace = time + 0.3;
 452                         if(self.monster_owner && self.monster_owner.classname != "monster_swarm")
 453                                 return self.monster_owner.origin;
 454                 }
 455                 case MONSTER_MOVE_WANDER:
 456                 {
 457                         self.monster_movestate = MONSTER_MOVE_WANDER;
 458                         self.last_trace = time + 2;
 459
 460                         self.angles_y = random() * 500;
 461                         makevectors(self.angles);
 462                         return self.origin + v_forward * 600;
 463                 }
 464                 case MONSTER_MOVE_SPAWNLOC:
 465                 {
 466                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 467                         self.last_trace = time + 2;
 468                         return self.pos1;
 469                 }
 470                 default:
 471                 case MONSTER_MOVE_NOMOVE:
 472                 {
 473                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 474                         self.last_trace = time + 2;
 475                         return self.origin;
 476                 }
 477         }
 478 }
 479
 480 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 481 {
 482         if(self.target2)
 483                 self.goalentity = find(world, targetname, self.target2);
 484
 485         entity targ;
 486
 487         if(self.frozen)
 488         {
 489                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 490                 self.health = max(1, self.max_health * self.revive_progress);
 491
 492                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 493
 494                 movelib_beak_simple(stopspeed);
 495
 496                 self.velocity = '0 0 0';
 497                 self.enemy = world;
 498                 self.nextthink = time + 0.1;
 499
 500                 if(self.revive_progress >= 1)
 501                         Unfreeze(self); // wait for next think before attacking
 502
 503                 self.SendFlags |= MSF_MOVE;
 504
 505                 return; // no moving while frozen
 506         }
 507
 508         if(self.flags & FL_SWIM)
 509         {
 510                 if(self.waterlevel < WATERLEVEL_WETFEET)
 511                 {
 512                         if(time >= self.last_trace)
 513                         {
 514                                 self.last_trace = time + 0.4;
 515
 516                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 517                                 self.angles = '90 90 0';
 518                                 if(random() < 0.5)
 519                                 {
 520                                         self.velocity_y += random() * 50;
 521                                         self.velocity_x -= random() * 50;
 522                                 }
 523                                 else
 524                                 {
 525                                         self.velocity_y -= random() * 50;
 526                                         self.velocity_x += random() * 50;
 527                                 }
 528                                 self.velocity_z += random() * 150;
 529                         }
 530
 531
 532                         self.movetype = MOVETYPE_BOUNCE;
 533                         //self.velocity_z = -200;
 534
 535                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 536
 537                         return;
 538                 }
 539                 else
 540                 {
 541                         self.angles = '0 0 0';
 542                         self.movetype = MOVETYPE_WALK;
 543                 }
 544         }
 545
 546         if(gameover || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start))
 547         {
 548                 runspeed = walkspeed = 0;
 549                 monsters_setframe(manim_idle);
 550                 movelib_beak_simple(stopspeed);
 551                 self.SendFlags |= MSF_MOVE;
 552                 return;
 553         }
 554
 555         targ = self.goalentity;
 556
 557         monster_target = targ;
 558         monster_speed_run = runspeed;
 559         monster_speed_walk = walkspeed;
 560         MUTATOR_CALLHOOK(MonsterMove);
 561         targ = monster_target;
 562         runspeed = monster_speed_run;
 563         walkspeed = monster_speed_walk;
 564
 565         if(IsDifferentTeam(self.monster_owner, self))
 566                 self.monster_owner = world;
 567
 568         if not(monster_isvalidtarget(self.enemy, self))
 569                 self.enemy = world; // check enemy each think frame?
 570
 571         if not(self.enemy)
 572         {
 573                 self.enemy = FindTarget(self);
 574                 if(self.enemy)
 575                         monster_sound(self.msound_sight, 0, FALSE);
 576         }
 577
 578         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 579                 self.state = 0;
 580
 581         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 582         if(time >= self.last_trace || self.enemy) // update enemy instantly
 583                 self.moveto = monster_pickmovetarget(targ);
 584
 585         if not(self.enemy)
 586                 monster_sound(self.msound_idle, 5, TRUE);
 587
 588         vector angles_face = vectoangles(self.moveto - self.origin);
 589         vector owner_face = vectoangles(self.monster_owner.origin - self.origin);
 590         vector enemy_face = vectoangles(self.enemy.origin - self.origin);
 591
 592         if(self.state != MONSTER_STATE_ATTACK_LEAP)
 593         {
 594                 self.angles_y = angles_face_y;
 595                 self.v_angle = self.angles;
 596         }
 597
 598         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 599         {
 600                 self.state = 0;
 601                 self.touch = MonsterTouch;
 602         }
 603
 604         v_forward = normalize(self.moveto - self.origin);
 605
 606         float l = vlen(self.moveto - self.origin);
 607         float t1 = trace_path(self.origin+'0 0 10', self.moveto+'0 0 10');
 608         float t2 = trace_path(self.origin-'0 0 15', self.moveto-'0 0 15');
 609
 610         if(t1*l-t2*l>50 && (t1*l > 100 || t1 > 0.8))
 611         if(self.flags & FL_ONGROUND)
 612                 movelib_jump_simple(100);
 613
 614         if(vlen(self.origin - self.moveto) > 64 * self.scale)
 615         {
 616                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 617                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 618                 else
 619                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 620                 if(time > self.pain_finished)
 621                 if(time > self.attack_finished_single)
 622                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 623         }
 624         else
 625         {
 626                 if(self.goalentity.target)
 627                         self.target2 = self.goalentity.target;
 628                 else if(self.goalentity.target2)
 629                         self.target2 = self.goalentity.target2;
 630                 else
 631                 {
 632                         movelib_beak_simple(stopspeed);
 633                         if(time > self.attack_finished_single)
 634                         if(time > self.pain_finished)
 635                         if (vlen(self.velocity) <= 30)
 636                         {
 637                                 monsters_setframe(manim_idle);
 638                                 if(self.enemy)
 639                                         self.angles_y = enemy_face_y;
 640                                 else
 641                                         self.angles_y = ((self.monster_owner) ? owner_face_y : self.pos2_y); // reset looking angle now?
 642                         }
 643                 }
 644         }
 645
 646         if(self.enemy && self.checkattack)
 647                 self.checkattack();
 648
 649         self.SendFlags |= MSF_ANG;
 650         self.SendFlags |= MSF_MOVE;
 651 }
 652
 653 void monster_dead_think()
 654 {
 655         self.think = monster_dead_think;
 656         self.nextthink = time + 0.3; // don't need to update so often now
 657
 658         self.deadflag = DEAD_DEAD;
 659
 660         if(time >= self.ltime)
 661         {
 662                 Monster_Fade();
 663                 return;
 664         }
 665
 666         self.SendFlags |= MSF_MOVE; // keep up to date on the monster's location
 667 }
 668
 669 void monsters_setstatus()
 670 {
 671         self.stat_monsters_total = monsters_total;
 672         self.stat_monsters_killed = monsters_killed;
 673 }
 674
 675 void Monster_Appear()
 676 {
 677         self.enemy = activator;
 678         self.spawnflags &~= MONSTERFLAG_APPEAR;
 679         self.monster_spawnfunc();
 680 }
 681
 682 float Monster_CheckAppearFlags(entity ent)
 683 {
 684         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 685                 return FALSE;
 686
 687         ent.think = func_null;
 688         ent.nextthink = 0;
 689         ent.use = Monster_Appear;
 690         ent.flags = FL_MONSTER; // set so this monster can get butchered
 691
 692         return TRUE;
 693 }
 694
 695 void monsters_reset()
 696 {
 697         setorigin(self, self.pos1);
 698         self.angles = self.pos2;
 699
 700         self.health = self.max_health;
 701         self.velocity = '0 0 0';
 702         self.enemy = world;
 703         self.goalentity = world;
 704         self.attack_finished_single = 0;
 705         self.moveto = self.origin;
 706
 707         WaypointSprite_UpdateHealth(self.sprite, self.health);
 708 }
 709
 710 float monster_send(entity to, float sf)
 711 {
 712         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 713         WriteByte(MSG_ENTITY, sf);
 714         if(sf & MSF_SETUP)
 715         {
 716             WriteByte(MSG_ENTITY, self.monsterid);
 717
 718             WriteCoord(MSG_ENTITY, self.origin_x);
 719             WriteCoord(MSG_ENTITY, self.origin_y);
 720             WriteCoord(MSG_ENTITY, self.origin_z);
 721
 722             WriteAngle(MSG_ENTITY, self.angles_x);
 723             WriteAngle(MSG_ENTITY, self.angles_y);
 724
 725                 WriteByte(MSG_ENTITY, self.scale);
 726                 WriteByte(MSG_ENTITY, self.skin);
 727     }
 728
 729         if(sf & MSF_SIZE)
 730         {
 731                 WriteByte(MSG_ENTITY, self.scale);
 732
 733                 WriteCoord(MSG_ENTITY, self.mins_x);
 734             WriteCoord(MSG_ENTITY, self.mins_y);
 735             WriteCoord(MSG_ENTITY, self.mins_z);
 736
 737                 WriteCoord(MSG_ENTITY, self.maxs_x);
 738             WriteCoord(MSG_ENTITY, self.maxs_y);
 739             WriteCoord(MSG_ENTITY, self.maxs_z);
 740         }
 741
 742     if(sf & MSF_ANG)
 743     {
 744         WriteShort(MSG_ENTITY, rint(self.angles_x));
 745         WriteShort(MSG_ENTITY, rint(self.angles_y));
 746     }
 747
 748     if(sf & MSF_MOVE)
 749     {
 750         WriteShort(MSG_ENTITY, rint(self.origin_x));
 751         WriteShort(MSG_ENTITY, rint(self.origin_y));
 752         WriteShort(MSG_ENTITY, rint(self.origin_z));
 753
 754         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 755         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 756         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 757
 758         WriteShort(MSG_ENTITY, rint(self.angles_y));
 759     }
 760
 761     if(sf & MSF_ANIM)
 762     {
 763         WriteCoord(MSG_ENTITY, self.anim_start_time);
 764         WriteByte(MSG_ENTITY, self.frame);
 765     }
 766
 767     if(sf & MSF_STATUS)
 768     {
 769                 WriteByte(MSG_ENTITY, self.skin);
 770
 771         WriteByte(MSG_ENTITY, self.team);
 772
 773                 WriteByte(MSG_ENTITY, self.deadflag);
 774
 775         if(self.health <= 0)
 776             WriteByte(MSG_ENTITY, 0);
 777         else
 778             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 779     }
 780
 781         return TRUE;
 782 }
 783
 784 void monster_link(void() spawnproc)
 785 {
 786     Net_LinkEntity(self, TRUE, 0, monster_send);
 787     self.think      = spawnproc;
 788     self.nextthink  = time;
 789 }
 790
 791 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 792 {
 793         self.health -= damage;
 794
 795         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 796
 797         if(self.health <= -100) // 100 health until gone?
 798         {
 799                 Violence_GibSplash(self, 1, 0.5, attacker);
 800
 801                 self.think = SUB_Remove;
 802                 self.nextthink = time + 0.1;
 803         }
 804 }
 805
 806 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 807 {
 808         if(self.frozen && deathtype != DEATH_KILL)
 809                 return;
 810
 811         if(time < self.pain_finished && deathtype != DEATH_KILL)
 812                 return;
 813
 814         if((ignore_turrets && !(attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET)) || !ignore_turrets)
 815         if(monster_isvalidtarget(attacker, self))
 816                 self.enemy = attacker;
 817
 818         if(deathtype != DEATH_KILL)
 819                 damage *= self.armorvalue;
 820
 821         if(self.weaponentity && self.weaponentity.classname == "shield")
 822                 self.weaponentity.health -= damage;
 823
 824         self.health -= damage;
 825
 826         if(self.sprite)
 827                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 828
 829         self.dmg_time = time;
 830
 831         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 832                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 833
 834         self.velocity += force * self.damageforcescale;
 835
 836         if(deathtype != DEATH_DROWN)
 837         {
 838                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 839                 if (damage > 50)
 840                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 841                 if (damage > 100)
 842                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 843         }
 844
 845         if(self.health <= 0)
 846         {
 847                 if(self.sprite)
 848                 {
 849                         // Update one more time to avoid waypoint fading without emptying healthbar
 850                         WaypointSprite_UpdateHealth(self.sprite, 0);
 851                 }
 852
 853                 if(deathtype == DEATH_KILL)
 854                         self.candrop = FALSE; // killed by mobkill command
 855
 856                 // TODO: fix this?
 857                 activator = attacker;
 858                 other = self.enemy;
 859                 SUB_UseTargets();
 860                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 861
 862                 self.monster_die();
 863
 864                 frag_attacker = attacker;
 865                 frag_target = self;
 866                 MUTATOR_CALLHOOK(MonsterDies);
 867
 868                 if(self.health <= -100) // check if we're already gibbed
 869                 {
 870                         Violence_GibSplash(self, 1, 0.5, attacker);
 871
 872                         self.think = SUB_Remove;
 873                         self.nextthink = time + 0.1;
 874                 }
 875         }
 876
 877         self.SendFlags |= MSF_STATUS;
 878 }
 879
 880 // used to hook into monster post death functions without a mutator
 881 void monster_hook_death()
 882 {
 883         WaypointSprite_Kill(self.sprite);
 884
 885         if(self.weaponentity)
 886         {
 887                 remove(self.weaponentity);
 888                 self.weaponentity = world;
 889         }
 890
 891         monster_sound(self.msound_death, 0, FALSE);
 892
 893         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 894                 monsters_killed += 1;
 895
 896         if(self.candrop && self.weapon)
 897                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 898
 899         if(IS_CLIENT(self.realowner))
 900                 self.realowner.monstercount -= 1;
 901
 902         self.event_damage       = monsters_corpse_damage;
 903         self.solid                      = SOLID_CORPSE;
 904         self.takedamage         = DAMAGE_AIM;
 905         self.enemy                      = world;
 906         self.movetype           = MOVETYPE_TOSS;
 907         self.moveto                     = self.origin;
 908
 909         if not(self.flags & FL_FLY)
 910                 self.velocity = '0 0 0';
 911
 912         self.SendFlags |= MSF_MOVE;
 913
 914         totalspawned -= 1;
 915 }
 916
 917 // used to hook into monster post spawn functions without a mutator
 918 void monster_hook_spawn()
 919 {
 920         if not(self.monster_respawned)
 921                 Monster_CheckMinibossFlag();
 922
 923         self.max_health = self.health;
 924         self.pain_finished = self.nextthink;
 925         self.anim_start_time = time;
 926
 927         if(self.noalign)
 928         {
 929                 setorigin(self, self.origin);
 930                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 931                 setorigin(self, trace_endpos);
 932         }
 933
 934         self.pos1 = self.origin;
 935
 936         monster_precachesounds(self);
 937
 938         if(teamplay)
 939                 self.monster_attack = TRUE; // we can have monster enemies in team games
 940
 941         if(autocvar_g_monsters_healthbars)
 942         {
 943                 WaypointSprite_Spawn(strzone(strdecolorize(self.netname)), 0, 600, self, '0 0 1' * (self.maxs_z + 15), world, 0, self, sprite, FALSE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 944                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 945                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 946         }
 947
 948         monster_sound(self.msound_spawn, 0, FALSE);
 949
 950         MUTATOR_CALLHOOK(MonsterSpawn);
 951
 952         self.SendFlags = MSF_SETUP;
 953 }
 954
 955 float monster_initialize(string  net_name, float mon_id,
 956                                                  vector  min_s,
 957                                                  vector  max_s,
 958                                                  float   nodrop,
 959                                                  void() dieproc,
 960                                                  void() spawnproc)
 961 {
 962         if not(autocvar_g_monsters)
 963                 return FALSE;
 964
 965         // support for quake style removing monsters based on skill
 966         if(monster_skill <= autocvar_g_monsters_skill_easy && (self.spawnflags & MONSTERSKILL_NOTEASY)) { return FALSE; }
 967         if(monster_skill == autocvar_g_monsters_skill_normal && (self.spawnflags & MONSTERSKILL_NOTMEDIUM)) { return FALSE; }
 968         if(monster_skill == autocvar_g_monsters_skill_hard && (self.spawnflags & MONSTERSKILL_NOTHARD)) { return FALSE; }
 969         if(monster_skill == autocvar_g_monsters_skill_insane && (self.spawnflags & MONSTERSKILL_NOTINSANE)) { return FALSE; }
 970         if(monster_skill >= autocvar_g_monsters_skill_nightmare && (self.spawnflags & MONSTERSKILL_NOTNIGHTMARE)) { return FALSE; }
 971
 972         if(self.netname == "")
 973                 self.netname = ((net_name == "") ? self.classname : net_name);
 974
 975         if(autocvar_g_monsters_giants_only)
 976                 self.spawnflags |= MONSTERFLAG_GIANT;
 977
 978         if not(self.scale)
 979                 self.scale = 1;
 980
 981         if(self.spawnflags & MONSTERFLAG_GIANT && !autocvar_g_monsters_nogiants)
 982                 self.scale = 5;
 983
 984         if(self.team && !teamplay)
 985                 self.team = 0;
 986
 987         self.flags = FL_MONSTER;
 988
 989         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 990         if not(self.monster_respawned)
 991                 monsters_total += 1;
 992
 993         ScaleMonster(self.scale, min_s, max_s);
 994
 995         self.takedamage                 = DAMAGE_AIM;
 996         self.bot_attack                 = TRUE;
 997         self.iscreature                 = TRUE;
 998         self.teleportable               = TRUE;
 999         self.damagedbycontents  = TRUE;
1000         self.monsterid                  = mon_id;
1001         self.damageforcescale   = 0.003;
1002         self.monster_die                = dieproc;
1003         self.event_damage               = monsters_damage;
1004         self.touch                              = MonsterTouch;
1005         self.use                                = monster_use;
1006         self.solid                              = SOLID_BBOX;
1007         self.movetype                   = MOVETYPE_WALK;
1008         self.delay                              = -1; // used in attack delay code
1009         monsters_spawned           += 1;
1010         self.enemy                              = world;
1011         self.velocity                   = '0 0 0';
1012         self.moveto                             = self.origin;
1013         self.pos2                               = self.angles;
1014         self.reset                              = monsters_reset;
1015         self.candrop                    = TRUE;
1016         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1017         self.oldtarget2                 = self.target2;
1018         self.deadflag                   = DEAD_NO; // UNDEAD
1019         self.noalign                    = !nodrop;
1020         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1021
1022         if not(self.ticrate)
1023                 self.ticrate = autocvar_g_monsters_think_delay;
1024
1025         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1026
1027         if not(self.armorvalue)
1028                 self.armorvalue = 1; // multiplier
1029
1030         if not(self.target_range)
1031                 self.target_range = autocvar_g_monsters_target_range;
1032
1033         if not(self.respawntime)
1034                 self.respawntime = autocvar_g_monsters_respawn_delay;
1035
1036         if not(self.monster_moveflags)
1037                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1038
1039         monster_link(spawnproc);
1040
1041         return TRUE;
1042 }