qcsrc/server/monsters/lib/monsters.qc

   1 // TODO: clean up this file?
   2
   3 void M_Item_Touch ()
   4 {
   5         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   6         {
   7                 Item_Touch();
   8                 self.think = SUB_Remove;
   9                 self.nextthink = time + 0.1;
  10         }
  11 }
  12
  13 void monster_item_spawn()
  14 {
  15         self.monster_delayedattack();
  16
  17         self.think = SUB_Remove;
  18         self.nextthink = time + 5;
  19         self.gravity = 1;
  20         self.velocity = randomvec() * 175 + '0 0 325';
  21         self.touch = M_Item_Touch;
  22
  23         SUB_SetFade(self, time + 5, 1);
  24 }
  25
  26 void Monster_DropItem (string itype, string itemsize)
  27 {
  28         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  29         entity e = spawn();
  30
  31         setorigin(e, org);
  32
  33         switch(itype)
  34         {
  35                 case "armor":
  36                 {
  37                         switch(itemsize)
  38                         {
  39                                 case "mega": e.monster_delayedattack = spawnfunc_item_armor_large; break;
  40                                 case "large": e.monster_delayedattack = spawnfunc_item_armor_big; break;
  41                                 case "medium": e.monster_delayedattack = spawnfunc_item_armor_medium; break;
  42                                 case "small": e.monster_delayedattack = spawnfunc_item_armor_small; break;
  43                         }
  44                         break; // break here?
  45                 }
  46                 case "health":
  47                 {
  48                         switch(itemsize)
  49                         {
  50                                 case "mega": e.monster_delayedattack = spawnfunc_item_health_mega; break;
  51                                 case "large": e.monster_delayedattack = spawnfunc_item_health_large; break;
  52                                 case "medium": e.monster_delayedattack = spawnfunc_item_health_medium; break;
  53                                 case "small": e.monster_delayedattack = spawnfunc_item_health_small; break;
  54                         }
  55                         break; // break here?
  56                 }
  57                 case "ammo":
  58                 {
  59                         switch(itemsize)
  60                         {
  61                                 case "shells": e.monster_delayedattack = spawnfunc_item_shells; break;
  62                                 case "cells": e.monster_delayedattack = spawnfunc_item_cells; break;
  63                                 case "rockets": e.monster_delayedattack = spawnfunc_item_rockets; break;
  64                                 case "bullets":
  65                                 case "nails": e.monster_delayedattack = spawnfunc_item_bullets; break;
  66                         }
  67                         break;
  68                 }
  69         }
  70
  71         if(g_minstagib)
  72                 e.monster_delayedattack = spawnfunc_item_minst_cells;
  73
  74         e.think = monster_item_spawn;
  75         e.nextthink = time + 0.1;
  76 }
  77
  78 void monsters_setframe(float _frame)
  79 {
  80         if(self.frame == _frame)
  81                 return;
  82
  83         self.anim_start_time = time;
  84         self.frame = _frame;
  85         self.SendFlags |= MSF_ANIM;
  86 }
  87
  88 float monster_isvalidtarget (entity targ, entity ent)
  89 {
  90         if(!targ || !ent)
  91                 return FALSE; // someone doesn't exist
  92
  93         if(time < game_starttime)
  94                 return FALSE; // monsters do nothing before the match has started
  95
  96         WarpZone_TraceLine(ent.origin, targ.origin, MOVE_NORMAL, ent);
  97
  98         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  99                 return FALSE; // enemy is too far away
 100
 101         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 102         if(trace_ent != targ)
 103                 return FALSE; // we can't see the enemy
 104
 105         if(targ.takedamage == DAMAGE_NO)
 106                 return FALSE; // enemy can't be damaged
 107
 108         if(targ.items & IT_INVISIBILITY)
 109                 return FALSE; // enemy is invisible
 110
 111         if(IS_SPEC(targ) || IS_OBSERVER(targ))
 112                 return FALSE; // enemy is a spectator
 113
 114         if not(targ.vehicle_flags & VHF_ISVEHICLE) // vehicles dont count as alive?
 115         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
 116                 return FALSE; // enemy/self is dead
 117
 118         if(targ.monster_owner == ent || ent.monster_owner == targ)
 119                 return FALSE; // enemy owns us, or we own them
 120
 121         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 122         if(targ.flags & FL_NOTARGET)
 123                 return FALSE; // enemy can't be targetted
 124
 125         if not(autocvar_g_monsters_typefrag)
 126         if(targ.BUTTON_CHAT)
 127                 return FALSE; // no typefragging!
 128
 129         if not(IsDifferentTeam(targ, ent))
 130                 return FALSE; // enemy is on our team
 131
 132         return TRUE;
 133 }
 134
 135 entity FindTarget (entity ent)
 136 {
 137         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 138         entity e;
 139
 140         for(e = world; (e = findflags(e, monster_attack, TRUE)); )
 141         if(monster_isvalidtarget(e, ent))
 142                 return e;
 143
 144         return world;
 145 }
 146
 147 void MonsterTouch ()
 148 {
 149         if(other == world)
 150                 return;
 151
 152         if(self.enemy != other)
 153         if not(other.flags & FL_MONSTER)
 154         if(monster_isvalidtarget(other, self))
 155                 self.enemy = other;
 156 }
 157
 158 void monster_sound(string msound, float sound_delay, float delaytoo)
 159 {
 160         if(delaytoo && time < self.msound_delay)
 161                 return; // too early
 162
 163         if(msound == "")
 164                 return; // sound doesn't exist
 165
 166         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTN_NORM);
 167
 168         self.msound_delay = time + sound_delay;
 169 }
 170
 171 void monster_precachesounds(entity e)
 172 {
 173         precache_sound(e.msound_idle);
 174         precache_sound(e.msound_death);
 175         precache_sound(e.msound_attack_melee);
 176         precache_sound(e.msound_attack_ranged);
 177         precache_sound(e.msound_sight);
 178         precache_sound(e.msound_pain);
 179 }
 180
 181 void monster_setupsounds(string mon)
 182 {
 183         if(self.msound_idle == "") self.msound_idle = strzone(strcat("monsters/", mon, "_idle.wav"));
 184         if(self.msound_death == "") self.msound_death = strzone(strcat("monsters/", mon, "_death.wav"));
 185         if(self.msound_pain == "") self.msound_pain = strzone(strcat("monsters/", mon, "_pain.wav"));
 186         if(self.msound_attack_melee == "") self.msound_attack_melee = strzone(strcat("monsters/", mon, "_melee.wav"));
 187         if(self.msound_attack_ranged == "") self.msound_attack_ranged = strzone(strcat("monsters/", mon, "_attack.wav"));
 188         if(self.msound_sight == "") self.msound_sight = strzone(strcat("monsters/", mon, "_sight.wav"));
 189 }
 190
 191 void monster_melee (entity targ, float damg, float er, float deathtype, float dostop)
 192 {
 193         float bigdmg, dot, rdmg = damg * random();
 194
 195         if (self.health <= 0)
 196                 return;
 197         if (targ == world)
 198                 return;
 199
 200         if(dostop)
 201         {
 202                 self.velocity_x = 0;
 203                 self.velocity_y = 0;
 204                 self.state = MONSTER_STATE_ATTACK_MELEE;
 205                 self.SendFlags |= MSF_MOVE;
 206         }
 207
 208         makevectors (self.angles);
 209         dot = normalize (targ.origin - self.origin) * v_forward;
 210
 211         bigdmg = rdmg * self.scale;
 212
 213         if(dot > er)
 214                 Damage(targ, self, self, bigdmg * monster_skill, deathtype, targ.origin, normalize(targ.origin - self.origin));
 215 }
 216
 217 void Monster_CheckDropCvars (string mon)
 218 {
 219         if not(self.candrop)
 220                 return; // forced off
 221
 222         string dropitem;
 223         string dropsize;
 224
 225         dropitem = cvar_string(strcat("g_monster_", mon, "_drop"));
 226         dropsize = cvar_string(strcat("g_monster_", mon, "_drop_size"));
 227
 228         monster_dropitem = dropitem;
 229         monster_dropsize = dropsize;
 230         MUTATOR_CALLHOOK(MonsterDropItem);
 231         dropitem = monster_dropitem;
 232         dropsize = monster_dropsize;
 233
 234         if(autocvar_g_monsters_forcedrop)
 235                 Monster_DropItem(autocvar_g_monsters_drop_type, autocvar_g_monsters_drop_size);
 236         else if(dropitem != "")
 237                 Monster_DropItem(dropitem, dropsize);
 238         else
 239                 Monster_DropItem("armor", "medium");
 240 }
 241
 242 void ScaleMonster (float scle, vector min_s, vector max_s)
 243 {
 244         // this should prevent monster from falling through floor when scale changes
 245         self.scale = scle;
 246         setsize(self, min_s * scle, max_s * scle);
 247         setorigin(self, self.origin + ('0 0 30' * scle));
 248         self.SendFlags |= MSF_SIZE | MSF_MOVE;
 249 }
 250
 251 void Monster_CheckMinibossFlag ()
 252 {
 253         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 254                 return;
 255
 256         if(self.spawnflags & MONSTERFLAG_GIANT)
 257                 return; // 1 size modifier at a time
 258
 259         float chance = random() * 100;
 260
 261         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 262         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 263         {
 264                 self.health += autocvar_g_monsters_miniboss_healthboost;
 265                 ScaleMonster(1.5, self.mins, self.maxs);
 266                 self.flags |= MONSTERFLAG_MINIBOSS;
 267                 if not(self.weapon)
 268                         self.weapon = WEP_NEX;
 269         }
 270 }
 271
 272 float Monster_CanRespawn(entity ent)
 273 {
 274         other = ent;
 275         if(MUTATOR_CALLHOOK(MonsterRespawn))
 276                 return TRUE; // enabled by a mutator
 277
 278         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 279                 return FALSE;
 280
 281         if not(autocvar_g_monsters_respawn)
 282                 return FALSE;
 283
 284         return TRUE;
 285 }
 286
 287 void Monster_Fade ()
 288 {
 289         if(Monster_CanRespawn(self))
 290         {
 291                 self.monster_respawned = TRUE;
 292                 self.think = self.monster_spawnfunc;
 293                 self.nextthink = time + self.respawntime;
 294                 self.deadflag = DEAD_RESPAWNING;
 295                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 296                 {
 297                         self.pos1 = self.origin;
 298                         self.pos2 = self.angles;
 299                 }
 300                 self.event_damage = func_null;
 301                 self.takedamage = DAMAGE_NO;
 302                 setorigin(self, self.pos1);
 303                 self.angles = self.pos2;
 304                 self.health = self.max_health; // TODO: check if resetting to max_health is wise here
 305
 306                 self.SendFlags |= MSF_MOVE;
 307
 308                 return;
 309         }
 310         SUB_SetFade(self, time + 3, 1);
 311 }
 312
 313 float Monster_CanJump (vector vel)
 314 {
 315         if(self.state)
 316                 return FALSE; // already attacking
 317         if not(self.flags & FL_ONGROUND)
 318                 return FALSE; // not on the ground
 319         if(self.health <= 0)
 320                 return FALSE; // called when dead?
 321         if(time < self.attack_finished_single)
 322                 return FALSE; // still attacking
 323
 324         vector old = self.velocity;
 325
 326         self.velocity = vel;
 327         tracetoss(self, self);
 328         self.velocity = old;
 329         if (trace_ent != self.enemy)
 330                 return FALSE;
 331
 332         return TRUE;
 333 }
 334
 335 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 336 {
 337         if(!Monster_CanJump(vel))
 338                 return FALSE;
 339
 340         monsters_setframe(anm);
 341         self.state = MONSTER_STATE_ATTACK_LEAP;
 342         self.touch = touchfunc;
 343         self.origin_z += 1;
 344         self.velocity = vel;
 345         self.flags &~= FL_ONGROUND;
 346
 347         self.attack_finished_single = time + anim_finished;
 348
 349         return TRUE;
 350 }
 351
 352 float GenericCheckAttack ()
 353 {
 354         // checking attack while dead?
 355         if (self.health <= 0)
 356                 return FALSE;
 357
 358         // reset delays when we have no enemy
 359         if not(self.enemy)
 360         {
 361                 self.monster_delayedattack = func_null;
 362                 self.delay = -1;
 363         }
 364
 365         if(self.monster_delayedattack && self.delay != -1)
 366         {
 367                 if(time < self.delay)
 368                         return FALSE;
 369
 370                 self.monster_delayedattack();
 371         }
 372
 373         if (time < self.attack_finished_single)
 374                 return FALSE;
 375
 376         if(self.attack_melee)
 377         if(vlen(self.enemy.origin - self.origin) <= 100 * self.scale)
 378         {
 379                 monster_sound(self.msound_attack_melee, 0, FALSE); // no delay for attack sounds
 380                 self.attack_melee(); // don't wait for nextthink - too slow
 381                 return TRUE;
 382         }
 383
 384         // monster doesn't have a ranged attack function, so stop here
 385         if not(self.attack_ranged)
 386                 return FALSE;
 387
 388         // see if any entities are in the way of the shot
 389         if not(findtrajectorywithleading(self.origin, '0 0 0', '0 0 0', self.enemy, 800, 0, 2.5, 0, self))
 390                 return FALSE;
 391
 392         if(self.attack_ranged())
 393         {
 394                 monster_sound(self.msound_attack_ranged, 0, FALSE); // no delay for attack sounds
 395                 return TRUE;
 396         }
 397
 398         return FALSE;
 399 }
 400
 401 void monster_use ()
 402 {
 403         if (self.enemy)
 404                 return;
 405         if (self.health <= 0)
 406                 return;
 407
 408         if(!monster_isvalidtarget(activator, self))
 409                 return;
 410
 411         self.enemy = activator;
 412 }
 413
 414 float trace_path(vector from, vector to)
 415 {
 416         vector dir = normalize(to - from) * 15, offset = '0 0 0';
 417         float trace1 = trace_fraction;
 418
 419         offset_x = dir_y;
 420         offset_y = -dir_x;
 421         traceline (from+offset, to+offset, TRUE, self);
 422
 423         traceline(from-offset, to-offset, TRUE, self);
 424
 425         return ((trace1 < trace_fraction) ? trace1 : trace_fraction);
 426 }
 427
 428 .float last_trace;
 429 vector monster_pickmovetarget(entity targ)
 430 {
 431         // enemy is always preferred target
 432         if(self.enemy)
 433         {
 434                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 435                 self.last_trace = time + 0.1;
 436                 return self.enemy.origin;
 437         }
 438         if(targ)
 439         {
 440                 self.monster_movestate = MONSTER_MOVE_WANDER;
 441                 self.last_trace = time + 0.5;
 442                 return targ.origin;
 443         }
 444
 445         switch(self.monster_moveflags)
 446         {
 447                 case MONSTER_MOVE_OWNER:
 448                 {
 449                         self.monster_movestate = MONSTER_MOVE_OWNER;
 450                         self.last_trace = time + 0.3;
 451                         if(self.monster_owner && self.monster_owner.classname != "monster_swarm")
 452                                 return self.monster_owner.origin;
 453                 }
 454                 case MONSTER_MOVE_WANDER:
 455                 {
 456                         self.monster_movestate = MONSTER_MOVE_WANDER;
 457                         self.last_trace = time + 2;
 458
 459                         self.angles_y = random() * 500;
 460                         makevectors(self.angles);
 461                         return self.origin + v_forward * 600;
 462                 }
 463                 case MONSTER_MOVE_SPAWNLOC:
 464                 {
 465                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 466                         self.last_trace = time + 2;
 467                         return self.pos1;
 468                 }
 469                 default:
 470                 case MONSTER_MOVE_NOMOVE:
 471                 {
 472                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 473                         self.last_trace = time + 2;
 474                         return self.origin;
 475                 }
 476         }
 477 }
 478
 479 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 480 {
 481         if(self.target2)
 482                 self.goalentity = find(world, targetname, self.target2);
 483
 484         entity targ;
 485
 486         if(self.frozen)
 487         {
 488                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 489                 self.health = max(1, self.max_health * self.revive_progress);
 490
 491                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 492
 493                 movelib_beak_simple(stopspeed);
 494
 495                 self.velocity = '0 0 0';
 496                 self.enemy = world;
 497                 self.nextthink = time + 0.1;
 498
 499                 if(self.revive_progress >= 1)
 500                         Unfreeze(self); // wait for next think before attacking
 501
 502                 self.SendFlags |= MSF_MOVE;
 503
 504                 return; // no moving while frozen
 505         }
 506
 507         if(self.flags & FL_SWIM)
 508         {
 509                 if(self.waterlevel < WATERLEVEL_WETFEET)
 510                 {
 511                         if(time >= self.last_trace)
 512                         {
 513                                 self.last_trace = time + 0.4;
 514
 515                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 516                                 self.angles = '90 90 0';
 517                                 if(random() < 0.5)
 518                                 {
 519                                         self.velocity_y += random() * 50;
 520                                         self.velocity_x -= random() * 50;
 521                                 }
 522                                 else
 523                                 {
 524                                         self.velocity_y -= random() * 50;
 525                                         self.velocity_x += random() * 50;
 526                                 }
 527                                 self.velocity_z += random() * 150;
 528                         }
 529
 530
 531                         self.movetype = MOVETYPE_BOUNCE;
 532                         //self.velocity_z = -200;
 533
 534                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 535
 536                         return;
 537                 }
 538                 else
 539                 {
 540                         self.angles = '0 0 0';
 541                         self.movetype = MOVETYPE_WALK;
 542                 }
 543         }
 544
 545         if(gameover || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start))
 546         {
 547                 runspeed = walkspeed = 0;
 548                 monsters_setframe(manim_idle);
 549                 movelib_beak_simple(stopspeed);
 550                 self.SendFlags |= MSF_MOVE;
 551                 return;
 552         }
 553
 554         targ = self.goalentity;
 555
 556         monster_target = targ;
 557         monster_speed_run = runspeed;
 558         monster_speed_walk = walkspeed;
 559         MUTATOR_CALLHOOK(MonsterMove);
 560         targ = monster_target;
 561         runspeed = monster_speed_run;
 562         walkspeed = monster_speed_walk;
 563
 564         if(IsDifferentTeam(self.monster_owner, self))
 565                 self.monster_owner = world;
 566
 567         if not(monster_isvalidtarget(self.enemy, self))
 568                 self.enemy = world; // check enemy each think frame?
 569
 570         if not(self.enemy)
 571         {
 572                 self.enemy = FindTarget(self);
 573                 if(self.enemy)
 574                         monster_sound(self.msound_sight, 0, FALSE);
 575         }
 576
 577         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 578                 self.state = 0;
 579
 580         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 581         if(time >= self.last_trace || self.enemy) // update enemy instantly
 582                 self.moveto = monster_pickmovetarget(targ);
 583
 584         if not(self.enemy)
 585                 monster_sound(self.msound_idle, 5, TRUE);
 586
 587         vector angles_face = vectoangles(self.moveto - self.origin);
 588         vector owner_face = vectoangles(self.monster_owner.origin - self.origin);
 589         vector enemy_face = vectoangles(self.enemy.origin - self.origin);
 590
 591         if(self.state != MONSTER_STATE_ATTACK_LEAP)
 592         {
 593                 self.angles_y = angles_face_y;
 594                 self.v_angle = self.angles;
 595         }
 596
 597         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 598         {
 599                 self.state = 0;
 600                 self.touch = MonsterTouch;
 601         }
 602
 603         v_forward = normalize(self.moveto - self.origin);
 604
 605         float l = vlen(self.moveto - self.origin);
 606         float t1 = trace_path(self.origin+'0 0 10', self.moveto+'0 0 10');
 607         float t2 = trace_path(self.origin-'0 0 15', self.moveto-'0 0 15');
 608
 609         if(t1*l-t2*l>50 && (t1*l > 100 || t1 > 0.8))
 610         if(self.flags & FL_ONGROUND)
 611                 movelib_jump_simple(100);
 612
 613         if(vlen(self.origin - self.moveto) > 64 * self.scale)
 614         {
 615                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 616                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 617                 else
 618                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 619                 if(time > self.pain_finished)
 620                 if(time > self.attack_finished_single)
 621                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 622         }
 623         else
 624         {
 625                 if(self.goalentity.target)
 626                         self.target2 = self.goalentity.target;
 627                 else if(self.goalentity.target2)
 628                         self.target2 = self.goalentity.target2;
 629                 else
 630                 {
 631                         movelib_beak_simple(stopspeed);
 632                         if(time > self.attack_finished_single)
 633                         if(time > self.pain_finished)
 634                         if (vlen(self.velocity) <= 30)
 635                         {
 636                                 monsters_setframe(manim_idle);
 637                                 if(self.enemy)
 638                                         self.angles_y = enemy_face_y;
 639                                 else
 640                                         self.angles_y = ((self.monster_owner) ? owner_face_y : self.pos2_y); // reset looking angle now?
 641                         }
 642                 }
 643         }
 644
 645         if(self.enemy && self.checkattack)
 646                 self.checkattack();
 647
 648         self.SendFlags |= MSF_ANG;
 649         self.SendFlags |= MSF_MOVE;
 650 }
 651
 652 void monster_dead_think()
 653 {
 654         self.think = monster_dead_think;
 655         self.nextthink = time + 0.3; // don't need to update so often now
 656
 657         self.deadflag = DEAD_DEAD;
 658
 659         if(time >= self.ltime)
 660         {
 661                 Monster_Fade();
 662                 return;
 663         }
 664
 665         self.SendFlags |= MSF_MOVE; // keep up to date on the monster's location
 666 }
 667
 668 void monsters_setstatus()
 669 {
 670         self.stat_monsters_total = monsters_total;
 671         self.stat_monsters_killed = monsters_killed;
 672 }
 673
 674 void Monster_Appear()
 675 {
 676         self.enemy = activator;
 677         self.spawnflags &~= MONSTERFLAG_APPEAR;
 678         self.monster_spawnfunc();
 679 }
 680
 681 float Monster_CheckAppearFlags(entity ent)
 682 {
 683         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 684                 return FALSE;
 685
 686         ent.think = func_null;
 687         ent.nextthink = 0;
 688         ent.use = Monster_Appear;
 689         ent.flags = FL_MONSTER; // set so this monster can get butchered
 690
 691         return TRUE;
 692 }
 693
 694 void monsters_reset()
 695 {
 696         setorigin(self, self.pos1);
 697         self.angles = self.pos2;
 698
 699         self.health = self.max_health;
 700         self.velocity = '0 0 0';
 701         self.enemy = world;
 702         self.goalentity = world;
 703         self.attack_finished_single = 0;
 704         self.moveto = self.origin;
 705
 706         WaypointSprite_UpdateHealth(self.sprite, self.health);
 707 }
 708
 709 float monster_send(entity to, float sf)
 710 {
 711         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 712         WriteByte(MSG_ENTITY, sf);
 713         if(sf & MSF_SETUP)
 714         {
 715             WriteByte(MSG_ENTITY, self.monsterid);
 716
 717             WriteCoord(MSG_ENTITY, self.origin_x);
 718             WriteCoord(MSG_ENTITY, self.origin_y);
 719             WriteCoord(MSG_ENTITY, self.origin_z);
 720
 721             WriteAngle(MSG_ENTITY, self.angles_x);
 722             WriteAngle(MSG_ENTITY, self.angles_y);
 723
 724                 WriteByte(MSG_ENTITY, self.scale);
 725                 WriteByte(MSG_ENTITY, self.skin);
 726     }
 727
 728         if(sf & MSF_SIZE)
 729         {
 730                 WriteByte(MSG_ENTITY, self.scale);
 731
 732                 WriteCoord(MSG_ENTITY, self.mins_x);
 733             WriteCoord(MSG_ENTITY, self.mins_y);
 734             WriteCoord(MSG_ENTITY, self.mins_z);
 735
 736                 WriteCoord(MSG_ENTITY, self.maxs_x);
 737             WriteCoord(MSG_ENTITY, self.maxs_y);
 738             WriteCoord(MSG_ENTITY, self.maxs_z);
 739         }
 740
 741     if(sf & MSF_ANG)
 742     {
 743         WriteShort(MSG_ENTITY, rint(self.angles_x));
 744         WriteShort(MSG_ENTITY, rint(self.angles_y));
 745     }
 746
 747     if(sf & MSF_MOVE)
 748     {
 749         WriteShort(MSG_ENTITY, rint(self.origin_x));
 750         WriteShort(MSG_ENTITY, rint(self.origin_y));
 751         WriteShort(MSG_ENTITY, rint(self.origin_z));
 752
 753         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 754         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 755         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 756
 757         WriteShort(MSG_ENTITY, rint(self.angles_y));
 758     }
 759
 760     if(sf & MSF_ANIM)
 761     {
 762         WriteCoord(MSG_ENTITY, self.anim_start_time);
 763         WriteByte(MSG_ENTITY, self.frame);
 764     }
 765
 766     if(sf & MSF_STATUS)
 767     {
 768                 WriteByte(MSG_ENTITY, self.skin);
 769
 770         WriteByte(MSG_ENTITY, self.team);
 771
 772                 WriteByte(MSG_ENTITY, self.deadflag);
 773
 774         if(self.health <= 0)
 775             WriteByte(MSG_ENTITY, 0);
 776         else
 777             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 778     }
 779
 780         return TRUE;
 781 }
 782
 783 void monster_link(void() spawnproc)
 784 {
 785     Net_LinkEntity(self, TRUE, 0, monster_send);
 786     self.think      = spawnproc;
 787     self.nextthink  = time;
 788 }
 789
 790 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 791 {
 792         self.health -= damage;
 793
 794         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 795
 796         if(self.health <= -100) // 100 health until gone?
 797         {
 798                 Violence_GibSplash(self, 1, 0.5, attacker);
 799
 800                 self.think = SUB_Remove;
 801                 self.nextthink = time + 0.1;
 802         }
 803 }
 804
 805 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 806 {
 807         if(self.frozen && deathtype != DEATH_KILL)
 808                 return;
 809
 810         if(time < self.pain_finished && deathtype != DEATH_KILL)
 811                 return;
 812
 813         if((ignore_turrets && !(attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET)) || !ignore_turrets)
 814         if(monster_isvalidtarget(attacker, self))
 815                 self.enemy = attacker;
 816
 817         if(deathtype != DEATH_KILL)
 818                 damage *= self.armorvalue;
 819
 820         if(self.weaponentity && self.weaponentity.classname == "shield")
 821                 self.weaponentity.health -= damage;
 822
 823         self.health -= damage;
 824
 825         if(self.sprite)
 826                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 827
 828         self.dmg_time = time;
 829
 830         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 831                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 832
 833         self.velocity += force * self.damageforcescale;
 834
 835         if(deathtype != DEATH_DROWN)
 836         {
 837                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 838                 if (damage > 50)
 839                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 840                 if (damage > 100)
 841                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 842         }
 843
 844         if(self.health <= 0)
 845         {
 846                 if(self.sprite)
 847                 {
 848                         // Update one more time to avoid waypoint fading without emptying healthbar
 849                         WaypointSprite_UpdateHealth(self.sprite, 0);
 850                 }
 851
 852                 if(deathtype == DEATH_KILL)
 853                         self.candrop = FALSE; // killed by mobkill command
 854
 855                 // TODO: fix this?
 856                 activator = attacker;
 857                 other = self.enemy;
 858                 SUB_UseTargets();
 859                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 860
 861                 self.monster_die();
 862
 863                 frag_attacker = attacker;
 864                 frag_target = self;
 865                 MUTATOR_CALLHOOK(MonsterDies);
 866
 867                 if(self.health <= -100) // check if we're already gibbed
 868                 {
 869                         Violence_GibSplash(self, 1, 0.5, attacker);
 870
 871                         self.think = SUB_Remove;
 872                         self.nextthink = time + 0.1;
 873                 }
 874         }
 875
 876         self.SendFlags |= MSF_STATUS;
 877 }
 878
 879 // used to hook into monster post death functions without a mutator
 880 void monster_hook_death()
 881 {
 882         WaypointSprite_Kill(self.sprite);
 883
 884         if(self.weaponentity)
 885         {
 886                 remove(self.weaponentity);
 887                 self.weaponentity = world;
 888         }
 889
 890         monster_sound(self.msound_death, 0, FALSE);
 891
 892         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 893                 monsters_killed += 1;
 894
 895         if(self.candrop && self.weapon)
 896                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 897
 898         if(IS_CLIENT(self.realowner))
 899                 self.realowner.monstercount -= 1;
 900
 901         self.event_damage       = monsters_corpse_damage;
 902         self.solid                      = SOLID_CORPSE;
 903         self.takedamage         = DAMAGE_AIM;
 904         self.enemy                      = world;
 905         self.movetype           = MOVETYPE_TOSS;
 906         self.moveto                     = self.origin;
 907
 908         if not(self.flags & FL_FLY)
 909                 self.velocity = '0 0 0';
 910
 911         self.SendFlags |= MSF_MOVE;
 912
 913         totalspawned -= 1;
 914 }
 915
 916 // used to hook into monster post spawn functions without a mutator
 917 void monster_hook_spawn()
 918 {
 919         if not(self.monster_respawned)
 920                 Monster_CheckMinibossFlag();
 921
 922         self.max_health = self.health;
 923         self.pain_finished = self.nextthink;
 924         self.anim_start_time = time;
 925
 926         if(self.noalign)
 927         {
 928                 setorigin(self, self.origin);
 929                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 930                 setorigin(self, trace_endpos);
 931         }
 932
 933         self.pos1 = self.origin;
 934
 935         monster_precachesounds(self);
 936
 937         if(teamplay)
 938                 self.monster_attack = TRUE; // we can have monster enemies in team games
 939
 940         if(autocvar_g_monsters_healthbars)
 941         {
 942                 WaypointSprite_Spawn(strzone(strdecolorize(self.netname)), 0, 600, self, '0 0 1' * (self.maxs_z + 15), world, 0, self, sprite, FALSE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 943                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 944                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 945         }
 946
 947         monster_sound(self.msound_spawn, 0, FALSE);
 948
 949         MUTATOR_CALLHOOK(MonsterSpawn);
 950
 951         self.SendFlags = MSF_SETUP;
 952 }
 953
 954 float monster_initialize(string  net_name, float mon_id,
 955                                                  vector  min_s,
 956                                                  vector  max_s,
 957                                                  float   nodrop,
 958                                                  void() dieproc,
 959                                                  void() spawnproc)
 960 {
 961         if not(autocvar_g_monsters)
 962                 return FALSE;
 963
 964         // support for quake style removing monsters based on skill
 965         if(monster_skill <= autocvar_g_monsters_skill_easy && (self.spawnflags & MONSTERSKILL_NOTEASY)) { return FALSE; }
 966         if(monster_skill == autocvar_g_monsters_skill_normal && (self.spawnflags & MONSTERSKILL_NOTMEDIUM)) { return FALSE; }
 967         if(monster_skill == autocvar_g_monsters_skill_hard && (self.spawnflags & MONSTERSKILL_NOTHARD)) { return FALSE; }
 968         if(monster_skill == autocvar_g_monsters_skill_insane && (self.spawnflags & MONSTERSKILL_NOTINSANE)) { return FALSE; }
 969         if(monster_skill >= autocvar_g_monsters_skill_nightmare && (self.spawnflags & MONSTERSKILL_NOTNIGHTMARE)) { return FALSE; }
 970
 971         if(self.netname == "")
 972                 self.netname = ((net_name == "") ? self.classname : net_name);
 973
 974         if(autocvar_g_monsters_giants_only)
 975                 self.spawnflags |= MONSTERFLAG_GIANT;
 976
 977         if not(self.scale)
 978                 self.scale = 1;
 979
 980         if(self.spawnflags & MONSTERFLAG_GIANT && !autocvar_g_monsters_nogiants)
 981                 self.scale = 5;
 982
 983         if(self.team && !teamplay)
 984                 self.team = 0;
 985
 986         self.flags = FL_MONSTER;
 987
 988         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 989         if not(self.monster_respawned)
 990                 monsters_total += 1;
 991
 992         ScaleMonster(self.scale, min_s, max_s);
 993
 994         self.takedamage                 = DAMAGE_AIM;
 995         self.bot_attack                 = TRUE;
 996         self.iscreature                 = TRUE;
 997         self.teleportable               = TRUE;
 998         self.damagedbycontents  = TRUE;
 999         self.monsterid                  = mon_id;
1000         self.damageforcescale   = 0.003;
1001         self.monster_die                = dieproc;
1002         self.event_damage               = monsters_damage;
1003         self.touch                              = MonsterTouch;
1004         self.use                                = monster_use;
1005         self.solid                              = SOLID_BBOX;
1006         self.movetype                   = MOVETYPE_WALK;
1007         self.delay                              = -1; // used in attack delay code
1008         monsters_spawned           += 1;
1009         self.enemy                              = world;
1010         self.velocity                   = '0 0 0';
1011         self.moveto                             = self.origin;
1012         self.pos2                               = self.angles;
1013         self.reset                              = monsters_reset;
1014         self.candrop                    = TRUE;
1015         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1016         self.oldtarget2                 = self.target2;
1017         self.deadflag                   = DEAD_NO; // UNDEAD
1018         self.noalign                    = !nodrop;
1019         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1020
1021         if not(self.ticrate)
1022                 self.ticrate = autocvar_g_monsters_think_delay;
1023
1024         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1025
1026         if not(self.armorvalue)
1027                 self.armorvalue = 1; // multiplier
1028
1029         if not(self.target_range)
1030                 self.target_range = autocvar_g_monsters_target_range;
1031
1032         if not(self.respawntime)
1033                 self.respawntime = autocvar_g_monsters_respawn_delay;
1034
1035         if not(self.monster_moveflags)
1036                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1037
1038         monster_link(spawnproc);
1039
1040         return TRUE;
1041 }