qcsrc/server/monsters/monster/hknight.qc

   1 // size
   2 const vector HELLKNIGHT_MIN = '-16 -16 -24';
   3 const vector HELLKNIGHT_MAX = '16 16 32';
   4
   5 // cvars
   6 float autocvar_g_monster_hellknight;
   7 float autocvar_g_monster_hellknight_health;
   8 float autocvar_g_monster_hellknight_melee_damage;
   9 float autocvar_g_monster_hellknight_inferno_damage;
  10 float autocvar_g_monster_hellknight_inferno_damagetime;
  11 float autocvar_g_monster_hellknight_inferno_chance;
  12 float autocvar_g_monster_hellknight_speed_walk;
  13 float autocvar_g_monster_hellknight_speed_run;
  14 float autocvar_g_monster_hellknight_fireball_damage;
  15 float autocvar_g_monster_hellknight_fireball_force;
  16 float autocvar_g_monster_hellknight_fireball_radius;
  17 float autocvar_g_monster_hellknight_fireball_chance;
  18 float autocvar_g_monster_hellknight_fireball_edgedamage;
  19 float autocvar_g_monster_hellknight_spike_chance;
  20 float autocvar_g_monster_hellknight_spike_force;
  21 float autocvar_g_monster_hellknight_spike_radius;
  22 float autocvar_g_monster_hellknight_spike_edgedamage;
  23 float autocvar_g_monster_hellknight_spike_damage;
  24 float autocvar_g_monster_hellknight_jump_chance;
  25 float autocvar_g_monster_hellknight_jump_damage;
  26 float autocvar_g_monster_hellknight_jump_dist;
  27
  28 // animations
  29 #define hellknight_anim_stand   0
  30 #define hellknight_anim_walk    1
  31 #define hellknight_anim_run     2
  32 #define hellknight_anim_pain    3
  33 #define hellknight_anim_death1  4
  34 #define hellknight_anim_death2  5
  35 #define hellknight_anim_charge1 6
  36 #define hellknight_anim_magic1  7
  37 #define hellknight_anim_magic2  8
  38 #define hellknight_anim_charge2 9
  39 #define hellknight_anim_slice   10
  40 #define hellknight_anim_smash   11
  41 #define hellknight_anim_wattack 12
  42 #define hellknight_anim_magic3  13
  43
  44 void hknight_spike_think()
  45 {
  46         if(self)
  47         {
  48                 RadiusDamage (self, self.realowner, autocvar_g_monster_hellknight_spike_damage * self.realowner.scale, autocvar_g_monster_hellknight_spike_edgedamage, autocvar_g_monster_hellknight_spike_force, world, autocvar_g_monster_hellknight_spike_radius, WEP_CRYLINK, other);
  49                 remove(self);
  50         }
  51 }
  52
  53 void hknight_spike_touch()
  54 {
  55         PROJECTILE_TOUCH;
  56
  57         pointparticles(particleeffectnum("TE_WIZSPIKE"), self.origin, '0 0 0', 1);
  58
  59         hknight_spike_think();
  60 }
  61
  62 void() hellknight_think;
  63 void hknight_shoot ()
  64 {
  65         local   entity  missile = world;
  66         local   vector  dir = normalize((self.enemy.origin + '0 0 10') - self.origin);
  67         local   float   dist = vlen (self.enemy.origin - self.origin), flytime = 0;
  68
  69         flytime = dist * 0.002;
  70         if (flytime < 0.1)
  71                 flytime = 0.1;
  72
  73         self.effects |= EF_MUZZLEFLASH;
  74         sound (self, CHAN_WEAPON, "weapons/spike.wav", 1, ATTN_NORM);
  75
  76         missile = spawn ();
  77         missile.owner = missile.realowner = self;
  78         missile.solid = SOLID_TRIGGER;
  79         missile.movetype = MOVETYPE_FLYMISSILE;
  80         setsize (missile, '0 0 0', '0 0 0');
  81         setorigin(missile, self.origin + '0 0 10' + v_forward * 14);
  82         missile.scale = self.scale;
  83         missile.flags = FL_PROJECTILE;
  84         missile.velocity = dir * 400;
  85         missile.avelocity = '300 300 300';
  86         missile.nextthink = time + 5;
  87         missile.think = hknight_spike_think;
  88         missile.enemy = self.enemy;
  89         missile.touch = hknight_spike_touch;
  90         CSQCProjectile(missile, TRUE, PROJECTILE_CRYLINK, TRUE);
  91 }
  92
  93 void hknight_inferno ()
  94 {
  95         traceline((self.absmin + self.absmax) * 0.5, (self.enemy.absmin + self.enemy.absmax) * 0.5, TRUE, world);
  96         if (trace_fraction != 1)
  97                 return; // not visible
  98         if(enemy_range() <= 2000)
  99                 Fire_AddDamage(self.enemy, self, autocvar_g_monster_hellknight_inferno_damage * monster_skill, autocvar_g_monster_hellknight_inferno_damagetime, self.projectiledeathtype);
 100 }
 101
 102 void hknight_infernowarning ()
 103 {
 104         if(!self.enemy)
 105                 return;
 106
 107         traceline((self.absmin + self.absmax) * 0.5, (self.enemy.absmin + self.enemy.absmax) * 0.5, TRUE, world);
 108         if (trace_fraction != 1)
 109                 return; // not visible
 110         self.enemy.effects |= EF_MUZZLEFLASH;
 111         sound(self.enemy, CHAN_AUTO, "player/lava.wav", 1, ATTN_NORM);
 112
 113         hknight_inferno();
 114 }
 115
 116 float() hknight_magic;
 117 float hknight_checkmagic ()
 118 {
 119         local vector v1 = '0 0 0', v2 = '0 0 0';
 120         local float dot = 0;
 121
 122         // use magic to kill zombies as they heal too fast for sword
 123         if (self.enemy.classname == "monster_zombie")
 124         {
 125                 traceline((self.absmin + self.absmax) * 0.5, (self.enemy.absmin + self.enemy.absmax) * 0.5, FALSE, self);
 126                 if (trace_ent == self.enemy)
 127                 {
 128                         hknight_magic();
 129                         return TRUE;
 130                 }
 131         }
 132
 133         if (random() < 0.25)
 134                 return FALSE; // 25% of the time it won't do anything
 135         v1 = normalize(self.enemy.velocity);
 136         v2 = normalize(self.enemy.origin - self.origin);
 137         dot = v1 * v2;
 138         if (dot >= 0.7) // moving away
 139         if (vlen(self.enemy.velocity) >= 150) // walking/running away
 140                 return hknight_magic();
 141         return FALSE;
 142 }
 143
 144 void() hellknight_charge;
 145 void CheckForCharge ()
 146 {
 147         // check for mad charge
 148         if (time < self.attack_finished_single)
 149                 return;
 150         if (fabs(self.origin_z - self.enemy.origin_z) > 20)
 151                 return;         // too much height change
 152         if (vlen (self.origin - self.enemy.origin) < 80)
 153                 return;         // use regular attack
 154         if (hknight_checkmagic())
 155                 return; // chose magic
 156
 157         // charge
 158         hellknight_charge();
 159 }
 160
 161 void CheckContinueCharge ()
 162 {
 163         if(hknight_checkmagic())
 164                 return; // chose magic
 165         if(time >= self.attack_finished_single)
 166         {
 167                 hellknight_think();
 168                 return;         // done charging
 169         }
 170 }
 171
 172 void hellknight_think ()
 173 {
 174         self.think = hellknight_think;
 175         self.nextthink = time + 0.1;
 176
 177         monster_move(autocvar_g_monster_hellknight_speed_run, autocvar_g_monster_hellknight_speed_walk, 100, hellknight_anim_run, hellknight_anim_walk, hellknight_anim_stand);
 178 }
 179
 180 .float hknight_cycles;
 181 void hellknight_magic ()
 182 {
 183         self.hknight_cycles += 1;
 184         self.think = hellknight_magic;
 185
 186         if(self.hknight_cycles >= 5)
 187         {
 188                 self.frame = hellknight_anim_magic1;
 189                 self.attack_finished_single = time + 0.7;
 190                 hknight_infernowarning();
 191                 self.think = hellknight_think;
 192         }
 193
 194         self.nextthink = time + 0.1;
 195 }
 196
 197 void hknight_fireball_explode(entity targ)
 198 {
 199         float scle = self.realowner.scale;
 200         if(self)
 201         {
 202                 RadiusDamage (self, self.realowner, autocvar_g_monster_hellknight_fireball_damage * scle, autocvar_g_monster_hellknight_fireball_edgedamage * scle, autocvar_g_monster_hellknight_fireball_force * scle, world, autocvar_g_monster_hellknight_fireball_radius * scle, WEP_FIREBALL, targ);
 203                 if(targ)
 204                         Fire_AddDamage(targ, self, 5 * monster_skill, autocvar_g_monster_hellknight_inferno_damagetime, self.projectiledeathtype);
 205                 remove(self);
 206         }
 207 }
 208
 209 void hknight_fireball_think()
 210 {
 211         hknight_fireball_explode(world);
 212 }
 213
 214 void hknight_fireball_touch()
 215 {
 216         PROJECTILE_TOUCH;
 217
 218         hknight_fireball_explode(other);
 219 }
 220
 221 void hellknight_fireball ()
 222 {
 223         local   entity  missile = spawn();
 224         local   vector  dir = normalize((self.enemy.origin + '0 0 10') - self.origin);
 225         vector fmins = ((self.scale >= 2) ? '-16 -16 -16' : '-4 -4 -4'), fmaxs = ((self.scale >= 2) ? '16 16 16' : '4 4 4');
 226
 227         self.effects |= EF_MUZZLEFLASH;
 228         sound (self, CHAN_WEAPON, "weapons/fireball2.wav", 1, ATTN_NORM);
 229
 230         missile.owner = missile.realowner = self;
 231         missile.solid = SOLID_TRIGGER;
 232         missile.movetype = MOVETYPE_FLYMISSILE;
 233         setsize (missile, fmins, fmaxs);
 234         setorigin(missile, self.origin + '0 0 10' + v_forward * 14);
 235         missile.flags = FL_PROJECTILE;
 236         missile.velocity = dir * 400;
 237         missile.avelocity = '300 300 300';
 238         missile.nextthink = time + 5;
 239         missile.think = hknight_fireball_think;
 240         missile.enemy = self.enemy;
 241         missile.touch = hknight_fireball_touch;
 242         CSQCProjectile(missile, TRUE, ((self.scale >= 2) ? PROJECTILE_FIREBALL : PROJECTILE_FIREMINE), TRUE);
 243
 244         self.delay = -1;
 245 }
 246
 247 void hellknight_magic2 ()
 248 {
 249         self.frame = hellknight_anim_magic2;
 250         self.attack_finished_single = time + 1.2;
 251         self.delay = time + 0.4;
 252         self.monster_delayedattack = hellknight_fireball;
 253 }
 254
 255 void hellknight_spikes ()
 256 {
 257         self.think = hellknight_spikes;
 258         self.nextthink = time + 0.1;
 259         self.hknight_cycles += 1;
 260         hknight_shoot();
 261         if(self.hknight_cycles >= 7)
 262                 self.think = hellknight_think;
 263 }
 264
 265 void hellknight_magic3 ()
 266 {
 267         self.frame = hellknight_anim_magic3;
 268         self.attack_finished_single = time + 1;
 269         self.think = hellknight_spikes;
 270         self.nextthink = time + 0.4;
 271 }
 272
 273 void hellknight_charge ()
 274 {
 275         self.frame = hellknight_anim_charge1;
 276         self.attack_finished_single = time + 0.5;
 277
 278         hknight_checkmagic();
 279         monster_melee(self.enemy, autocvar_g_monster_hellknight_melee_damage, 70, DEATH_MONSTER_MELEE);
 280         hknight_checkmagic();
 281 }
 282
 283 void hellknight_charge2 ()
 284 {
 285         self.frame = hellknight_anim_charge2;
 286         self.attack_finished_single = time + 0.5;
 287
 288         CheckContinueCharge ();
 289         monster_melee(self.enemy, autocvar_g_monster_hellknight_melee_damage, 70, DEATH_MONSTER_MELEE);
 290 }
 291
 292 void hellknight_slice ()
 293 {
 294         self.frame = hellknight_anim_slice;
 295         self.attack_finished_single = time + 0.7;
 296         monster_melee(self.enemy, autocvar_g_monster_hellknight_melee_damage, 70, DEATH_MONSTER_MELEE);
 297 }
 298
 299 void hellknight_smash ()
 300 {
 301         self.frame = hellknight_anim_smash;
 302         self.attack_finished_single = time + 0.7;
 303         monster_melee(self.enemy, autocvar_g_monster_hellknight_melee_damage, 70, DEATH_MONSTER_MELEE);
 304 }
 305
 306 void hellknight_weapon_attack ()
 307 {
 308         self.frame = hellknight_anim_wattack;
 309         self.attack_finished_single = time + 0.7;
 310         monster_melee(self.enemy, autocvar_g_monster_hellknight_melee_damage, 70, DEATH_MONSTER_MELEE);
 311 }
 312
 313 float hknight_type;
 314 void hknight_melee ()
 315 {
 316         hknight_type += 1;
 317
 318         if (hknight_type == 1)
 319                 hellknight_slice();
 320         else if (hknight_type == 2)
 321                 hellknight_smash();
 322         else
 323         {
 324                 hellknight_weapon_attack();
 325                 hknight_type = 0;
 326         }
 327 }
 328
 329 float hknight_magic ()
 330 {
 331         if not(self.flags & FL_ONGROUND)
 332                 return FALSE;
 333
 334         if not(self.enemy)
 335                 return FALSE; // calling attack check with no enemy?!
 336
 337         if(time < self.attack_finished_single)
 338                 return FALSE;
 339
 340         self.hknight_cycles = 0;
 341
 342         if (self.enemy.classname == "monster_zombie")
 343         {
 344                 // always use fireball to kill zombies
 345                 hellknight_magic2();
 346                 self.attack_finished_single = time + 2;
 347                 return TRUE;
 348         }
 349         RandomSelection_Init();
 350         RandomSelection_Add(world, 0, "fireball", autocvar_g_monster_hellknight_fireball_chance, 1);
 351         RandomSelection_Add(world, 0, "inferno", autocvar_g_monster_hellknight_inferno_chance, 1);
 352         RandomSelection_Add(world, 0, "spikes", autocvar_g_monster_hellknight_spike_chance, 1);
 353         if(self.health >= 100)
 354                 RandomSelection_Add(world, 0, "jump", ((enemy_range() > autocvar_g_monster_hellknight_jump_dist * self.scale) ? 1 : autocvar_g_monster_hellknight_jump_chance), 1);
 355
 356         switch(RandomSelection_chosen_string)
 357         {
 358                 case "fireball":
 359                 {
 360                         hellknight_magic2();
 361                         self.attack_finished_single = time + 2;
 362                         return TRUE;
 363                 }
 364                 case "spikes":
 365                 {
 366                         hellknight_magic3();
 367                         self.attack_finished_single = time + 3;
 368                         return TRUE;
 369                 }
 370                 case "inferno":
 371                 {
 372                         hellknight_magic();
 373                         self.attack_finished_single = time + 3;
 374                         return TRUE;
 375                 }
 376                 case "jump":
 377                 {
 378                         if (enemy_range() >= 400)
 379                         if (findtrajectorywithleading(self.origin, self.mins, self.maxs, self.enemy, 1000, 0, 10, 0, self))
 380                         {
 381                                 self.velocity = findtrajectory_velocity;
 382                                 Damage(self.enemy, self, self, autocvar_g_monster_hellknight_jump_damage * monster_skill, DEATH_VHCRUSH, self.enemy.origin, normalize(self.enemy.origin - self.origin));
 383                                 self.attack_finished_single = time + 2;
 384                                 return TRUE;
 385                         }
 386                         return FALSE;
 387                 }
 388                 default:
 389                         return FALSE;
 390         }
 391         // never get here
 392 }
 393
 394 void hellknight_die ()
 395 {
 396         float chance = random();
 397         Monster_CheckDropCvars ("hellknight");
 398
 399         self.solid                      = SOLID_NOT;
 400         self.takedamage         = DAMAGE_NO;
 401         self.event_damage   = func_null;
 402         self.enemy                      = world;
 403         self.movetype           = MOVETYPE_TOSS;
 404         self.think                      = Monster_Fade;
 405         self.nextthink          = time + 2.1;
 406         self.pain_finished  = self.nextthink;
 407
 408         if(chance < 0.10 || self.flags & MONSTERFLAG_MINIBOSS)
 409         {
 410                 self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 411                 W_ThrowNewWeapon(self, WEP_FIREBALL, 0, self.origin, self.velocity);
 412         }
 413
 414         if (random() > 0.5)
 415                 self.frame = hellknight_anim_death1;
 416         else
 417                 self.frame = hellknight_anim_death2;
 418
 419         monster_hook_death(); // for post-death mods
 420 }
 421
 422 void hellknight_spawn ()
 423 {
 424         if not(self.health)
 425                 self.health = autocvar_g_monster_hellknight_health * self.scale;
 426
 427         self.damageforcescale   = 0.003;
 428         self.classname                  = "monster_hellknight";
 429         self.checkattack                = GenericCheckAttack;
 430         self.attack_melee               = hknight_melee;
 431         self.attack_ranged              = hknight_magic;
 432         self.nextthink                  = time + random() * 0.5 + 0.1;
 433         self.think                              = hellknight_think;
 434         self.sprite_height              = 30 * self.scale;
 435         self.frame                              = hellknight_anim_stand;
 436
 437         monster_hook_spawn(); // for post-spawn mods
 438 }
 439
 440 void spawnfunc_monster_hell_knight ()
 441 {
 442         if not(autocvar_g_monster_hellknight) { remove(self); return; }
 443
 444         self.monster_spawnfunc = spawnfunc_monster_hell_knight;
 445
 446         if(self.spawnflags & MONSTERFLAG_APPEAR)
 447         {
 448                 self.think = func_null;
 449                 self.nextthink = -1;
 450                 self.use = Monster_Appear;
 451                 return;
 452         }
 453
 454         self.scale = 1.3;
 455
 456         if not (monster_initialize(
 457                          "Hell-knight",
 458                          "models/monsters/hknight.mdl",
 459                          HELLKNIGHT_MIN, HELLKNIGHT_MAX,
 460                          FALSE,
 461                          hellknight_die, hellknight_spawn))
 462         {
 463                 remove(self);
 464                 return;
 465         }
 466
 467         precache_sound ("weapons/spike.wav");
 468 }
 469
 470 // compatibility with old spawns
 471 void spawnfunc_monster_hellknight () { spawnfunc_monster_hell_knight(); }