qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         warmup = time + autocvar_g_start_delay + autocvar_g_freezetag_warmup;
   5         ScoreRules_freezetag();
   6 }
   7
   8 void freezetag_CheckWinner()
   9 {
  10         if(time <= game_starttime) // game didn't even start yet! nobody can win in that case.
  11                 return;
  12
  13         if(next_round || (time > warmup - autocvar_g_freezetag_warmup && time < warmup))
  14                 return; // already waiting for next round to start
  15
  16         if((redalive >= 1 && bluealive >= 1)
  17                 || (redalive >= 1 && yellowalive >= 1)
  18                 || (redalive >= 1 && pinkalive >= 1)
  19                 || (bluealive >= 1 && yellowalive >= 1)
  20                 || (bluealive >= 1 && pinkalive >= 1)
  21                 || (yellowalive >= 1 && pinkalive >= 1))
  22                 return; // we still have active players on two or more teams, nobody won yet
  23
  24         entity e, winner;
  25         winner = world;
  26
  27         FOR_EACH_PLAYER(e)
  28         {
  29                 if(e.freezetag_frozen == 0 && e.health >= 1) // here's one player from the winning team... good
  30                 {
  31                         winner = e;
  32                         break; // break, we found the winner
  33                 }
  34         }
  35
  36         if(winner != world) // just in case a winner wasn't found
  37         {
  38                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM_4(winner.team, CENTER_FREEZETAG_ROUND_WIN_));
  39                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(winner.team, INFO_FREEZETAG_ROUND_WIN_));
  40                 TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
  41         }
  42
  43         next_round = time + 5;
  44 }
  45
  46 // this is needed to allow the player to turn his view around (fixangle can't
  47 // be used to freeze his view, as that also changes the angles), while not
  48 // turning that ice object with the player
  49 void freezetag_Ice_Think()
  50 {
  51         setorigin(self, self.owner.origin - '0 0 16');
  52         self.nextthink = time;
  53 }
  54
  55 void freezetag_Freeze(entity attacker)
  56 {
  57         if(self.freezetag_frozen)
  58                 return;
  59
  60         self.health = 1;
  61
  62         Freeze(self, 0, freezetag_frozen, freezetag_revive_progress);
  63
  64         if(attacker == self)
  65         {
  66                 // you froze your own dumb self
  67                 // counted as "suicide" already
  68                 PlayerScore_Add(self, SP_SCORE, -1);
  69         }
  70         else if(attacker.classname == "player")
  71         {
  72                 // got frozen by an enemy
  73                 // counted as "kill" and "death" already
  74                 PlayerScore_Add(self, SP_SCORE, -1);
  75                 PlayerScore_Add(attacker, SP_SCORE, +1);
  76         }
  77         else
  78         {
  79                 // nothing - got frozen by the game type rules themselves
  80         }
  81 }
  82
  83 void freezetag_Unfreeze(entity attacker)
  84 {
  85         Unfreeze(self, freezetag_frozen, freezetag_revive_progress);
  86
  87         // remove waypoint
  88         if(self.waypointsprite_attached)
  89                 WaypointSprite_Kill(self.waypointsprite_attached);
  90 }
  91
  92
  93 // ================
  94 // Bot player logic
  95 // ================
  96
  97 void() havocbot_role_ft_freeing;
  98 void() havocbot_role_ft_offense;
  99
 100 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 101 {
 102         entity head;
 103         float distance;
 104
 105         FOR_EACH_PLAYER(head)
 106         {
 107                 if ((head != self) && (head.team == self.team))
 108                 {
 109                         if (head.freezetag_frozen)
 110                         {
 111                                 distance = vlen(head.origin - org);
 112                                 if (distance > sradius)
 113                                         continue;
 114                                 navigation_routerating(head, ratingscale, 2000);
 115                         }
 116                         else
 117                         {
 118                                 // If teamate is not frozen still seek them out as fight better
 119                                 // in a group.
 120                                 navigation_routerating(head, ratingscale/3, 2000);
 121                         }
 122                 }
 123         }
 124 }
 125
 126 void havocbot_role_ft_offense()
 127 {
 128         entity head;
 129         float unfrozen;
 130
 131         if(self.deadflag != DEAD_NO)
 132                 return;
 133
 134         if (!self.havocbot_role_timeout)
 135                 self.havocbot_role_timeout = time + random() * 10 + 20;
 136
 137         // Count how many players on team are unfrozen.
 138         unfrozen = 0;
 139         FOR_EACH_PLAYER(head)
 140         {
 141                 if ((head.team == self.team) && (!head.freezetag_frozen))
 142                         unfrozen++;
 143         }
 144
 145         // If only one left on team or if role has timed out then start trying to free players.
 146         if (((unfrozen == 0) && (!self.freezetag_frozen)) || (time > self.havocbot_role_timeout))
 147         {
 148                 dprint("changing role to freeing\n");
 149                 self.havocbot_role = havocbot_role_ft_freeing;
 150                 self.havocbot_role_timeout = 0;
 151                 return;
 152         }
 153
 154         if (time > self.bot_strategytime)
 155         {
 156                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 157
 158                 navigation_goalrating_start();
 159                 havocbot_goalrating_items(10000, self.origin, 10000);
 160                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 161                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 162                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 163                 navigation_goalrating_end();
 164         }
 165 }
 166
 167 void havocbot_role_ft_freeing()
 168 {
 169         if(self.deadflag != DEAD_NO)
 170                 return;
 171
 172         if (!self.havocbot_role_timeout)
 173                 self.havocbot_role_timeout = time + random() * 10 + 20;
 174
 175         if (time > self.havocbot_role_timeout)
 176         {
 177                 dprint("changing role to offense\n");
 178                 self.havocbot_role = havocbot_role_ft_offense;
 179                 self.havocbot_role_timeout = 0;
 180                 return;
 181         }
 182
 183         if (time > self.bot_strategytime)
 184         {
 185                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 186
 187                 navigation_goalrating_start();
 188                 havocbot_goalrating_items(8000, self.origin, 10000);
 189                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 190                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 191                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 192                 navigation_goalrating_end();
 193         }
 194 }
 195
 196
 197 // ==============
 198 // Hook Functions
 199 // ==============
 200
 201 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 202 {
 203         if(self.freezetag_frozen == 0 && self.health >= 1)
 204         {
 205                 if(self.team == NUM_TEAM_1)
 206                         --redalive;
 207                 else if(self.team == NUM_TEAM_2)
 208                         --bluealive;
 209                 else if(self.team == NUM_TEAM_3)
 210                         --yellowalive;
 211                 else if(self.team == NUM_TEAM_4)
 212                         --pinkalive;
 213                 --totalalive;
 214         }
 215
 216         if(total_players > 2) // only check for winners if we had more than two players (one of them left, don't let the other player win just because of that)
 217                 freezetag_CheckWinner();
 218
 219         freezetag_Unfreeze(world);
 220
 221         return 1;
 222 }
 223
 224 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 225 {
 226         if(self.freezetag_frozen == 0)
 227         {
 228                 if(self.team == NUM_TEAM_1)
 229                         --redalive;
 230                 else if(self.team == NUM_TEAM_2)
 231                         --bluealive;
 232                 else if(self.team == NUM_TEAM_3)
 233                         --yellowalive;
 234                 else if(self.team == NUM_TEAM_4)
 235                         --pinkalive;
 236                 --totalalive;
 237
 238                 freezetag_Freeze(frag_attacker);
 239         }
 240
 241         if(frag_attacker == frag_target || frag_attacker == world)
 242         {
 243                 if(frag_target.classname == STR_PLAYER)
 244                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_SELF);
 245                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_SELF, frag_target.netname);
 246         }
 247         else
 248         {
 249                 if(frag_target.classname == STR_PLAYER)
 250                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_FROZEN, frag_attacker.netname);
 251                 if(frag_attacker.classname == STR_PLAYER)
 252                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_FREEZETAG_FREEZE, frag_target.netname);
 253                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_FREEZE, frag_target.netname, frag_attacker.netname);
 254         }
 255
 256         frag_target.health = 1; // "respawn" the player :P
 257
 258         freezetag_CheckWinner();
 259
 260         return 1;
 261 }
 262
 263 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 264 {
 265         freezetag_Unfreeze(world); // start by making sure that all ice blocks are removed
 266
 267         if(total_players == 1 && time > game_starttime) // only one player active on server, start a new match immediately
 268         if(!next_round && warmup && (time < warmup - autocvar_g_freezetag_warmup || time > warmup)) // not awaiting next round
 269         {
 270                 next_round = time;
 271                 return 1;
 272         }
 273         if(warmup && time > warmup) // spawn too late, freeze player
 274         {
 275                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_SPAWN_LATE);
 276                 freezetag_Freeze(world);
 277         }
 278
 279         return 1;
 280 }
 281
 282 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 283 {
 284         frag_score = 0; // no frags counted in Freeze Tag
 285         return 1;
 286 }
 287
 288 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 289 {
 290         float n;
 291         vector revive_extra_size;
 292
 293         revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 294
 295         // add waypoint
 296         if(self.freezetag_frozen && self.waypointsprite_attached == world)
 297                 WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 298
 299         entity o;
 300         o = world;
 301         n = 0;
 302         FOR_EACH_PLAYER(other) if(self != other)
 303         {
 304                 if(other.freezetag_frozen == 0)
 305                 {
 306                         if(other.team == self.team)
 307                         {
 308                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 309                                 {
 310                                         if(!o)
 311                                                 o = other;
 312                                         ++n;
 313                                 }
 314                         }
 315                 }
 316         }
 317
 318         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 319         {
 320                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * autocvar_g_freezetag_revive_speed, 1);
 321                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 322
 323                 if(self.freezetag_revive_progress >= 1)
 324                 {
 325                         freezetag_Unfreeze(self);
 326
 327                         // EVERY team mate nearby gets a point (even if multiple!)
 328                         FOR_EACH_PLAYER(other) if(self != other)
 329                         {
 330                                 if(other.freezetag_frozen == 0)
 331                                 {
 332                                         if(other.team == self.team)
 333                                         {
 334                                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 335                                                 {
 336                                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 337                                                         PlayerScore_Add(other, SP_SCORE, +1);
 338                                                 }
 339                                         }
 340                                 }
 341                         }
 342
 343                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
 344                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
 345                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVE, self.netname, o.netname);
 346                 }
 347
 348                 // now find EVERY teammate within reviving radius, set their revive_progress values correct
 349                 FOR_EACH_PLAYER(other) if(self != other)
 350                 {
 351                         if(other.freezetag_frozen == 0)
 352                         {
 353                                 if(other.team == self.team)
 354                                 {
 355                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 356                                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 357                                 }
 358                         }
 359                 }
 360         }
 361         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 362         {
 363                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 364                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 365         }
 366         else if(!n)
 367         {
 368                 self.freezetag_revive_progress = 0; // thawing nobody
 369         }
 370
 371         return 1;
 372 }
 373
 374 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 375 {
 376         if(self.freezetag_frozen)
 377         {
 378                 self.movement = '0 0 0';
 379                 self.disableclientprediction = 1;
 380         }
 381         return 1;
 382 }
 383
 384 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 385 {
 386     if(g_freezetag)
 387     {
 388         if(frag_target.freezetag_frozen == 1 && frag_deathtype != DEATH_HURTTRIGGER)
 389         {
 390             frag_damage = 0;
 391             frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 392         }
 393     }
 394     return 1;
 395 }
 396
 397 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 398 {
 399         if (self.freezetag_frozen)
 400                 return 1;
 401         return 0;
 402 }
 403
 404 MUTATOR_HOOKFUNCTION(freezetag_BotRoles)
 405 {
 406         if not(self.deadflag)
 407         {
 408                 if (random() < 0.5)
 409                         self.havocbot_role = havocbot_role_ft_freeing;
 410                 else
 411                         self.havocbot_role = havocbot_role_ft_offense;
 412         }
 413
 414         return TRUE;
 415 }
 416
 417 MUTATOR_DEFINITION(gamemode_freezetag)
 418 {
 419         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 420         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 421         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 422         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 423         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 424         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 425         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 426         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 427         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_FIRST); //first, last or any? dunno.
 428         MUTATOR_HOOK(HavocBot_ChooseRule, freezetag_BotRoles, CBC_ORDER_ANY);
 429
 430         MUTATOR_ONADD
 431         {
 432                 if(time > 1) // game loads at time 1
 433                         error("This is a game type and it cannot be added at runtime.");
 434                 freezetag_Initialize();
 435         }
 436
 437         MUTATOR_ONROLLBACK_OR_REMOVE
 438         {
 439                 // we actually cannot roll back freezetag_Initialize here
 440                 // BUT: we don't need to! If this gets called, adding always
 441                 // succeeds.
 442         }
 443
 444         MUTATOR_ONREMOVE
 445         {
 446                 print("This is a game type and it cannot be removed at runtime.");
 447                 return -1;
 448         }
 449
 450         return 0;
 451 }