qcsrc/server/monsters/lib/monsters.qc

   1 // TODO: clean up this file?
   2
   3 void M_Item_Touch ()
   4 {
   5         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   6         {
   7                 Item_Touch();
   8                 self.think = SUB_Remove;
   9                 self.nextthink = time + 0.1;
  10         }
  11 }
  12
  13 void monster_item_spawn()
  14 {
  15         self.monster_delayedattack();
  16
  17         self.think = SUB_Remove;
  18         self.nextthink = time + 5;
  19         self.gravity = 1;
  20         self.velocity = randomvec() * 175 + '0 0 325';
  21         self.touch = M_Item_Touch;
  22
  23         SUB_SetFade(self, time + 5, 1);
  24 }
  25
  26 void Monster_DropItem (string itype, string itemsize)
  27 {
  28         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  29         entity e = spawn();
  30
  31         setorigin(e, org);
  32
  33         switch(itype)
  34         {
  35                 case "armor":
  36                 {
  37                         switch(itemsize)
  38                         {
  39                                 case "mega": e.monster_delayedattack = spawnfunc_item_armor_large; break;
  40                                 case "large": e.monster_delayedattack = spawnfunc_item_armor_big; break;
  41                                 case "medium": e.monster_delayedattack = spawnfunc_item_armor_medium; break;
  42                                 case "small": e.monster_delayedattack = spawnfunc_item_armor_small; break;
  43                         }
  44                         break; // break here?
  45                 }
  46                 case "health":
  47                 {
  48                         switch(itemsize)
  49                         {
  50                                 case "mega": e.monster_delayedattack = spawnfunc_item_health_mega; break;
  51                                 case "large": e.monster_delayedattack = spawnfunc_item_health_large; break;
  52                                 case "medium": e.monster_delayedattack = spawnfunc_item_health_medium; break;
  53                                 case "small": e.monster_delayedattack = spawnfunc_item_health_small; break;
  54                         }
  55                         break; // break here?
  56                 }
  57                 case "ammo":
  58                 {
  59                         switch(itemsize)
  60                         {
  61                                 case "shells": e.monster_delayedattack = spawnfunc_item_shells; break;
  62                                 case "cells": e.monster_delayedattack = spawnfunc_item_cells; break;
  63                                 case "rockets": e.monster_delayedattack = spawnfunc_item_rockets; break;
  64                                 case "bullets":
  65                                 case "nails": e.monster_delayedattack = spawnfunc_item_bullets; break;
  66                         }
  67                         break;
  68                 }
  69         }
  70
  71         if(g_minstagib)
  72                 e.monster_delayedattack = spawnfunc_item_minst_cells;
  73
  74         e.think = monster_item_spawn;
  75         e.nextthink = time + 0.1;
  76 }
  77
  78 void monsters_setframe(float _frame)
  79 {
  80         if(self.frame == _frame)
  81                 return;
  82
  83         self.anim_start_time = time;
  84         self.frame = _frame;
  85         self.SendFlags |= MSF_ANIM;
  86 }
  87
  88 float monster_isvalidtarget (entity targ, entity ent)
  89 {
  90         if(!targ || !ent)
  91                 return FALSE; // someone doesn't exist
  92
  93         if(time < game_starttime)
  94                 return FALSE; // monsters do nothing before the match has started
  95
  96         WarpZone_TraceLine(ent.origin, targ.origin, MOVE_NORMAL, ent);
  97
  98         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  99                 return FALSE; // enemy is too far away
 100
 101         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 102         if(trace_ent != targ)
 103                 return FALSE; // we can't see the enemy
 104
 105         if(targ.takedamage == DAMAGE_NO)
 106                 return FALSE; // enemy can't be damaged
 107
 108         if(targ.items & IT_INVISIBILITY)
 109                 return FALSE; // enemy is invisible
 110
 111         if(IS_SPEC(targ) || IS_OBSERVER(targ))
 112                 return FALSE; // enemy is a spectator
 113
 114         if not(targ.vehicle_flags & VHF_ISVEHICLE) // vehicles dont count as alive?
 115         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
 116                 return FALSE; // enemy/self is dead
 117
 118         if(targ.monster_owner == ent || ent.monster_owner == targ)
 119                 return FALSE; // enemy owns us, or we own them
 120
 121         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 122         if(targ.flags & FL_NOTARGET)
 123                 return FALSE; // enemy can't be targetted
 124
 125         if not(autocvar_g_monsters_typefrag)
 126         if(targ.BUTTON_CHAT)
 127                 return FALSE; // no typefragging!
 128
 129         if not(IsDifferentTeam(targ, ent))
 130                 return FALSE; // enemy is on our team
 131
 132         return TRUE;
 133 }
 134
 135 entity FindTarget (entity ent)
 136 {
 137         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 138         entity e;
 139
 140         for(e = world; (e = findflags(e, monster_attack, TRUE)); )
 141         if(monster_isvalidtarget(e, ent))
 142                 return e;
 143
 144         return world;
 145 }
 146
 147 void MonsterTouch ()
 148 {
 149         if(other == world)
 150                 return;
 151
 152         if(self.enemy != other)
 153         if not(other.flags & FL_MONSTER)
 154         if(monster_isvalidtarget(other, self))
 155                 self.enemy = other;
 156 }
 157
 158 void monster_sound(string msound, float sound_delay, float delaytoo)
 159 {
 160         if(delaytoo && time < self.msound_delay)
 161                 return; // too early
 162
 163         if(msound == "")
 164                 return; // sound doesn't exist
 165
 166         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTN_NORM);
 167
 168         self.msound_delay = time + sound_delay;
 169 }
 170
 171 void monster_precachesounds(entity e)
 172 {
 173         precache_sound(e.msound_idle);
 174         precache_sound(e.msound_death);
 175         precache_sound(e.msound_attack_melee);
 176         precache_sound(e.msound_attack_ranged);
 177         precache_sound(e.msound_sight);
 178         precache_sound(e.msound_pain);
 179 }
 180
 181 void monster_setupsounds(string mon)
 182 {
 183         if(self.msound_idle == "") self.msound_idle = strzone(strcat("monsters/", mon, "_idle.wav"));
 184         if(self.msound_death == "") self.msound_death = strzone(strcat("monsters/", mon, "_death.wav"));
 185         if(self.msound_pain == "") self.msound_pain = strzone(strcat("monsters/", mon, "_pain.wav"));
 186         if(self.msound_attack_melee == "") self.msound_attack_melee = strzone(strcat("monsters/", mon, "_melee.wav"));
 187         if(self.msound_attack_ranged == "") self.msound_attack_ranged = strzone(strcat("monsters/", mon, "_attack.wav"));
 188         if(self.msound_sight == "") self.msound_sight = strzone(strcat("monsters/", mon, "_sight.wav"));
 189 }
 190
 191 void monster_melee (entity targ, float damg, float er, float deathtype, float dostop)
 192 {
 193         float dot, rdmg = damg * random();
 194
 195         if (self.health <= 0)
 196                 return;
 197         if (targ == world)
 198                 return;
 199
 200         if(dostop)
 201         {
 202                 self.velocity_x = 0;
 203                 self.velocity_y = 0;
 204                 self.state = MONSTER_STATE_ATTACK_MELEE;
 205                 self.SendFlags |= MSF_MOVE;
 206         }
 207
 208         makevectors (self.angles);
 209         dot = normalize (targ.origin - self.origin) * v_forward;
 210
 211         if(dot > er)
 212                 Damage(targ, self, self, rdmg * monster_skill, deathtype, targ.origin, normalize(targ.origin - self.origin));
 213 }
 214
 215 void Monster_CheckDropCvars (string mon)
 216 {
 217         if not(self.candrop)
 218                 return; // forced off
 219
 220         string dropitem;
 221         string dropsize;
 222
 223         dropitem = cvar_string(strcat("g_monster_", mon, "_drop"));
 224         dropsize = cvar_string(strcat("g_monster_", mon, "_drop_size"));
 225
 226         monster_dropitem = dropitem;
 227         monster_dropsize = dropsize;
 228         MUTATOR_CALLHOOK(MonsterDropItem);
 229         dropitem = monster_dropitem;
 230         dropsize = monster_dropsize;
 231
 232         if(autocvar_g_monsters_forcedrop)
 233                 Monster_DropItem(autocvar_g_monsters_drop_type, autocvar_g_monsters_drop_size);
 234         else if(dropitem != "")
 235                 Monster_DropItem(dropitem, dropsize);
 236         else
 237                 Monster_DropItem("armor", "medium");
 238 }
 239
 240 void Monster_CheckMinibossFlag ()
 241 {
 242         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 243                 return;
 244
 245         float chance = random() * 100;
 246
 247         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 248         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 249         {
 250                 self.health += autocvar_g_monsters_miniboss_healthboost;
 251                 self.flags |= MONSTERFLAG_MINIBOSS;
 252                 if not(self.weapon)
 253                         self.weapon = WEP_NEX;
 254         }
 255 }
 256
 257 float Monster_CanRespawn(entity ent)
 258 {
 259         other = ent;
 260         if(MUTATOR_CALLHOOK(MonsterRespawn))
 261                 return TRUE; // enabled by a mutator
 262
 263         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 264                 return FALSE;
 265
 266         if not(autocvar_g_monsters_respawn)
 267                 return FALSE;
 268
 269         return TRUE;
 270 }
 271
 272 void Monster_Fade ()
 273 {
 274         if(Monster_CanRespawn(self))
 275         {
 276                 self.monster_respawned = TRUE;
 277                 self.think = self.monster_spawnfunc;
 278                 self.nextthink = time + self.respawntime;
 279                 self.deadflag = DEAD_RESPAWNING;
 280                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 281                 {
 282                         self.pos1 = self.origin;
 283                         self.pos2 = self.angles;
 284                 }
 285                 self.event_damage = func_null;
 286                 self.takedamage = DAMAGE_NO;
 287                 setorigin(self, self.pos1);
 288                 self.angles = self.pos2;
 289                 self.health = self.max_health; // TODO: check if resetting to max_health is wise here
 290
 291                 self.SendFlags |= MSF_MOVE;
 292                 self.SendFlags |= MSF_STATUS;
 293
 294                 return;
 295         }
 296         SUB_SetFade(self, time + 3, 1);
 297 }
 298
 299 float Monster_CanJump (vector vel)
 300 {
 301         if(self.state)
 302                 return FALSE; // already attacking
 303         if not(self.flags & FL_ONGROUND)
 304                 return FALSE; // not on the ground
 305         if(self.health <= 0)
 306                 return FALSE; // called when dead?
 307         if(time < self.attack_finished_single)
 308                 return FALSE; // still attacking
 309
 310         vector old = self.velocity;
 311
 312         self.velocity = vel;
 313         tracetoss(self, self);
 314         self.velocity = old;
 315         if (trace_ent != self.enemy)
 316                 return FALSE;
 317
 318         return TRUE;
 319 }
 320
 321 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 322 {
 323         if(!Monster_CanJump(vel))
 324                 return FALSE;
 325
 326         monsters_setframe(anm);
 327         self.state = MONSTER_STATE_ATTACK_LEAP;
 328         self.touch = touchfunc;
 329         self.origin_z += 1;
 330         self.velocity = vel;
 331         self.flags &~= FL_ONGROUND;
 332
 333         self.attack_finished_single = time + anim_finished;
 334
 335         return TRUE;
 336 }
 337
 338 float GenericCheckAttack ()
 339 {
 340         // checking attack while dead?
 341         if (self.health <= 0)
 342                 return FALSE;
 343
 344         // reset delays when we have no enemy
 345         if not(self.enemy)
 346         {
 347                 self.monster_delayedattack = func_null;
 348                 self.delay = -1;
 349         }
 350
 351         if(self.monster_delayedattack && self.delay != -1)
 352         {
 353                 if(time < self.delay)
 354                         return FALSE;
 355
 356                 self.monster_delayedattack();
 357         }
 358
 359         if (time < self.attack_finished_single)
 360                 return FALSE;
 361
 362         if(self.attack_melee)
 363         if(vlen(self.enemy.origin - self.origin) <= 100)
 364         {
 365                 monster_sound(self.msound_attack_melee, 0, FALSE); // no delay for attack sounds
 366                 self.attack_melee(); // don't wait for nextthink - too slow
 367                 return TRUE;
 368         }
 369
 370         // monster doesn't have a ranged attack function, so stop here
 371         if not(self.attack_ranged)
 372                 return FALSE;
 373
 374         // see if any entities are in the way of the shot
 375         if not(findtrajectorywithleading(self.origin, '0 0 0', '0 0 0', self.enemy, 800, 0, 2.5, 0, self))
 376                 return FALSE;
 377
 378         if(self.attack_ranged())
 379         {
 380                 monster_sound(self.msound_attack_ranged, 0, FALSE); // no delay for attack sounds
 381                 return TRUE;
 382         }
 383
 384         return FALSE;
 385 }
 386
 387 void monster_use ()
 388 {
 389         if (self.enemy)
 390                 return;
 391         if (self.health <= 0)
 392                 return;
 393
 394         if(!monster_isvalidtarget(activator, self))
 395                 return;
 396
 397         self.enemy = activator;
 398 }
 399
 400 float trace_path(vector from, vector to)
 401 {
 402         vector dir = normalize(to - from) * 15, offset = '0 0 0';
 403         float trace1 = trace_fraction;
 404
 405         offset_x = dir_y;
 406         offset_y = -dir_x;
 407         traceline (from+offset, to+offset, TRUE, self);
 408
 409         traceline(from-offset, to-offset, TRUE, self);
 410
 411         return ((trace1 < trace_fraction) ? trace1 : trace_fraction);
 412 }
 413
 414 .float last_trace;
 415 vector monster_pickmovetarget(entity targ)
 416 {
 417         // enemy is always preferred target
 418         if(self.enemy)
 419         {
 420                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 421                 self.last_trace = time + 0.1;
 422                 return self.enemy.origin;
 423         }
 424         if(targ)
 425         {
 426                 self.monster_movestate = MONSTER_MOVE_WANDER;
 427                 self.last_trace = time + 0.5;
 428                 return targ.origin;
 429         }
 430
 431         switch(self.monster_moveflags)
 432         {
 433                 case MONSTER_MOVE_OWNER:
 434                 {
 435                         self.monster_movestate = MONSTER_MOVE_OWNER;
 436                         self.last_trace = time + 0.3;
 437                         if(self.monster_owner && self.monster_owner.classname != "monster_swarm")
 438                                 return self.monster_owner.origin;
 439                 }
 440                 case MONSTER_MOVE_WANDER:
 441                 {
 442                         vector pos;
 443                         self.monster_movestate = MONSTER_MOVE_WANDER;
 444                         self.last_trace = time + 2;
 445
 446                         self.angles_y = random() * 500;
 447                         makevectors(self.angles);
 448                         pos = self.origin + v_forward * 600;
 449
 450                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 451                         {
 452                                 pos_z = random() * 200;
 453                                 if(random() >= 0.5)
 454                                         pos_z *= -1;
 455                         }
 456
 457                         return pos;
 458                 }
 459                 case MONSTER_MOVE_SPAWNLOC:
 460                 {
 461                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 462                         self.last_trace = time + 2;
 463                         return self.pos1;
 464                 }
 465                 default:
 466                 case MONSTER_MOVE_NOMOVE:
 467                 {
 468                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 469                         self.last_trace = time + 2;
 470                         return self.origin;
 471                 }
 472         }
 473 }
 474
 475 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 476 {
 477         if(self.target2)
 478                 self.goalentity = find(world, targetname, self.target2);
 479
 480         entity targ;
 481
 482         if(self.frozen)
 483         {
 484                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 485                 self.health = max(1, self.max_health * self.revive_progress);
 486
 487                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 488
 489                 movelib_beak_simple(stopspeed);
 490
 491                 self.velocity = '0 0 0';
 492                 self.enemy = world;
 493                 self.nextthink = time + 0.1;
 494
 495                 if(self.revive_progress >= 1)
 496                         Unfreeze(self); // wait for next think before attacking
 497
 498                 self.SendFlags |= MSF_MOVE;
 499
 500                 return; // no moving while frozen
 501         }
 502
 503         if(self.flags & FL_SWIM)
 504         {
 505                 if(self.waterlevel < WATERLEVEL_WETFEET)
 506                 {
 507                         if(time >= self.last_trace)
 508                         {
 509                                 self.last_trace = time + 0.4;
 510
 511                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 512                                 self.angles = '90 90 0';
 513                                 if(random() < 0.5)
 514                                 {
 515                                         self.velocity_y += random() * 50;
 516                                         self.velocity_x -= random() * 50;
 517                                 }
 518                                 else
 519                                 {
 520                                         self.velocity_y -= random() * 50;
 521                                         self.velocity_x += random() * 50;
 522                                 }
 523                                 self.velocity_z += random() * 150;
 524                         }
 525
 526
 527                         self.movetype = MOVETYPE_BOUNCE;
 528                         //self.velocity_z = -200;
 529
 530                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 531
 532                         return;
 533                 }
 534                 else
 535                 {
 536                         self.angles = '0 0 0';
 537                         self.movetype = MOVETYPE_WALK;
 538                 }
 539         }
 540
 541         if(gameover || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 542         {
 543                 runspeed = walkspeed = 0;
 544                 if(time >= self.spawn_time)
 545                         monsters_setframe(manim_idle);
 546                 movelib_beak_simple(stopspeed);
 547                 self.SendFlags |= MSF_MOVE;
 548                 return;
 549         }
 550
 551         targ = self.goalentity;
 552
 553         monster_target = targ;
 554         monster_speed_run = runspeed;
 555         monster_speed_walk = walkspeed;
 556         MUTATOR_CALLHOOK(MonsterMove);
 557         targ = monster_target;
 558         runspeed = monster_speed_run;
 559         walkspeed = monster_speed_walk;
 560
 561         if(IsDifferentTeam(self.monster_owner, self))
 562                 self.monster_owner = world;
 563
 564         if not(monster_isvalidtarget(self.enemy, self))
 565                 self.enemy = world; // check enemy each think frame?
 566
 567         if not(self.enemy)
 568         {
 569                 self.enemy = FindTarget(self);
 570                 if(self.enemy)
 571                         monster_sound(self.msound_sight, 0, FALSE);
 572         }
 573
 574         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 575                 self.state = 0;
 576
 577         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 578         if(time >= self.last_trace || self.enemy) // update enemy instantly
 579                 self.moveto = monster_pickmovetarget(targ);
 580
 581         if not(self.enemy)
 582                 monster_sound(self.msound_idle, 5, TRUE);
 583
 584         vector angles_face = vectoangles(self.moveto - self.origin);
 585         vector owner_face = vectoangles(self.monster_owner.origin - self.origin);
 586         vector enemy_face = vectoangles(self.enemy.origin - self.origin);
 587
 588         if(!(self.flags & FL_FLY || self.flags & FL_SWIM))
 589                 self.moveto_z = self.origin_z;
 590
 591         if(self.state != MONSTER_STATE_ATTACK_LEAP)
 592         {
 593                 self.angles_y = angles_face_y;
 594                 self.v_angle = self.angles;
 595         }
 596
 597         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 598         {
 599                 self.state = 0;
 600                 self.touch = MonsterTouch;
 601         }
 602
 603         v_forward = normalize(self.moveto - self.origin);
 604
 605         float l = vlen(self.moveto - self.origin);
 606         float t1 = trace_path(self.origin+'0 0 10', self.moveto+'0 0 10');
 607         float t2 = trace_path(self.origin-'0 0 15', self.moveto-'0 0 15');
 608
 609         if(t1*l-t2*l>50 && (t1*l > 100 || t1 > 0.8))
 610         if(self.flags & FL_ONGROUND)
 611                 movelib_jump_simple(100);
 612
 613         if(vlen(self.origin - self.moveto) > 64)
 614         {
 615                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 616                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 617                 else
 618                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 619                 if(time > self.pain_finished)
 620                 if(time > self.attack_finished_single)
 621                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 622         }
 623         else
 624         {
 625                 if(targ.target)
 626                         self.target2 = targ.target;
 627                 else if(targ.target2)
 628                         self.target2 = targ.target2;
 629                 else
 630                 {
 631                         movelib_beak_simple(stopspeed);
 632                         if(time > self.attack_finished_single)
 633                         if(time > self.pain_finished)
 634                         if (vlen(self.velocity) <= 30)
 635                         {
 636                                 monsters_setframe(manim_idle);
 637                                 if(self.enemy)
 638                                         self.angles_y = enemy_face_y;
 639                                 else
 640                                         self.angles_y = ((self.monster_owner) ? owner_face_y : self.pos2_y); // reset looking angle now?
 641                         }
 642                 }
 643         }
 644
 645         if(self.enemy && self.checkattack)
 646                 self.checkattack();
 647
 648         self.SendFlags |= MSF_ANG;
 649         self.SendFlags |= MSF_MOVE;
 650 }
 651
 652 void monster_dead_think()
 653 {
 654         self.think = monster_dead_think;
 655         self.nextthink = time + 0.3; // don't need to update so often now
 656
 657         self.deadflag = DEAD_DEAD;
 658
 659         if(time >= self.ltime)
 660         {
 661                 Monster_Fade();
 662                 return;
 663         }
 664
 665         self.SendFlags |= MSF_MOVE; // keep up to date on the monster's location
 666 }
 667
 668 void monsters_setstatus()
 669 {
 670         self.stat_monsters_total = monsters_total;
 671         self.stat_monsters_killed = monsters_killed;
 672 }
 673
 674 void Monster_Appear()
 675 {
 676         self.enemy = activator;
 677         self.spawnflags &~= MONSTERFLAG_APPEAR;
 678         self.monster_spawnfunc();
 679 }
 680
 681 float Monster_CheckAppearFlags(entity ent)
 682 {
 683         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 684                 return FALSE;
 685
 686         ent.think = func_null;
 687         ent.nextthink = 0;
 688         ent.use = Monster_Appear;
 689         ent.flags = FL_MONSTER; // set so this monster can get butchered
 690
 691         return TRUE;
 692 }
 693
 694 void monsters_reset()
 695 {
 696         setorigin(self, self.pos1);
 697         self.angles = self.pos2;
 698
 699         self.health = self.max_health;
 700         self.velocity = '0 0 0';
 701         self.enemy = world;
 702         self.goalentity = world;
 703         self.attack_finished_single = 0;
 704         self.moveto = self.origin;
 705
 706         WaypointSprite_UpdateHealth(self.sprite, self.health);
 707 }
 708
 709 float monster_send(entity to, float sf)
 710 {
 711         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 712         WriteByte(MSG_ENTITY, sf);
 713         if(sf & MSF_SETUP)
 714         {
 715             WriteByte(MSG_ENTITY, self.monsterid);
 716
 717             WriteCoord(MSG_ENTITY, self.origin_x);
 718             WriteCoord(MSG_ENTITY, self.origin_y);
 719             WriteCoord(MSG_ENTITY, self.origin_z);
 720
 721             WriteAngle(MSG_ENTITY, self.angles_x);
 722             WriteAngle(MSG_ENTITY, self.angles_y);
 723
 724                 WriteByte(MSG_ENTITY, self.skin);
 725     }
 726
 727     if(sf & MSF_ANG)
 728     {
 729         WriteShort(MSG_ENTITY, rint(self.angles_x));
 730         WriteShort(MSG_ENTITY, rint(self.angles_y));
 731     }
 732
 733     if(sf & MSF_MOVE)
 734     {
 735         WriteShort(MSG_ENTITY, rint(self.origin_x));
 736         WriteShort(MSG_ENTITY, rint(self.origin_y));
 737         WriteShort(MSG_ENTITY, rint(self.origin_z));
 738
 739         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 740         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 741         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 742
 743         WriteShort(MSG_ENTITY, rint(self.angles_y));
 744     }
 745
 746     if(sf & MSF_ANIM)
 747     {
 748         WriteCoord(MSG_ENTITY, self.anim_start_time);
 749         WriteByte(MSG_ENTITY, self.frame);
 750     }
 751
 752     if(sf & MSF_STATUS)
 753     {
 754                 WriteByte(MSG_ENTITY, self.skin);
 755
 756         WriteByte(MSG_ENTITY, self.team);
 757
 758                 WriteByte(MSG_ENTITY, self.deadflag);
 759
 760         if(self.health <= 0)
 761             WriteByte(MSG_ENTITY, 0);
 762         else
 763             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 764     }
 765
 766         return TRUE;
 767 }
 768
 769 void monster_link(void() spawnproc)
 770 {
 771     Net_LinkEntity(self, TRUE, 0, monster_send);
 772     self.think      = spawnproc;
 773     self.nextthink  = time;
 774 }
 775
 776 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 777 {
 778         self.health -= damage;
 779
 780         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 781
 782         if(self.health <= -100) // 100 health until gone?
 783         {
 784                 Violence_GibSplash(self, 1, 0.5, attacker);
 785
 786                 self.think = SUB_Remove;
 787                 self.nextthink = time + 0.1;
 788         }
 789 }
 790
 791 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 792 {
 793         if(self.frozen && deathtype != DEATH_KILL)
 794                 return;
 795
 796         if(time < self.pain_finished && deathtype != DEATH_KILL)
 797                 return;
 798
 799         if((ignore_turrets && !(attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET)) || !ignore_turrets)
 800         if(monster_isvalidtarget(attacker, self))
 801                 self.enemy = attacker;
 802
 803         if(deathtype != DEATH_KILL)
 804                 damage *= self.armorvalue;
 805
 806         if(self.weaponentity && self.weaponentity.classname == "shield")
 807                 self.weaponentity.health -= damage;
 808
 809         self.health -= damage;
 810
 811         if(self.sprite)
 812                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 813
 814         self.dmg_time = time;
 815
 816         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 817                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 818
 819         self.velocity += force * self.damageforcescale;
 820
 821         if(deathtype != DEATH_DROWN)
 822         {
 823                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 824                 if (damage > 50)
 825                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 826                 if (damage > 100)
 827                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 828         }
 829
 830         if(self.health <= 0)
 831         {
 832                 if(self.sprite)
 833                 {
 834                         // Update one more time to avoid waypoint fading without emptying healthbar
 835                         WaypointSprite_UpdateHealth(self.sprite, 0);
 836                 }
 837
 838                 if(deathtype == DEATH_KILL)
 839                         self.candrop = FALSE; // killed by mobkill command
 840
 841                 // TODO: fix this?
 842                 activator = attacker;
 843                 other = self.enemy;
 844                 SUB_UseTargets();
 845                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 846
 847                 self.monster_die();
 848
 849                 frag_attacker = attacker;
 850                 frag_target = self;
 851                 MUTATOR_CALLHOOK(MonsterDies);
 852
 853                 if(self.health <= -100) // check if we're already gibbed
 854                 {
 855                         Violence_GibSplash(self, 1, 0.5, attacker);
 856
 857                         self.think = SUB_Remove;
 858                         self.nextthink = time + 0.1;
 859                 }
 860         }
 861
 862         self.SendFlags |= MSF_STATUS;
 863 }
 864
 865 // used to hook into monster post death functions without a mutator
 866 void monster_hook_death()
 867 {
 868         WaypointSprite_Kill(self.sprite);
 869
 870         if(self.weaponentity)
 871         {
 872                 remove(self.weaponentity);
 873                 self.weaponentity = world;
 874         }
 875
 876         monster_sound(self.msound_death, 0, FALSE);
 877
 878         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 879                 monsters_killed += 1;
 880
 881         if(self.candrop && self.weapon)
 882                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 883
 884         if(IS_CLIENT(self.realowner))
 885                 self.realowner.monstercount -= 1;
 886
 887         self.event_damage       = monsters_corpse_damage;
 888         self.solid                      = SOLID_CORPSE;
 889         self.takedamage         = DAMAGE_AIM;
 890         self.enemy                      = world;
 891         self.movetype           = MOVETYPE_TOSS;
 892         self.moveto                     = self.origin;
 893
 894         if not(self.flags & FL_FLY)
 895                 self.velocity = '0 0 0';
 896
 897         self.SendFlags |= MSF_MOVE;
 898
 899         totalspawned -= 1;
 900 }
 901
 902 // used to hook into monster post spawn functions without a mutator
 903 void monster_hook_spawn()
 904 {
 905         if not(self.monster_respawned)
 906                 Monster_CheckMinibossFlag();
 907
 908         self.max_health = self.health;
 909         self.pain_finished = self.nextthink;
 910         self.anim_start_time = time;
 911
 912         if not(self.noalign)
 913         {
 914                 setorigin(self, self.origin + '0 0 20');
 915                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 916                 setorigin(self, trace_endpos);
 917         }
 918
 919         self.pos1 = self.origin;
 920
 921         monster_precachesounds(self);
 922
 923         if(teamplay)
 924                 self.monster_attack = TRUE; // we can have monster enemies in team games
 925
 926         if(autocvar_g_monsters_healthbars)
 927         {
 928                 WaypointSprite_Spawn(strzone(strdecolorize(self.netname)), 0, 600, self, '0 0 1' * (self.maxs_z + 15), world, 0, self, sprite, FALSE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 929                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 930                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 931         }
 932
 933         monster_sound(self.msound_spawn, 0, FALSE);
 934
 935         MUTATOR_CALLHOOK(MonsterSpawn);
 936
 937         self.SendFlags = MSF_SETUP;
 938 }
 939
 940 float monster_initialize(string  net_name, float mon_id,
 941                                                  vector  min_s,
 942                                                  vector  max_s,
 943                                                  float   nodrop,
 944                                                  void() dieproc,
 945                                                  void() spawnproc)
 946 {
 947         if not(autocvar_g_monsters)
 948                 return FALSE;
 949
 950         // support for quake style removing monsters based on skill
 951         if(monster_skill <= autocvar_g_monsters_skill_easy && (self.spawnflags & MONSTERSKILL_NOTEASY)) { return FALSE; }
 952         if(monster_skill == autocvar_g_monsters_skill_normal && (self.spawnflags & MONSTERSKILL_NOTMEDIUM)) { return FALSE; }
 953         if(monster_skill == autocvar_g_monsters_skill_hard && (self.spawnflags & MONSTERSKILL_NOTHARD)) { return FALSE; }
 954         if(monster_skill == autocvar_g_monsters_skill_insane && (self.spawnflags & MONSTERSKILL_NOTINSANE)) { return FALSE; }
 955         if(monster_skill >= autocvar_g_monsters_skill_nightmare && (self.spawnflags & MONSTERSKILL_NOTNIGHTMARE)) { return FALSE; }
 956
 957         if(self.netname == "")
 958                 self.netname = ((net_name == "") ? self.classname : net_name);
 959
 960         if(self.team && !teamplay)
 961                 self.team = 0;
 962
 963         self.flags = FL_MONSTER;
 964
 965         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 966         if not(self.monster_respawned)
 967                 monsters_total += 1;
 968
 969         setsize(self, min_s, max_s);
 970         self.takedamage                 = DAMAGE_AIM;
 971         self.bot_attack                 = TRUE;
 972         self.iscreature                 = TRUE;
 973         self.teleportable               = TRUE;
 974         self.damagedbycontents  = TRUE;
 975         self.monsterid                  = mon_id;
 976         self.damageforcescale   = 0.003;
 977         self.monster_die                = dieproc;
 978         self.event_damage               = monsters_damage;
 979         self.touch                              = MonsterTouch;
 980         self.use                                = monster_use;
 981         self.solid                              = SOLID_BBOX;
 982         self.scale                              = 1;
 983         self.movetype                   = MOVETYPE_WALK;
 984         self.delay                              = -1; // used in attack delay code
 985         monsters_spawned           += 1;
 986         self.enemy                              = world;
 987         self.velocity                   = '0 0 0';
 988         self.moveto                             = self.origin;
 989         self.pos2                               = self.angles;
 990         self.reset                              = monsters_reset;
 991         self.candrop                    = TRUE;
 992         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
 993         self.oldtarget2                 = self.target2;
 994         self.deadflag                   = DEAD_NO; // UNDEAD
 995         self.noalign                    = nodrop;
 996         self.spawn_time                 = time;
 997         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
 998
 999         if not(self.ticrate)
1000                 self.ticrate = autocvar_g_monsters_think_delay;
1001
1002         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1003
1004         if not(self.armorvalue)
1005                 self.armorvalue = 1; // multiplier
1006
1007         if not(self.target_range)
1008                 self.target_range = autocvar_g_monsters_target_range;
1009
1010         if not(self.respawntime)
1011                 self.respawntime = autocvar_g_monsters_respawn_delay;
1012
1013         if not(self.monster_moveflags)
1014                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1015
1016         monster_link(spawnproc);
1017
1018         return TRUE;
1019 }