qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .float object_flood;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 void sandbox_ObjectFunction_Think()
  34 {
  35         entity e;
  36
  37         // decide if and how this object can be grabbed
  38         if(autocvar_g_sandbox_readonly)
  39                 self.grab = 0; // no grabbing
  40         else if(autocvar_g_sandbox_editor_free < 2 && self.crypto_idfp)
  41                 self.grab = 1; // owner only
  42         else
  43                 self.grab = 3; // anyone
  44
  45         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
  46         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
  47         // since if the owning player disconnects, the object's owner should also be reset.
  48         FOR_EACH_REALPLAYER(e) // bots can't have objects
  49         {
  50                 if(self.crypto_idfp == e.crypto_idfp)
  51                 {
  52                         self.realowner = e;
  53                         break;
  54                 }
  55                 self.realowner = world;
  56         }
  57
  58         self.nextthink = time;
  59 }
  60
  61 .float old_solid, old_movetype;
  62 entity sandbox_ObjectEdit_Get(float permissions)
  63 {
  64         // Returns the traced entity if the player can edit it, and world if not.
  65         // If permissions if FALSE, the object is returned regardless of editing rights.
  66         // Attached objects are SOLID_NOT and do not get traced.
  67
  68         crosshair_trace_plusvisibletriggers(self);
  69         if(vlen(self.origin - trace_ent.origin) > autocvar_g_sandbox_editor_distance_edit)
  70                 return world; // out of trace range
  71         if(trace_ent.classname != "object")
  72                 return world; // entity is not an object
  73         if(!permissions)
  74                 return trace_ent; // don't check permissions, anyone can edit this object
  75         if(!trace_ent.crypto_idfp)
  76                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  77         if not(trace_ent.realowner != self && autocvar_g_sandbox_editor_free < 2)
  78                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  79         return world;
  80 }
  81
  82 void sandbox_ObjectEdit_Scale(entity e, float f)
  83 {
  84         e.scale = f;
  85         if(e.scale)
  86         {
  87                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  88                 setmodel(e, e.model); // reset mins and maxs based on mesh
  89                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  90         }
  91 }
  92
  93 void sandbox_ObjectAttach_Remove(entity e);
  94 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  95 {
  96         // attaches e to parent on string s
  97
  98         // we can't attach to an attachment, for obvious reasons
  99         sandbox_ObjectAttach_Remove(e);
 100
 101         e.old_solid = e.solid; // persist solidity
 102         e.old_movetype = e.movetype; // persist physics
 103         e.movetype = MOVETYPE_FOLLOW;
 104         e.solid = SOLID_NOT;
 105         e.takedamage = DAMAGE_NO;
 106
 107         setattachment(e, parent, s);
 108         e.owner = parent;
 109 }
 110
 111 void sandbox_ObjectAttach_Remove(entity e)
 112 {
 113         // detaches any object attached to e
 114
 115         entity head;
 116         for(head = world; (head = find(head, classname, "object")); )
 117         {
 118                 if(head.owner == e)
 119                 {
 120                         vector org;
 121                         org = gettaginfo(head, 0);
 122                         setattachment(head, world, "");
 123                         head.owner = world;
 124
 125                         // objects change origin and angles when detached, so apply previous position
 126                         setorigin(head, org);
 127                         head.angles = e.angles; // don't allow detached objects to spin or roll
 128
 129                         head.solid = head.old_solid; // restore persisted solidity
 130                         head.movetype = head.old_movetype; // restore persisted physics
 131                         head.takedamage = DAMAGE_AIM;
 132                 }
 133         }
 134 }
 135
 136 entity sandbox_ObjectSpawn(float database)
 137 {
 138         // spawn a new object with default properties
 139
 140         entity e;
 141         e = spawn();
 142         e.classname = "object";
 143         e.takedamage = DAMAGE_AIM;
 144         e.damageforcescale = 1;
 145         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 146         e.movetype = MOVETYPE_TOSS;
 147         e.frame = 0;
 148         e.skin = 0;
 149         e.material = string_null;
 150         e.touch = sandbox_ObjectFunction_Touch;
 151         e.think = sandbox_ObjectFunction_Think;
 152         e.nextthink = time;
 153         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 154
 155         if(!database)
 156         {
 157                 // set the object's owner via player UID
 158                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 159                 if(self.crypto_idfp != "")
 160                         e.crypto_idfp = strzone(self.crypto_idfp);
 161                 else
 162                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 163
 164                 // set public object information
 165                 e.netname = strzone(self.netname); // name of the owner
 166                 e.message = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // creation time
 167                 e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // last editing time
 168
 169                 // set origin and direction based on player position and view angle
 170                 makevectors(self.v_angle);
 171                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 172                 setorigin(e, trace_endpos);
 173                 e.angles_y = self.v_angle_y;
 174         }
 175
 176         object_count += 1;
 177         return e;
 178 }
 179
 180 void sandbox_ObjectRemove(entity e)
 181 {
 182         sandbox_ObjectAttach_Remove(e); // detach child objects
 183
 184         // if the object being removed has been selected for attachment by a player, unset it
 185         entity head;
 186         FOR_EACH_REALPLAYER(head) // bots can't have objects
 187         {
 188                 if(head.object_attach == e)
 189                         head.object_attach = world;
 190         }
 191
 192         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
 193         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
 194         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
 195         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
 196         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
 197         remove(e);
 198         e = world;
 199
 200         object_count -= 1;
 201 }
 202
 203 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 204
 205 string sandbox_ObjectPort_Save(entity e, float database)
 206 {
 207         // save object properties, and return them as a string
 208         float i;
 209         string s;
 210         entity head;
 211
 212         for(head = world; (head = find(head, classname, "object")); )
 213         {
 214                 // the main object needs to be first in the array [0] with attached objects following
 215                 float slot, physics, solidity;
 216                 if(head == e) // this is the main object, place it first
 217                 {
 218                         slot = 0;
 219                         solidity = head.solid; // applied solidity is normal solidity for children
 220                         physics = head.movetype; // applied physics are normal physics for parents
 221                 }
 222                 else if(head.owner == e) // child object, list them in order
 223                 {
 224                         i += 1; // children start from 1
 225                         slot = i;
 226                         solidity = head.old_solid; // persisted solidity is normal solidity for children
 227                         physics = head.old_movetype; // persisted physics are normal physics for children
 228                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 229                 }
 230                 else
 231                         continue;
 232
 233                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 234                 if(slot)
 235                 {
 236                         // properties stored only for child objects
 237                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 238                 }
 239                 else
 240                 {
 241                         // properties stored only for parent objects
 242                         if(database)
 243                         {
 244                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 245                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 246                         }
 247                 }
 248                 // properties stored for all objects
 249                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 250                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 251                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 252                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 253                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 254                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 255                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 256                 port_string[slot] = strcat(port_string[slot], ftos(solidity), " ");
 257                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 258                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 259                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 260                 if(database)
 261                 {
 262                         // properties stored only for the database
 263                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 264                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 265                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 266                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 267                 }
 268         }
 269
 270         // now apply the array to a simple string, with the ; symbol separating objects
 271         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 272         {
 273                 if(port_string[i])
 274                         s = strcat(s, port_string[i], "; ");
 275                 port_string[i] = string_null; // fully clear the string
 276         }
 277
 278         return s;
 279 }
 280
 281 entity sandbox_ObjectPort_Load(string s, float database)
 282 {
 283         // load object properties, and spawn a new object with them
 284         float n, i;
 285         entity e, parent;
 286
 287         // separate objects between the ; symbols
 288         n = tokenizebyseparator(s, "; ");
 289         for(i = 0; i < n; ++i)
 290                 port_string[i] = argv(i);
 291
 292         // now separate and apply the properties of each object
 293         for(i = 0; i < n; ++i)
 294         {
 295                 float argv_num;
 296                 string tagname;
 297                 argv_num = 0;
 298                 tokenize_console(port_string[i]);
 299                 e = sandbox_ObjectSpawn(database);
 300
 301                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 302                 if(i)
 303                 {
 304                         // properties stored only for child objects
 305                         if(argv(argv_num) != "")        tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 306                 }
 307                 else
 308                 {
 309                         // properties stored only for parent objects
 310                         if(database)
 311                         {
 312                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 313                                 e.angles = stov(argv(argv_num));        ++argv_num;
 314                         }
 315                         parent = e; // mark parent objects as such
 316                 }
 317                 // properties stored for all objects
 318                 setmodel(e, argv(argv_num));    ++argv_num;
 319                 e.skin = stof(argv(argv_num));  ++argv_num;
 320                 e.alpha = stof(argv(argv_num)); ++argv_num;
 321                 e.colormod = stov(argv(argv_num));      ++argv_num;
 322                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 323                 e.frame = stof(argv(argv_num)); ++argv_num;
 324                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 325                 e.solid = e.old_solid = stof(argv(argv_num));   ++argv_num;
 326                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 327                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 328                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "")        e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 329                 if(database)
 330                 {
 331                         // properties stored only for the database
 332                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "")        e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 333                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
 334                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
 335                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
 336                 }
 337
 338                 // attach last
 339                 if(i)
 340                         sandbox_ObjectAttach_Set(e, parent, tagname);
 341         }
 342
 343         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 344                 port_string[i] = string_null; // fully clear the string
 345
 346         return e;
 347 }
 348
 349 void sandbox_Database_Save()
 350 {
 351         // saves all objects to the database file
 352         entity head;
 353         string file_name;
 354         float file_get;
 355
 356         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 357         file_get = fopen(file_name, FILE_WRITE);
 358         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 359         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 360
 361         for(head = world; (head = find(head, classname, "object")); )
 362         {
 363                 // attached objects are persisted separately, ignore them here
 364                 if(head.owner != world)
 365                         continue;
 366
 367                 // use a line of text for each object, listing all properties
 368                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 369         }
 370         fclose(file_get);
 371 }
 372
 373 void sandbox_Database_Load()
 374 {
 375         // loads all objects from the database file
 376         string file_read, file_name;
 377         float file_get, i;
 378
 379         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 380         file_get = fopen(file_name, FILE_READ);
 381         if(file_get < 0)
 382         {
 383                 if(autocvar_g_sandbox_info > 0)
 384                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 385         }
 386         else
 387         {
 388                 for(;;)
 389                 {
 390                         file_read = fgets(file_get);
 391                         if(!file_read)
 392                                 break;
 393                         if(substring(file_read, 0, 2) == "//")
 394                                 continue;
 395                         if(substring(file_read, 0, 1) == "#")
 396                                 continue;
 397
 398                         entity e;
 399                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 400
 401                         if(e.material)
 402                         {
 403                                 // since objects are being loaded for the first time, precache material sounds for each
 404                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 405                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 406                         }
 407                 }
 408                 if(autocvar_g_sandbox_info > 0)
 409                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 410         }
 411         fclose(file_get);
 412 }
 413
 414 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 415 {
 416         if(MUTATOR_RETURNVALUE) // command was already handled?
 417                 return FALSE;
 418         if(cmd_name == "g_sandbox")
 419         {
 420                 if(autocvar_g_sandbox_readonly)
 421                 {
 422                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
 423                         return TRUE;
 424                 }
 425                 if(cmd_argc < 2)
 426                 {
 427                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
 428                         return TRUE;
 429                 }
 430
 431                 switch(argv(1))
 432                 {
 433                         entity e;
 434                         float i;
 435                         string s;
 436
 437                         // ---------------- COMMAND: HELP ----------------
 438                         case "help":
 439                                 print_to(self, "You can use the following sandbox commands:");
 440                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 441                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 442                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 443                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 444                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 445                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 446                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 447                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 448                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 449                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 450                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 451                                 print_to(self, "^3alpha value ^7- sets object transparency");
 452                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 453                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 454                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 455                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 456                                 print_to(self, "^3solidity value ^7- object collisions, 0 = non-solid, 1 = solid");
 457                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 458                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 459                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 460                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 461                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object");
 462                                 print_to(self, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
 463                                 print_to(self, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
 464                                 print_to(self, "^3attachments ^7- prints information about the object's attachments");
 465                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 466                                 return TRUE;
 467
 468                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 469                         case "object_spawn":
 470                                 if(time < self.object_flood)
 471                                 {
 472                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 473                                         return TRUE;
 474                                 }
 475                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 476                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 477                                 {
 478                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 479                                         return TRUE;
 480                                 }
 481                                 if(cmd_argc < 3)
 482                                 {
 483                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 484                                         return TRUE;
 485                                 }
 486                                 if not(fexists(argv(2)))
 487                                 {
 488                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 489                                         return TRUE;
 490                                 }
 491
 492                                 e = sandbox_ObjectSpawn(FALSE);
 493                                 setmodel(e, argv(2));
 494
 495                                 if(autocvar_g_sandbox_info > 0)
 496                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 497                                 return TRUE;
 498
 499                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 500                         case "object_remove":
 501                                 e = sandbox_ObjectEdit_Get(TRUE);
 502                                 if(e != world)
 503                                 {
 504                                         if(autocvar_g_sandbox_info > 0)
 505                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 506                                         sandbox_ObjectRemove(e);
 507                                         return TRUE;
 508                                 }
 509
 510                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 511                                 return TRUE;
 512
 513                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 514                         case "object_duplicate":
 515                                 switch(argv(2))
 516                                 {
 517                                         case "copy":
 518                                                 // copies customizable properties of the selected object to the clipboard cvar
 519                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 520                                                 if(e != world)
 521                                                 {
 522                                                         s = sandbox_ObjectPort_Save(e, FALSE);
 523                                                         s = strreplace("\"", "\\\"", s);
 524                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 525
 526                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 527                                                         return TRUE;
 528                                                 }
 529                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 530                                                 return TRUE;
 531
 532                                         case "paste":
 533                                                 // spawns a new object using the properties in the player's clipboard cvar
 534                                                 if(time < self.object_flood)
 535                                                 {
 536                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 537                                                         return TRUE;
 538                                                 }
 539                                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 540                                                 if(!argv(3)) // no object in clipboard
 541                                                 {
 542                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 543                                                         return TRUE;
 544                                                 }
 545                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 546                                                 {
 547                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 548                                                         return TRUE;
 549                                                 }
 550                                                 e = sandbox_ObjectPort_Load(argv(3), FALSE);
 551
 552                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 553                                                 if(autocvar_g_sandbox_info > 0)
 554                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 555                                                 return TRUE;
 556                                 }
 557                                 return TRUE;
 558
 559                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 560                         case "object_attach":
 561                                 switch(argv(2))
 562                                 {
 563                                         case "get":
 564                                                 // select e as the object as meant to be attached
 565                                                 e = sandbox_ObjectEdit_Get(TRUE);
 566                                                 if(e != world)
 567                                                 {
 568                                                         self.object_attach = e;
 569                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 570                                                         return TRUE;
 571                                                 }
 572                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 573                                                 return TRUE;
 574                                         case "set":
 575                                                 if(self.object_attach == world)
 576                                                 {
 577                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 578                                                         return TRUE;
 579                                                 }
 580
 581                                                 // attaches the previously selected object to e
 582                                                 e = sandbox_ObjectEdit_Get(TRUE);
 583                                                 if(e != world)
 584                                                 {
 585                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 586                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 587                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 588                                                         if(autocvar_g_sandbox_info > 1)
 589                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 590                                                         return TRUE;
 591                                                 }
 592                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 593                                                 return TRUE;
 594                                         case "remove":
 595                                                 // removes e if it was attached
 596                                                 e = sandbox_ObjectEdit_Get(TRUE);
 597                                                 if(e != world)
 598                                                 {
 599                                                         sandbox_ObjectAttach_Remove(e);
 600                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 601                                                         if(autocvar_g_sandbox_info > 1)
 602                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 603                                                         return TRUE;
 604                                                 }
 605                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 606                                                 return TRUE;
 607                                 }
 608                                 return TRUE;
 609
 610                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 611                         case "object_edit":
 612                                 if(!argv(2))
 613                                 {
 614                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 615                                         return TRUE;
 616                                 }
 617
 618                                 e = sandbox_ObjectEdit_Get(TRUE);
 619                                 if(e != world)
 620                                 {
 621                                         switch(argv(2))
 622                                         {
 623                                                 case "skin":
 624                                                         e.skin = stof(argv(3));
 625                                                         break;
 626                                                 case "alpha":
 627                                                         e.alpha = stof(argv(3));
 628                                                         break;
 629                                                 case "color_main":
 630                                                         e.colormod = stov(argv(3));
 631                                                         break;
 632                                                 case "color_glow":
 633                                                         e.glowmod = stov(argv(3));
 634                                                         break;
 635                                                 case "frame":
 636                                                         e.frame = stof(argv(3));
 637                                                         break;
 638                                                 case "scale":
 639                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 640                                                         break;
 641                                                 case "solidity":
 642                                                         switch(argv(3))
 643                                                         {
 644                                                                 case "0": // non-solid
 645                                                                         e.solid = SOLID_TRIGGER;
 646                                                                         break;
 647                                                                 case "1": // solid
 648                                                                         e.solid = SOLID_BBOX;
 649                                                                         break;
 650                                                                 default:
 651                                                                         break;
 652                                                         }
 653                                                 case "physics":
 654                                                         switch(argv(3))
 655                                                         {
 656                                                                 case "0": // static
 657                                                                         e.movetype = MOVETYPE_NONE;
 658                                                                         break;
 659                                                                 case "1": // movable
 660                                                                         e.movetype = MOVETYPE_TOSS;
 661                                                                         break;
 662                                                                 case "2": // physical
 663                                                                         e.movetype = MOVETYPE_PHYSICS;
 664                                                                         break;
 665                                                                 default:
 666                                                                         break;
 667                                                         }
 668                                                         break;
 669                                                 case "force":
 670                                                         e.damageforcescale = stof(argv(3));
 671                                                         break;
 672                                                 case "material":
 673                                                         if(e.material)  strunzone(e.material);
 674                                                         if(argv(3))
 675                                                         {
 676                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 677                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 678                                                                 e.material = strzone(argv(3));
 679                                                         }
 680                                                         else
 681                                                                 e.material = string_null; // no material
 682                                                         break;
 683                                                 default:
 684                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 685                                                         return TRUE;
 686                                         }
 687
 688                                         // update last editing time
 689                                         if(e.message2)  strunzone(e.message2);
 690                                         e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S"));
 691
 692                                         if(autocvar_g_sandbox_info > 1)
 693                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 694                                         return TRUE;
 695                                 }
 696
 697                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 698                                 return TRUE;
 699
 700                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 701                         case "object_claim":
 702                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 703                                 if(self.crypto_idfp == "")
 704                                 {
 705                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 706                                         return TRUE;
 707                                 }
 708                                 e = sandbox_ObjectEdit_Get(TRUE);
 709                                 if(e != world)
 710                                 {
 711                                         // update the owner's name
 712                                         // Do this before checking if you're already the owner and skipping if such, so we
 713                                         // also update the player's nickname if he changed it (but has the same player UID)
 714                                         if(e.netname != self.netname)
 715                                         {
 716                                                 if(e.netname)   strunzone(e.netname);
 717                                                 e.netname = strzone(self.netname);
 718                                                 print_to(self, "^2SANDBOX - INFO: ^7Object owner name updated");
 719                                         }
 720
 721                                         if(e.crypto_idfp == self.crypto_idfp)
 722                                         {
 723                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 724                                                 return TRUE;
 725                                         }
 726
 727                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
 728                                         e.crypto_idfp = strzone(self.crypto_idfp);
 729
 730                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 731                                 }
 732                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 733                                 return TRUE;
 734
 735                         // ---------------- COMMAND: OBJECT, INFO ----------------
 736                         case "object_info":
 737                                 // prints public information about the object to the player
 738                                 e = sandbox_ObjectEdit_Get(FALSE);
 739                                 if(e != world)
 740                                 {
 741                                         switch(argv(2))
 742                                         {
 743                                                 case "object":
 744                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
 745                                                         return TRUE;
 746                                                 case "mesh":
 747                                                         for(i = 1; gettaginfo(e, i); i++)
 748                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
 749                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
 750                                                         return TRUE;
 751                                                 case "attachments":
 752                                                         // this should show the same info as 'mesh' but for attachments
 753                                                         entity head;
 754                                                         for(head = world; (head = find(head, classname, "object")); )
 755                                                         {
 756                                                                 if(head.owner == e)
 757                                                                 {
 758                                                                         ++i; // start from 1
 759                                                                         gettaginfo(e, head.tag_index);
 760                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
 761                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
 762                                                                 }
 763                                                         }
 764                                                         if(i) // object contains attachments
 765                                                                 print_to(self, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
 766                                                         else
 767                                                                 print_to(self, "^2SANDBOX - INFO: ^7Object contains no attachments");
 768                                                         return TRUE;
 769                                         }
 770                                 }
 771                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
 772                                 return TRUE;
 773
 774                         // ---------------- COMMAND: DEFAULT ----------------
 775                         default:
 776                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 777                                 return TRUE;
 778                 }
 779         }
 780         return FALSE;
 781 }
 782
 783 float autosave_time;
 784 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 785 {
 786         if(!autocvar_g_sandbox_storage_autosave)
 787                 return FALSE;
 788         if(time < autosave_time)
 789                 return FALSE;
 790         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 791
 792         sandbox_Database_Save();
 793
 794         return TRUE;
 795 }
 796
 797 MUTATOR_DEFINITION(sandbox)
 798 {
 799         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 800         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 801
 802         MUTATOR_ONADD
 803         {
 804                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 805                 if(autocvar_g_sandbox_storage_autoload)
 806                         sandbox_Database_Load();
 807         }
 808
 809         return FALSE;
 810 }
 811