qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .string object_clipboard;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 entity sandbox_ObjectEdit_Get()
  34 {
  35         // returns the traced entity if the player can edit it, and world if not
  36         // attached objects are SOLID_NOT and don't risk getting traced
  37
  38         makevectors(self.v_angle);
  39         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  40
  41         if(trace_ent.classname != "object")
  42                 return world; // entity is not an object
  43         if(!trace_ent.crypto_idfp)
  44                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  45         else if not(trace_ent.crypto_idfp != self.crypto_idfp && !autocvar_g_sandbox_editor_free)
  46                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  47         return world;
  48 }
  49
  50 void sandbox_ObjectEdit_Scale(entity e, float f)
  51 {
  52         e.scale = f;
  53         if(e.scale)
  54         {
  55                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  56                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  57         }
  58 }
  59
  60 void sandbox_ObjectAttach_Remove(entity e);
  61 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  62 {
  63         // attaches e to parent on string s
  64
  65         // we can't attach to an attachment, for obvious reasons
  66         sandbox_ObjectAttach_Remove(e);
  67
  68         e.movetype = MOVETYPE_FOLLOW;
  69         e.solid = SOLID_NOT;
  70         e.takedamage = DAMAGE_NO;
  71
  72         setattachment(e, parent, s);
  73         e.owner = parent;
  74 }
  75
  76 void sandbox_ObjectAttach_Remove(entity e)
  77 {
  78         // detaches any object attached to e
  79
  80         entity head;
  81         for(head = world; (head = find(head, classname, "object")); )
  82         {
  83                 if(head.owner == e)
  84                 {
  85                         head.movetype = MOVETYPE_TOSS; // default
  86                         head.solid = SOLID_BBOX;
  87                         head.takedamage = DAMAGE_AIM;
  88
  89                         setattachment(head, world, "");
  90                         head.owner = world;
  91
  92                         // objects reset origin and angles when detached, so apply the parent's to prevent teleporting
  93                         setorigin(head, e.origin);
  94                         head.angles = e.angles;
  95                 }
  96         }
  97 }
  98
  99 entity sandbox_ObjectSpawn(float database)
 100 {
 101         // spawn a new object with default properties
 102
 103         entity e;
 104         e = spawn();
 105         e.classname = "object";
 106         e.takedamage = DAMAGE_AIM;
 107         e.damageforcescale = 1;
 108         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 109         e.movetype = MOVETYPE_TOSS;
 110         e.frame = 0;
 111         e.skin = 0;
 112         e.material = string_null;
 113         e.touch = sandbox_ObjectFunction_Touch;
 114
 115         if(!database)
 116         {
 117                 // set the object's owner via player UID
 118                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 119                 if(self.crypto_idfp != "")
 120                         e.crypto_idfp = strzone(self.crypto_idfp);
 121                 else
 122                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 123
 124                 // set origin and direction based on player position and view angle
 125                 makevectors(self.v_angle);
 126                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 127                 setorigin(e, trace_endpos);
 128                 e.angles_y = self.v_angle_y;
 129         }
 130
 131         object_count += 1;
 132         return e;
 133 }
 134
 135 void sandbox_ObjectRemove(entity e)
 136 {
 137         sandbox_ObjectAttach_Remove(e); // detach child objects
 138         if(e.material)
 139         {
 140                 strunzone(e.material);
 141                 e.material = string_null;
 142         }
 143         if(e.crypto_idfp)
 144         {
 145                 strunzone(e.crypto_idfp);
 146                 e.crypto_idfp = string_null;
 147         }
 148         remove(e);
 149         e = world;
 150
 151         object_count -= 1;
 152 }
 153
 154 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 155 string sandbox_ObjectPort_Save(entity e, float database)
 156 {
 157         // save object properties
 158         float i;
 159         string s;
 160         entity head;
 161
 162         for(head = world; (head = find(head, classname, "object")); )
 163         {
 164                 // the main object needs to be saved first in the array, with attached objects following after
 165                 float tmp;
 166                 if(head == e)
 167                         tmp = 0;
 168                 else if(head.owner == e)
 169                 {
 170                         i += 1; // child objects start from 1
 171                         tmp = i;
 172                 }
 173                 else
 174                         continue;
 175
 176                 port_string[tmp] = strcat(port_string[tmp], head.model, " ");
 177                 port_string[tmp] = strcat(port_string[tmp], ftos(head.skin), " ");
 178                 port_string[tmp] = strcat(port_string[tmp], ftos(head.alpha), " ");
 179                 port_string[tmp] = strcat(port_string[tmp], sprintf("\"%.9v\"", head.colormod), " ");
 180                 port_string[tmp] = strcat(port_string[tmp], sprintf("\"%.9v\"", head.glowmod), " ");
 181                 port_string[tmp] = strcat(port_string[tmp], ftos(head.frame), " ");
 182                 port_string[tmp] = strcat(port_string[tmp], ftos(head.scale), " ");
 183                 port_string[tmp] = strcat(port_string[tmp], ftos(head.movetype), " ");
 184                 port_string[tmp] = strcat(port_string[tmp], ftos(head.damageforcescale), " ");
 185                 if(head.material)       port_string[tmp] = strcat(port_string[tmp], head.material, " ");        else    port_string[tmp] = strcat(port_string[tmp], "- "); // none
 186                 if(database)
 187                 {
 188                         if(head.crypto_idfp)    port_string[tmp] = strcat(port_string[tmp], head.crypto_idfp, " ");     else    port_string[tmp] = strcat(port_string[tmp], "- "); // none
 189                         port_string[tmp] = strcat(port_string[tmp], sprintf("\"%.9v\"", head.origin), " ");
 190                         port_string[tmp] = strcat(port_string[tmp], sprintf("\"%.9v\"", head.angles), " ");
 191                 }
 192         }
 193
 194         // now apply the array to a simple string, with ; separating objects
 195         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 196         {
 197                 if(port_string[i])
 198                         s = strcat(s, port_string[i], "; ");
 199                 port_string[i] = string_null; // fully clear string
 200         }
 201
 202         return s;
 203 }
 204
 205 entity sandbox_ObjectPort_Load(string s, float database)
 206 {
 207         // load object properties
 208         float n, i;
 209         entity e, parent;
 210
 211         n = tokenizebyseparator(s, "; ");
 212         for(i = 0; i < n; ++i)
 213                 port_string[i] = argv(i);
 214
 215         for(i = 0; i < n; ++i)
 216         {
 217                 tokenize_console(port_string[i]);
 218                 e = sandbox_ObjectSpawn(database);
 219
 220                 setmodel(e, argv(0));
 221                 e.skin = stof(argv(1));
 222                 e.alpha = stof(argv(2));
 223                 e.colormod = stov(argv(3));
 224                 e.glowmod = stov(argv(4));
 225                 e.frame = stof(argv(5));
 226                 sandbox_ObjectEdit_Scale(e, stof(argv(6)));
 227                 e.movetype = stof(argv(7));
 228                 e.damageforcescale = stof(argv(8));
 229                 if(e.material)  strunzone(e.material);  if(argv(9) != "-")      e.material = strzone(argv(9));  else    e.material = string_null;
 230                 if(database)
 231                 {
 232                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(10) != "-")     e.crypto_idfp = strzone(argv(10));      else    e.crypto_idfp = string_null;
 233                         setorigin(e, stov(argv(11)));
 234                         e.angles = stov(argv(12));
 235                 }
 236
 237                 if(!i) // parent object
 238                         parent = e;
 239                 else // child object, attach to parent
 240                         sandbox_ObjectAttach_Set(e, parent, "");
 241         }
 242
 243         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 244                 port_string[i] = string_null; // fully clear string
 245
 246         return e;
 247 }
 248
 249 void sandbox_Database_Save()
 250 {
 251         // saves all objects to the database file
 252         entity head;
 253         string file_name;
 254         float file_get;
 255
 256         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 257         file_get = fopen(file_name, FILE_WRITE);
 258         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 259         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 260
 261         for(head = world; (head = find(head, classname, "object")); )
 262         {
 263                 // Unfortunately, attached objects cannot be persisted yet. That's because the parent is specified as an entity,
 264                 // but only properties can be saved to this file, leaving no way to identify the owner once all objects are spawned
 265                 // TODO: Find some way to fix this!
 266                 if(head.owner != world)
 267                         continue;
 268
 269                 // use a line for each object, listing all properties
 270                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 271         }
 272         fclose(file_get);
 273 }
 274
 275 void sandbox_Database_Load()
 276 {
 277         // loads all objects from the database file
 278         string file_read, file_name;
 279         float file_get, i;
 280
 281         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 282         file_get = fopen(file_name, FILE_READ);
 283         if(file_get < 0)
 284         {
 285                 if(autocvar_g_sandbox_info > 0)
 286                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 287         }
 288         else
 289         {
 290                 for(;;)
 291                 {
 292                         file_read = fgets(file_get);
 293                         if(!file_read)
 294                                 break;
 295                         if(substring(file_read, 0, 2) == "//")
 296                                 continue;
 297                         if(substring(file_read, 0, 1) == "#")
 298                                 continue;
 299
 300                         entity e;
 301                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 302
 303                         if(e.material)
 304                         {
 305                                 // since objects are being loaded for the first time, precache material sounds for each
 306                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 307                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 308                         }
 309                 }
 310                 if(autocvar_g_sandbox_info > 0)
 311                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 312         }
 313 }
 314
 315 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 316 {
 317         if(MUTATOR_RETURNVALUE) // command was already handled?
 318                 return FALSE;
 319         if(cmd_name == "g_sandbox")
 320         {
 321                 if(cmd_argc < 2)
 322                 {
 323                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 324                         return TRUE;
 325                 }
 326
 327                 switch(argv(1))
 328                 {
 329                         entity e;
 330                         float i;
 331
 332                         // ---------------- COMMAND: HELP ----------------
 333                         case "help":
 334                                 print_to(self, "You can use the following sandbox commands:");
 335                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 336                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 337                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 338                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 339                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 340                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 341                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 342                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 343                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 344                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 345                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 346                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 347                                 print_to(self, "^3alpha value ^7- sets object transparency");
 348                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 349                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 350                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 351                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 352                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 353                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 354                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 355                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 356                                 return TRUE;
 357
 358                         // ---------------- COMMAND: SPAWN OBJECT ----------------
 359                         case "object_spawn":
 360                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 361                                 {
 362                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 363                                         return TRUE;
 364                                 }
 365                                 if(cmd_argc < 3)
 366                                 {
 367                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 368                                         return TRUE;
 369                                 }
 370                                 else if not(fexists(argv(2)))
 371                                 {
 372                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 373                                         return TRUE;
 374                                 }
 375
 376                                 e = sandbox_ObjectSpawn(FALSE);
 377                                 setmodel(e, argv(2));
 378
 379                                 if(autocvar_g_sandbox_info > 0)
 380                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 381                                 return TRUE;
 382
 383                         // ---------------- COMMAND: REMOVE OBJECT ----------------
 384                         case "object_remove":
 385                                 e = sandbox_ObjectEdit_Get();
 386                                 if(e != world)
 387                                 {
 388                                         if(autocvar_g_sandbox_info > 0)
 389                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 390                                         sandbox_ObjectRemove(e);
 391                                         return TRUE;
 392                                 }
 393
 394                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 395                                 return TRUE;
 396
 397                         // ---------------- COMMAND: DUPLICATE OBJECT ----------------
 398                         case "object_duplicate":
 399                                 switch(argv(2))
 400                                 {
 401                                         case "copy":
 402                                                 // copies customizable properties of the selected object to the clipboard
 403                                                 e = sandbox_ObjectEdit_Get(); // you can only copy objects you can edit, so this works
 404                                                 if(e != world)
 405                                                 {
 406                                                         if(self.object_clipboard)
 407                                                                 strunzone(self.object_clipboard);
 408                                                         self.object_clipboard = strzone(sandbox_ObjectPort_Save(e, FALSE));
 409
 410                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 411                                                         return TRUE;
 412                                                 }
 413                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have edit rights over");
 414                                                 return TRUE;
 415
 416                                         case "paste":
 417                                                 // spawns a new object using the properties in the player's clipboard
 418                                                 if(!self.object_clipboard) // no object in clipboard
 419                                                 {
 420                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 421                                                         return TRUE;
 422                                                 }
 423                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 424                                                 {
 425                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 426                                                         return TRUE;
 427                                                 }
 428
 429                                                 e = sandbox_ObjectPort_Load(self.object_clipboard, FALSE);
 430
 431                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 432                                                 if(autocvar_g_sandbox_info > 0)
 433                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 434                                                 return TRUE;
 435                                 }
 436                                 return TRUE;
 437
 438                         // ---------------- COMMAND: CLAIM OBJECT ----------------
 439                         case "object_claim":
 440                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 441                                 if(self.crypto_idfp == "")
 442                                 {
 443                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 444                                         return TRUE;
 445                                 }
 446                                 e = sandbox_ObjectEdit_Get();
 447                                 if(e != world)
 448                                 {
 449                                         if(e.crypto_idfp == self.crypto_idfp)
 450                                         {
 451                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 452                                                 return TRUE;
 453                                         }
 454
 455                                         if(e.crypto_idfp)
 456                                                 strunzone(e.crypto_idfp);
 457                                         e.crypto_idfp = self.crypto_idfp;
 458                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 459                                 }
 460                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 461                                 return TRUE;
 462
 463                         // ---------------- COMMAND: ATTACH OBJECT ----------------
 464                         case "object_attach":
 465                                 switch(argv(2))
 466                                 {
 467                                         case "get":
 468                                                 // select e as the object as meant to be attached
 469                                                 e = sandbox_ObjectEdit_Get();
 470                                                 if(e != world)
 471                                                 {
 472                                                         self.object_attach = e;
 473                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 474                                                         return TRUE;
 475                                                 }
 476                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 477                                                 return TRUE;
 478                                         case "set":
 479                                                 if(self.object_attach == world)
 480                                                 {
 481                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 482                                                         return TRUE;
 483                                                 }
 484
 485                                                 // attaches the previously selected object to e
 486                                                 e = sandbox_ObjectEdit_Get();
 487                                                 if(e != world)
 488                                                 {
 489                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 490                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 491                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 492                                                         if(autocvar_g_sandbox_info > 1)
 493                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 494                                                         return TRUE;
 495                                                 }
 496                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 497                                                 return TRUE;
 498                                         case "remove":
 499                                                 // removes e if it was attached
 500                                                 e = sandbox_ObjectEdit_Get();
 501                                                 if(e != world)
 502                                                 {
 503                                                         sandbox_ObjectAttach_Remove(e);
 504                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 505                                                         if(autocvar_g_sandbox_info > 1)
 506                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 507                                                         return TRUE;
 508                                                 }
 509                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 510                                                 return TRUE;
 511                                 }
 512                                 return TRUE;
 513
 514                         // ---------------- COMMAND: EDIT OBJECT ----------------
 515                         case "object_edit":
 516                                 if(!argv(2))
 517                                 {
 518                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 519                                         return TRUE;
 520                                 }
 521
 522                                 e = sandbox_ObjectEdit_Get();
 523                                 if(e != world)
 524                                 {
 525                                         switch(argv(2))
 526                                         {
 527                                                 case "skin":
 528                                                         e.skin = stof(argv(3));
 529                                                         break;
 530                                                 case "alpha":
 531                                                         e.alpha = stof(argv(3));
 532                                                         break;
 533                                                 case "color_main":
 534                                                         e.colormod = stov(argv(3));
 535                                                         break;
 536                                                 case "color_glow":
 537                                                         e.glowmod = stov(argv(3));
 538                                                         break;
 539                                                 case "frame":
 540                                                         e.frame = stof(argv(3));
 541                                                         break;
 542                                                 case "scale":
 543                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 544                                                         break;
 545                                                 case "physics":
 546                                                         switch(argv(3))
 547                                                         {
 548                                                                 case "0": // static
 549                                                                         e.movetype = MOVETYPE_NONE;
 550                                                                         break;
 551                                                                 case "1": // movable
 552                                                                         e.movetype = MOVETYPE_TOSS;
 553                                                                         break;
 554                                                                 case "2": // physical
 555                                                                         e.movetype = MOVETYPE_PHYSICS;
 556                                                                         break;
 557                                                                 default:
 558                                                                         break;
 559                                                         }
 560                                                         break;
 561                                                 case "force":
 562                                                         e.damageforcescale = stof(argv(3));
 563                                                         break;
 564                                                 case "material":
 565                                                         if(e.material)
 566                                                                 strunzone(e.material);
 567                                                         if(argv(3))
 568                                                         {
 569                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 570                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 571                                                                 e.material = strzone(argv(3));
 572                                                         }
 573                                                         else
 574                                                                 e.material = string_null; // no material
 575                                                         break;
 576                                                 default:
 577                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 578                                                         break;
 579                                         }
 580                                         if(autocvar_g_sandbox_info > 1)
 581                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 582                                         return TRUE;
 583                                 }
 584
 585                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 586                                 return TRUE;
 587
 588                         // ---------------- COMMAND: DEFAULT ----------------
 589                         default:
 590                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 591                                 return TRUE;
 592                 }
 593         }
 594         return FALSE;
 595 }
 596
 597 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 598 {
 599         // if the player is close enough to their object, they can drag it
 600
 601         if(autocvar_sv_cheats)
 602                 return FALSE; // cheat dragging is used instead
 603
 604         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 605         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 606         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 607         // it goes out of range while slinging it around.
 608
 609         entity e;
 610         float grab;
 611
 612         e = sandbox_ObjectEdit_Get();
 613         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 614                 grab = TRUE;
 615
 616         if(Drag(e, grab)) // execute dragging
 617                 return TRUE;
 618
 619         return FALSE;
 620 }
 621
 622 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 623 {
 624         // unzone the player's clipboard if it's not empty
 625         if(self.object_clipboard)
 626         {
 627                 strunzone(self.object_clipboard);
 628                 self.object_clipboard = string_null;
 629         }
 630
 631         return FALSE;
 632 }
 633
 634 float autosave_time;
 635 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 636 {
 637         if(!autocvar_g_sandbox_storage_autosave)
 638                 return FALSE;
 639         if(time < autosave_time)
 640                 return FALSE;
 641         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 642
 643         sandbox_Database_Save();
 644
 645         return TRUE;
 646 }
 647
 648 MUTATOR_DEFINITION(sandbox)
 649 {
 650         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 651         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 652         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 653         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 654
 655         MUTATOR_ONADD
 656         {
 657                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 658                 if(autocvar_g_sandbox_storage_autoload)
 659                         sandbox_Database_Load();
 660         }
 661
 662         return FALSE;
 663 }
 664