qcsrc/server/monsters/monster/soldier.qc

   1 // size
   2 const vector SOLDIER_MIN = '-16 -16 -30';
   3 const vector SOLDIER_MAX = '16 16 24';
   4
   5 // model
   6 string SOLDIER_MODEL = "models/monsters/soldier.zym";
   7
   8 #ifdef SVQC
   9 // cvars
  10 float autocvar_g_monster_soldier;
  11 float autocvar_g_monster_soldier_health;
  12 float autocvar_g_monster_soldier_melee_damage;
  13 float autocvar_g_monster_soldier_speed_walk;
  14 float autocvar_g_monster_soldier_speed_run;
  15 float autocvar_g_monster_soldier_ammo;
  16 float autocvar_g_monster_soldier_weapon_laser_chance;
  17 float autocvar_g_monster_soldier_weapon_shotgun_chance;
  18 float autocvar_g_monster_soldier_weapon_machinegun_chance;
  19 float autocvar_g_monster_soldier_weapon_rocketlauncher_chance;
  20 float autocvar_g_monster_soldier_attack_uzi_bullets;
  21 float autocvar_g_monster_soldier_attack_uzi_damage;
  22 float autocvar_g_monster_soldier_attack_uzi_force;
  23 float autocvar_g_monster_soldier_attack_shotgun_damage;
  24 float autocvar_g_monster_soldier_attack_shotgun_force;
  25 float autocvar_g_monster_soldier_attack_shotgun_spread;
  26 float autocvar_g_monster_soldier_attack_shotgun_bullets;
  27 float autocvar_g_monster_soldier_attack_rocket_damage;
  28 float autocvar_g_monster_soldier_attack_rocket_edgedamage;
  29 float autocvar_g_monster_soldier_attack_rocket_radius;
  30 float autocvar_g_monster_soldier_attack_rocket_force;
  31 float autocvar_g_monster_soldier_attack_rocket_lifetime;
  32 float autocvar_g_monster_soldier_attack_rocket_speed;
  33 float autocvar_g_monster_soldier_attack_laser_damage;
  34 float autocvar_g_monster_soldier_attack_laser_edgedamage;
  35 float autocvar_g_monster_soldier_attack_laser_radius;
  36 float autocvar_g_monster_soldier_attack_laser_force;
  37
  38 // animations
  39 const float soldier_anim_die1                   = 0;
  40 const float soldier_anim_die2                   = 1;
  41 const float soldier_anim_draw                   = 2;
  42 const float soldier_anim_duck                   = 3;
  43 const float soldier_anim_duckwalk               = 4;
  44 const float soldier_anim_duckjump               = 5;
  45 const float soldier_anim_duckidle               = 6;
  46 const float soldier_anim_idle                   = 7;
  47 const float soldier_anim_jump                   = 8;
  48 const float soldier_anim_pain1                  = 9;
  49 const float soldier_anim_pain2                  = 10;
  50 const float soldier_anim_shoot                  = 11;
  51 const float soldier_anim_taunt                  = 12;
  52 const float soldier_anim_run                    = 13;
  53 const float soldier_anim_runbackwards   = 14;
  54 const float soldier_anim_strafeleft     = 15;
  55 const float soldier_anim_straferight    = 16;
  56 const float soldier_anim_dead1                  = 17;
  57 const float soldier_anim_dead2                  = 18;
  58 const float soldier_anim_forwardright   = 19;
  59 const float soldier_anim_forwardleft    = 20;
  60 const float soldier_anim_backright              = 21;
  61 const float soldier_anim_backleft               = 22;
  62
  63 void soldier_think ()
  64 {
  65         self.think = soldier_think;
  66         self.nextthink = time + self.ticrate;
  67
  68         if(self.delay != -1)
  69                 self.nextthink = self.delay;
  70
  71         if(time < self.attack_finished_single)
  72                 monster_move(0, 0, 0, soldier_anim_shoot, soldier_anim_shoot, soldier_anim_shoot);
  73         else
  74                 monster_move(autocvar_g_monster_soldier_speed_run, autocvar_g_monster_soldier_speed_walk, 50, soldier_anim_run, soldier_anim_run, soldier_anim_idle);
  75 }
  76
  77 void soldier_reload ()
  78 {
  79         self.monster_delayedattack = func_null; // out of ammo, don't keep attacking
  80         self.delay = -1;
  81         monsters_setframe(soldier_anim_draw);
  82         self.attack_finished_single = time + 2;
  83         self.currentammo = autocvar_g_monster_soldier_ammo;
  84         sound (self, CH_SHOTS, "weapons/reload.wav", VOL_BASE, ATTN_LARGE);
  85 }
  86
  87 .float grunt_cycles;
  88 void soldier_uzi_fire ()
  89 {
  90         self.currentammo -= 1;
  91         if(self.currentammo <= 0)
  92         {
  93                 soldier_reload();
  94                 return;
  95         }
  96
  97         self.grunt_cycles += 1;
  98
  99         if(self.grunt_cycles > autocvar_g_monster_soldier_attack_uzi_bullets)
 100         {
 101                 self.monster_delayedattack = func_null;
 102                 self.delay = -1;
 103                 return;
 104         }
 105
 106         W_SetupShot (self, autocvar_g_antilag_bullets && 18000 >= autocvar_g_antilag_bullets, 0, "weapons/uzi_fire.wav", CH_WEAPON_A, autocvar_g_monster_soldier_attack_uzi_damage);
 107         fireBallisticBullet(w_shotorg, w_shotdir, 0.02, 18000, 5, autocvar_g_monster_soldier_attack_uzi_damage, autocvar_g_monster_soldier_attack_uzi_force, DEATH_MONSTER_MARINE, 0, 1, 115);
 108         endFireBallisticBullet();
 109
 110         self.delay = time + 0.1;
 111         self.monster_delayedattack = soldier_uzi_fire;
 112 }
 113
 114 void soldier_rocket_explode()
 115 {
 116         self.event_damage = func_null;
 117         self.takedamage = DAMAGE_NO;
 118
 119         pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 120         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 121
 122         RadiusDamage (self, self.realowner, autocvar_g_monster_soldier_attack_rocket_damage, autocvar_g_monster_soldier_attack_rocket_edgedamage, autocvar_g_monster_soldier_attack_rocket_radius, world, autocvar_g_monster_soldier_attack_rocket_force, self.projectiledeathtype, other);
 123
 124         remove (self);
 125 }
 126
 127 void soldier_rocket_touch()
 128 {
 129         PROJECTILE_TOUCH;
 130
 131         soldier_rocket_explode();
 132 }
 133
 134 void soldier_rocket_think()
 135 {
 136         self.nextthink = time;
 137         if (time > self.cnt)
 138         {
 139                 soldier_rocket_explode();
 140                 return;
 141         }
 142 }
 143
 144 void soldier_rocket_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 145 {
 146         if (self.health <= 0)
 147                 return;
 148
 149         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 150                 return; // g_projectiles_damage says to halt
 151
 152         self.health -= damage;
 153         self.angles = vectoangles(self.velocity);
 154
 155         if (self.health <= 0)
 156                 W_PrepareExplosionByDamage(attacker, soldier_rocket_explode);
 157 }
 158
 159 void soldier_rocket_fire()
 160 {
 161         entity missile;
 162
 163         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CH_WEAPON_A, autocvar_g_monster_soldier_attack_rocket_damage);
 164
 165         missile = spawn();
 166         missile.owner = missile.realowner = self;
 167         missile.classname = "rocket";
 168         missile.bot_dodge = TRUE;
 169         missile.bot_dodgerating = autocvar_g_monster_soldier_attack_rocket_damage * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 170
 171         missile.takedamage = DAMAGE_YES;
 172         missile.health = 50;
 173         missile.event_damage = soldier_rocket_damage;
 174         missile.damagedbycontents = TRUE;
 175
 176         missile.movetype = MOVETYPE_FLY;
 177         PROJECTILE_MAKETRIGGER(missile);
 178         missile.projectiledeathtype = DEATH_MONSTER_MARINE;
 179         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 180
 181         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 182         W_SetupProjectileVelocity(missile, autocvar_g_monster_soldier_attack_rocket_speed, 0);
 183         missile.angles = vectoangles (missile.velocity);
 184
 185         missile.touch = soldier_rocket_touch;
 186         missile.think = soldier_rocket_think;
 187         missile.nextthink = time;
 188         missile.cnt = time + autocvar_g_monster_soldier_attack_rocket_lifetime;
 189         missile.flags = FL_PROJECTILE;
 190         missile.missile_flags = MIF_SPLASH;
 191
 192         CSQCProjectile(missile, TRUE, PROJECTILE_ROCKET, FALSE);
 193 }
 194
 195 void soldier_shotgun_fire()
 196 {
 197         float sc;
 198         W_SetupShot (self, autocvar_g_antilag_bullets && 18000 >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CH_WEAPON_A, autocvar_g_monster_soldier_attack_shotgun_damage * autocvar_g_monster_soldier_attack_shotgun_bullets);
 199         for (sc = 0;sc < autocvar_g_monster_soldier_attack_shotgun_bullets;sc = sc + 1)
 200                 fireBallisticBullet(w_shotorg, w_shotdir, autocvar_g_monster_soldier_attack_shotgun_spread, 18000, 5, autocvar_g_monster_soldier_attack_shotgun_damage, autocvar_g_monster_soldier_attack_shotgun_force, DEATH_MONSTER_MARINE, 0, 1, 115);
 201         endFireBallisticBullet();
 202 }
 203
 204 void soldier_laser_touch()
 205 {
 206         PROJECTILE_TOUCH;
 207
 208         self.event_damage = func_null;
 209         RadiusDamage (self, self.realowner, autocvar_g_monster_soldier_attack_laser_damage, autocvar_g_monster_soldier_attack_laser_edgedamage, autocvar_g_monster_soldier_attack_laser_radius, world, autocvar_g_monster_soldier_attack_laser_force, self.projectiledeathtype, other);
 210
 211         remove (self);
 212 }
 213
 214 void soldier_laser_fire()
 215 {
 216         entity missile;
 217
 218         W_SetupShot_Dir(self, v_forward, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, autocvar_g_monster_soldier_attack_laser_damage);
 219
 220         missile = spawn ();
 221         missile.owner = missile.realowner = self;
 222         missile.classname = "laserbolt";
 223         PROJECTILE_MAKETRIGGER(missile);
 224         missile.projectiledeathtype = DEATH_MONSTER_MARINE;
 225
 226         setorigin (missile, w_shotorg);
 227         setsize(missile, '0 0 0', '0 0 0');
 228
 229         W_SETUPPROJECTILEVELOCITY(missile, g_monster_soldier_attack_laser);
 230         missile.angles = vectoangles(missile.velocity);
 231         missile.touch = soldier_laser_touch;
 232
 233         missile.flags = FL_PROJECTILE;
 234         missile.missile_flags = MIF_SPLASH;
 235         missile.movetype = MOVETYPE_FLY;
 236
 237         missile.think = SUB_Remove;
 238         missile.nextthink = time + 5;
 239
 240         CSQCProjectile(missile, TRUE, PROJECTILE_LASER, TRUE);
 241 }
 242
 243 float soldier_attack()
 244 {
 245         monsters_setframe(soldier_anim_shoot);
 246         makevectors(self.angles);
 247
 248         if(self.currentammo <= 0)
 249         {
 250                 soldier_reload();
 251                 return FALSE;
 252         }
 253
 254         self.grunt_cycles = 0;
 255
 256         switch(self.weapon)
 257         {
 258                 case WEP_ROCKET_LAUNCHER:
 259                 {
 260                         self.currentammo -= 1;
 261                         self.attack_finished_single = time + 0.8;
 262                         soldier_rocket_fire();
 263                         return TRUE;
 264                 }
 265                 case WEP_SHOTGUN:
 266                 {
 267                         self.currentammo -= 1;
 268                         self.attack_finished_single = time + 0.8;
 269                         soldier_shotgun_fire();
 270                         return TRUE;
 271                 }
 272                 case WEP_UZI:
 273                 {
 274                         self.attack_finished_single = time + 0.8;
 275                         self.delay = time + 0.1;
 276                         self.monster_delayedattack = soldier_uzi_fire;
 277                         return TRUE;
 278                 }
 279                 case WEP_LASER:
 280                 {
 281                         self.attack_finished_single = time + 0.8;
 282                         soldier_laser_fire();
 283                         return TRUE;
 284                 }
 285                 default:
 286                         return FALSE; // no weapon?
 287         }
 288 }
 289
 290 void soldier_melee ()
 291 {
 292         monsters_setframe(soldier_anim_shoot);
 293         self.attack_finished_single = time + 0.8;
 294         monster_melee(self.enemy, autocvar_g_monster_soldier_melee_damage, 0.3, DEATH_MONSTER_MARINE_SLAP, TRUE);
 295 }
 296
 297 void soldier_die()
 298 {
 299         Monster_CheckDropCvars ("soldier");
 300
 301         self.think = monster_dead_think;
 302         self.nextthink = time + self.ticrate;
 303         self.ltime = time + 5;
 304         monsters_setframe((random() > 0.5) ? soldier_anim_die1 : soldier_anim_die2);
 305
 306         monster_hook_death(); // for post-death mods
 307 }
 308
 309 void soldier_spawn ()
 310 {
 311         if not(self.health)
 312                 self.health = autocvar_g_monster_soldier_health * self.scale;
 313
 314         self.damageforcescale   = 0.003;
 315         self.classname                  = "monster_soldier";
 316         self.checkattack                = GenericCheckAttack;
 317         self.attack_melee               = soldier_melee;
 318         self.attack_ranged              = soldier_attack;
 319         self.nextthink                  = time + random() * 0.5 + 0.1;
 320         self.think                              = soldier_think;
 321         self.currentammo                = 3;
 322         self.items                              = (IT_SHELLS | IT_ROCKETS | IT_NAILS);
 323
 324         monsters_setframe(soldier_anim_draw);
 325
 326         monster_setupsounds("soldier");
 327
 328         setmodel(self, SOLDIER_MODEL);
 329
 330         RandomSelection_Init();
 331         RandomSelection_Add(world, WEP_LASER, string_null, autocvar_g_monster_soldier_weapon_laser_chance, 1);
 332         RandomSelection_Add(world, WEP_SHOTGUN, string_null, autocvar_g_monster_soldier_weapon_shotgun_chance, 1);
 333         RandomSelection_Add(world, WEP_UZI, string_null, autocvar_g_monster_soldier_weapon_machinegun_chance, 1);
 334         RandomSelection_Add(world, WEP_ROCKET_LAUNCHER, string_null, autocvar_g_monster_soldier_weapon_rocketlauncher_chance, 1);
 335
 336         self.weaponentity = spawn();
 337         self.weaponentity.movetype = MOVETYPE_NOCLIP;
 338         self.weaponentity.team = self.team;
 339         self.weaponentity.solid = SOLID_NOT;
 340         self.weaponentity.owner = self.weaponentity.realowner = self;
 341         setmodel(self.weaponentity, "models/weapons/v_seeker.md3");
 342         setattachment(self.weaponentity, self, "bip01 r hand");
 343
 344         self.armorvalue = bound(0.5, random(), 1);
 345         self.weapon = RandomSelection_chosen_float;
 346
 347         monster_hook_spawn(); // for post-spawn mods
 348 }
 349
 350 void spawnfunc_monster_soldier ()
 351 {
 352         if not(autocvar_g_monster_soldier) { remove(self); return; }
 353
 354         self.monster_spawnfunc = spawnfunc_monster_soldier;
 355
 356         if(Monster_CheckAppearFlags(self))
 357                 return;
 358
 359         precache_model("models/weapons/v_seeker.md3");
 360         precache_model(SOLDIER_MODEL);
 361
 362         if not (monster_initialize(
 363                          "Marine", MONSTER_MARINE,
 364                          SOLDIER_MIN, SOLDIER_MAX,
 365                          FALSE,
 366                          soldier_die, soldier_spawn))
 367         {
 368                 remove(self);
 369                 return;
 370         }
 371 }
 372
 373 // compatibility with old spawns
 374 void spawnfunc_monster_army () { spawnfunc_monster_soldier(); }
 375
 376 #endif // SVQC