qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         next_round = time + 5;
   5 }
   6
   7 void freezetag_CheckWinner()
   8 {
   9         if((redalive >= 1 && bluealive >= 1) // counted in arena.qc
  10                 || (redalive >= 1 && yellowalive >= 1)
  11                 || (redalive >= 1 && pinkalive >= 1)
  12                 || (bluealive >= 1 && yellowalive >= 1)
  13                 || (bluealive >= 1 && pinkalive >= 1)
  14                 || (yellowalive >= 1 && pinkalive >= 1))
  15                 return; // we still have active players on two or more teams
  16
  17         if(redalive + bluealive + yellowalive + pinkalive <= 0)
  18         {
  19                 next_round = time + 5;
  20                 return;
  21         }
  22
  23         entity e, winner;
  24         string teamname;
  25
  26         FOR_EACH_PLAYER(e)
  27         {
  28                 if(e.freezetag_frozen == 0) // here's one player from the winning team... good
  29                 {
  30                         winner = e;
  31                         break; // break, we found the winner
  32                 }
  33         }
  34
  35         TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
  36
  37         if(winner.team == COLOR_TEAM1)
  38                 teamname = "^1Red Team";
  39         else if(winner.team == COLOR_TEAM2)
  40                 teamname = "^4Blue Team";
  41         else if(winner.team == COLOR_TEAM3)
  42                 teamname = "^3Yellow Team";
  43         else
  44                 teamname = "^6Pink Team";
  45         FOR_EACH_PLAYER(e) {
  46                 centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen.\n"));
  47         }
  48         bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
  49
  50         next_round = time + 5;
  51 }
  52
  53 void freezetag_Ice_Think()
  54 {
  55         setorigin(self, self.owner.origin - '0 0 16');
  56         self.nextthink = time;
  57 }
  58
  59 void freezetag_Freeze()
  60 {
  61         self.freezetag_frozen = 1;
  62
  63         entity ice;
  64         ice = spawn();
  65         ice.owner = self;
  66         ice.classname = "freezetag_ice";
  67         ice.think = freezetag_Ice_Think;
  68         ice.nextthink = time;
  69         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
  70         setmodel(ice, "models/ice/ice.md3");
  71
  72         //setattachment(ice, self, "");
  73
  74         //self.movetype = MOVETYPE_NONE;
  75
  76         self.movement = '0 0 0';
  77 }
  78
  79 void freezetag_Unfreeze()
  80 {
  81         self.freezetag_frozen = 0;
  82
  83         self.movetype = MOVETYPE_WALK;
  84
  85         // remove the ice block
  86         entity ice;
  87         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
  88         {
  89                 remove(ice);
  90                 break;
  91         }
  92 }
  93
  94 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
  95 {
  96         freezetag_CheckWinner();
  97
  98         return 1;
  99 }
 100
 101 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 102 {
 103         // if the player was previously not frozen (should be the case anyway), decrement alive playercount before running CheckWinner
 104         if (self.team == COLOR_TEAM1 && self.freezetag_frozen == 0) redalive -= 1;
 105         else if (self.team == COLOR_TEAM2 && self.freezetag_frozen == 0) bluealive -= 1;
 106         else if (self.team == COLOR_TEAM3 && self.freezetag_frozen == 0) yellowalive -= 1;
 107         else if (self.team == COLOR_TEAM4 && self.freezetag_frozen == 0) pinkalive -= 1;
 108
 109         freezetag_Freeze();
 110
 111         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 112         if(frag_attacker == frag_target || frag_attacker == world)
 113         {
 114                 centerprint(frag_target, "^1You froze yourself.\n");
 115                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 116         }
 117         else
 118         {
 119                 centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 120                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 121         }
 122
 123         frag_target.health = cvar("g_balance_health_start"); // "respawn" the player :P
 124
 125         freezetag_CheckWinner();
 126
 127         return 1;
 128 }
 129
 130 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 131 {
 132         if(redalive + bluealive + yellowalive + pinkalive == 1 && time > warmup)
 133                 next_round = time; // start a new round immediately
 134
 135         if(time > warmup) // spawn too late, freeze player
 136         {
 137                 centerprint(self, "^1You spawned after the round started, you'll spawn as frozen.\n");
 138                 freezetag_Freeze();
 139         }
 140         else // we are still in the delay period before the round starts
 141         {
 142                 freezetag_Unfreeze();
 143         }
 144
 145         return 1;
 146 }
 147
 148 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 149 {
 150         frag_score = 0; // no frags counted in Freeze Tag
 151         return 1;
 152 }
 153
 154 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 155 {
 156         vector revive_extra_size;
 157         revive_extra_size = '1 1 1' * cvar("g_freezetag_revive_extra_size");
 158
 159         float teammate_nearby;
 160         FOR_EACH_PLAYER(other) if(self != other)
 161         {
 162                 if(other.freezetag_frozen == 0)
 163                 {
 164                         if(other.team == self.team)
 165                         {
 166                                 teammate_nearby = boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax);
 167                                 break;
 168                         }
 169                 }
 170         }
 171
 172         if(teammate_nearby && self.freezetag_frozen == 1)
 173         {
 174                 if(self.freezetag_beginrevive_time == -9999)
 175                 {
 176                         self.freezetag_beginrevive_time = time;
 177                 }
 178                 else
 179                 {
 180                         if(time - self.freezetag_beginrevive_time >= cvar("g_freezetag_revive_time"))
 181                         {
 182                                 freezetag_Unfreeze();
 183
 184                                 centerprint(self, strcat("^5You were revived by ^7", other.netname, ".\n"));
 185                                 centerprint(other, strcat("^5You revived ^7", self.netname, ".\n"));
 186                                 bprint("^7", other.netname, "^5 revived ^7", self.netname, ".\n");
 187
 188                                 self.freezetag_beginrevive_time = -9999;
 189                         }
 190                 }
 191         }
 192         else
 193         {
 194                 self.freezetag_beginrevive_time = -9999;
 195         }
 196
 197         return 1;
 198 }
 199
 200 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 201 {
 202         if(self.freezetag_frozen)
 203                 self.movement = '0 0 0';
 204         return 1;
 205 }
 206
 207 MUTATOR_DEFINITION(gamemode_freezetag)
 208 {
 209         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 210         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 211         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 212         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 213         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 214         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 215         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 216
 217         MUTATOR_ONADD
 218         {
 219                 if(time > 1) // game loads at time 1
 220                         error("This is a game type and it cannot be added at runtime.");
 221                 g_freezetag = 1;
 222                 freezetag_Initialize();
 223         }
 224
 225         MUTATOR_ONREMOVE
 226         {
 227                 g_freezetag = 0;
 228                 error("This is a game type and it cannot be removed at runtime.");
 229         }
 230
 231         return 0;
 232 }