qcsrc/server/mutators/sandbox.qc

   1 .string object_clipboard;
   2 .entity object_attach;
   3 .float material;
   4
   5 const float MATERIAL_NONE = 0;
   6 const float MATERIAL_METAL = 1;
   7 const float MATERIAL_STONE = 2;
   8 const float MATERIAL_WOOD = 3;
   9 const float MATERIAL_FLESH = 4;
  10
  11 .float touch_timer;
  12 void sandbox_Object_Touch()
  13 {
  14         // apply material impact effects
  15
  16         if(self.touch_timer > time)
  17                 return; // don't execute each frame
  18         self.touch_timer = time + 0.1;
  19
  20         // make particle count and sound volume depend on impact speed
  21         float intensity;
  22         intensity = vlen(self.velocity) + vlen(other.velocity);
  23         if(intensity) // avoid divisions by 0
  24                 intensity /= 2; // average the two velocities
  25         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  26                 return; // impact not strong enough to do anything
  27         // now offset intensity and apply it to the effects
  28         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  29         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  30
  31         switch(self.material)
  32         {
  33                 case MATERIAL_METAL:
  34                         sound(self, CH_TRIGGER, strcat("object/impact_metal_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  35                         pointparticles(particleeffectnum("impact_metal"), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  36                         break;
  37                 case MATERIAL_STONE:
  38                         sound(self, CH_TRIGGER, strcat("object/impact_stone_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  39                         pointparticles(particleeffectnum("impact_stone"), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  40                         break;
  41                 case MATERIAL_WOOD:
  42                         sound(self, CH_TRIGGER, strcat("object/impact_wood_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  43                         pointparticles(particleeffectnum("impact_wood"), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  44                         break;
  45                 case MATERIAL_FLESH:
  46                         sound(self, CH_TRIGGER, strcat("object/impact_flesh_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  47                         pointparticles(particleeffectnum("impact_flesh"), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  48                         break;
  49                 default:
  50                         break;
  51         }
  52 }
  53
  54 entity sandbox_EditObject_Get()
  55 {
  56         // returns the traced entity if the player can edit it, and world if not
  57         // attached objects are SOLID_NOT and don't risk getting traced
  58
  59         makevectors(self.v_angle);
  60         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  61         if(trace_ent.classname == "object" && trace_ent.realowner == self)
  62                 return trace_ent;
  63         else
  64                 return world;
  65 }
  66
  67 void sandbox_EditObject_Scale(entity e, float f)
  68 {
  69         e.scale = f;
  70         if(e.scale)
  71         {
  72                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  73                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  74         }
  75 }
  76
  77 .float old_movetype;
  78 void sandbox_AttachObject_Set(entity e, entity parent, string s)
  79 {
  80         // attaches e to parent on string s
  81
  82         e.old_movetype = e.movetype; // persist this
  83
  84         e.movetype = MOVETYPE_FOLLOW;
  85         e.solid = SOLID_NOT;
  86         e.takedamage = DAMAGE_NO;
  87
  88         setattachment(e, parent, s);
  89         e.owner = parent;
  90 }
  91
  92 void sandbox_AttachObject_Remove(entity e)
  93 {
  94         // detaches any object attached to e
  95
  96         entity head;
  97         for(head = world; (head = find(head, classname, "object")); )
  98         {
  99                 if(head.owner == e)
 100                 {
 101                         head.movetype = e.old_movetype; // revert to previous physics
 102                         head.solid = SOLID_BBOX;
 103                         head.takedamage = DAMAGE_AIM;
 104
 105                         setattachment(head, world, "");
 106                         head.owner = world;
 107
 108                         // objects reset origin and angles when detached, so apply the parent's to prevent teleporting
 109                         setorigin(head, e.origin);
 110                         head.angles = e.angles;
 111                 }
 112         }
 113 }
 114
 115 entity sandbox_SpawnObject()
 116 {
 117         // spawn a new object with default properties
 118
 119         entity e;
 120         e = spawn();
 121         e.realowner = self;
 122         e.classname = "object";
 123         e.takedamage = DAMAGE_AIM;
 124         e.damageforcescale = 1;
 125         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 126         e.movetype = MOVETYPE_TOSS;
 127         e.frame = 0;
 128         e.skin = 0;
 129         e.material = MATERIAL_NONE;
 130
 131         e.touch = sandbox_Object_Touch;
 132
 133         // set origin and direction based on player position and view angle
 134         makevectors(self.v_angle);
 135         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 136         setorigin(e, trace_endpos);
 137         e.angles_y = self.v_angle_y;
 138
 139         return e;
 140 }
 141
 142 string sandbox_Storage_Save(entity e)
 143 {
 144         // save object properties
 145         string s;
 146
 147         s = strcat(e.model, " ");
 148         s = strcat(s, ftos(e.skin), " ");
 149         s = strcat(s, ftos(e.alpha), " ");
 150         s = strcat(s, sprintf("\"%.9v\"", e.colormod), " ");
 151         s = strcat(s, sprintf("\"%.9v\"", e.glowmod), " ");
 152         s = strcat(s, ftos(e.frame), " ");
 153         s = strcat(s, ftos(e.scale), " ");
 154         s = strcat(s, ftos(e.movetype), " ");
 155         s = strcat(s, ftos(e.damageforcescale), " ");
 156         s = strcat(s, ftos(e.material), " ");
 157
 158         return s;
 159 }
 160
 161 void sandbox_Storage_Load(entity e, string s)
 162 {
 163         // load object properties
 164         tokenize_console(s);
 165
 166         setmodel(e, argv(0));
 167         e.skin = stof(argv(1));
 168         e.alpha = stof(argv(2));
 169         e.colormod = stov(argv(3));
 170         e.glowmod = stov(argv(4));
 171         e.frame = stof(argv(5));
 172         sandbox_EditObject_Scale(e, stof(argv(6)));
 173         e.movetype = stof(argv(7));
 174         e.damageforcescale = stof(argv(8));
 175         e.material = stof(argv(9));
 176 }
 177
 178 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 179 {
 180         if(MUTATOR_RETURNVALUE) // command was already handled?
 181                 return FALSE;
 182         if(cmd_name == "g_sandbox")
 183         {
 184                 if(cmd_argc < 2)
 185                 {
 186                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 187                         return TRUE;
 188                 }
 189
 190                 switch(argv(1))
 191                 {
 192                         entity e;
 193
 194                         // ---------------- COMMAND: HELP ----------------
 195                         case "help":
 196                                 print_to(self, "You can use the following sandbox commands:");
 197                                 print_to(self, "^7\"^2spawn_item ^3item^7\" spawns the specified item in front of the player. Only weapons are currently supported");
 198                                 print_to(self, "^7\"^2spawn_object ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 199                                 print_to(self, "^7\"^2remove_object^7\" removes the object the player is looking at. Players can only remove their own objects");
 200                                 print_to(self, "^7\"^2duplicate_object_copy^7\" copies the object the player is looking at. Players can only copy their own objects");
 201                                 print_to(self, "^7\"^2duplicate_object_paste^7\" pastes the copied object in front of the player");
 202                                 print_to(self, "^7\"^2edit_object ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 203                                 print_to(self, "^7Object properties for ^2edit_object^7:");
 204                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 205                                 print_to(self, "^3alpha value ^7- sets object transparency");
 206                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 207                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 208                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 209                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 210                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 211                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 212                                 print_to(self, "^3material value ^7- sets the material of the object. Valid materials are: 1 (metal), 2 (stone), 3 (wood), 4 (flesh)");
 213                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 214                                 return TRUE;
 215
 216                         // ---------------- COMMAND: SPAWN ITEM ----------------
 217                         case "spawn_item":
 218                                 // only weapons are currently supported
 219
 220                                 if(cmd_argc < 3)
 221                                 {
 222                                         print_to(self, "WARNING: Attempted to spawn an item without specifying its type. Please specify the name of your item after the 'spawn_item' command");
 223                                         return TRUE;
 224                                 }
 225
 226                                 // spawn a new item
 227                                 float i;
 228                                 makevectors(self.v_angle);
 229                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NOMONSTERS, self);
 230
 231                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 232                                 {
 233                                         e = get_weaponinfo(i);
 234                                         if(e.netname == argv(2))
 235                                         {
 236                                                 W_ThrowNewWeapon(self, i, FALSE, trace_endpos, '0 0 0');
 237                                                 if(autocvar_g_sandbox_info)
 238                                                         print(strcat(self.netname, " spawned a ^2", e.netname, "^7 at origin ", vtos(e.origin), "\n"));
 239                                                 return TRUE;
 240                                         }
 241                                 }
 242
 243                                 print_to(self, "WARNING: Attempted to spawn an invalid or unsupported item. See 'sandbox help' for allowed items");
 244                                 return TRUE;
 245
 246                         // ---------------- COMMAND: SPAWN OBJECT ----------------
 247                         case "spawn_object":
 248                                 // don't allow spawning objects without a model
 249                                 if(cmd_argc < 3)
 250                                 {
 251                                         print_to(self, "WARNING: Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'spawn_object' command");
 252                                         return TRUE;
 253                                 }
 254                                 else if not(fexists(argv(2)))
 255                                 {
 256                                         print_to(self, "WARNING: Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 257                                         return TRUE;
 258                                 }
 259
 260                                 e = sandbox_SpawnObject();
 261                                 setmodel(e, argv(2));
 262
 263                                 if(autocvar_g_sandbox_info)
 264                                         print(strcat(self.netname, " spawned an object at origin ", vtos(e.origin), "\n"));
 265
 266                                 return TRUE;
 267
 268                         // ---------------- COMMAND: REMOVE OBJECT ----------------
 269                         case "remove_object":
 270                                 e = sandbox_EditObject_Get();
 271                                 if(e != world)
 272                                 {
 273                                         if(autocvar_g_sandbox_info)
 274                                                 print(strcat(self.netname, " removed an object at origin ", vtos(e.origin), "\n"));
 275                                         remove(e);
 276                                         e = world;
 277                                         return TRUE;
 278                                 }
 279
 280                                 print_to(self, "WARNING: Object could not be removed. Make sure you are facing an object that belongs to you");
 281                                 return TRUE;
 282
 283                         // ---------------- COMMAND: DUPLICATE OBJECT COPY ----------------
 284                         case "duplicate_object_copy":
 285                                 // copies customizable properties of the selected object to the clipboard
 286
 287                                 e = sandbox_EditObject_Get(); // you can only copy objects you can edit, so this works
 288                                 if(e != world)
 289                                 {
 290                                         if(self.object_clipboard)
 291                                                 strunzone(self.object_clipboard);
 292                                         self.object_clipboard = strzone(sandbox_Storage_Save(e));
 293
 294                                         print_to(self, "Object copied to clipboard");
 295                                         return TRUE;
 296                                 }
 297
 298                                 print_to(self, "WARNING: Object could not be copied. Make sure you are facing an object that belongs to you");
 299                                 return TRUE;
 300
 301                         // ---------------- COMMAND: DUPLICATE OBJECT PASTE ----------------
 302                         case "duplicate_object_paste":
 303                                 // spawns a new object using the properties in the player's clipboard
 304
 305                                 if(!self.object_clipboard) // no object in clipboard
 306                                 {
 307                                         print_to(self, "WARNING: No object in clipboard. You must copy an object before you can paste it");
 308                                         return TRUE;
 309                                 }
 310
 311                                 e = sandbox_SpawnObject();
 312                                 sandbox_Storage_Load(e, self.object_clipboard);
 313
 314                                 print_to(self, "Object pasted successfully");
 315                                 if(autocvar_g_sandbox_info)
 316                                         print(strcat(self.netname, " pasted an object at origin ", vtos(e.origin), "\n"));
 317
 318                                 return TRUE;
 319
 320                         // ---------------- COMMAND: ATTACH OBJECT ----------------
 321                         case "attach_object":
 322                                 switch(argv(2))
 323                                 {
 324                                         case "get":
 325                                                 // select e as the object as meant to be attached
 326                                                 e = sandbox_EditObject_Get();
 327                                                 if(e != world)
 328                                                 {
 329                                                         self.object_attach = e;
 330                                                         print_to(self, "Object selected for attachment");
 331                                                         return TRUE;
 332                                                 }
 333                                                 print_to(self, "WARNING: Object could not be selected for attachment. Make sure you are facing an object that belongs to you");
 334                                                 return TRUE;
 335                                         case "set":
 336                                                 if(self.object_attach == world)
 337                                                 {
 338                                                         print_to(self, "WARNING: No object selected for attachment. Please select an object to be attached first.");
 339                                                         return TRUE;
 340                                                 }
 341
 342                                                 // attaches the previously selected object to e
 343                                                 e = sandbox_EditObject_Get();
 344                                                 if(e != world)
 345                                                 {
 346                                                         sandbox_AttachObject_Set(self.object_attach, e, argv(3));
 347                                                         print_to(self, "Object attached successfully");
 348                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 349                                                         return TRUE;
 350                                                 }
 351                                                 print_to(self, "WARNING: Object could not be attached to the parent. Make sure you are facing an object that belongs to you");
 352                                                 return TRUE;
 353                                         case "remove":
 354                                                 // removes e if it was attached
 355                                                 e = sandbox_EditObject_Get();
 356                                                 if(e != world)
 357                                                 {
 358                                                         sandbox_AttachObject_Remove(e);
 359                                                         print_to(self, "Child objects detached successfully");
 360                                                         return TRUE;
 361                                                 }
 362                                                 print_to(self, "WARNING: Child objects could not be detached. Make sure you are facing an object that belongs to you");
 363                                                 return TRUE;
 364                                 }
 365                                 return TRUE;
 366
 367                         // ---------------- COMMAND: EDIT OBJECT ----------------
 368                         case "edit_object":
 369                                 if(!argv(2) || !argv(3))
 370                                 {
 371                                         print_to(self, "WARNING: Too few parameters. You must specify a property to edit, followed by its value");
 372                                         return TRUE;
 373                                 }
 374
 375                                 e = sandbox_EditObject_Get();
 376                                 if(e != world)
 377                                 {
 378                                         switch(argv(2))
 379                                         {
 380                                                 case "skin":
 381                                                         e.skin = stof(argv(3));
 382                                                         break;
 383                                                 case "alpha":
 384                                                         e.alpha = stof(argv(3));
 385                                                         break;
 386                                                 case "color_main":
 387                                                         e.colormod = stov(argv(3));
 388                                                         break;
 389                                                 case "color_glow":
 390                                                         e.glowmod = stov(argv(3));
 391                                                         break;
 392                                                 case "frame":
 393                                                         e.frame = stof(argv(3));
 394                                                         break;
 395                                                 case "scale":
 396                                                         sandbox_EditObject_Scale(e, stof(argv(3)));
 397                                                         break;
 398                                                 case "physics":
 399                                                         switch(argv(3))
 400                                                         {
 401                                                                 case "0": // static
 402                                                                         e.movetype = MOVETYPE_NONE;
 403                                                                         break;
 404                                                                 case "1": // movable
 405                                                                         e.movetype = MOVETYPE_TOSS;
 406                                                                         break;
 407                                                                 case "2": // physical
 408                                                                         e.movetype = MOVETYPE_PHYSICS;
 409                                                                         break;
 410                                                                 default:
 411                                                                         break;
 412                                                         }
 413                                                         break;
 414                                                 case "force":
 415                                                         e.damageforcescale = stof(argv(3));
 416                                                         break;
 417                                                 case "material":
 418                                                         e.material = stof(argv(3));
 419                                                         break;
 420                                                 default:
 421                                                         print_to(self, "WARNING: Invalid object property. For usage information, type 'sandbox help'");
 422                                                         break;
 423                                         }
 424                                         return TRUE;
 425                                 }
 426
 427                                 print_to(self, "WARNING: Object could not be edited. Make sure you are facing an object that belongs to you");
 428                                 return TRUE;
 429
 430                         // ---------------- COMMAND: DEFAULT ----------------
 431                         default:
 432                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 433                                 return TRUE;
 434                 }
 435         }
 436         return FALSE;
 437 }
 438
 439 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 440 {
 441         // if the player is close enough to their object, they can drag it
 442
 443         if(autocvar_sv_cheats)
 444                 return FALSE; // cheat dragging is used instead
 445
 446         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 447         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 448         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 449         // it goes out of range while slinging it around.
 450
 451         entity e;
 452         float grab;
 453
 454         e = sandbox_EditObject_Get();
 455         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 456                 grab = TRUE;
 457
 458         if(Drag(e, grab)) // execute dragging
 459         {
 460                 if(autocvar_g_sandbox_info)
 461                         print(strcat(self.netname, " grabbed an object at origin ", vtos(e.origin), "\n"));
 462                 return TRUE;
 463         }
 464
 465         return FALSE;
 466 }
 467
 468 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 469 {
 470         // unzone the player's clipboard if it's not empty
 471         if(self.object_clipboard)
 472         {
 473                 strunzone(self.object_clipboard);
 474                 self.object_clipboard = string_null;
 475         }
 476
 477         return FALSE;
 478 }
 479
 480 MUTATOR_DEFINITION(sandbox)
 481 {
 482         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 483         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 484         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 485
 486         MUTATOR_ONADD
 487         {
 488                 float i;
 489                 for (i = 1; i <= 5; i++)
 490                 {
 491                         // precache material sounds
 492                         precache_sound(strcat("objects/impact_metal_", ftos(i), ".ogg"));
 493                         precache_sound(strcat("objects/impact_stone_", ftos(i), ".ogg"));
 494                         precache_sound(strcat("objects/impact_wood_", ftos(i), ".ogg"));
 495                         precache_sound(strcat("objects/impact_flesh_", ftos(i), ".ogg"));
 496                 }
 497         }
 498
 499         return FALSE;
 500 }
 501