qcsrc/server/mutators/gamemode_arena.qc

   1 .float spawned;
   2 float maxspawned;
   3 float numspawned;
   4 .entity spawnqueue_next;
   5 .entity spawnqueue_prev;
   6 .float spawnqueue_in;
   7 entity spawnqueue_first;
   8 entity spawnqueue_last;
   9
  10 void Spawnqueue_Insert(entity e)
  11 {
  12         if(e.spawnqueue_in)
  13                 return;
  14         dprint(strcat("Into queue: ", e.netname, "\n"));
  15         e.spawnqueue_in = TRUE;
  16         e.spawnqueue_prev = spawnqueue_last;
  17         e.spawnqueue_next = world;
  18         if(spawnqueue_last)
  19                 spawnqueue_last.spawnqueue_next = e;
  20         spawnqueue_last = e;
  21         if(!spawnqueue_first)
  22                 spawnqueue_first = e;
  23 }
  24
  25 void Spawnqueue_Remove(entity e)
  26 {
  27         if(!e.spawnqueue_in)
  28                 return;
  29         dprint(strcat("Out of queue: ", e.netname, "\n"));
  30         e.spawnqueue_in = FALSE;
  31         if(e == spawnqueue_first)
  32                 spawnqueue_first = e.spawnqueue_next;
  33         if(e == spawnqueue_last)
  34                 spawnqueue_last = e.spawnqueue_prev;
  35         if(e.spawnqueue_prev)
  36                 e.spawnqueue_prev.spawnqueue_next = e.spawnqueue_next;
  37         if(e.spawnqueue_next)
  38                 e.spawnqueue_next.spawnqueue_prev = e.spawnqueue_prev;
  39         e.spawnqueue_next = world;
  40         e.spawnqueue_prev = world;
  41 }
  42
  43 void Spawnqueue_Unmark(entity e)
  44 {
  45         if(!e.spawned)
  46                 return;
  47         e.spawned = FALSE;
  48         numspawned = numspawned - 1;
  49 }
  50
  51 void Spawnqueue_Mark(entity e)
  52 {
  53         if(e.spawned)
  54                 return;
  55         e.spawned = TRUE;
  56         numspawned = numspawned + 1;
  57 }
  58
  59 float Arena_CheckWinner()
  60 {
  61         entity e;
  62
  63         if(round_handler_GetTimeLeft() <= 0)
  64         {
  65                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
  66                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
  67                 round_handler_Init(5, autocvar_g_arena_warmup, autocvar_g_arena_round_timelimit);
  68                 return 1;
  69         }
  70
  71         if(numspawned > 1)
  72                 return 0;
  73
  74         entity champion;
  75         champion = world;
  76         FOR_EACH_CLIENT(e)
  77         {
  78                 if(e.spawned && e.classname == "player")
  79                         champion = e;
  80         }
  81
  82         if(champion)
  83         {
  84                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_PLAYER_WIN, champion.netname);
  85                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_PLAYER_WIN, champion.netname);
  86                 UpdateFrags(champion, +1);
  87         }
  88         else
  89         {
  90                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
  91                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
  92         }
  93         round_handler_Init(5, autocvar_g_arena_warmup, autocvar_g_arena_round_timelimit);
  94         return 1;
  95 }
  96
  97 void Arena_AddChallengers()
  98 {
  99         entity e;
 100         e = self;
 101         while(numspawned < maxspawned && spawnqueue_first)
 102         {
 103                 self = spawnqueue_first;
 104
 105                 bprint ("^4", self.netname, "^4 is the next challenger\n");
 106
 107                 Spawnqueue_Remove(self);
 108                 Spawnqueue_Mark(self);
 109
 110                 self.classname = "player";
 111                 PutClientInServer();
 112         }
 113         self = e;
 114 }
 115
 116 float prev_numspawned;
 117 float Arena_CheckPlayers()
 118 {
 119         Arena_AddChallengers();
 120
 121         if(numspawned >= 2)
 122         {
 123                 if(prev_numspawned > 0)
 124                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_PLAYERS);
 125                 prev_numspawned = -1;
 126                 return 1;
 127         }
 128
 129         if(prev_numspawned != numspawned && numspawned == 1)
 130         {
 131                 if(maxspawned - numspawned > 0)
 132                         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_PLAYERS, maxspawned - numspawned);
 133                 prev_numspawned = numspawned;
 134         }
 135
 136         return 0;
 137 }
 138
 139 void Arena_RoundStart()
 140 {
 141         entity e;
 142         FOR_EACH_PLAYER(e)
 143                 e.player_blocked = 0;
 144 }
 145
 146 MUTATOR_HOOKFUNCTION(arena_ClientDisconnect)
 147 {
 148         Spawnqueue_Unmark(self);
 149         Spawnqueue_Remove(self);
 150         return 1;
 151 }
 152
 153 MUTATOR_HOOKFUNCTION(arena_reset_map_players)
 154 {
 155         FOR_EACH_CLIENT(self)
 156         {
 157                 if(self.spawned)
 158                 {
 159                         PutClientInServer();
 160                         self.player_blocked = 1;
 161                 }
 162                 else
 163                         PutObserverInServer();
 164         }
 165         return 1;
 166 }
 167
 168 MUTATOR_HOOKFUNCTION(arena_MakePlayerObserver)
 169 {
 170         if(self.version_mismatch)
 171         {
 172                 self.frags = FRAGS_SPECTATOR;
 173                 Spawnqueue_Unmark(self);
 174                 Spawnqueue_Remove(self);
 175         }
 176         else
 177         {
 178                 self.frags = FRAGS_LMS_LOSER;
 179                 Spawnqueue_Insert(self);
 180         }
 181         return 1;
 182 }
 183
 184 MUTATOR_HOOKFUNCTION(arena_PutClientInServer)
 185 {
 186         if(!self.spawned)
 187                 self.classname = "observer";
 188         return 1;
 189 }
 190
 191 MUTATOR_HOOKFUNCTION(arena_ClientConnect)
 192 {
 193         self.classname = "observer";
 194         Spawnqueue_Insert(self);
 195         return 1;
 196 }
 197
 198 MUTATOR_HOOKFUNCTION(arena_PlayerSpawn)
 199 {
 200         Spawnqueue_Remove(self);
 201         Spawnqueue_Mark(self);
 202         if(arena_roundbased)
 203                 self.player_blocked = 1;
 204         return 1;
 205 }
 206
 207 MUTATOR_HOOKFUNCTION(arena_PlayerPreThink)
 208 {
 209         self.stat_respawn_time = 0;
 210
 211         // put dead players in the spawn queue
 212         if(arena_roundbased)
 213         if(self.deadflag && time - self.death_time >= 1.5)
 214                 PutClientInServer();
 215
 216         return 1;
 217 }
 218
 219 MUTATOR_HOOKFUNCTION(arena_ForbidPlayerScore_Clear)
 220 {
 221         return 1;
 222 }
 223
 224 MUTATOR_HOOKFUNCTION(arena_GiveFragsForKill)
 225 {
 226         if(arena_roundbased)
 227                 frag_score = 0; // score will be given to the champion when the round ends
 228         return 1;
 229 }
 230
 231 MUTATOR_HOOKFUNCTION(arena_PlayerDies)
 232 {
 233         Spawnqueue_Unmark(self);
 234         return 1;
 235 }
 236
 237 MUTATOR_HOOKFUNCTION(arena_SV_StartFrame)
 238 {
 239         if(gameover) return 1;
 240         if(time <= game_starttime || !arena_roundbased)
 241                 Arena_AddChallengers();
 242         return 1;
 243 }
 244
 245 void arena_Initialize()
 246 {
 247         maxspawned = max(2, autocvar_g_arena_maxspawned);
 248         arena_roundbased = autocvar_g_arena_roundbased;
 249         if(arena_roundbased)
 250         {
 251                 round_handler_Spawn(Arena_CheckPlayers, Arena_CheckWinner, Arena_RoundStart);
 252                 round_handler_Init(5, autocvar_g_arena_warmup, autocvar_g_arena_round_timelimit);
 253         }
 254 }
 255
 256 MUTATOR_DEFINITION(gamemode_arena)
 257 {
 258         MUTATOR_HOOK(ClientDisconnect, arena_ClientDisconnect, CBC_ORDER_ANY);
 259         MUTATOR_HOOK(reset_map_players, arena_reset_map_players, CBC_ORDER_ANY);
 260         MUTATOR_HOOK(MakePlayerObserver, arena_MakePlayerObserver, CBC_ORDER_ANY);
 261         MUTATOR_HOOK(PutClientInServer, arena_PutClientInServer, CBC_ORDER_ANY);
 262         MUTATOR_HOOK(ClientConnect, arena_ClientConnect, CBC_ORDER_ANY);
 263         MUTATOR_HOOK(PlayerSpawn, arena_PlayerSpawn, CBC_ORDER_ANY);
 264         MUTATOR_HOOK(PlayerPreThink, arena_PlayerPreThink, CBC_ORDER_ANY);
 265         MUTATOR_HOOK(ForbidPlayerScore_Clear, arena_ForbidPlayerScore_Clear, CBC_ORDER_ANY);
 266         MUTATOR_HOOK(GiveFragsForKill, arena_GiveFragsForKill, CBC_ORDER_ANY);
 267         MUTATOR_HOOK(PlayerDies, arena_PlayerDies, CBC_ORDER_ANY);
 268         MUTATOR_HOOK(SV_StartFrame, arena_SV_StartFrame, CBC_ORDER_ANY);
 269
 270         MUTATOR_ONADD
 271         {
 272                 if(time > 1) // game loads at time 1
 273                         error("This is a game type and it cannot be added at runtime.");
 274                 arena_Initialize();
 275         }
 276
 277         MUTATOR_ONREMOVE
 278         {
 279                 print("This is a game type and it cannot be removed at runtime.");
 280                 return -1;
 281         }
 282
 283         return 0;
 284 }