qcsrc/server/mutators/gamemode_lms.qc

   1 #include "gamemode_lms.qh"
   2 #include "../_all.qh"
   3
   4 #include "gamemode.qh"
   5
   6 #include "../campaign.qh"
   7 #include "../command/cmd.qh"
   8
   9 // main functions
  10 float LMS_NewPlayerLives()
  11 {
  12         float fl;
  13         fl = autocvar_fraglimit;
  14         if(fl == 0)
  15                 fl = 999;
  16
  17         // first player has left the game for dying too much? Nobody else can get in.
  18         if(lms_lowest_lives < 1)
  19                 return 0;
  20
  21         if(!autocvar_g_lms_join_anytime)
  22                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  23                         return 0;
  24
  25         return bound(1, lms_lowest_lives, fl);
  26 }
  27
  28 // mutator hooks
  29 MUTATOR_HOOKFUNCTION(lms_ResetMap)
  30 {
  31         lms_lowest_lives = 999;
  32         lms_next_place = player_count;
  33
  34         return false;
  35 }
  36
  37 MUTATOR_HOOKFUNCTION(lms_ResetPlayers)
  38 {SELFPARAM();
  39         entity e;
  40         if(restart_mapalreadyrestarted || (time < game_starttime))
  41         FOR_EACH_CLIENT(e)
  42         if(IS_PLAYER(e))
  43         {
  44                 SELFCALL(e, PlayerScore_Add(e, SP_LMS_LIVES, LMS_NewPlayerLives()));
  45                 SELFCALL_DONE();
  46         }
  47
  48         return false;
  49 }
  50
  51 MUTATOR_HOOKFUNCTION(lms_PlayerPreSpawn)
  52 {SELFPARAM();
  53         // player is dead and becomes observer
  54         // FIXME fix LMS scoring for new system
  55         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
  56                 self.classname = "observer";
  57
  58         return false;
  59 }
  60
  61 MUTATOR_HOOKFUNCTION(lms_PlayerDies)
  62 {SELFPARAM();
  63         self.respawn_flags |= RESPAWN_FORCE;
  64
  65         return false;
  66 }
  67
  68 MUTATOR_HOOKFUNCTION(lms_RemovePlayer)
  69 {SELFPARAM();
  70         // Only if the player cannot play at all
  71         if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
  72                 self.frags = FRAGS_SPECTATOR;
  73         else
  74                 self.frags = FRAGS_LMS_LOSER;
  75
  76         if(self.killcount != -666)
  77                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0 && self.lms_spectate_warning != 2)
  78                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, self.netname);
  79                 else
  80                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, self.netname);
  81
  82         return false;
  83 }
  84
  85 MUTATOR_HOOKFUNCTION(lms_ClientConnect)
  86 {SELFPARAM();
  87         self.classname = "player";
  88         campaign_bots_may_start = 1;
  89
  90         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
  91         {
  92                 PlayerScore_Add(self, SP_LMS_RANK, 666);
  93                 self.frags = FRAGS_SPECTATOR;
  94         }
  95
  96         return false;
  97 }
  98
  99 MUTATOR_HOOKFUNCTION(lms_PlayerThink)
 100 {SELFPARAM();
 101         if(self.deadflag == DEAD_DYING)
 102                 self.deadflag = DEAD_RESPAWNING;
 103
 104         return false;
 105 }
 106
 107 MUTATOR_HOOKFUNCTION(lms_PlayerRegen)
 108 {
 109         if(autocvar_g_lms_regenerate)
 110                 return false;
 111         return true;
 112 }
 113
 114 MUTATOR_HOOKFUNCTION(lms_ForbidThrowing)
 115 {
 116         // forbode!
 117         return true;
 118 }
 119
 120 MUTATOR_HOOKFUNCTION(lms_GiveFragsForKill)
 121 {
 122         // remove a life
 123         float tl;
 124         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
 125         if(tl < lms_lowest_lives)
 126                 lms_lowest_lives = tl;
 127         if(tl <= 0)
 128         {
 129                 if(!lms_next_place)
 130                         lms_next_place = player_count;
 131                 else
 132                         lms_next_place = min(lms_next_place, player_count);
 133                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 134                 --lms_next_place;
 135         }
 136         frag_score = 0;
 137
 138         return true;
 139 }
 140
 141 MUTATOR_HOOKFUNCTION(lms_SetStartItems)
 142 {
 143         start_items &= ~IT_UNLIMITED_AMMO;
 144         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 145         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 146         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 147         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 148         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 149         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 150         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 151         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 152
 153         return false;
 154 }
 155
 156 MUTATOR_HOOKFUNCTION(lms_KeepScore)
 157 {
 158         // don't clear player score
 159         return true;
 160 }
 161
 162 MUTATOR_HOOKFUNCTION(lms_FilterItem)
 163 {SELFPARAM();
 164         if(autocvar_g_lms_extra_lives)
 165         if(self.itemdef == ITEM_HealthMega)
 166         {
 167                 self.max_health = 1;
 168                 return false;
 169         }
 170
 171         return true;
 172 }
 173
 174 MUTATOR_HOOKFUNCTION(lms_ItemTouch)
 175 {SELFPARAM();
 176         // give extra lives for mega health
 177         if (self.items & ITEM_HealthMega.m_itemid)
 178         {
 179                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 180                 PlayerScore_Add(other, SP_LMS_LIVES, autocvar_g_lms_extra_lives);
 181         }
 182
 183         return MUT_ITEMTOUCH_CONTINUE;
 184 }
 185
 186 // scoreboard stuff
 187 void lms_ScoreRules()
 188 {
 189         ScoreRules_basics(0, 0, 0, false);
 190         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 191         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 192         ScoreRules_basics_end();
 193 }
 194
 195 void lms_Initialize()
 196 {
 197         lms_lowest_lives = 9999;
 198         lms_next_place = 0;
 199
 200         lms_ScoreRules();
 201 }
 202
 203 MUTATOR_DEFINITION(gamemode_lms)
 204 {
 205         MUTATOR_HOOK(reset_map_global, lms_ResetMap, CBC_ORDER_ANY);
 206         MUTATOR_HOOK(reset_map_players, lms_ResetPlayers, CBC_ORDER_ANY);
 207         MUTATOR_HOOK(PutClientInServer, lms_PlayerPreSpawn, CBC_ORDER_ANY);
 208         MUTATOR_HOOK(PlayerDies, lms_PlayerDies, CBC_ORDER_ANY);
 209         MUTATOR_HOOK(MakePlayerObserver, lms_RemovePlayer, CBC_ORDER_ANY);
 210         MUTATOR_HOOK(ClientConnect, lms_ClientConnect, CBC_ORDER_ANY);
 211         MUTATOR_HOOK(PlayerPreThink, lms_PlayerThink, CBC_ORDER_ANY);
 212         MUTATOR_HOOK(PlayerRegen, lms_PlayerRegen, CBC_ORDER_ANY);
 213         MUTATOR_HOOK(ForbidThrowCurrentWeapon, lms_ForbidThrowing, CBC_ORDER_ANY);
 214         MUTATOR_HOOK(GiveFragsForKill, lms_GiveFragsForKill, CBC_ORDER_ANY);
 215         MUTATOR_HOOK(SetStartItems, lms_SetStartItems, CBC_ORDER_ANY);
 216         MUTATOR_HOOK(ForbidPlayerScore_Clear, lms_KeepScore, CBC_ORDER_ANY);
 217         MUTATOR_HOOK(FilterItem, lms_FilterItem, CBC_ORDER_ANY);
 218         MUTATOR_HOOK(ItemTouch, lms_ItemTouch, CBC_ORDER_ANY);
 219
 220         MUTATOR_ONADD
 221         {
 222                 if(time > 1) // game loads at time 1
 223                         error("This is a game type and it cannot be added at runtime.");
 224                 lms_Initialize();
 225         }
 226
 227         MUTATOR_ONROLLBACK_OR_REMOVE
 228         {
 229                 // we actually cannot roll back lms_Initialize here
 230                 // BUT: we don't need to! If this gets called, adding always
 231                 // succeeds.
 232         }
 233
 234         MUTATOR_ONREMOVE
 235         {
 236                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
 237                 return -1;
 238         }
 239
 240         return 0;
 241 }