qcsrc/server/mutators/mutator_multijump.qc

   1 .float multijump_count;
   2 .float multijump_ready;
   3
   4 #ifdef CSQC
   5
   6 #define PHYS_MULTIJUMP                          getstati(STAT_MULTIJUMP)
   7 #define PHYS_MULTIJUMP_SPEED            getstatf(STAT_MULTIJUMP_SPEED)
   8 #define PHYS_MULTIJUMP_ADD                      getstati(STAT_MULTIJUMP_ADD)
   9
  10 #elif defined(SVQC)
  11
  12 #define PHYS_MULTIJUMP                          autocvar_g_multijump
  13 #define PHYS_MULTIJUMP_SPEED            autocvar_g_multijump_speed
  14 #define PHYS_MULTIJUMP_ADD                      autocvar_g_multijump_add
  15
  16
  17 .float stat_multijump;
  18 .float stat_multijump_speed;
  19 .float stat_multijump_add;
  20
  21 void multijump_UpdateStats()
  22 {
  23         self.stat_multijump = PHYS_MULTIJUMP;
  24         self.stat_multijump_speed = PHYS_MULTIJUMP_SPEED;
  25         self.stat_multijump_add = PHYS_MULTIJUMP_ADD;
  26 }
  27
  28 void multijump_AddStats()
  29 {
  30         addstat(STAT_MULTIJUMP, AS_INT, stat_multijump);
  31         addstat(STAT_MULTIJUMP_SPEED, AS_FLOAT, stat_multijump_speed);
  32         addstat(STAT_MULTIJUMP_ADD, AS_INT, stat_multijump_add);
  33 }
  34
  35 #endif
  36
  37 void PM_multijump()
  38 {
  39         if(!PHYS_MULTIJUMP) { return; }
  40
  41         if(IS_ONGROUND(self))
  42         {
  43                 if (PHYS_MULTIJUMP > 0)
  44                         self.multijump_count = 0;
  45                 else
  46                         self.multijump_count = -2; // the cvar value for infinite jumps is -1, so this needs to be smaller
  47         }
  48 }
  49
  50 float PM_multijump_checkjump()
  51 {
  52         if(!PHYS_MULTIJUMP) { return FALSE; }
  53
  54         if (!IS_JUMP_HELD(self) && !IS_ONGROUND(self)) // jump button pressed this frame and we are in midair
  55                 self.multijump_ready = TRUE;  // this is necessary to check that we released the jump button and pressed it again
  56         else
  57                 self.multijump_ready = FALSE;
  58
  59         if(!player_multijump && self.multijump_ready && self.multijump_count < PHYS_MULTIJUMP && self.velocity_z > PHYS_MULTIJUMP_SPEED)
  60         {
  61                 if (PHYS_MULTIJUMP)
  62                 {
  63                         if (!PHYS_MULTIJUMP_ADD) // in this case we make the z velocity == jumpvelocity
  64                         {
  65                                 if (self.velocity_z < PHYS_JUMPVELOCITY)
  66                                 {
  67                                         player_multijump = TRUE;
  68                                         self.velocity_z = 0;
  69                                 }
  70                         }
  71                         else
  72                                 player_multijump = TRUE;
  73
  74                         if(player_multijump)
  75                         {
  76                                 if(PHYS_INPUT_MOVEVALUES(self)_x != 0 || PHYS_INPUT_MOVEVALUES(self)_y != 0) // don't remove all speed if player isnt pressing any movement keys
  77                                 {
  78                                         float curspeed = vlen(vec2(self.velocity));
  79                                         vector wishvel, wishdir;
  80
  81                                         makevectors(PHYS_INPUT_ANGLES(self)_y * '0 1 0');
  82                                         wishvel = v_forward * PHYS_INPUT_MOVEVALUES(self)_x + v_right * PHYS_INPUT_MOVEVALUES(self)_y;
  83                                         wishdir = normalize(wishvel);
  84
  85                                         self.velocity_x = wishdir_x * curspeed; // allow "dodging" at a multijump
  86                                         self.velocity_y = wishdir_y * curspeed;
  87                                         // keep velocity_z unchanged!
  88                                 }
  89                                 if (PHYS_MULTIJUMP > 0)
  90                                         self.multijump_count += 1;
  91                         }
  92                 }
  93                 self.multijump_ready = FALSE; // require releasing and pressing the jump button again for the next jump
  94         }
  95
  96         return FALSE;
  97 }
  98
  99 #ifdef SVQC
 100 MUTATOR_HOOKFUNCTION(multijump_PlayerPhysics)
 101 {
 102         multijump_UpdateStats();
 103         PM_multijump();
 104
 105         return FALSE;
 106 }
 107
 108 MUTATOR_HOOKFUNCTION(multijump_PlayerJump)
 109 {
 110         return PM_multijump_checkjump();
 111 }
 112
 113 MUTATOR_HOOKFUNCTION(multijump_BuildMutatorsString)
 114 {
 115         ret_string = strcat(ret_string, ":multijump");
 116         return FALSE;
 117 }
 118
 119 MUTATOR_HOOKFUNCTION(multijump_BuildMutatorsPrettyString)
 120 {
 121         ret_string = strcat(ret_string, ", Multi jump");
 122         return FALSE;
 123 }
 124
 125 MUTATOR_DEFINITION(mutator_multijump)
 126 {
 127         MUTATOR_HOOK(PlayerPhysics, multijump_PlayerPhysics, CBC_ORDER_ANY);
 128         MUTATOR_HOOK(PlayerJump, multijump_PlayerJump, CBC_ORDER_ANY);
 129         MUTATOR_HOOK(BuildMutatorsString, multijump_BuildMutatorsString, CBC_ORDER_ANY);
 130         MUTATOR_HOOK(BuildMutatorsPrettyString, multijump_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 131
 132         MUTATOR_ONADD
 133         {
 134                 multijump_AddStats();
 135         }
 136
 137         return FALSE;
 138 }
 139 #endif