qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         next_round = time + 5;
   5 }
   6
   7 void freezetag_CheckWinner()
   8 {
   9         if((redalive >= 1 && bluealive >= 1) // counted in arena.qc
  10                 || (redalive >= 1 && yellowalive >= 1)
  11                 || (redalive >= 1 && pinkalive >= 1)
  12                 || (bluealive >= 1 && yellowalive >= 1)
  13                 || (bluealive >= 1 && pinkalive >= 1)
  14                 || (yellowalive >= 1 && pinkalive >= 1))
  15                 return; // we still have active players on two or more teams
  16
  17         if(redalive + bluealive + yellowalive + pinkalive <= 0)
  18         {
  19                 next_round = time + 5;
  20                 return;
  21         }
  22
  23         entity e, winner;
  24         string teamname;
  25
  26         FOR_EACH_PLAYER(e)
  27         {
  28                 if(e.freezetag_frozen == 0) // here's one player from the winning team... good
  29                 {
  30                         winner = e;
  31                         break; // break, we found the winner
  32                 }
  33         }
  34
  35         TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
  36
  37         if(winner.team == COLOR_TEAM1)
  38                 teamname = "^1Red Team";
  39         else if(winner.team == COLOR_TEAM2)
  40                 teamname = "^4Blue Team";
  41         else if(winner.team == COLOR_TEAM3)
  42                 teamname = "^3Yellow Team";
  43         else
  44                 teamname = "^6Pink Team";
  45         FOR_EACH_PLAYER(e) {
  46                 centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen.\n"));
  47         }
  48         bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
  49
  50         next_round = time + 5;
  51 }
  52
  53 void freezetag_Ice_Think()
  54 {
  55         setorigin(self, self.owner.origin - '0 0 16');
  56         self.nextthink = time;
  57 }
  58
  59 void freezetag_Freeze()
  60 {
  61         self.freezetag_frozen = 1;
  62
  63         entity ice;
  64         ice = spawn();
  65         ice.owner = self;
  66         ice.classname = "freezetag_ice";
  67         ice.think = freezetag_Ice_Think;
  68         ice.nextthink = time;
  69         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
  70         setmodel(ice, "models/ice/ice.md3");
  71
  72         self.movement = '0 0 0';
  73
  74         // add waypoint
  75         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE);
  76         if(self.waypointsprite_attached)
  77         {
  78                 WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_WAYPOINT, '0.25 0.90 1');
  79                 //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
  80                 //WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
  81         }
  82 }
  83
  84 void freezetag_Unfreeze()
  85 {
  86         self.freezetag_frozen = 0;
  87
  88         self.movetype = MOVETYPE_WALK;
  89
  90         // remove the ice block
  91         entity ice;
  92         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
  93         {
  94                 remove(ice);
  95                 break;
  96         }
  97
  98         // remove waypoint
  99         if(self.waypointsprite_attached)
 100                 WaypointSprite_Kill(self.waypointsprite_attached);
 101 }
 102
 103 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 104 {
 105         freezetag_CheckWinner();
 106
 107         return 1;
 108 }
 109
 110 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 111 {
 112         // if the player was previously not frozen (should be the case anyway), decrement alive playercount before running CheckWinner
 113         if (self.team == COLOR_TEAM1 && self.freezetag_frozen == 0) redalive -= 1;
 114         else if (self.team == COLOR_TEAM2 && self.freezetag_frozen == 0) bluealive -= 1;
 115         else if (self.team == COLOR_TEAM3 && self.freezetag_frozen == 0) yellowalive -= 1;
 116         else if (self.team == COLOR_TEAM4 && self.freezetag_frozen == 0) pinkalive -= 1;
 117
 118         freezetag_Freeze();
 119
 120         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 121         if(frag_attacker == frag_target || frag_attacker == world)
 122         {
 123                 centerprint(frag_target, "^1You froze yourself.\n");
 124                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 125         }
 126         else
 127         {
 128                 centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 129                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 130         }
 131
 132         frag_target.health = cvar("g_balance_health_start"); // "respawn" the player :P
 133
 134         freezetag_CheckWinner();
 135
 136         return 1;
 137 }
 138
 139 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 140 {
 141         if(redalive + bluealive + yellowalive + pinkalive == 1 && time > warmup)
 142                 next_round = time; // start a new round immediately
 143
 144         if(time > warmup) // spawn too late, freeze player
 145         {
 146                 centerprint(self, "^1You spawned after the round started, you'll spawn as frozen.\n");
 147                 freezetag_Freeze();
 148         }
 149         else // we are still in the delay period before the round starts
 150         {
 151                 freezetag_Unfreeze();
 152         }
 153
 154         return 1;
 155 }
 156
 157 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 158 {
 159         frag_score = 0; // no frags counted in Freeze Tag
 160         return 1;
 161 }
 162
 163 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 164 {
 165         vector revive_extra_size;
 166         revive_extra_size = '1 1 1' * cvar("g_freezetag_revive_extra_size");
 167
 168         float teammate_nearby;
 169         FOR_EACH_PLAYER(other) if(self != other)
 170         {
 171                 if(other.freezetag_frozen == 0)
 172                 {
 173                         if(other.team == self.team)
 174                         {
 175                                 teammate_nearby = boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax);
 176                                 break;
 177                         }
 178                 }
 179         }
 180
 181         if(teammate_nearby && self.freezetag_frozen == 1)
 182         {
 183                 if(self.freezetag_beginrevive_time == -9999)
 184                 {
 185                         self.freezetag_beginrevive_time = time;
 186                 }
 187                 else
 188                 {
 189                         if(time - self.freezetag_beginrevive_time >= cvar("g_freezetag_revive_time"))
 190                         {
 191                                 freezetag_Unfreeze();
 192
 193                                 centerprint(self, strcat("^5You were revived by ^7", other.netname, ".\n"));
 194                                 centerprint(other, strcat("^5You revived ^7", self.netname, ".\n"));
 195                                 bprint("^7", other.netname, "^5 revived ^7", self.netname, ".\n");
 196
 197                                 self.freezetag_beginrevive_time = -9999;
 198                         }
 199                 }
 200         }
 201         else
 202         {
 203                 self.freezetag_beginrevive_time = -9999;
 204         }
 205
 206         return 1;
 207 }
 208
 209 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 210 {
 211         if(self.freezetag_frozen)
 212                 self.movement = '0 0 0';
 213         return 1;
 214 }
 215
 216 MUTATOR_DEFINITION(gamemode_freezetag)
 217 {
 218         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 219         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 220         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 221         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 222         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 223         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 224         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 225
 226         MUTATOR_ONADD
 227         {
 228                 if(time > 1) // game loads at time 1
 229                         error("This is a game type and it cannot be added at runtime.");
 230                 g_freezetag = 1;
 231                 freezetag_Initialize();
 232         }
 233
 234         MUTATOR_ONREMOVE
 235         {
 236                 g_freezetag = 0;
 237                 error("This is a game type and it cannot be removed at runtime.");
 238         }
 239
 240         return 0;
 241 }