qcsrc/server/mutators/mutator/gamemode_domination.qc

   1 #include "gamemode_domination.qh"
   2
   3 #include <server/teamplay.qh>
   4
   5 bool g_domination;
   6
   7 int autocvar_g_domination_default_teams;
   8 bool autocvar_g_domination_disable_frags;
   9 int autocvar_g_domination_point_amt;
  10 bool autocvar_g_domination_point_fullbright;
  11 float autocvar_g_domination_round_timelimit;
  12 float autocvar_g_domination_warmup;
  13 float autocvar_g_domination_point_rate;
  14 int autocvar_g_domination_teams_override;
  15
  16 void dom_EventLog(string mode, float team_before, entity actor) // use an alias for easy changing and quick editing later
  17 {
  18         if(autocvar_sv_eventlog)
  19                 GameLogEcho(strcat(":dom:", mode, ":", ftos(team_before), ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  20 }
  21
  22 void set_dom_state(entity e)
  23 {
  24         STAT(DOM_TOTAL_PPS, e) = total_pps;
  25         STAT(DOM_PPS_RED, e) = pps_red;
  26         STAT(DOM_PPS_BLUE, e) = pps_blue;
  27         if(domination_teams >= 3)
  28                 STAT(DOM_PPS_YELLOW, e) = pps_yellow;
  29         if(domination_teams >= 4)
  30                 STAT(DOM_PPS_PINK, e) = pps_pink;
  31 }
  32
  33 void dompoint_captured(entity this)
  34 {
  35         float old_delay, old_team, real_team;
  36
  37         // now that the delay has expired, switch to the latest team to lay claim to this point
  38         entity head = this.owner;
  39
  40         real_team = this.cnt;
  41         this.cnt = -1;
  42
  43         dom_EventLog("taken", this.team, this.dmg_inflictor);
  44         this.dmg_inflictor = NULL;
  45
  46         this.goalentity = head;
  47         this.model = head.mdl;
  48         this.modelindex = head.dmg;
  49         this.skin = head.skin;
  50
  51         float points, wait_time;
  52         if (autocvar_g_domination_point_amt)
  53                 points = autocvar_g_domination_point_amt;
  54         else
  55                 points = this.frags;
  56         if (autocvar_g_domination_point_rate)
  57                 wait_time = autocvar_g_domination_point_rate;
  58         else
  59                 wait_time = this.wait;
  60
  61         if(domination_roundbased)
  62                 bprint(sprintf("^3%s^3%s\n", head.netname, this.message));
  63         else
  64                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_DOMINATION_CAPTURE_TIME, head.netname, this.message, points, wait_time);
  65
  66         if(this.enemy.playerid == this.enemy_playerid)
  67                 GameRules_scoring_add(this.enemy, DOM_TAKES, 1);
  68         else
  69                 this.enemy = NULL;
  70
  71         if (head.noise != "")
  72                 if(this.enemy)
  73                         _sound(this.enemy, CH_TRIGGER, head.noise, VOL_BASE, ATTEN_NORM);
  74                 else
  75                         _sound(this, CH_TRIGGER, head.noise, VOL_BASE, ATTEN_NORM);
  76         if (head.noise1 != "")
  77                 play2all(head.noise1);
  78
  79         this.delay = time + wait_time;
  80
  81         // do trigger work
  82         old_delay = this.delay;
  83         old_team = this.team;
  84         this.team = real_team;
  85         this.delay = 0;
  86         SUB_UseTargets (this, this, NULL);
  87         this.delay = old_delay;
  88         this.team = old_team;
  89
  90         entity msg = WP_DomNeut;
  91         switch(real_team)
  92         {
  93                 case NUM_TEAM_1: msg = WP_DomRed; break;
  94                 case NUM_TEAM_2: msg = WP_DomBlue; break;
  95                 case NUM_TEAM_3: msg = WP_DomYellow; break;
  96                 case NUM_TEAM_4: msg = WP_DomPink; break;
  97         }
  98
  99         WaypointSprite_UpdateSprites(this.sprite, msg, WP_Null, WP_Null);
 100
 101         total_pps = 0, pps_red = 0, pps_blue = 0, pps_yellow = 0, pps_pink = 0;
 102         IL_EACH(g_dompoints, true,
 103         {
 104                 if (autocvar_g_domination_point_amt)
 105                         points = autocvar_g_domination_point_amt;
 106                 else
 107                         points = it.frags;
 108                 if (autocvar_g_domination_point_rate)
 109                         wait_time = autocvar_g_domination_point_rate;
 110                 else
 111                         wait_time = it.wait;
 112                 switch(it.goalentity.team)
 113                 {
 114                         case NUM_TEAM_1: pps_red += points/wait_time; break;
 115                         case NUM_TEAM_2: pps_blue += points/wait_time; break;
 116                         case NUM_TEAM_3: pps_yellow += points/wait_time; break;
 117                         case NUM_TEAM_4: pps_pink += points/wait_time; break;
 118                 }
 119                 total_pps += points/wait_time;
 120         });
 121
 122         WaypointSprite_UpdateTeamRadar(this.sprite, RADARICON_DOMPOINT, colormapPaletteColor(this.goalentity.team - 1, 0));
 123         WaypointSprite_Ping(this.sprite);
 124
 125         this.captime = time;
 126
 127         FOREACH_CLIENT(IS_REAL_CLIENT(it), { set_dom_state(it); });
 128 }
 129
 130 void AnimateDomPoint(entity this)
 131 {
 132         if(this.pain_finished > time)
 133                 return;
 134         this.pain_finished = time + this.t_width;
 135         if(this.nextthink > this.pain_finished)
 136                 this.nextthink = this.pain_finished;
 137
 138         this.frame = this.frame + 1;
 139         if(this.frame > this.t_length)
 140                 this.frame = 0;
 141 }
 142
 143 void dompointthink(entity this)
 144 {
 145         float fragamt;
 146
 147         this.nextthink = time + 0.1;
 148
 149         //this.frame = this.frame + 1;
 150         //if(this.frame > 119)
 151         //      this.frame = 0;
 152         AnimateDomPoint(this);
 153
 154         // give points
 155
 156         if (game_stopped || this.delay > time || time < game_starttime) // game has ended, don't keep giving points
 157                 return;
 158
 159         if(autocvar_g_domination_point_rate)
 160                 this.delay = time + autocvar_g_domination_point_rate;
 161         else
 162                 this.delay = time + this.wait;
 163
 164         // give credit to the team
 165         // NOTE: this defaults to 0
 166         if (!domination_roundbased)
 167         if (this.goalentity.netname != "")
 168         {
 169                 if(autocvar_g_domination_point_amt)
 170                         fragamt = autocvar_g_domination_point_amt;
 171                 else
 172                         fragamt = this.frags;
 173                 TeamScore_AddToTeam(this.goalentity.team, ST_SCORE, fragamt);
 174                 TeamScore_AddToTeam(this.goalentity.team, ST_DOM_TICKS, fragamt);
 175
 176                 // give credit to the individual player, if he is still there
 177                 if (this.enemy.playerid == this.enemy_playerid)
 178                 {
 179                         GameRules_scoring_add(this.enemy, SCORE, fragamt);
 180                         GameRules_scoring_add(this.enemy, DOM_TICKS, fragamt);
 181                 }
 182                 else
 183                         this.enemy = NULL;
 184         }
 185 }
 186
 187 void dompointtouch(entity this, entity toucher)
 188 {
 189         if (!IS_PLAYER(toucher))
 190                 return;
 191         if (toucher.health < 1)
 192                 return;
 193
 194         if(round_handler_IsActive() && !round_handler_IsRoundStarted())
 195                 return;
 196
 197         if(time < this.captime + 0.3)
 198                 return;
 199
 200         // only valid teams can claim it
 201         entity head = find(NULL, classname, "dom_team");
 202         while (head && head.team != toucher.team)
 203                 head = find(head, classname, "dom_team");
 204         if (!head || head.netname == "" || head == this.goalentity)
 205                 return;
 206
 207         // delay capture
 208
 209         this.team = this.goalentity.team; // this stores the PREVIOUS team!
 210
 211         this.cnt = toucher.team;
 212         this.owner = head; // team to switch to after the delay
 213         this.dmg_inflictor = toucher;
 214
 215         // this.state = 1;
 216         // this.delay = time + cvar("g_domination_point_capturetime");
 217         //this.nextthink = time + cvar("g_domination_point_capturetime");
 218         //this.think = dompoint_captured;
 219
 220         // go to neutral team in the mean time
 221         head = find(NULL, classname, "dom_team");
 222         while (head && head.netname != "")
 223                 head = find(head, classname, "dom_team");
 224         if(head == NULL)
 225                 return;
 226
 227         WaypointSprite_UpdateSprites(this.sprite, WP_DomNeut, WP_Null, WP_Null);
 228         WaypointSprite_UpdateTeamRadar(this.sprite, RADARICON_DOMPOINT, '0 1 1');
 229         WaypointSprite_Ping(this.sprite);
 230
 231         this.goalentity = head;
 232         this.model = head.mdl;
 233         this.modelindex = head.dmg;
 234         this.skin = head.skin;
 235
 236         this.enemy = toucher; // individual player scoring
 237         this.enemy_playerid = toucher.playerid;
 238         dompoint_captured(this);
 239 }
 240
 241 void dom_controlpoint_setup(entity this)
 242 {
 243         entity head;
 244         // find the spawnfunc_dom_team representing unclaimed points
 245         head = find(NULL, classname, "dom_team");
 246         while(head && head.netname != "")
 247                 head = find(head, classname, "dom_team");
 248         if (!head)
 249                 objerror(this, "no spawnfunc_dom_team with netname \"\" found\n");
 250
 251         // copy important properties from spawnfunc_dom_team entity
 252         this.goalentity = head;
 253         _setmodel(this, head.mdl); // precision already set
 254         this.skin = head.skin;
 255
 256         this.cnt = -1;
 257
 258         if(this.message == "")
 259                 this.message = " has captured a control point";
 260
 261         if(this.frags <= 0)
 262                 this.frags = 1;
 263         if(this.wait <= 0)
 264                 this.wait = 5;
 265
 266         float points, waittime;
 267         if (autocvar_g_domination_point_amt)
 268                 points = autocvar_g_domination_point_amt;
 269         else
 270                 points = this.frags;
 271         if (autocvar_g_domination_point_rate)
 272                 waittime = autocvar_g_domination_point_rate;
 273         else
 274                 waittime = this.wait;
 275
 276         total_pps += points/waittime;
 277
 278         if(!this.t_width)
 279                 this.t_width = 0.02; // frame animation rate
 280         if(!this.t_length)
 281                 this.t_length = 239; // maximum frame
 282
 283         setthink(this, dompointthink);
 284         this.nextthink = time;
 285         settouch(this, dompointtouch);
 286         this.solid = SOLID_TRIGGER;
 287         if(!this.flags & FL_ITEM)
 288                 IL_PUSH(g_items, this);
 289         this.flags = FL_ITEM;
 290         setsize(this, '-32 -32 -32', '32 32 32');
 291         setorigin(this, this.origin + '0 0 20');
 292         droptofloor(this);
 293
 294         waypoint_spawnforitem(this);
 295         WaypointSprite_SpawnFixed(WP_DomNeut, this.origin + '0 0 32', this, sprite, RADARICON_DOMPOINT);
 296 }
 297
 298 int total_control_points;
 299 void Domination_count_controlpoints()
 300 {
 301         total_control_points = 0;
 302         for (int i = 1; i <= NUM_TEAMS; ++i)
 303         {
 304                 Team_SetNumberOfControlPoints(Team_GetTeamFromIndex(i), 0);
 305         }
 306         IL_EACH(g_dompoints, true,
 307         {
 308                 ++total_control_points;
 309                 entity team_ = Entity_GetTeam(it.goalentity);
 310                 int num_control_points = Team_GetNumberOfControlPoints(team_);
 311                 ++num_control_points;
 312                 Team_SetNumberOfControlPoints(team_, num_control_points);
 313         });
 314 }
 315
 316 int Domination_GetWinnerTeam()
 317 {
 318         int winner_team = 0;
 319         if (Team_GetNumberOfControlPoints(Team_GetTeamFromIndex(1)) ==
 320                 total_control_points)
 321         {
 322                 winner_team = NUM_TEAM_1;
 323         }
 324         for (int i = 2; i <= NUM_TEAMS; ++i)
 325         {
 326                 if (Team_GetNumberOfControlPoints(Team_GetTeamFromIndex(i)) ==
 327                         total_control_points)
 328                 {
 329                         if (winner_team != 0)
 330                         {
 331                                 return 0;
 332                         }
 333                         winner_team = Team_IndexToTeam(i);
 334                 }
 335         }
 336         if (winner_team)
 337         {
 338                 return winner_team;
 339         }
 340         return -1; // no control points left?
 341 }
 342
 343 float Domination_CheckWinner()
 344 {
 345         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 346         {
 347                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
 348                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
 349
 350                 game_stopped = true;
 351                 round_handler_Init(5, autocvar_g_domination_warmup, autocvar_g_domination_round_timelimit);
 352                 return 1;
 353         }
 354
 355         Domination_count_controlpoints();
 356
 357         float winner_team = Domination_GetWinnerTeam();
 358
 359         if(winner_team == -1)
 360                 return 0;
 361
 362         if(winner_team > 0)
 363         {
 364                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 365                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 366                 TeamScore_AddToTeam(winner_team, ST_DOM_CAPS, +1);
 367         }
 368         else if(winner_team == -1)
 369         {
 370                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
 371                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
 372         }
 373
 374         game_stopped = true;
 375         round_handler_Init(5, autocvar_g_domination_warmup, autocvar_g_domination_round_timelimit);
 376
 377         return 1;
 378 }
 379
 380 float Domination_CheckPlayers()
 381 {
 382         return 1;
 383 }
 384
 385 void Domination_RoundStart()
 386 {
 387         FOREACH_CLIENT(IS_PLAYER(it), { it.player_blocked = false; });
 388 }
 389
 390 //go to best items, or control points you don't own
 391 void havocbot_goalrating_controlpoints(entity this, float ratingscale, vector org, float sradius)
 392 {
 393         IL_EACH(g_dompoints, vdist((((it.absmin + it.absmax) * 0.5) - org), <, sradius),
 394         {
 395                 if(it.cnt > -1) // this is just being fought
 396                         navigation_routerating(this, it, ratingscale, 5000);
 397                 else if(it.goalentity.cnt == 0) // unclaimed
 398                         navigation_routerating(this, it, ratingscale * 0.5, 5000);
 399                 else if(it.goalentity.team != this.team) // other team's point
 400                         navigation_routerating(this, it, ratingscale * 0.2, 5000);
 401         });
 402 }
 403
 404 void havocbot_role_dom(entity this)
 405 {
 406         if(IS_DEAD(this))
 407                 return;
 408
 409         if (navigation_goalrating_timeout(this))
 410         {
 411                 navigation_goalrating_start(this);
 412                 havocbot_goalrating_controlpoints(this, 10000, this.origin, 15000);
 413                 havocbot_goalrating_items(this, 8000, this.origin, 8000);
 414                 //havocbot_goalrating_enemyplayers(this, 3000, this.origin, 2000);
 415                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 416                 navigation_goalrating_end(this);
 417
 418                 navigation_goalrating_timeout_set(this);
 419         }
 420 }
 421
 422 MUTATOR_HOOKFUNCTION(dom, TeamBalance_CheckAllowedTeams)
 423 {
 424         // fallback?
 425         M_ARGV(0, float) = domination_teams;
 426         string ret_string = "dom_team";
 427
 428         entity head = find(NULL, classname, ret_string);
 429         while(head)
 430         {
 431                 if(head.netname != "")
 432                 {
 433                         if (Team_IsValidTeam(head.team))
 434                         {
 435                                 M_ARGV(0, float) |= Team_TeamToBit(head.team);
 436                         }
 437                 }
 438
 439                 head = find(head, classname, ret_string);
 440         }
 441
 442         M_ARGV(1, string) = string_null;
 443
 444         return true;
 445 }
 446
 447 MUTATOR_HOOKFUNCTION(dom, reset_map_players)
 448 {
 449         total_pps = 0, pps_red = 0, pps_blue = 0, pps_yellow = 0, pps_pink = 0;
 450         FOREACH_CLIENT(IS_PLAYER(it), {
 451                 PutClientInServer(it);
 452                 if(domination_roundbased)
 453                         it.player_blocked = 1;
 454                 if(IS_REAL_CLIENT(it))
 455                         set_dom_state(it);
 456         });
 457         return true;
 458 }
 459
 460 MUTATOR_HOOKFUNCTION(dom, PlayerSpawn)
 461 {
 462         entity player = M_ARGV(0, entity);
 463
 464         if(domination_roundbased)
 465         if(!round_handler_IsRoundStarted())
 466                 player.player_blocked = 1;
 467         else
 468                 player.player_blocked = 0;
 469 }
 470
 471 MUTATOR_HOOKFUNCTION(dom, ClientConnect)
 472 {
 473         entity player = M_ARGV(0, entity);
 474
 475         set_dom_state(player);
 476 }
 477
 478 MUTATOR_HOOKFUNCTION(dom, HavocBot_ChooseRole)
 479 {
 480         entity bot = M_ARGV(0, entity);
 481
 482         bot.havocbot_role = havocbot_role_dom;
 483         return true;
 484 }
 485
 486 /*QUAKED spawnfunc_dom_controlpoint (0 .5 .8) (-16 -16 -24) (16 16 32)
 487 Control point for Domination gameplay.
 488 */
 489 spawnfunc(dom_controlpoint)
 490 {
 491         if(!g_domination)
 492         {
 493                 delete(this);
 494                 return;
 495         }
 496         setthink(this, dom_controlpoint_setup);
 497         this.nextthink = time + 0.1;
 498         this.reset = dom_controlpoint_setup;
 499
 500         if(!this.scale)
 501                 this.scale = 0.6;
 502
 503         this.effects = this.effects | EF_LOWPRECISION;
 504         if (autocvar_g_domination_point_fullbright)
 505                 this.effects |= EF_FULLBRIGHT;
 506
 507         IL_PUSH(g_dompoints, this);
 508 }
 509
 510 /*QUAKED spawnfunc_dom_team (0 .5 .8) (-32 -32 -24) (32 32 32)
 511 Team declaration for Domination gameplay, this allows you to decide what team
 512 names and control point models are used in your map.
 513
 514 Note: If you use spawnfunc_dom_team entities you must define at least 3 and only two
 515 can have netname set!  The nameless team owns all control points at start.
 516
 517 Keys:
 518 "netname"
 519  Name of the team (for example Red Team, Blue Team, Green Team, Yellow Team, Life, Death, etc)
 520 "cnt"
 521  Scoreboard color of the team (for example 4 is red and 13 is blue)
 522 "model"
 523  Model to use for control points owned by this team (for example
 524  "progs/b_g_key.mdl" is a gold keycard, and "progs/b_s_key.mdl" is a silver
 525  keycard)
 526 "skin"
 527  Skin of the model to use (for team skins on a single model)
 528 "noise"
 529  Sound to play when this team captures a point.
 530  (this is a localized sound, like a small alarm or other effect)
 531 "noise1"
 532  Narrator speech to play when this team captures a point.
 533  (this is a global sound, like "Red team has captured a control point")
 534 */
 535
 536 spawnfunc(dom_team)
 537 {
 538         if(!g_domination || autocvar_g_domination_teams_override >= 2)
 539         {
 540                 delete(this);
 541                 return;
 542         }
 543         precache_model(this.model);
 544         if (this.noise != "")
 545                 precache_sound(this.noise);
 546         if (this.noise1 != "")
 547                 precache_sound(this.noise1);
 548         this.classname = "dom_team";
 549         _setmodel(this, this.model); // precision not needed
 550         this.mdl = this.model;
 551         this.dmg = this.modelindex;
 552         this.model = "";
 553         this.modelindex = 0;
 554         // this would have to be changed if used in quakeworld
 555         if(this.cnt)
 556                 this.team = this.cnt + 1; // WHY are these different anyway?
 557 }
 558
 559 // scoreboard setup
 560 void ScoreRules_dom(int teams)
 561 {
 562         if(domination_roundbased)
 563         {
 564             GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, 0, {
 565             field_team(ST_DOM_CAPS, "caps", SFL_SORT_PRIO_PRIMARY);
 566             field(SP_DOM_TAKES, "takes", 0);
 567             });
 568         }
 569         else
 570         {
 571                 float sp_domticks, sp_score;
 572                 sp_score = sp_domticks = 0;
 573                 if(autocvar_g_domination_disable_frags)
 574                         sp_domticks = SFL_SORT_PRIO_PRIMARY;
 575                 else
 576                         sp_score = SFL_SORT_PRIO_PRIMARY;
 577                 GameRules_scoring(teams, sp_score, sp_score, {
 578             field_team(ST_DOM_TICKS, "ticks", sp_domticks);
 579             field(SP_DOM_TICKS, "ticks", sp_domticks);
 580             field(SP_DOM_TAKES, "takes", 0);
 581                 });
 582         }
 583 }
 584
 585 // code from here on is just to support maps that don't have control point and team entities
 586 void dom_spawnteam (string teamname, float teamcolor, string pointmodel, float pointskin, Sound capsound, string capnarration, string capmessage)
 587 {
 588     TC(Sound, capsound);
 589     entity e = new_pure(dom_team);
 590         e.netname = strzone(teamname);
 591         e.cnt = teamcolor;
 592         e.model = pointmodel;
 593         e.skin = pointskin;
 594         e.noise = strzone(Sound_fixpath(capsound));
 595         e.noise1 = strzone(capnarration);
 596         e.message = strzone(capmessage);
 597
 598         // this code is identical to spawnfunc_dom_team
 599         _setmodel(e, e.model); // precision not needed
 600         e.mdl = e.model;
 601         e.dmg = e.modelindex;
 602         e.model = "";
 603         e.modelindex = 0;
 604         // this would have to be changed if used in quakeworld
 605         e.team = e.cnt + 1;
 606
 607         //eprint(e);
 608 }
 609
 610 void dom_spawnpoint(vector org)
 611 {
 612         entity e = spawn();
 613         e.classname = "dom_controlpoint";
 614         setthink(e, spawnfunc_dom_controlpoint);
 615         e.nextthink = time;
 616         setorigin(e, org);
 617         spawnfunc_dom_controlpoint(e);
 618 }
 619
 620 // spawn some default teams if the map is not set up for domination
 621 void dom_spawnteams(int teams)
 622 {
 623     TC(int, teams);
 624         dom_spawnteam(Team_ColoredFullName(NUM_TEAM_1), NUM_TEAM_1-1, "models/domination/dom_red.md3", 0, SND_DOM_CLAIM, "", "Red team has captured a control point");
 625         dom_spawnteam(Team_ColoredFullName(NUM_TEAM_2), NUM_TEAM_2-1, "models/domination/dom_blue.md3", 0, SND_DOM_CLAIM, "", "Blue team has captured a control point");
 626         if(teams >= 3)
 627                 dom_spawnteam(Team_ColoredFullName(NUM_TEAM_3), NUM_TEAM_3-1, "models/domination/dom_yellow.md3", 0, SND_DOM_CLAIM, "", "Yellow team has captured a control point");
 628         if(teams >= 4)
 629                 dom_spawnteam(Team_ColoredFullName(NUM_TEAM_4), NUM_TEAM_4-1, "models/domination/dom_pink.md3", 0, SND_DOM_CLAIM, "", "Pink team has captured a control point");
 630         dom_spawnteam("", 0, "models/domination/dom_unclaimed.md3", 0, SND_Null, "", "");
 631 }
 632
 633 void dom_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up.
 634 {
 635         // if no teams are found, spawn defaults
 636         if(find(NULL, classname, "dom_team") == NULL || autocvar_g_domination_teams_override >= 2)
 637         {
 638                 LOG_TRACE("No \"dom_team\" entities found on this map, creating them anyway.");
 639                 domination_teams = autocvar_g_domination_teams_override;
 640                 if (domination_teams < 2)
 641                         domination_teams = autocvar_g_domination_default_teams;
 642                 domination_teams = bound(2, domination_teams, 4);
 643                 dom_spawnteams(domination_teams);
 644         }
 645
 646         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 647         int teams = TeamBalance_GetAllowedTeams(balance);
 648         TeamBalance_Destroy(balance);
 649         domination_teams = teams;
 650
 651         domination_roundbased = autocvar_g_domination_roundbased;
 652
 653         ScoreRules_dom(domination_teams);
 654
 655         if(domination_roundbased)
 656         {
 657                 round_handler_Spawn(Domination_CheckPlayers, Domination_CheckWinner, Domination_RoundStart);
 658                 round_handler_Init(5, autocvar_g_domination_warmup, autocvar_g_domination_round_timelimit);
 659         }
 660 }
 661
 662 void dom_Initialize()
 663 {
 664         g_domination = true;
 665         InitializeEntity(NULL, dom_DelayedInit, INITPRIO_GAMETYPE);
 666 }