qcsrc/server/mutators/mutator_buffs.qc

   1 float buffs_BuffModel_Customize()
   2 {
   3         float same_team = (SAME_TEAM(other, self.owner) || (IS_SPEC(other) && SAME_TEAM(other.enemy, self.owner)));
   4         if(self.owner.alpha <= 0.5 && !same_team && self.owner.alpha != 0)
   5                 return FALSE;
   6
   7         if(other == self.owner || (IS_SPEC(other) && other.enemy == self.owner))
   8         {
   9                 // somewhat hide the model, but keep the glow
  10                 self.effects = 0;
  11                 self.alpha = -1;
  12         }
  13         else
  14         {
  15                 self.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
  16                 self.alpha = 1;
  17         }
  18         return TRUE;
  19 }
  20
  21 // buff item
  22 float buff_Waypoint_visible_for_player(entity plr)
  23 {
  24     if(!self.owner.buff_active && !self.owner.buff_activetime)
  25         return FALSE;
  26
  27         if(plr.buffs)
  28         {
  29                 if(plr.cvar_cl_buffs_autoreplace)
  30                 {
  31                         if(plr.buffs == self.owner.buffs)
  32                                 return FALSE;
  33                 }
  34                 else
  35                         return FALSE;
  36         }
  37
  38     return WaypointSprite_visible_for_player(plr);
  39 }
  40
  41 void buff_Waypoint_Spawn(entity e)
  42 {
  43     WaypointSprite_Spawn(Buff_PrettyName(e.buffs), 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs_z, world, e.team, e, buff_waypoint, TRUE, RADARICON_POWERUP, e.glowmod);
  44     WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_POWERUP, e.glowmod);
  45     e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
  46 }
  47
  48 void buff_SetCooldown(float cd)
  49 {
  50         cd = max(0, cd);
  51
  52         if(!self.buff_waypoint)
  53                 buff_Waypoint_Spawn(self);
  54
  55         WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + cd);
  56         self.buff_activetime = cd;
  57         self.buff_active = !cd;
  58 }
  59
  60 void buff_Respawn(entity ent)
  61 {
  62         if(gameover) { return; }
  63
  64         vector oldbufforigin = ent.origin;
  65
  66         if(!MoveToRandomMapLocation(ent, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
  67         {
  68                 entity spot = SelectSpawnPoint(TRUE);
  69                 setorigin(self, (spot.origin + '0 0 200') + (randomvec() * 300));
  70                 self.angles = spot.angles;
  71         }
  72
  73         ent.movetype = MOVETYPE_TOSS;
  74
  75         makevectors(ent.angles);
  76         ent.velocity = '0 0 200';
  77         ent.angles = '0 0 0';
  78         if(autocvar_g_buffs_random_lifetime > 0)
  79                 ent.lifetime = time + autocvar_g_buffs_random_lifetime;
  80
  81         pointparticles(particleeffectnum("electro_combo"), oldbufforigin + ((ent.mins + ent.maxs) * 0.5), '0 0 0', 1);
  82         pointparticles(particleeffectnum("electro_combo"), CENTER_OR_VIEWOFS(ent), '0 0 0', 1);
  83
  84         WaypointSprite_Ping(ent.buff_waypoint);
  85
  86         sound(ent, CH_TRIGGER, "keepaway/respawn.wav", VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
  87 }
  88
  89 void buff_Touch()
  90 {
  91         if(gameover) { return; }
  92
  93         if(ITEM_TOUCH_NEEDKILL())
  94         {
  95                 buff_Respawn(self);
  96                 return;
  97         }
  98
  99         if((self.team && DIFF_TEAM(other, self))
 100         || (other.freezetag_frozen)
 101         || (other.vehicle)
 102         || (!IS_PLAYER(other))
 103         || (!self.buff_active)
 104         )
 105         {
 106                 // can't touch this
 107                 return;
 108         }
 109
 110         if(other.buffs)
 111         {
 112                 if(other.cvar_cl_buffs_autoreplace && other.buffs != self.buffs)
 113                 {
 114                         //Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_DROP, other.buffs);
 115                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ITEM_BUFF_LOST, other.netname, other.buffs);
 116
 117                         other.buffs = 0;
 118                         //sound(other, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 119                 }
 120                 else { return; } // do nothing
 121         }
 122
 123         self.owner = other;
 124         self.buff_active = FALSE;
 125         self.lifetime = 0;
 126
 127         Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_GOT, self.buffs);
 128         Send_Notification(NOTIF_ALL_EXCEPT, other, MSG_INFO, INFO_ITEM_BUFF, other.netname, self.buffs);
 129
 130         pointparticles(particleeffectnum("item_pickup"), CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 131         sound(other, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);
 132         other.buffs |= (self.buffs);
 133 }
 134
 135 float buff_Available(float buffid)
 136 {
 137         if(buffid == BUFF_AMMO && ((start_items & IT_UNLIMITED_WEAPON_AMMO) || (start_items & IT_UNLIMITED_AMMO) || (cvar("g_melee_only"))))
 138                 return FALSE;
 139
 140         if(buffid == BUFF_VAMPIRE && cvar("g_vampire"))
 141                 return FALSE;
 142
 143         if(!cvar(strcat("g_buffs_", Buff_Name(buffid))))
 144                 return FALSE;
 145
 146         return TRUE;
 147 }
 148
 149 void buff_NewType(entity ent, float cb)
 150 {
 151         entity e;
 152         RandomSelection_Init();
 153         for(e = Buff_Type_first; e; e = e.enemy)
 154         if(buff_Available(e.items))
 155         {
 156                 RandomSelection_Add(world, e.items, string_null, 1, 1 / e.count); // if it's already been chosen, give it a lower priority
 157                 e.count += 1;
 158         }
 159         ent.buffs = RandomSelection_chosen_float;
 160 }
 161
 162 void buff_Think()
 163 {
 164         if(self.buffs != self.oldbuffs)
 165         {
 166                 self.color = Buff_Color(self.buffs);
 167                 self.glowmod = ((self.team) ? Team_ColorRGB(self.team) + '0.1 0.1 0.1' : self.color);
 168                 self.skin = Buff_Skin(self.buffs);
 169
 170                 setmodel(self, "models/relics/relic.md3");
 171
 172                 if(self.buff_waypoint)
 173                 {
 174                         //WaypointSprite_Disown(self.buff_waypoint, 1);
 175                         WaypointSprite_Kill(self.buff_waypoint);
 176                         buff_Waypoint_Spawn(self);
 177                         if(self.buff_activetime)
 178                                 WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + self.buff_activetime - frametime);
 179                 }
 180
 181                 self.oldbuffs = self.buffs;
 182         }
 183
 184         if(!gameover)
 185         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 186         if(!self.buff_activetime_updated)
 187         {
 188                 buff_SetCooldown(self.buff_activetime);
 189                 self.buff_activetime_updated = TRUE;
 190     }
 191
 192         if(!self.buff_active && !self.buff_activetime)
 193         if(!self.owner || self.owner.freezetag_frozen || self.owner.deadflag != DEAD_NO || !self.owner.iscreature || !(self.owner.buffs & self.buffs))
 194         {
 195                 buff_SetCooldown(autocvar_g_buffs_cooldown_respawn + frametime);
 196                 self.owner = world;
 197                 if(autocvar_g_buffs_randomize)
 198                         buff_NewType(self, self.buffs);
 199
 200                 if(autocvar_g_buffs_random_location || (self.spawnflags & 1))
 201                         buff_Respawn(self);
 202         }
 203
 204         if(self.buff_activetime)
 205         if(!gameover)
 206         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 207         {
 208                 self.buff_activetime = max(0, self.buff_activetime - frametime);
 209
 210                 if(!self.buff_activetime)
 211                 {
 212                         self.buff_active = TRUE;
 213                         sound(self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);
 214                         pointparticles(particleeffectnum("item_respawn"), CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 215                 }
 216         }
 217
 218         if(!self.buff_active)
 219         {
 220                 self.alpha = 0.3;
 221                 self.effects &= ~(EF_FULLBRIGHT);
 222                 self.pflags = 0;
 223         }
 224         else
 225         {
 226                 self.alpha = 1;
 227                 self.effects |= EF_FULLBRIGHT;
 228                 self.light_lev = 220 + 36 * sin(time);
 229                 self.pflags = PFLAGS_FULLDYNAMIC;
 230
 231                 if(self.team && !self.buff_waypoint)
 232                         buff_Waypoint_Spawn(self);
 233
 234                 if(self.lifetime)
 235                 if(time >= self.lifetime)
 236                         buff_Respawn(self);
 237         }
 238
 239         self.nextthink = time;
 240         //self.angles_y = time * 110.1;
 241 }
 242
 243 void buff_Waypoint_Reset()
 244 {
 245         WaypointSprite_Kill(self.buff_waypoint);
 246
 247         if(self.buff_activetime) { buff_Waypoint_Spawn(self); }
 248 }
 249
 250 void buff_Reset()
 251 {
 252         if(autocvar_g_buffs_randomize)
 253                 buff_NewType(self, self.buffs);
 254         self.owner = world;
 255         buff_SetCooldown(autocvar_g_buffs_cooldown_activate);
 256         buff_Waypoint_Reset();
 257         self.buff_activetime_updated = FALSE;
 258
 259         if(autocvar_g_buffs_random_location || (self.spawnflags & 1))
 260                 buff_Respawn(self);
 261 }
 262
 263 void buff_Init(entity ent)
 264 {
 265         if(!cvar("g_buffs")) { remove(self); return; }
 266
 267         if(!teamplay && self.team) { self.team = 0; }
 268
 269         entity oldself = self;
 270         self = ent;
 271         if(!self.buffs || buff_Available(self.buffs))
 272                 buff_NewType(self, 0);
 273
 274         self.classname = "item_buff";
 275         self.solid = SOLID_TRIGGER;
 276         self.flags = FL_ITEM;
 277         self.think = buff_Think;
 278         self.touch = buff_Touch;
 279         self.reset = buff_Reset;
 280         self.nextthink = time + 0.1;
 281         self.gravity = 1;
 282         self.movetype = MOVETYPE_TOSS;
 283         self.scale = 1;
 284         self.skin = Buff_Skin(self.buffs);
 285         self.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 286         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 287         //self.gravity = 100;
 288         self.color = Buff_Color(self.buffs);
 289         self.glowmod = ((self.team) ? Team_ColorRGB(self.team) + '0.1 0.1 0.1' : self.color);
 290         buff_SetCooldown(autocvar_g_buffs_cooldown_activate + game_starttime);
 291         self.buff_active = !self.buff_activetime;
 292         self.pflags = PFLAGS_FULLDYNAMIC;
 293
 294         if(self.noalign)
 295                 self.movetype = MOVETYPE_NONE; // reset by random location
 296
 297         setmodel(self, "models/relics/relic.md3");
 298         setsize(self, BUFF_MIN, BUFF_MAX);
 299
 300         if(cvar("g_buffs_random_location") || (self.spawnflags & 1))
 301                 buff_Respawn(self);
 302
 303         self = oldself;
 304 }
 305
 306 void buff_Init_Compat(entity ent, float replacement)
 307 {
 308         if(ent.spawnflags & 2)
 309                 ent.team = NUM_TEAM_1;
 310         else if(ent.spawnflags & 4)
 311                 ent.team = NUM_TEAM_2;
 312
 313         ent.buffs = replacement;
 314
 315         buff_Init(ent);
 316 }
 317
 318 void buff_SpawnReplacement(entity ent, entity old)
 319 {
 320         setorigin(ent, old.origin);
 321         ent.angles = old.angles;
 322         ent.noalign = old.noalign;
 323
 324         buff_Init(ent);
 325 }
 326
 327 // mutator hooks
 328 MUTATOR_HOOKFUNCTION(buffs_PlayerDamage_SplitHealthArmor)
 329 {
 330         if(frag_deathtype == DEATH_BUFF_VENGEANCE) { return FALSE; } // oh no you don't
 331
 332         if(frag_target.buffs & BUFF_RESISTANCE)
 333         {
 334                 vector v = healtharmor_applydamage(50, autocvar_g_buffs_resistance_blockpercent, frag_deathtype, frag_damage);
 335                 damage_take = v_x;
 336                 damage_save = v_y;
 337         }
 338
 339         return FALSE;
 340 }
 341
 342 void buff_Vengeance_DelayedDamage()
 343 {
 344         if(self.enemy)
 345                 Damage(self.enemy, self.owner, self.owner, self.dmg, DEATH_BUFF_VENGEANCE, self.enemy.origin, '0 0 0');
 346
 347         remove(self);
 348         return;
 349 }
 350
 351 MUTATOR_HOOKFUNCTION(buffs_PlayerDamage_Calculate)
 352 {
 353         if(frag_deathtype == DEATH_BUFF_VENGEANCE) { return FALSE; } // oh no you don't
 354
 355         if(frag_target.buffs & BUFF_SPEED)
 356         if(frag_target != frag_attacker)
 357                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 358
 359         if(frag_target.buffs & BUFF_MEDIC)
 360         if((frag_target.health - frag_damage) <= 0)
 361         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 362         if(frag_attacker)
 363         if(random() <= autocvar_g_buffs_medic_survive_chance)
 364         if(frag_target.health - autocvar_g_buffs_medic_survive_health > 0) // not if the final result would be less than 0, medic must get health
 365                 frag_damage = frag_target.health - autocvar_g_buffs_medic_survive_health;
 366
 367         if(frag_target.buffs & BUFF_VENGEANCE)
 368         if(frag_attacker)
 369         if(frag_attacker != frag_target)
 370         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 371         {
 372                 entity dmgent = spawn();
 373                 vector v = healtharmor_applydamage(frag_attacker.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_BUFF_VENGEANCE, frag_damage * autocvar_g_buffs_vengeance_damage_multiplier);
 374                 float take = v_x;
 375
 376                 dmgent.dmg = take;
 377                 dmgent.enemy = frag_attacker;
 378                 dmgent.owner = frag_target;
 379                 dmgent.think = buff_Vengeance_DelayedDamage;
 380                 dmgent.nextthink = time + 0.1;
 381         }
 382
 383         if(frag_target.buffs & BUFF_BASH)
 384         if(frag_attacker != frag_target)
 385         if(vlen(frag_force))
 386                 frag_force = '0 0 0';
 387
 388         if(frag_attacker.buffs & BUFF_BASH)
 389         if(vlen(frag_force))
 390         if(frag_attacker == frag_target)
 391                 frag_force *= autocvar_g_buffs_bash_force_self;
 392         else
 393                 frag_force *= autocvar_g_buffs_bash_force;
 394
 395         if(frag_attacker.buffs & BUFF_DISABILITY)
 396         if(frag_target != frag_attacker)
 397                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_time;
 398
 399         if(frag_attacker.buffs & BUFF_MEDIC)
 400         if(SAME_TEAM(frag_attacker, frag_target))
 401         if(frag_attacker != frag_target)
 402         {
 403                 frag_target.health = min(g_pickup_healthmega_max, frag_target.health + frag_damage);
 404                 frag_damage = 0;
 405         }
 406
 407         // this... is ridiculous (TODO: fix!)
 408         if(frag_attacker.buffs & BUFF_VAMPIRE)
 409         if(!frag_target.vehicle)
 410         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 411         if(frag_target.deadflag == DEAD_NO)
 412         if(IS_PLAYER(frag_target) || (frag_target.flags & FL_MONSTER))
 413         if(frag_attacker != frag_target)
 414         if(!frag_target.freezetag_frozen)
 415         if(frag_target.takedamage)
 416         if(DIFF_TEAM(frag_attacker, frag_target))
 417                 frag_attacker.health = bound(0, frag_attacker.health + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.health), g_pickup_healthsmall_max);
 418
 419         return FALSE;
 420 }
 421
 422 MUTATOR_HOOKFUNCTION(buffs_PlayerSpawn)
 423 {
 424         self.buffs = 0;
 425         // reset timers here to prevent them continuing after re-spawn
 426         self.buff_disability_time = 0;
 427         self.buff_disability_effect_time = 0;
 428         return FALSE;
 429 }
 430
 431 MUTATOR_HOOKFUNCTION(buffs_PlayerPhysics)
 432 {
 433         if(self.buffs & BUFF_SPEED)
 434         {
 435                 self.stat_sv_maxspeed *= autocvar_g_buffs_speed_speed;
 436                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_speed_speed;
 437         }
 438
 439         if(time < self.buff_disability_time)
 440         {
 441                 self.stat_sv_maxspeed *= autocvar_g_buffs_disability_speed;
 442                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_disability_speed;
 443         }
 444
 445         return FALSE;
 446 }
 447
 448 MUTATOR_HOOKFUNCTION(buffs_PlayerJump)
 449 {
 450         if(self.buffs & BUFF_JUMP)
 451                 player_jumpheight = autocvar_g_buffs_jump_height;
 452
 453         return FALSE;
 454 }
 455
 456 MUTATOR_HOOKFUNCTION(buffs_MonsterMove)
 457 {
 458         if(time < self.buff_disability_time)
 459         {
 460                 monster_speed_walk *= autocvar_g_buffs_disability_speed;
 461                 monster_speed_run *= autocvar_g_buffs_disability_speed;
 462         }
 463
 464         return FALSE;
 465 }
 466
 467 MUTATOR_HOOKFUNCTION(buffs_PlayerDies)
 468 {
 469         if(self.buffs)
 470         {
 471                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 472                 self.buffs = 0;
 473
 474                 if(self.buff_model)
 475                 {
 476                         remove(self.buff_model);
 477                         self.buff_model = world;
 478                 }
 479         }
 480         return FALSE;
 481 }
 482
 483 MUTATOR_HOOKFUNCTION(buffs_PlayerUseKey)
 484 {
 485         if(MUTATOR_RETURNVALUE || gameover) { return FALSE; }
 486         if(self.buffs)
 487         {
 488                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, self.buffs);
 489                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 490
 491                 self.buffs = 0;
 492                 sound(self, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 493                 return TRUE;
 494         }
 495         return FALSE;
 496 }
 497
 498 MUTATOR_HOOKFUNCTION(buffs_RemovePlayer)
 499 {
 500         if(self.buff_model)
 501         {
 502                 remove(self.buff_model);
 503                 self.buff_model = world;
 504         }
 505
 506         // also reset timers here to prevent them continuing after spectating
 507         self.buff_disability_time = 0;
 508         self.buff_disability_effect_time = 0;
 509
 510         return FALSE;
 511 }
 512
 513 MUTATOR_HOOKFUNCTION(buffs_OnEntityPreSpawn)
 514 {
 515         if(autocvar_g_buffs_replace_powerups)
 516         switch(self.classname)
 517         {
 518                 case "item_strength":
 519                 case "item_invincible":
 520                 {
 521                         entity e = spawn();
 522                         buff_SpawnReplacement(e, self);
 523                         return TRUE;
 524                 }
 525         }
 526         return FALSE;
 527 }
 528
 529 MUTATOR_HOOKFUNCTION(buffs_WeaponRate)
 530 {
 531         if(self.buffs & BUFF_SPEED)
 532                 weapon_rate *= autocvar_g_buffs_speed_rate;
 533
 534         if(time < self.buff_disability_time)
 535                 weapon_rate *= autocvar_g_buffs_disability_rate;
 536
 537         return FALSE;
 538 }
 539
 540 MUTATOR_HOOKFUNCTION(buffs_PlayerThink)
 541 {
 542         if(gameover || self.deadflag != DEAD_NO) { return FALSE; }
 543
 544         if(time < self.buff_disability_time)
 545         if(time >= self.buff_disability_effect_time)
 546         {
 547                 pointparticles(particleeffectnum("smoking"), self.origin + ((self.mins + self.maxs) * 0.5), '0 0 0', 1);
 548                 self.buff_disability_effect_time = time + 0.5;
 549         }
 550
 551         if(self.freezetag_frozen)
 552         {
 553                 if(self.buffs)
 554                 {
 555                         Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 556                         self.buffs = 0;
 557                 }
 558         }
 559
 560         if(!(self.oldbuffs & BUFF_JUMP) && !(self.buffs & BUFF_JUMP))
 561                 self.stat_jumpheight = autocvar_sv_jumpvelocity; // reset so we don't break anything
 562         else if((self.buffs & BUFF_JUMP) && self.stat_jumpheight != autocvar_g_buffs_jump_height)
 563                 self.stat_jumpheight = autocvar_g_buffs_jump_height;
 564
 565         if((self.buffs & BUFF_INVISIBLE) && (self.oldbuffs & BUFF_INVISIBLE))
 566         if(self.alpha != autocvar_g_buffs_invisible_alpha)
 567                 self.alpha = autocvar_g_buffs_invisible_alpha;
 568
 569         if(self.buffs != self.oldbuffs)
 570         {
 571                 if(self.oldbuffs & BUFF_AMMO)
 572                 {
 573                         if(self.buff_ammo_prev_infitems)
 574                                 self.items |= IT_UNLIMITED_WEAPON_AMMO;
 575                         else
 576                                 self.items &= ~IT_UNLIMITED_WEAPON_AMMO;
 577                 }
 578                 else if(self.buffs & BUFF_AMMO)
 579                 {
 580                         self.buff_ammo_prev_infitems = (self.items & IT_UNLIMITED_WEAPON_AMMO);
 581                         self.items |= IT_UNLIMITED_WEAPON_AMMO;
 582                         if(!self.ammo_shells) { self.ammo_shells = 20; }
 583                         if(!self.ammo_cells) { self.ammo_cells = 20; }
 584                         if(!self.ammo_rockets) { self.ammo_rockets = 20; }
 585                         if(!self.ammo_nails) { self.ammo_nails = 20; }
 586                         if(!self.ammo_fuel) { self.ammo_fuel = 20; }
 587                 }
 588
 589                 if(self.oldbuffs & BUFF_JUMP)
 590                         self.stat_jumpheight = autocvar_sv_jumpvelocity;
 591                 else if(self.buffs & BUFF_JUMP)
 592                         self.stat_jumpheight = autocvar_g_buffs_jump_height;
 593
 594                 if(self.oldbuffs & BUFF_INVISIBLE)
 595                 {
 596                         if(time < self.strength_finished && g_minstagib)
 597                                 self.alpha = autocvar_g_minstagib_invis_alpha;
 598                         else
 599                                 self.alpha = self.buff_invisible_prev_alpha;
 600                 }
 601                 else if(self.buffs & BUFF_INVISIBLE)
 602                 {
 603                         if(time < self.strength_finished && g_minstagib)
 604                                 self.buff_invisible_prev_alpha = default_player_alpha;
 605                         else
 606                                 self.buff_invisible_prev_alpha = self.alpha;
 607                         self.alpha = autocvar_g_buffs_invisible_alpha;
 608                 }
 609
 610                 if(self.oldbuffs & BUFF_FLIGHT)
 611                         self.gravity = self.buff_flight_prev_gravity;
 612                 else if(self.buffs & BUFF_FLIGHT)
 613                 {
 614                         self.buff_flight_prev_gravity = self.gravity;
 615                         self.gravity = autocvar_g_buffs_flight_gravity;
 616                 }
 617
 618                 self.oldbuffs = self.buffs;
 619                 if(self.buffs)
 620                 {
 621                         if(!self.buff_model)
 622                         {
 623                                 self.buff_model = spawn();
 624                                 setmodel(self.buff_model, "models/relics/relic.md3");
 625                                 setsize(self.buff_model, '0 0 -40', '0 0 40');
 626                                 setattachment(self.buff_model, self, "");
 627                                 setorigin(self.buff_model, '0 0 1' * (self.buff_model.maxs_z * 1));
 628                                 self.buff_model.owner = self;
 629                                 self.buff_model.scale = 0.7;
 630                                 self.buff_model.pflags = PFLAGS_FULLDYNAMIC;
 631                                 self.buff_model.light_lev = 200;
 632                                 self.buff_model.customizeentityforclient = buffs_BuffModel_Customize;
 633                         }
 634                         self.buff_model.color = Buff_Color(self.buffs);
 635                         self.buff_model.glowmod = ((self.buff_model.team) ? Team_ColorRGB(self.buff_model.team) + '0.1 0.1 0.1' : self.buff_model.color);
 636                         self.buff_model.skin = Buff_Skin(self.buffs);
 637
 638                         self.effects |= EF_NOSHADOW;
 639                 }
 640                 else
 641                 {
 642                         remove(self.buff_model);
 643                         self.buff_model = world;
 644
 645                         self.effects &= ~(EF_NOSHADOW);
 646                 }
 647         }
 648
 649         if(self.buff_model)
 650         {
 651                 self.buff_model.effects = self.effects;
 652                 self.buff_model.effects |= EF_LOWPRECISION;
 653                 self.buff_model.effects = self.buff_model.effects & EFMASK_CHEAP; // eat performance
 654
 655                 self.buff_model.alpha = self.alpha;
 656         }
 657
 658         return FALSE;
 659 }
 660
 661 MUTATOR_HOOKFUNCTION(buffs_SpectateCopy)
 662 {
 663         self.buffs = other.buffs;
 664         return FALSE;
 665 }
 666
 667 MUTATOR_HOOKFUNCTION(buffs_VehicleEnter)
 668 {
 669         vh_vehicle.buffs = vh_player.buffs;
 670         vh_player.buffs = 0;
 671         return FALSE;
 672 }
 673
 674 MUTATOR_HOOKFUNCTION(buffs_VehicleExit)
 675 {
 676         vh_player.buffs = vh_vehicle.buffs;
 677         vh_vehicle.buffs = 0;
 678         return FALSE;
 679 }
 680
 681 MUTATOR_HOOKFUNCTION(buffs_PlayerRegen)
 682 {
 683         if(self.buffs & BUFF_MEDIC)
 684         {
 685                 regen_mod_rot = autocvar_g_buffs_medic_rot;
 686                 regen_mod_limit = regen_mod_max = autocvar_g_buffs_medic_max;
 687                 regen_mod_regen = autocvar_g_buffs_medic_regen;
 688         }
 689
 690         if(self.buffs & BUFF_SPEED)
 691                 regen_mod_regen = autocvar_g_buffs_speed_regen;
 692
 693         return FALSE;
 694 }
 695
 696 MUTATOR_HOOKFUNCTION(buffs_GetCvars)
 697 {
 698         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_buffs_autoreplace, "cl_buffs_autoreplace");
 699         return FALSE;
 700 }
 701
 702 MUTATOR_HOOKFUNCTION(buffs_BuildMutatorsString)
 703 {
 704         ret_string = strcat(ret_string, ":Buffs");
 705         return FALSE;
 706 }
 707
 708 MUTATOR_HOOKFUNCTION(buffs_BuildMutatorsPrettyString)
 709 {
 710         ret_string = strcat(ret_string, ", Buffs");
 711         return FALSE;
 712 }
 713
 714 void buffs_DelayedInit()
 715 {
 716         if(autocvar_g_buffs_spawn_count > 0)
 717         if(find(world, classname, "item_buff") == world)
 718         {
 719                 float i;
 720                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
 721                 {
 722                         entity e = spawn();
 723                         e.spawnflags |= 1; // always randomize
 724                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
 725                         buff_Init(e);
 726                 }
 727         }
 728 }
 729
 730 void buffs_Initialize()
 731 {
 732         precache_model("models/relics/relic.md3");
 733         precache_sound("misc/strength_respawn.wav");
 734         precache_sound("misc/shield_respawn.wav");
 735         precache_sound("relics/relic_effect.wav");
 736         precache_sound("weapons/rocket_impact.wav");
 737         precache_sound("keepaway/respawn.wav");
 738
 739         addstat(STAT_BUFFS, AS_INT, buffs);
 740         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_jumpheight);
 741
 742         InitializeEntity(world, buffs_DelayedInit, INITPRIO_FINDTARGET);
 743 }
 744
 745 MUTATOR_DEFINITION(mutator_buffs)
 746 {
 747         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, buffs_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 748         MUTATOR_HOOK(PlayerDamage_Calculate, buffs_PlayerDamage_Calculate, CBC_ORDER_LAST);
 749         MUTATOR_HOOK(PlayerSpawn, buffs_PlayerSpawn, CBC_ORDER_ANY);
 750         MUTATOR_HOOK(PlayerPhysics, buffs_PlayerPhysics, CBC_ORDER_ANY);
 751         MUTATOR_HOOK(PlayerJump, buffs_PlayerJump, CBC_ORDER_ANY);
 752         MUTATOR_HOOK(MonsterMove, buffs_MonsterMove, CBC_ORDER_ANY);
 753         MUTATOR_HOOK(SpectateCopy, buffs_SpectateCopy, CBC_ORDER_ANY);
 754         MUTATOR_HOOK(VehicleEnter, buffs_VehicleEnter, CBC_ORDER_ANY);
 755         MUTATOR_HOOK(VehicleExit, buffs_VehicleExit, CBC_ORDER_ANY);
 756         MUTATOR_HOOK(PlayerRegen, buffs_PlayerRegen, CBC_ORDER_ANY);
 757         MUTATOR_HOOK(PlayerDies, buffs_PlayerDies, CBC_ORDER_ANY);
 758         MUTATOR_HOOK(PlayerUseKey, buffs_PlayerUseKey, CBC_ORDER_ANY);
 759         MUTATOR_HOOK(MakePlayerObserver, buffs_RemovePlayer, CBC_ORDER_ANY);
 760         MUTATOR_HOOK(ClientDisconnect, buffs_RemovePlayer, CBC_ORDER_ANY);
 761         MUTATOR_HOOK(OnEntityPreSpawn, buffs_OnEntityPreSpawn, CBC_ORDER_ANY);
 762         MUTATOR_HOOK(WeaponRateFactor, buffs_WeaponRate, CBC_ORDER_ANY);
 763         MUTATOR_HOOK(PlayerPreThink, buffs_PlayerThink, CBC_ORDER_ANY);
 764         MUTATOR_HOOK(GetCvars, buffs_GetCvars, CBC_ORDER_ANY);
 765         MUTATOR_HOOK(BuildMutatorsString, buffs_BuildMutatorsString, CBC_ORDER_ANY);
 766         MUTATOR_HOOK(BuildMutatorsPrettyString, buffs_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 767
 768         MUTATOR_ONADD
 769         {
 770                 buffs_Initialize();
 771         }
 772
 773         return FALSE;
 774 }