qcsrc/server/mutators/mutator_dodging.qc

   1
   2 .float cvar_cl_dodging_timeout;
   3
   4
   5 // these are used to store the last key press time for each of the keys..
   6 .float last_FORWARD_KEY_time;
   7 .float last_BACKWARD_KEY_time;
   8 .float last_LEFT_KEY_time;
   9 .float last_RIGHT_KEY_time;
  10
  11 // these store the movement direction at the time of the dodge action happening.
  12 .float dodging_direction_x;
  13 .float dodging_direction_y;
  14
  15 // this indicates the last time a dodge was executed. used to check if another one is allowed
  16 // and to ramp up the dodge acceleration in the physics hook.
  17 .float last_dodging_time;
  18
  19 // set to 1 to indicate dodging has started.. reset by physics hook after dodge has been done..
  20 .float dodging_action;
  21
  22 // the jump part of the dodge cannot be ramped
  23 .float dodging_single_action;
  24
  25 void dodging_Initialize() {
  26         // print("dodging_Initialize\n");
  27
  28         self.last_FORWARD_KEY_time = 0;
  29         self.last_BACKWARD_KEY_time = 0;
  30         self.last_RIGHT_KEY_time = 0;
  31         self.last_LEFT_KEY_time = 0;
  32         self.last_dodging_time = 0;
  33         self.dodging_action = 0;
  34         self.dodging_single_action = 0;
  35         self.dodging_direction_x = 0;
  36         self.dodging_direction_y = 0;
  37 }
  38
  39 MUTATOR_HOOKFUNCTION(dodging_GetCvars) {
  40         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_dodging_timeout, "cl_dodging_timeout");
  41         return 0;
  42 }
  43
  44 MUTATOR_HOOKFUNCTION(dodging_PlayerPhysics) {
  45         // print("dodging_PlayerPhysics\n");
  46
  47         float common_factor;
  48
  49         // is dodging enabled at all? if not, do nothing..
  50         if (g_dodging == 0)
  51                 return 0;
  52
  53         // make sure v_up, v_right and v_forward are sane
  54         makevectors(self.angles);
  55
  56         // if we have e.g. 0.5 sec ramptime and a frametime of 0.25, then the ramp code
  57         // will be called ramp_time/frametime times = 2 times. so, we need to
  58         // add 0.5 * the total speed each frame until the dodge action is done..
  59         common_factor = sys_frametime / cvar("sv_dodging_ramp_time");
  60
  61         // if ramp time is smaller than frametime we get problems ;D
  62         if (common_factor > 1)
  63                 common_factor = 1;
  64
  65
  66         // ramp up dodging speed by adding some velocity each frame.. TODO: do it! :D
  67         if (self.dodging_action == 1) {
  68                 //disable jump key during dodge accel phase
  69                 if (self.movement_z > 0) self.movement_z = 0;
  70
  71                 self.velocity =
  72                           self.velocity
  73                         + (common_factor * (self.dodging_direction_y * cvar("sv_dodging_horiz_speed")) * v_right)
  74                         + (common_factor * (self.dodging_direction_x * cvar("sv_dodging_horiz_speed")) * v_forward);
  75         }
  76
  77         // the up part of the dodge is a single shot action
  78         if (self.dodging_single_action == 1) {
  79                 self.velocity =
  80                           self.velocity
  81                         + (cvar("sv_dodging_up_speed") * v_up);
  82
  83                 if (cvar("sv_dodging_sound") == 1)
  84                         PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
  85
  86                 self.dodging_single_action = 0;
  87         }
  88
  89         // are we done with the dodging ramp yet?
  90         if((self.dodging_action == 1) && ((time - self.last_dodging_time) > cvar("sv_dodging_ramp_time")))
  91         {
  92                 // reset state so next dodge can be done correctly
  93                 self.dodging_action = 0;
  94                 self.dodging_direction_x = 0;
  95                 self.dodging_direction_y = 0;
  96         }
  97
  98         return 0;
  99 }
 100
 101 MUTATOR_HOOKFUNCTION(dodging_GetPressedKeys) {
 102         // print("dodging_PlayerPhysics\n");
 103
 104         float length;
 105         float dodge_detected;
 106         vector trace_start;
 107         vector trace_end;
 108         float height_above_ground;
 109
 110         if (g_dodging == 0)
 111                 return 0;
 112
 113         dodge_detected = 0;
 114
 115         // no dodging and jumping at the same time..
 116         if (self.BUTTON_JUMP)
 117                 return 0;
 118
 119         // first check if the last dodge is far enough back in time so we can dodge again
 120         if ((time - self.last_dodging_time) < cvar("sv_dodging_delay"))
 121                 return 0;
 122
 123         // determine height above ground is below a threshold
 124         trace_start = self.origin;
 125         trace_end = self.origin - (100*v_up);
 126
 127         traceline(trace_start, trace_end, TRUE, self);
 128         height_above_ground = self.origin_z - trace_endpos_z;
 129
 130         // check if our feet are on the ground or at least close :D
 131         if (height_above_ground > (fabs(PL_MIN_z) + cvar("sv_dodging_height_threshold")))
 132                 return 0;
 133
 134         if (self.movement_x > 0) {
 135                 // is this a state change?
 136                 if (!(self.pressedkeys & KEY_FORWARD)) {
 137                         if ((time - self.last_FORWARD_KEY_time) < self.cvar_cl_dodging_timeout) {
 138                                 dodge_detected = 1;
 139                                 self.dodging_direction_x = 1.0;
 140                         }
 141                         self.last_FORWARD_KEY_time = time;
 142                 }
 143         }
 144
 145         if (self.movement_x < 0) {
 146                 // is this a state change?
 147                 if (!(self.pressedkeys & KEY_BACKWARD)) {
 148                         if ((time - self.last_BACKWARD_KEY_time) < self.cvar_cl_dodging_timeout)        {
 149                                 dodge_detected = 1;
 150                                 self.dodging_direction_x = -1.0;
 151                         }
 152                         self.last_BACKWARD_KEY_time = time;
 153                 }
 154         }
 155
 156         if (self.movement_y > 0) {
 157                 // is this a state change?
 158                 if (!(self.pressedkeys & KEY_RIGHT)) {
 159                         if ((time - self.last_RIGHT_KEY_time) < self.cvar_cl_dodging_timeout)   {
 160                                 dodge_detected = 1;
 161                                 self.dodging_direction_y = 1.0;
 162                         }
 163                         self.last_RIGHT_KEY_time = time;
 164                 }
 165         }
 166
 167         if (self.movement_y < 0) {
 168                 // is this a state change?
 169                 if (!(self.pressedkeys & KEY_LEFT)) {
 170                         if ((time - self.last_LEFT_KEY_time) < self.cvar_cl_dodging_timeout)    {
 171                                 dodge_detected = 1;
 172                                 self.dodging_direction_y = -1.0;
 173                         }
 174                         self.last_LEFT_KEY_time = time;
 175                 }
 176         }
 177
 178
 179
 180         if (dodge_detected == 1) {
 181                 if (self.movement_z > 0)
 182                         self.movement_z = 0;
 183
 184                 self.last_dodging_time = time;
 185
 186                 self.dodging_action = 1;
 187                 self.dodging_single_action = 1;
 188
 189                 // normalize the dodging_direction vector.. (unlike UT99) XD
 190                 length = length + self.dodging_direction_x * self.dodging_direction_x;
 191                 length = length + self.dodging_direction_y * self.dodging_direction_y;
 192                 length = sqrt(length);
 193
 194                 self.dodging_direction_x = self.dodging_direction_x * 1.0/length;
 195                 self.dodging_direction_y = self.dodging_direction_y * 1.0/length;
 196         }
 197
 198         return 0;
 199 }
 200
 201 MUTATOR_DEFINITION(dodging)
 202 {
 203         // we need to be called before GetPressedKey does its thing so we can
 204         // detect state changes and therefore dodging actions..
 205         MUTATOR_HOOK(GetPressedKeys, dodging_GetPressedKeys, CBC_ORDER_ANY);
 206
 207         // in the physics hook we actually implement the dodge..
 208         MUTATOR_HOOK(PlayerPhysics, dodging_PlayerPhysics, CBC_ORDER_ANY);
 209
 210         MUTATOR_HOOK(GetCvars, dodging_GetCvars, CBC_ORDER_ANY);
 211
 212         // this just turns on the cvar.
 213         MUTATOR_ONADD
 214         {
 215                 g_dodging = 1;
 216                 dodging_Initialize();
 217         }
 218
 219         // this just turns off the cvar.
 220         MUTATOR_ONREMOVE
 221         {
 222                 g_dodging = 0;
 223         }
 224
 225         return 0;
 226 }