qcsrc/server/player.qc

   1 #include "player.qh"
   2
   3 #include "bot/api.qh"
   4 #include "cheats.qh"
   5 #include "g_damage.qh"
   6 #include "g_subs.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "weapons/throwing.qh"
  11 #include "command/common.qh"
  12 #include "../common/state.qh"
  13 #include "../common/anim.qh"
  14 #include "../common/animdecide.qh"
  15 #include "../common/csqcmodel_settings.qh"
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/triggers/subs.qh"
  18 #include "../common/playerstats.qh"
  19 #include "../lib/csqcmodel/sv_model.qh"
  20
  21 #include "../common/minigames/sv_minigames.qh"
  22
  23 #include "../common/physics/player.qh"
  24 #include "../common/effects/qc/all.qh"
  25 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  26 #include "../common/triggers/include.qh"
  27 #include "../common/wepent.qh"
  28
  29 #include "weapons/weaponstats.qh"
  30
  31 #include "../common/animdecide.qh"
  32
  33 void Drop_Special_Items(entity player)
  34 {
  35         // called when the player has become stuck or frozen
  36         // so objective items aren't stuck with the player
  37
  38         MUTATOR_CALLHOOK(DropSpecialItems, player);
  39 }
  40
  41 void CopyBody_Think(entity this)
  42 {
  43         if(this.CopyBody_nextthink && time > this.CopyBody_nextthink)
  44         {
  45                 this.CopyBody_think(this);
  46                 if(wasfreed(this))
  47                         return;
  48                 this.CopyBody_nextthink = this.nextthink;
  49                 this.CopyBody_think = getthink(this);
  50                 setthink(this, CopyBody_Think);
  51         }
  52         CSQCMODEL_AUTOUPDATE(this);
  53         this.nextthink = time;
  54 }
  55 void CopyBody(entity this, float keepvelocity)
  56 {
  57         if (this.effects & EF_NODRAW)
  58                 return;
  59         entity clone = new(body);
  60         clone.enemy = this;
  61         clone.lip = this.lip;
  62         clone.colormap = this.colormap;
  63         clone.iscreature = this.iscreature;
  64         clone.teleportable = this.teleportable;
  65         clone.damagedbycontents = this.damagedbycontents;
  66         if(clone.damagedbycontents)
  67                 IL_PUSH(g_damagedbycontents, clone);
  68         clone.angles = this.angles;
  69         clone.v_angle = this.v_angle;
  70         clone.avelocity = this.avelocity;
  71         clone.damageforcescale = this.damageforcescale;
  72         clone.effects = this.effects;
  73         clone.glowmod = this.glowmod;
  74         clone.event_damage = this.event_damage;
  75         clone.anim_state = this.anim_state;
  76         clone.anim_time = this.anim_time;
  77         clone.anim_lower_action = this.anim_lower_action;
  78         clone.anim_lower_time = this.anim_lower_time;
  79         clone.anim_upper_action = this.anim_upper_action;
  80         clone.anim_upper_time = this.anim_upper_time;
  81         clone.anim_implicit_state = this.anim_implicit_state;
  82         clone.anim_implicit_time = this.anim_implicit_time;
  83         clone.anim_lower_implicit_action = this.anim_lower_implicit_action;
  84         clone.anim_lower_implicit_time = this.anim_lower_implicit_time;
  85         clone.anim_upper_implicit_action = this.anim_upper_implicit_action;
  86         clone.anim_upper_implicit_time = this.anim_upper_implicit_time;
  87         clone.dphitcontentsmask = this.dphitcontentsmask;
  88         clone.death_time = this.death_time;
  89         clone.pain_finished = this.pain_finished;
  90         clone.health = this.health;
  91         clone.armorvalue = this.armorvalue;
  92         clone.armortype = this.armortype;
  93         clone.model = this.model;
  94         clone.modelindex = this.modelindex;
  95         clone.skin = this.skin;
  96         clone.species = this.species;
  97         clone.move_qcphysics = false; // don't run gamecode logic on clones, too many
  98         set_movetype(clone, this.move_movetype);
  99         clone.solid = this.solid;
 100         clone.ballistics_density = this.ballistics_density;
 101         clone.takedamage = this.takedamage;
 102         setcefc(clone, getcefc(this));
 103         clone.uncustomizeentityforclient = this.uncustomizeentityforclient;
 104         clone.uncustomizeentityforclient_set = this.uncustomizeentityforclient_set;
 105         if (keepvelocity == 1)
 106                 clone.velocity = this.velocity;
 107         clone.oldvelocity = clone.velocity;
 108         clone.alpha = this.alpha;
 109         clone.fade_time = this.fade_time;
 110         clone.fade_rate = this.fade_rate;
 111         //clone.weapon = this.weapon;
 112         setorigin(clone, this.origin);
 113         setsize(clone, this.mins, this.maxs);
 114         clone.prevorigin = this.origin;
 115         clone.reset = SUB_Remove;
 116         clone._ps = this._ps;
 117
 118         Drag_MoveDrag(this, clone);
 119
 120         if(clone.colormap <= maxclients && clone.colormap > 0)
 121                 clone.colormap = 1024 + this.clientcolors;
 122
 123         CSQCMODEL_AUTOINIT(clone);
 124         clone.CopyBody_nextthink = this.nextthink;
 125         clone.CopyBody_think = getthink(this);
 126         clone.nextthink = time;
 127         setthink(clone, CopyBody_Think);
 128         // "bake" the current animation frame for clones (they don't get clientside animation)
 129         animdecide_load_if_needed(clone);
 130         animdecide_setframes(clone, false, frame, frame1time, frame2, frame2time);
 131
 132         IL_PUSH(g_clones, clone);
 133
 134         MUTATOR_CALLHOOK(CopyBody, this, clone, keepvelocity);
 135 }
 136
 137 void player_setupanimsformodel(entity this)
 138 {
 139         // load animation info
 140         animdecide_load_if_needed(this);
 141         animdecide_setstate(this, 0, false);
 142 }
 143
 144 void player_anim(entity this)
 145 {
 146         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 147         if(IS_DEAD(this)) {
 148                 if (!deadbits) {
 149                         // Decide on which death animation to use.
 150                         if(random() < 0.5)
 151                                 deadbits = ANIMSTATE_DEAD1;
 152                         else
 153                                 deadbits = ANIMSTATE_DEAD2;
 154                 }
 155         } else {
 156                 // Clear a previous death animation.
 157                 deadbits = 0;
 158         }
 159         int animbits = deadbits;
 160         if(STAT(FROZEN, this))
 161                 animbits |= ANIMSTATE_FROZEN;
 162         if(this.move_movetype == MOVETYPE_FOLLOW)
 163                 animbits |= ANIMSTATE_FOLLOW;
 164         if(this.crouch)
 165                 animbits |= ANIMSTATE_DUCK;
 166         animdecide_setstate(this, animbits, false);
 167         animdecide_setimplicitstate(this, IS_ONGROUND(this));
 168 }
 169
 170 void PlayerCorpseDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 171 {
 172         float take, save;
 173         vector v;
 174         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 175
 176         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 177         take = v.x;
 178         save = v.y;
 179
 180         if(sound_allowed(MSG_BROADCAST, attacker))
 181         {
 182                 if (save > 10)
 183                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 184                 else if (take > 30)
 185                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 186                 else if (take > 10)
 187                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);
 188         }
 189
 190         if (take > 50)
 191                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 192         if (take > 100)
 193                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 194
 195         this.armorvalue = this.armorvalue - save;
 196         this.health = this.health - take;
 197         // pause regeneration for 5 seconds
 198         this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 199
 200         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 201         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 202         this.dmg_inflictor = inflictor;
 203
 204         if (this.health <= -autocvar_sv_gibhealth && this.alpha >= 0)
 205         {
 206                 // don't use any animations as a gib
 207                 this.frame = 0;
 208                 // view just above the floor
 209                 this.view_ofs = '0 0 4';
 210
 211                 Violence_GibSplash(this, 1, 1, attacker);
 212                 this.alpha = -1;
 213                 this.solid = SOLID_NOT; // restore later
 214                 this.takedamage = DAMAGE_NO; // restore later
 215                 if(this.damagedbycontents)
 216                         IL_REMOVE(g_damagedbycontents, this);
 217                 this.damagedbycontents = false;
 218         }
 219 }
 220
 221 void calculate_player_respawn_time(entity this)
 222 {
 223         if(g_ca)
 224                 return;
 225
 226         float gametype_setting_tmp;
 227         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 228         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 229         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 230         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 231         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 232         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 233
 234         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 235         if (teamplay)
 236         {
 237                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 238                         if(it.team == this.team)
 239                                 ++pcount;
 240                 ));
 241                 if (sdelay_small_count == 0)
 242                         sdelay_small_count = 1;
 243                 if (sdelay_large_count == 0)
 244                         sdelay_large_count = 1;
 245         }
 246         else
 247         {
 248                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 249                         ++pcount;
 250                 ));
 251                 if (sdelay_small_count == 0)
 252                 {
 253                         if (IS_INDEPENDENT_PLAYER(this))
 254                         {
 255                                 // Players play independently. No point in requiring enemies.
 256                                 sdelay_small_count = 1;
 257                         }
 258                         else
 259                         {
 260                                 // Players play AGAINST each other. Enemies required.
 261                                 sdelay_small_count = 2;
 262                         }
 263                 }
 264                 if (sdelay_large_count == 0)
 265                 {
 266                         if (IS_INDEPENDENT_PLAYER(this))
 267                         {
 268                                 // Players play independently. No point in requiring enemies.
 269                                 sdelay_large_count = 1;
 270                         }
 271                         else
 272                         {
 273                                 // Players play AGAINST each other. Enemies required.
 274                                 sdelay_large_count = 2;
 275                         }
 276                 }
 277         }
 278
 279         float sdelay;
 280
 281         if (pcount <= sdelay_small_count)
 282                 sdelay = sdelay_small;
 283         else if (pcount >= sdelay_large_count)
 284                 sdelay = sdelay_large;
 285         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 286                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 287
 288         if(waves)
 289                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
 290         else
 291                 this.respawn_time = time + sdelay;
 292
 293         if(sdelay < sdelay_max)
 294                 this.respawn_time_max = time + sdelay_max;
 295         else
 296                 this.respawn_time_max = this.respawn_time;
 297
 298         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
 299                 this.respawn_countdown = 10; // first number to count down from is 10
 300         else
 301                 this.respawn_countdown = -1; // do not count down
 302
 303         if(autocvar_g_forced_respawn)
 304                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
 305 }
 306
 307 void PlayerDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 308 {
 309         float take, save, dh, da;
 310         vector v;
 311         float excess;
 312
 313         dh = max(this.health, 0);
 314         da = max(this.armorvalue, 0);
 315
 316         if(!DEATH_ISSPECIAL(deathtype))
 317         {
 318                 damage *= bound(1.0, this.cvar_cl_handicap, 10.0);
 319                 if(this != attacker)
 320                         damage /= bound(1.0, attacker.cvar_cl_handicap, 10.0);
 321         }
 322
 323         if (time < this.spawnshieldtime && autocvar_g_spawnshield_blockdamage < 1)
 324                 damage *= 1 - max(0, autocvar_g_spawnshield_blockdamage);
 325
 326         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 327         {
 328                 // tuba causes blood to come out of the ears
 329                 vector ear1, ear2;
 330                 vector d;
 331                 float f;
 332                 ear1 = this.origin;
 333                 ear1_z += 0.125 * this.view_ofs.z + 0.875 * this.maxs.z; // 7/8
 334                 ear2 = ear1;
 335                 makevectors(this.angles);
 336                 ear1 += v_right * -10;
 337                 ear2 += v_right * +10;
 338                 d = inflictor.origin - this.origin;
 339                 if (d)
 340                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 341                 else
 342                         f = 0;  // Assum ecenter.
 343                 force = v_right * vlen(force);
 344                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), this, attacker);
 345                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), this, attacker);
 346                 if(f > 0)
 347                 {
 348                         hitloc = ear1;
 349                         force = force * -1;
 350                 }
 351                 else
 352                 {
 353                         hitloc = ear2;
 354                         // force is already good
 355                 }
 356         }
 357         else
 358                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 359
 360         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 361         take = v.x;
 362         save = v.y;
 363
 364         if(attacker == this)
 365         {
 366                 // don't reset pushltime for this damage as it may be an attempt to
 367                 // escape a lava pit or similar
 368                 //this.pushltime = 0;
 369                 this.istypefrag = 0;
 370         }
 371         else if(IS_PLAYER(attacker))
 372         {
 373                 this.pusher = attacker;
 374                 this.pushltime = time + autocvar_g_maxpushtime;
 375                 this.istypefrag = PHYS_INPUT_BUTTON_CHAT(this);
 376         }
 377         else if(time < this.pushltime)
 378         {
 379                 attacker = this.pusher;
 380                 this.pushltime = max(this.pushltime, time + 0.6);
 381         }
 382         else
 383         {
 384                 this.pushltime = 0;
 385                 this.istypefrag = 0;
 386         }
 387
 388         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor, inflictor, attacker, this, force, take, save, deathtype, damage);
 389         take = bound(0, M_ARGV(4, float), this.health);
 390         save = bound(0, M_ARGV(5, float), this.armorvalue);
 391         excess = max(0, damage - take - save);
 392
 393         if(sound_allowed(MSG_BROADCAST, attacker))
 394         {
 395                 if (save > 10)
 396                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 397                 else if (take > 30)
 398                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 399                 else if (take > 10)
 400                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 401         }
 402
 403         if (take > 50)
 404                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 405         if (take > 100)
 406                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 407
 408         if (time >= this.spawnshieldtime || autocvar_g_spawnshield_blockdamage < 1)
 409         {
 410                 if (!(this.flags & FL_GODMODE))
 411                 {
 412                         this.armorvalue = this.armorvalue - save;
 413                         this.health = this.health - take;
 414                         // pause regeneration for 5 seconds
 415                         if(take)
 416                                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 417
 418                         if (time > this.pain_finished)          //Don't switch pain sequences like crazy
 419                         {
 420                                 this.pain_finished = time + 0.5;        //Supajoe
 421
 422                                 if(autocvar_sv_gentle < 1) {
 423                                         if(this.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 424                                         {
 425                                                 if (!this.animstate_override)
 426                                                 {
 427                                                         if (random() > 0.5)
 428                                                                 animdecide_setaction(this, ANIMACTION_PAIN1, true);
 429                                                         else
 430                                                                 animdecide_setaction(this, ANIMACTION_PAIN2, true);
 431                                                 }
 432                                         }
 433
 434                                         if(sound_allowed(MSG_BROADCAST, attacker))
 435                                         if(this.health < 25 || !(DEATH_WEAPONOF(deathtype).spawnflags & WEP_FLAG_CANCLIMB) || take > 20 || attacker != this)
 436                                         if(this.health > 1)
 437                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 438                                         {
 439                                                 if(deathtype == DEATH_FALL.m_id)
 440                                                         PlayerSound(this, playersound_fall, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 441                                                 else if(this.health > 75)
 442                                                         PlayerSound(this, playersound_pain100, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 443                                                 else if(this.health > 50)
 444                                                         PlayerSound(this, playersound_pain75, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 445                                                 else if(this.health > 25)
 446                                                         PlayerSound(this, playersound_pain50, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 447                                                 else
 448                                                         PlayerSound(this, playersound_pain25, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 449                                         }
 450                                 }
 451                         }
 452
 453                         // throw off bot aim temporarily
 454                         float shake;
 455                         if(IS_BOT_CLIENT(this) && this.health >= 1)
 456                         {
 457                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 458                                 this.v_angle_x = this.v_angle.x + (random() * 2 - 1) * shake;
 459                                 this.v_angle_y = this.v_angle.y + (random() * 2 - 1) * shake;
 460                                 this.v_angle_x = bound(-90, this.v_angle.x, 90);
 461                         }
 462                 }
 463                 else
 464                         this.max_armorvalue += (save + take);
 465         }
 466         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 467         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 468         this.dmg_inflictor = inflictor;
 469
 470         if (this != attacker) {
 471                 float realdmg = damage - excess;
 472                 if (IS_PLAYER(attacker)) {
 473                         PlayerScore_Add(attacker, SP_DMG, realdmg);
 474                 }
 475                 if (IS_PLAYER(this)) {
 476                         PlayerScore_Add(this, SP_DMGTAKEN, realdmg);
 477                 }
 478         }
 479
 480         bool abot = (IS_BOT_CLIENT(attacker));
 481         bool vbot = (IS_BOT_CLIENT(this));
 482
 483         bool valid_damage_for_weaponstats = false;
 484         Weapon awep = WEP_Null;
 485         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 486
 487         if(vbot || IS_REAL_CLIENT(this))
 488         if(abot || IS_REAL_CLIENT(attacker))
 489         if(attacker && this != attacker)
 490         if(DIFF_TEAM(this, attacker))
 491         {
 492                 if(DEATH_ISSPECIAL(deathtype))
 493                         awep = attacker.(weaponentity).m_weapon;
 494                 else
 495                         awep = DEATH_WEAPONOF(deathtype);
 496                 valid_damage_for_weaponstats = true;
 497         }
 498
 499         dh = dh - max(this.health, 0);
 500         da = da - max(this.armorvalue, 0);
 501         if(valid_damage_for_weaponstats)
 502         {
 503                 WeaponStats_LogDamage(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot, dh + da);
 504         }
 505
 506         MUTATOR_CALLHOOK(PlayerDamaged, attacker, this, dh, da, hitloc, deathtype, damage);
 507
 508         if (this.health < 1)
 509         {
 510                 float defer_ClientKill_Now_TeamChange;
 511                 defer_ClientKill_Now_TeamChange = false;
 512
 513                 if(this.alivetime)
 514                 {
 515                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 516                         this.alivetime = 0;
 517                 }
 518
 519                 if(valid_damage_for_weaponstats)
 520                         WeaponStats_LogKill(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot);
 521
 522                 if(autocvar_sv_gentle < 1)
 523                 if(sound_allowed(MSG_BROADCAST, attacker))
 524                 {
 525                         if(deathtype == DEATH_DROWN.m_id)
 526                                 PlayerSound(this, playersound_drown, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 527                         else
 528                                 PlayerSound(this, playersound_death, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 529                 }
 530
 531                 // get rid of kill indicator
 532                 if(this.killindicator)
 533                 {
 534                         delete(this.killindicator);
 535                         this.killindicator = NULL;
 536                         if(this.killindicator_teamchange)
 537                                 defer_ClientKill_Now_TeamChange = true;
 538
 539                         if(this.classname == "body")
 540                         if(deathtype == DEATH_KILL.m_id)
 541                         {
 542                                 // for the lemmings fans, a small harmless explosion
 543                                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 544                         }
 545                 }
 546
 547                 // print an obituary message
 548                 if(this.classname != "body")
 549                         Obituary (attacker, inflictor, this, deathtype);
 550
 551         // increment frag counter for used weapon type
 552         Weapon w = DEATH_WEAPONOF(deathtype);
 553                 if(w != WEP_Null && accuracy_isgooddamage(attacker, this))
 554                         attacker.accuracy.(accuracy_frags[w.m_id-1]) += 1;
 555
 556                 MUTATOR_CALLHOOK(PlayerDies, inflictor, attacker, this, deathtype, damage);
 557                 damage = M_ARGV(4, float);
 558                 excess = max(0, damage - take - save);
 559
 560                 //Weapon wep = this.(weaponentity).m_weapon;
 561                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 562                 {
 563                         .entity went = weaponentities[slot];
 564                         if(!this.(weaponentity))
 565                                 continue; // TODO: clones have no weapon, but we don't want to have to check this all the time
 566                         Weapon wep = this.(weaponentity).m_weapon;
 567                         wep.wr_playerdeath(wep, this, went);
 568                 }
 569
 570                 RemoveGrapplingHooks(this);
 571
 572                 Portal_ClearAllLater(this);
 573
 574                 this.fixangle = true;
 575
 576                 if(defer_ClientKill_Now_TeamChange)
 577                         ClientKill_Now_TeamChange(this); // can turn player into spectator
 578
 579                 // player could have been miraculously resuscitated ;)
 580                 // e.g. players in freezetag get frozen, they don't really die
 581                 if(this.health >= 1 || !(IS_PLAYER(this) || this.classname == "body"))
 582                         return;
 583
 584                 // when we get here, player actually dies
 585
 586                 Unfreeze(this); // remove any icy remains
 587                 this.health = 0; // Unfreeze resets health, so we need to set it back
 588
 589                 // clear waypoints
 590                 WaypointSprite_PlayerDead(this);
 591                 // throw a weapon
 592                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 593                 {
 594                         .entity went = weaponentities[slot];
 595                         SpawnThrownWeapon(this, this.origin + (this.mins + this.maxs) * 0.5, this.(went).m_weapon, went);
 596                 }
 597
 598                 // become fully visible
 599                 this.alpha = default_player_alpha;
 600                 // make the corpse upright (not tilted)
 601                 this.angles_x = 0;
 602                 this.angles_z = 0;
 603                 // don't spin
 604                 this.avelocity = '0 0 0';
 605                 // view from the floor
 606                 this.view_ofs = '0 0 -8';
 607                 // toss the corpse
 608                 set_movetype(this, MOVETYPE_TOSS);
 609                 // shootable corpse
 610                 this.solid = SOLID_CORPSE;
 611                 this.ballistics_density = autocvar_g_ballistics_density_corpse;
 612                 // don't stick to the floor
 613                 UNSET_ONGROUND(this);
 614                 // dying animation
 615                 this.deadflag = DEAD_DYING;
 616
 617                 // when to allow respawn
 618                 calculate_player_respawn_time(this);
 619
 620                 this.death_time = time;
 621                 if (random() < 0.5)
 622                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD1, true);
 623                 else
 624                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD2, true);
 625
 626                 /* // postpone resize until frame end so that dead player can still
 627                 // properly get hit by all the projectiles fired in this frame (shotgun)
 628                 if (this.maxs.z > 5)
 629                 {
 630                         this.maxs_z = 5;
 631                         setsize(this, this.mins, this.maxs);
 632                 }
 633                 */
 634
 635                 // set damage function to corpse damage
 636                 this.event_damage = PlayerCorpseDamage;
 637                 // call the corpse damage function just in case it wants to gib
 638                 this.event_damage(this, inflictor, attacker, excess, deathtype, hitloc, force);
 639
 640                 // set up to fade out later
 641                 SUB_SetFade (this, time + 6 + random (), 1);
 642                 // reset body think wrapper broken by SUB_SetFade
 643                 if(this.classname == "body" && getthink(this) != CopyBody_Think) {
 644                         this.CopyBody_think = getthink(this);
 645                         this.CopyBody_nextthink = this.nextthink;
 646                         setthink(this, CopyBody_Think);
 647                         this.nextthink = time;
 648                 }
 649
 650                 if(autocvar_sv_gentle > 0 || autocvar_ekg || this.classname == "body") {
 651                         // remove corpse
 652                         // clones don't run any animation code any more, so we must gib them when they die :(
 653                         this.event_damage(this, inflictor, attacker, autocvar_sv_gibhealth + 1, deathtype, hitloc, force);
 654                 }
 655
 656                 // reset fields the weapons may use just in case
 657                 if(this.classname != "body")
 658                 {
 659                         FOREACH(Weapons, it != WEP_Null,
 660                         {
 661                                 it.wr_resetplayer(it, this);
 662                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 663                                 {
 664                                         ATTACK_FINISHED_FOR(this, it.m_id, slot) = 0;
 665                                 }
 666                         });
 667                 }
 668                 MUTATOR_CALLHOOK(PlayerDied, this);
 669         }
 670 }
 671
 672 void MoveToTeam(entity client, int team_colour, int type)
 673 {
 674         int lockteams_backup = lockteams;  // backup any team lock
 675         lockteams = 0;  // disable locked teams
 676         TeamchangeFrags(client);  // move the players frags
 677         SetPlayerColors(client, team_colour - 1);  // set the players colour
 678         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE.m_id, client.origin, '0 0 0');  // kill the player
 679         lockteams = lockteams_backup;  // restore the team lock
 680         LogTeamchange(client.playerid, client.team, type);
 681 }
 682
 683 /** print(), but only print if the server is not local */
 684 void dedicated_print(string input)
 685 {
 686         if (server_is_dedicated) print(input);
 687 }
 688
 689 void PrintToChat(entity player, string text)
 690 {
 691         text = strcat("\{1}^7", text, "\n");
 692         sprint(player, text);
 693 }
 694
 695 void DebugPrintToChat(entity player, string text)
 696 {
 697         if (autocvar_developer)
 698         {
 699                 PrintToChat(player, text);
 700         }
 701 }
 702
 703 void PrintToChatAll(string text)
 704 {
 705         text = strcat("\{1}^7", text, "\n");
 706         bprint(text);
 707 }
 708
 709 void DebugPrintToChatAll(string text)
 710 {
 711         if (autocvar_developer)
 712         {
 713                 PrintToChatAll(text);
 714         }
 715 }
 716
 717 void PrintToChatTeam(int teamnum, string text)
 718 {
 719         text = strcat("\{1}^7", text, "\n");
 720         FOREACH_CLIENT(IS_REAL_CLIENT(it),
 721         {
 722                 if (it.team == teamnum)
 723                 {
 724                         sprint(it, text);
 725                 }
 726         });
 727 }
 728
 729 void DebugPrintToChatTeam(int teamnum, string text)
 730 {
 731         if (autocvar_developer)
 732         {
 733                 PrintToChatTeam(teamnum, text);
 734         }
 735 }
 736
 737 /**
 738  * message "": do not say, just test flood control
 739  * return value:
 740  *   1 = accept
 741  *   0 = reject
 742  *  -1 = fake accept
 743  */
 744 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
 745 {
 746         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
 747         msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
 748
 749         msgin = formatmessage(source, msgin);
 750
 751     string colorstr;
 752         if (!IS_PLAYER(source))
 753                 colorstr = "^0"; // black for spectators
 754         else if(teamplay)
 755                 colorstr = Team_ColorCode(source.team);
 756         else
 757         {
 758                 colorstr = "";
 759                 teamsay = false;
 760         }
 761
 762         if(game_stopped)
 763                 teamsay = false;
 764
 765     if (!source) {
 766                 colorstr = "";
 767                 teamsay = false;
 768     }
 769
 770         if(msgin != "")
 771                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 772
 773         /*
 774          * using bprint solves this... me stupid
 775         // how can we prevent the message from appearing in a listen server?
 776         // for now, just give "say" back and only handle say_team
 777         if(!teamsay)
 778         {
 779                 clientcommand(source, strcat("say ", msgin));
 780                 return;
 781         }
 782         */
 783
 784     string namestr = "";
 785     if (source)
 786         namestr = playername(source, autocvar_g_chat_teamcolors);
 787
 788     string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
 789
 790     string msgstr, cmsgstr;
 791     string privatemsgprefix = string_null;
 792     int privatemsgprefixlen = 0;
 793         if (msgin == "") {
 794         msgstr = cmsgstr = "";
 795         } else {
 796                 if(privatesay)
 797                 {
 798                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 799                         privatemsgprefixlen = strlen(msgstr);
 800                         msgstr = strcat(msgstr, msgin);
 801                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 802                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
 803                 }
 804                 else if(teamsay)
 805                 {
 806                         if(strstrofs(msgin, "/me", 0) >= 0)
 807                         {
 808                                 //msgin = strreplace("/me", "", msgin);
 809                                 //msgin = substring(msgin, 3, strlen(msgin));
 810                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
 811                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
 812                         }
 813                         else
 814                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 815                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 816                 }
 817                 else
 818                 {
 819                         if(strstrofs(msgin, "/me", 0) >= 0)
 820                         {
 821                                 //msgin = strreplace("/me", "", msgin);
 822                                 //msgin = substring(msgin, 3, strlen(msgin));
 823                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
 824                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
 825                         }
 826                         else {
 827                 msgstr = "\{1}";
 828                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
 829                 msgstr = strcat(msgstr, msgin);
 830             }
 831                         cmsgstr = "";
 832                 }
 833                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 834         }
 835
 836         string fullmsgstr = msgstr;
 837         string fullcmsgstr = cmsgstr;
 838
 839         // FLOOD CONTROL
 840         int flood = 0;
 841         var .float flood_field = floodcontrol_chat;
 842         if(floodcontrol)
 843         {
 844                 float flood_spl;
 845                 float flood_burst;
 846                 float flood_lmax;
 847                 float lines;
 848                 if(privatesay)
 849                 {
 850                         flood_spl = autocvar_g_chat_flood_spl_tell;
 851                         flood_burst = autocvar_g_chat_flood_burst_tell;
 852                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 853                         flood_field = floodcontrol_chattell;
 854                 }
 855                 else if(teamsay)
 856                 {
 857                         flood_spl = autocvar_g_chat_flood_spl_team;
 858                         flood_burst = autocvar_g_chat_flood_burst_team;
 859                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 860                         flood_field = floodcontrol_chatteam;
 861                 }
 862                 else
 863                 {
 864                         flood_spl = autocvar_g_chat_flood_spl;
 865                         flood_burst = autocvar_g_chat_flood_burst;
 866                         flood_lmax = autocvar_g_chat_flood_lmax;
 867                         flood_field = floodcontrol_chat;
 868                 }
 869                 flood_burst = max(0, flood_burst - 1);
 870                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 871
 872                 // do flood control for the default line size
 873                 if(msgstr != "")
 874                 {
 875                         getWrappedLine_remaining = msgstr;
 876                         msgstr = "";
 877                         lines = 0;
 878                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 879                         {
 880                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 881                                 ++lines;
 882                         }
 883                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 884
 885                         if(getWrappedLine_remaining != "")
 886                         {
 887                                 msgstr = strcat(msgstr, "\n");
 888                                 flood = 2;
 889                         }
 890
 891                         if (time >= source.(flood_field))
 892                         {
 893                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
 894                         }
 895                         else
 896                         {
 897                                 flood = 1;
 898                                 msgstr = fullmsgstr;
 899                         }
 900                 }
 901                 else
 902                 {
 903                         if (time >= source.(flood_field))
 904                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
 905                         else
 906                                 flood = 1;
 907                 }
 908
 909                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 910                         source.(flood_field) = flood = 0;
 911         }
 912
 913     string sourcemsgstr, sourcecmsgstr;
 914         if(flood == 2) // cannot happen for empty msgstr
 915         {
 916                 if(autocvar_g_chat_flood_notify_flooder)
 917                 {
 918                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 919                         sourcecmsgstr = "";
 920                 }
 921                 else
 922                 {
 923                         sourcemsgstr = fullmsgstr;
 924                         sourcecmsgstr = fullcmsgstr;
 925                 }
 926                 cmsgstr = "";
 927         }
 928         else
 929         {
 930                 sourcemsgstr = msgstr;
 931                 sourcecmsgstr = cmsgstr;
 932         }
 933
 934         if (!privatesay && source && !IS_PLAYER(source))
 935         {
 936                 if (!game_stopped)
 937                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
 938                         teamsay = -1; // spectators
 939         }
 940
 941         if(flood)
 942                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.\n");
 943
 944         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 945         if(privatesay)
 946                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 947
 948     int ret;
 949         if(source.muted)
 950         {
 951                 // always fake the message
 952                 ret = -1;
 953         }
 954         else if(flood == 1)
 955         {
 956                 if (autocvar_g_chat_flood_notify_flooder)
 957                 {
 958                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
 959                         ret = 0;
 960                 }
 961                 else
 962                         ret = -1;
 963         }
 964         else
 965         {
 966                 ret = 1;
 967         }
 968
 969         if (privatesay && source && !IS_PLAYER(source))
 970         {
 971                 if (!game_stopped)
 972                 if ((privatesay && !IS_PLAYER(privatesay)) || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
 973                         ret = -1; // just hide the message completely
 974         }
 975
 976         MUTATOR_CALLHOOK(ChatMessage, source, ret);
 977         ret = M_ARGV(1, int);
 978
 979         if(sourcemsgstr != "" && ret != 0)
 980         {
 981                 if(ret < 0) // faked message, because the player is muted
 982                 {
 983                         sprint(source, sourcemsgstr);
 984                         if(sourcecmsgstr != "" && !privatesay)
 985                                 centerprint(source, sourcecmsgstr);
 986                 }
 987                 else if(privatesay) // private message, between 2 people only
 988                 {
 989                         sprint(source, sourcemsgstr);
 990                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 991                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
 992                         {
 993                                 sprint(privatesay, msgstr);
 994                                 if(cmsgstr != "")
 995                                         centerprint(privatesay, cmsgstr);
 996                         }
 997                 }
 998                 else if ( teamsay && source.active_minigame )
 999                 {
1000                         sprint(source, sourcemsgstr);
1001                         dedicated_print(msgstr); // send to server console too
1002                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && it.active_minigame == source.active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1003                 }
1004                 else if(teamsay > 0) // team message, only sent to team mates
1005                 {
1006                         sprint(source, sourcemsgstr);
1007                         dedicated_print(msgstr); // send to server console too
1008                         if(sourcecmsgstr != "")
1009                                 centerprint(source, sourcecmsgstr);
1010                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
1011                                 sprint(it, msgstr);
1012                                 if(cmsgstr != "")
1013                                         centerprint(it, cmsgstr);
1014                         });
1015                 }
1016                 else if(teamsay < 0) // spectator message, only sent to spectators
1017                 {
1018                         sprint(source, sourcemsgstr);
1019                         dedicated_print(msgstr); // send to server console too
1020                         FOREACH_CLIENT(!IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1021                 }
1022                 else
1023                 {
1024             if (source) {
1025                 sprint(source, sourcemsgstr);
1026                 dedicated_print(msgstr); // send to server console too
1027                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
1028             }
1029             FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1030         }
1031         }
1032
1033         return ret;
1034 }