qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         warmup = time + cvar("g_freezetag_warmup");
   5 }
   6
   7 void freezetag_CheckWinner()
   8 {
   9         if(next_round || (time > warmup - cvar("g_freezetag_warmup") && time < warmup))
  10                 return; // already waiting for next round to start
  11
  12         if((redalive >= 1 && bluealive >= 1) // counted in arena.qc
  13                 || (redalive >= 1 && yellowalive >= 1)
  14                 || (redalive >= 1 && pinkalive >= 1)
  15                 || (bluealive >= 1 && yellowalive >= 1)
  16                 || (bluealive >= 1 && pinkalive >= 1)
  17                 || (yellowalive >= 1 && pinkalive >= 1))
  18                 return; // we still have active players on two or more teams
  19
  20         if(redalive + bluealive + yellowalive + pinkalive <= 0)
  21         {
  22                 next_round = time + 5;
  23                 return;
  24         }
  25
  26         entity e, winner;
  27         string teamname;
  28
  29         FOR_EACH_PLAYER(e)
  30         {
  31                 if(e.freezetag_frozen == 0 && e.classname == "player" && e.health >= 1) // here's one player from the winning team... good
  32                 {
  33                         winner = e;
  34                         if(winner != world) // just in case a winner isn't found (causes crashes otherwise...)
  35                                 TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
  36                         break; // break, we found the winner
  37                 }
  38         }
  39
  40         if(winner.team == COLOR_TEAM1)
  41                 teamname = "^1Red Team";
  42         else if(winner.team == COLOR_TEAM2)
  43                 teamname = "^4Blue Team";
  44         else if(winner.team == COLOR_TEAM3)
  45                 teamname = "^3Yellow Team";
  46         else
  47                 teamname = "^6Pink Team";
  48         FOR_EACH_PLAYER(e) {
  49                 centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen.\n"));
  50         }
  51         bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
  52
  53         next_round = time + 5;
  54 }
  55
  56 void freezetag_Ice_Think()
  57 {
  58         setorigin(self, self.owner.origin - '0 0 16');
  59         self.nextthink = time;
  60 }
  61
  62 void freezetag_Freeze()
  63 {
  64         self.freezetag_frozen = 1;
  65
  66         entity ice;
  67         ice = spawn();
  68         ice.owner = self;
  69         ice.classname = "freezetag_ice";
  70         ice.think = freezetag_Ice_Think;
  71         ice.nextthink = time;
  72         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
  73         setmodel(ice, "models/ice/ice.md3");
  74
  75         self.movement = '0 0 0';
  76
  77         // add waypoint
  78         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE);
  79         if(self.waypointsprite_attached)
  80         {
  81                 WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_WAYPOINT, '0.25 0.90 1');
  82         }
  83 }
  84
  85 void freezetag_Unfreeze()
  86 {
  87         self.freezetag_frozen = 0;
  88
  89         // remove the ice block
  90         entity ice;
  91         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
  92         {
  93                 remove(ice);
  94                 break;
  95         }
  96
  97         // remove waypoint
  98         if(self.waypointsprite_attached)
  99                 WaypointSprite_Kill(self.waypointsprite_attached);
 100 }
 101
 102 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 103 {
 104         if(self.freezetag_frozen == 0)
 105         {
 106                 if(self.team == COLOR_TEAM1)
 107                         --redalive;
 108                 else if(self.team == COLOR_TEAM2)
 109                         --bluealive;
 110                 else if(self.team == COLOR_TEAM3)
 111                         --yellowalive;
 112                 else if(self.team == COLOR_TEAM4)
 113                         --pinkalive;
 114         }
 115
 116         freezetag_CheckWinner();
 117         freezetag_Unfreeze();
 118
 119         return 1;
 120 }
 121
 122 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 123 {
 124         freezetag_Freeze();
 125         count_alive_players();
 126
 127         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 128         if(frag_attacker == frag_target || frag_attacker == world)
 129         {
 130                 centerprint(frag_target, "^1You froze yourself.\n");
 131                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 132         }
 133         else
 134         {
 135                 centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 136                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 137         }
 138
 139         frag_target.health = cvar("g_balance_health_start"); // "respawn" the player :P
 140
 141         freezetag_CheckWinner();
 142
 143         return 1;
 144 }
 145
 146 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 147 {
 148         if(time > warmup) // spawn too late, freeze player
 149         {
 150                 centerprint(self, "^1You spawned after the round started, you'll spawn as frozen.\n");
 151                 freezetag_Freeze();
 152         }
 153         else // we are still in the delay period before the round starts
 154         {
 155                 freezetag_Unfreeze();
 156         }
 157
 158         return 1;
 159 }
 160
 161 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 162 {
 163         frag_score = 0; // no frags counted in Freeze Tag
 164         return 1;
 165 }
 166
 167 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 168 {
 169         vector revive_extra_size;
 170         revive_extra_size = '1 1 1' * cvar("g_freezetag_revive_extra_size");
 171
 172         float teammate_nearby;
 173         FOR_EACH_PLAYER(other) if(self != other)
 174         {
 175                 if(other.freezetag_frozen == 0)
 176                 {
 177                         if(other.team == self.team)
 178                         {
 179                                 teammate_nearby = boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax);
 180                                 if(teammate_nearby)
 181                                         break;
 182                         }
 183                 }
 184         }
 185
 186         if(teammate_nearby && self.freezetag_frozen == 1)
 187         {
 188                 if(self.freezetag_beginrevive_time == -9999)
 189                 {
 190                         self.freezetag_beginrevive_time = time;
 191                         self.freezetag_revive_progress = 0;
 192                         other.freezetag_revive_progress = 0;
 193                 }
 194                 else
 195                 {
 196                         self.freezetag_revive_progress = (time - self.freezetag_beginrevive_time) / cvar("g_freezetag_revive_time");
 197                         other.freezetag_revive_progress = (time - self.freezetag_beginrevive_time) / cvar("g_freezetag_revive_time");
 198                         if(time - self.freezetag_beginrevive_time >= cvar("g_freezetag_revive_time"))
 199                         {
 200                                 freezetag_Unfreeze();
 201
 202                                 centerprint(self, strcat("^5You were revived by ^7", other.netname, ".\n"));
 203                                 centerprint(other, strcat("^5You revived ^7", self.netname, ".\n"));
 204                                 bprint("^7", other.netname, "^5 revived ^7", self.netname, ".\n");
 205
 206                                 self.freezetag_beginrevive_time = -9999;
 207                                 self.freezetag_revive_progress = 0;
 208                                 other.freezetag_revive_progress = 0;
 209                         }
 210                 }
 211         }
 212         else if(!teammate_nearby) // only if no teammate is nearby will we reset
 213         {
 214                 self.freezetag_beginrevive_time = -9999;
 215                 self.freezetag_revive_progress = 0;
 216         }
 217
 218         return 1;
 219 }
 220
 221 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 222 {
 223         if(self.freezetag_frozen)
 224                 self.movement = '0 0 0';
 225         return 1;
 226 }
 227
 228 MUTATOR_DEFINITION(gamemode_freezetag)
 229 {
 230         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 231         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 232         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 233         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 234         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 235         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 236         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 237
 238         MUTATOR_ONADD
 239         {
 240                 if(time > 1) // game loads at time 1
 241                         error("This is a game type and it cannot be added at runtime.");
 242                 g_freezetag = 1;
 243                 freezetag_Initialize();
 244         }
 245
 246         MUTATOR_ONREMOVE
 247         {
 248                 g_freezetag = 0;
 249                 error("This is a game type and it cannot be removed at runtime.");
 250         }
 251
 252         return 0;
 253 }