qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43 .float pickup_anyway;
  44
  45 float Item_Customize()
  46 {
  47         if(self.spawnshieldtime)
  48                 return TRUE;
  49         if(self.weapons != (self.weapons & other.weapons))
  50         {
  51                 self.colormod = '0 0 0';
  52                 self.glowmod = self.colormod;
  53                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  54                 return TRUE;
  55         }
  56         else
  57         {
  58                 if(g_ghost_items)
  59                 {
  60                         self.colormod = stov(autocvar_g_ghost_items_color);
  61                         self.glowmod = self.colormod;
  62                         self.alpha = g_ghost_items;
  63                         return TRUE;
  64                 }
  65                 else
  66                         return FALSE;
  67         }
  68 }
  69
  70 void Item_Show (entity e, float mode)
  71 {
  72         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
  73         if (mode > 0)
  74         {
  75                 // make the item look normal, and be touchable
  76                 e.model = e.mdl;
  77                 e.solid = SOLID_TRIGGER;
  78                 e.colormod = '0 0 0';
  79                 self.glowmod = self.colormod;
  80                 e.alpha = 0;
  81                 e.customizeentityforclient = func_null;
  82
  83                 e.spawnshieldtime = 1;
  84         }
  85         else if (mode < 0)
  86         {
  87                 // hide the item completely
  88                 e.model = string_null;
  89                 e.solid = SOLID_NOT;
  90                 e.colormod = '0 0 0';
  91                 self.glowmod = self.colormod;
  92                 e.alpha = 0;
  93                 e.customizeentityforclient = func_null;
  94
  95                 e.spawnshieldtime = 1;
  96         }
  97         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
  98         {
  99                 // make the item translucent green and not touchable
 100                 e.model = e.mdl;
 101                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 102                 e.colormod = '0 0 0';
 103                 self.glowmod = self.colormod;
 104                 e.effects |= EF_STARDUST;
 105                 e.customizeentityforclient = Item_Customize;
 106
 107                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 108         }
 109         else if(g_ghost_items)
 110         {
 111                 // make the item translucent green and not touchable
 112                 e.model = e.mdl;
 113                 e.solid = SOLID_NOT;
 114                 e.colormod = stov(autocvar_g_ghost_items_color);
 115                 e.glowmod = e.colormod;
 116                 e.alpha = g_ghost_items;
 117                 e.customizeentityforclient = func_null;
 118
 119                 e.spawnshieldtime = 1;
 120         }
 121         else
 122         {
 123                 // hide the item completely
 124                 e.model = string_null;
 125                 e.solid = SOLID_NOT;
 126                 e.colormod = stov(autocvar_g_ghost_items_color);
 127                 e.glowmod = e.colormod;
 128                 e.alpha = 0;
 129                 e.customizeentityforclient = func_null;
 130
 131                 e.spawnshieldtime = 1;
 132         }
 133
 134         if (e.strength_finished || e.invincible_finished)
 135                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 136         if (autocvar_g_nodepthtestitems)
 137                 e.effects |= EF_NODEPTHTEST;
 138         if (autocvar_g_fullbrightitems)
 139                 e.effects |= EF_FULLBRIGHT;
 140
 141         // relink entity (because solid may have changed)
 142         setorigin(e, e.origin);
 143 }
 144
 145 void Item_Respawn (void)
 146 {
 147         Item_Show(self, 1);
 148         if(!g_minstagib && self.items == IT_STRENGTH)
 149                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
 150         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 151                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 152         else
 153                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
 154         setorigin (self, self.origin);
 155
 156         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 157         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 158 }
 159
 160 void Item_RespawnCountdown (void)
 161 {
 162         if(self.count >= ITEM_RESPAWN_TICKS)
 163         {
 164                 if(self.waypointsprite_attached)
 165                         WaypointSprite_Kill(self.waypointsprite_attached);
 166                 Item_Respawn();
 167         }
 168         else
 169         {
 170                 self.nextthink = time + 1;
 171                 self.count += 1;
 172                 if(self.count == 1)
 173                 {
 174                         string name;
 175                         vector rgb;
 176                         name = string_null;
 177                         if(g_minstagib)
 178                         {
 179                                 switch(self.items)
 180                                 {
 181                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 182                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 183                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 184                                 }
 185                         }
 186                         else
 187                         {
 188                                 switch(self.items)
 189                                 {
 190                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 191                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 192                                 }
 193                         }
 194                         switch(self.items)
 195                         {
 196                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 197                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 198                         }
 199                         if(name)
 200                         {
 201                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 202                                 if(self.waypointsprite_attached)
 203                                 {
 204                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 205                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 206                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 207                                 }
 208                         }
 209                 }
 210                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 211                 if(self.waypointsprite_attached)
 212                 {
 213                         WaypointSprite_Ping(self.waypointsprite_attached);
 214                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 215                 }
 216         }
 217 }
 218
 219 void Item_ScheduleRespawnIn(entity e, float t)
 220 {
 221         if(e.flags & FL_POWERUP)
 222         {
 223                 e.think = Item_RespawnCountdown;
 224                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 225                 e.count = 0;
 226         }
 227         else
 228         {
 229                 e.think = Item_Respawn;
 230                 e.nextthink = time + t;
 231         }
 232 }
 233
 234 void Item_ScheduleRespawn(entity e)
 235 {
 236         if(e.respawntime > 0)
 237         {
 238                 Item_Show(e, 0);
 239                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 240         }
 241         else // if respawntime is -1, this item does not respawn
 242                 Item_Show(e, -1);
 243 }
 244
 245 void Item_ScheduleInitialRespawn(entity e)
 246 {
 247         Item_Show(e, 0);
 248         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 249 }
 250
 251 float Item_GiveTo(entity item, entity player)
 252 {
 253         float _switchweapon;
 254         float pickedup;
 255         float it;
 256         float i;
 257         entity e;
 258
 259         // if nothing happens to player, just return without taking the item
 260         pickedup = FALSE;
 261         _switchweapon = FALSE;
 262
 263         if (g_minstagib)
 264         {
 265                 if(item.spawnshieldtime)
 266                 {
 267                         if (item.ammo_fuel)
 268                         if (player.ammo_fuel < g_pickup_fuel_max)
 269                         {
 270                                 pickedup = TRUE;
 271                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 272                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 273                         }
 274                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 275                         {
 276                                 pickedup = TRUE;
 277                                 player.items |= it;
 278                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 279                         }
 280
 281                         _switchweapon = TRUE;
 282                         if (item.ammo_cells)
 283                         {
 284                                 pickedup = TRUE;
 285                                 // play some cool sounds ;)
 286                                 centerprint(player, "\n");
 287                                 if (clienttype(player) == CLIENTTYPE_REAL)
 288                                 {
 289                                         if(player.health <= 5)
 290                                                 AnnounceTo(player, "lastsecond");
 291                                         else if(player.health < 50)
 292                                                 AnnounceTo(player, "narrowly");
 293                                 }
 294                                 // sound not available
 295                                 // else if(item.items == IT_CELLS)
 296                                 //      AnnounceTo(player, "ammo");
 297
 298                                 if (item.weapons & WEPBIT_MINSTANEX)
 299                                         W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 300                                 if (item.ammo_cells)
 301                                         player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 302                                 player.health = 100;
 303                         }
 304
 305                         // extralife powerup
 306                         if (item.max_health)
 307                         {
 308                                 pickedup = TRUE;
 309                                 // sound not available
 310                                 // AnnounceTo(player, "_lives");
 311                                 player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 312                                 sprint(player, "^3You picked up some extra lives\n");
 313                         }
 314
 315                         // invis powerup
 316                         if (item.strength_finished)
 317                         {
 318                                 pickedup = TRUE;
 319                                 // sound not available
 320                                 // AnnounceTo(player, "invisible");
 321                                 player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 322                         }
 323
 324                         // speed powerup
 325                         if (item.invincible_finished)
 326                         {
 327                                 pickedup = TRUE;
 328                                 // sound not available
 329                                 // AnnounceTo(player, "speed");
 330                                 player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 331                         }
 332                 }
 333         }
 334         else
 335         {
 336                 if (g_weapon_stay == 1)
 337                 if not(item.flags & FL_NO_WEAPON_STAY)
 338                 if (item.flags & FL_WEAPON)
 339                 {
 340                         if(item.classname == "droppedweapon")
 341                         {
 342                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 343                                         goto skip;
 344                         }
 345                         else
 346                         {
 347                                 if (player.weapons & item.weapons)
 348                                         goto skip;
 349                         }
 350                 }
 351
 352                 // in case the player has autoswitch enabled do the following:
 353                 // if the player is using their best weapon before items are given, they
 354                 // probably want to switch to an even better weapon after items are given
 355                 if (player.autoswitch)
 356                 if (player.switchweapon == w_getbestweapon(player))
 357                         _switchweapon = TRUE;
 358
 359                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 360                         _switchweapon = TRUE;
 361
 362                 if(item.spawnshieldtime)
 363                 {
 364                         if (item.ammo_shells)
 365                         if ((player.ammo_shells < g_pickup_shells_max) || item.pickup_anyway)
 366                         {
 367                                 pickedup = TRUE;
 368                                 player.ammo_shells = bound(player.ammo_shells, g_pickup_shells_max, player.ammo_shells + item.ammo_shells);
 369                         }
 370                         if (item.ammo_nails)
 371                         if ((player.ammo_nails < g_pickup_nails_max) || item.pickup_anyway)
 372                         {
 373                                 pickedup = TRUE;
 374                                 player.ammo_nails = bound(player.ammo_nails, g_pickup_nails_max, player.ammo_nails + item.ammo_nails);
 375                         }
 376                         if (item.ammo_rockets)
 377                         if ((player.ammo_rockets < g_pickup_rockets_max) || item.pickup_anyway)
 378                         {
 379                                 pickedup = TRUE;
 380                                 player.ammo_rockets = bound(player.ammo_rockets, g_pickup_rockets_max, player.ammo_rockets + item.ammo_rockets);
 381                         }
 382                         if (item.ammo_cells)
 383                         if ((player.ammo_cells < g_pickup_cells_max) || item.pickup_anyway)
 384                         {
 385                                 pickedup = TRUE;
 386                                 player.ammo_cells = bound(player.ammo_cells, g_pickup_cells_max, player.ammo_cells + item.ammo_cells);
 387                         }
 388                         if (item.ammo_fuel)
 389                         if ((player.ammo_fuel < g_pickup_fuel_max) || item.pickup_anyway)
 390                         {
 391                                 pickedup = TRUE;
 392                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 393                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 394                         }
 395                 }
 396
 397                 if (item.flags & FL_WEAPON)
 398                 if ((it = item.weapons - (item.weapons & player.weapons)) || g_pickup_weapons_anyway)
 399                 {
 400                         pickedup = TRUE;
 401                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 402                         {
 403                                 e = get_weaponinfo(i);
 404                                 if(it & e.weapons)
 405                                         W_GiveWeapon (player, e.weapon, item.netname);
 406                         }
 407                 }
 408
 409                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 410                 {
 411                         pickedup = TRUE;
 412                         player.items |= it;
 413                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 414                 }
 415
 416                 if(item.spawnshieldtime)
 417                 {
 418                         if (item.strength_finished)
 419                         {
 420                                 pickedup = TRUE;
 421                                 player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 422                         }
 423                         if (item.invincible_finished)
 424                         {
 425                                 pickedup = TRUE;
 426                                 player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 427                         }
 428
 429                         if (item.health)
 430                         if ((player.health < item.max_health) || item.pickup_anyway)
 431                         {
 432                                 pickedup = TRUE;
 433                                 player.health = bound(player.health, item.max_health, player.health + item.health);
 434                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 435                         }
 436                         if (item.armorvalue)
 437                         if ((player.armorvalue < item.max_armorvalue) || item.pickup_anyway)
 438                         {
 439                                 pickedup = TRUE;
 440                                 player.armorvalue = bound(player.armorvalue, item.max_armorvalue, player.armorvalue + item.armorvalue);
 441                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 442                         }
 443                 }
 444         }
 445
 446 :skip
 447         // always eat teamed entities
 448         if(item.team)
 449                 pickedup = TRUE;
 450
 451         if (!pickedup)
 452                 return 0;
 453
 454         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 455         if (_switchweapon)
 456                 if (player.switchweapon != w_getbestweapon(player))
 457                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 458
 459         return 1;
 460 }
 461
 462 void Item_Touch (void)
 463 {
 464         entity e, head;
 465
 466         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 467         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 468         {
 469                 remove(self);
 470                 return;
 471         }
 472         if (other.classname != "player")
 473                 return;
 474         if (other.deadflag)
 475                 return;
 476         if (self.solid != SOLID_TRIGGER)
 477                 return;
 478         if (self.owner == other)
 479                 return;
 480
 481         if(!Item_GiveTo(self, other))
 482                 return;
 483
 484         other.last_pickup = time;
 485
 486         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 487
 488         if (self.classname == "droppedweapon")
 489                 remove (self);
 490         else if not(self.spawnshieldtime)
 491                 return;
 492         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
 493                 return;
 494         else
 495         {
 496                 if(self.team)
 497                 {
 498                         RandomSelection_Init();
 499                         for(head = world; (head = findfloat(head, team, self.team)); )
 500                         {
 501                                 if(head.flags & FL_ITEM)
 502                                 {
 503                                         Item_Show(head, -1);
 504                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 505                                 }
 506                         }
 507                         e = RandomSelection_chosen_ent;
 508                 }
 509                 else
 510                         e = self;
 511                 Item_ScheduleRespawn(e);
 512         }
 513 }
 514
 515 void Item_FindTeam()
 516 {
 517         entity head, e;
 518
 519         if(self.effects & EF_NODRAW)
 520         {
 521                 // marker for item team search
 522                 dprint("Initializing item team ", ftos(self.team), "\n");
 523                 RandomSelection_Init();
 524                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 525                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 526                 e = RandomSelection_chosen_ent;
 527                 e.state = 0;
 528                 Item_Show(e, 1);
 529
 530                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 531                 {
 532                         if(head != e)
 533                         {
 534                                 // make it a non-spawned item
 535                                 Item_Show(head, -1);
 536                                 head.state = 1; // state 1 = initially hidden item
 537                         }
 538                         head.effects &~= EF_NODRAW;
 539                 }
 540
 541                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 542                         Item_ScheduleInitialRespawn(e);
 543         }
 544 }
 545
 546 void Item_Reset()
 547 {
 548         Item_Show(self, !self.state);
 549         setorigin (self, self.origin);
 550         self.think = SUB_Null;
 551         self.nextthink = 0;
 552
 553         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 554                 Item_ScheduleInitialRespawn(self);
 555 }
 556
 557 // Savage: used for item garbage-collection
 558 // TODO: perhaps nice special effect?
 559 void RemoveItem(void)
 560 {
 561         remove(self);
 562 }
 563
 564 // pickup evaluation functions
 565 // these functions decide how desirable an item is to the bots
 566
 567 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 568
 569 float weapon_pickupevalfunc(entity player, entity item)
 570 {
 571         float c, i, j, position;
 572
 573         // See if I have it already
 574         if(player.weapons & item.weapons == item.weapons)
 575         {
 576                 // If I can pick it up
 577                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
 578                         c = 0;
 579                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 580                 {
 581                         // Skilled bots will grab more
 582                         c = bound(0, skill / 10, 1) * 0.5;
 583                 }
 584                 else
 585                         c = 0;
 586         }
 587         else
 588                 c = 1;
 589
 590         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 591         if( bot_custom_weapon && c )
 592         {
 593                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 594                 {
 595                         // Find weapon
 596                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 597                                 continue;
 598
 599                         // Find the highest position on any range
 600                         position = -1;
 601                         for(j = 0; j < WEP_LAST ; ++j){
 602                                 if(
 603                                                 bot_weapons_far[j] == i ||
 604                                                 bot_weapons_mid[j] == i ||
 605                                                 bot_weapons_close[j] == i
 606                                   )
 607                                 {
 608                                         position = j;
 609                                         break;
 610                                 }
 611                         }
 612
 613                         // Rate it
 614                         if (position >= 0 )
 615                         {
 616                                 position = WEP_LAST - position;
 617                                 // item.bot_pickupbasevalue is overwritten here
 618                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 619                         }
 620                 }
 621         }
 622
 623         return item.bot_pickupbasevalue * c;
 624 };
 625
 626 float commodity_pickupevalfunc(entity player, entity item)
 627 {
 628         float c, i, need_shells, need_nails, need_rockets, need_cells;
 629         entity wi;
 630         c = 0;
 631
 632         // Detect needed ammo
 633         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 634         {
 635                 wi = get_weaponinfo(i);
 636
 637                 if not(wi.weapons & player.weapons)
 638                         continue;
 639
 640                 if(wi.items & IT_SHELLS)
 641                         need_shells = TRUE;
 642                 else if(wi.items & IT_NAILS)
 643                         need_nails = TRUE;
 644                 else if(wi.items & IT_ROCKETS)
 645                         need_rockets = TRUE;
 646                 else if(wi.items & IT_CELLS)
 647                         need_cells = TRUE;
 648         }
 649
 650         // TODO: figure out if the player even has the weapon this ammo is for?
 651         // may not affect strategy much though...
 652         // find out how much more ammo/armor/health the player can hold
 653         if (need_shells)
 654         if (item.ammo_shells)
 655         if (player.ammo_shells < g_pickup_shells_max)
 656                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 657         if (need_nails)
 658         if (item.ammo_nails)
 659         if (player.ammo_nails < g_pickup_nails_max)
 660                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 661         if (need_rockets)
 662         if (item.ammo_rockets)
 663         if (player.ammo_rockets < g_pickup_rockets_max)
 664                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 665         if (need_cells)
 666         if (item.ammo_cells)
 667         if (player.ammo_cells < g_pickup_cells_max)
 668                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 669         if (item.armorvalue)
 670         if (player.armorvalue < item.max_armorvalue)
 671                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 672         if (item.health)
 673         if (player.health < item.max_health)
 674                 c = c + max(0, 1 - player.health / item.max_health);
 675
 676         return item.bot_pickupbasevalue * c;
 677 };
 678
 679
 680 .float is_item;
 681 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 682 {
 683         startitem_failed = FALSE;
 684
 685         self.items = itemid;
 686         self.weapons = weaponid;
 687
 688         // is it a dropped weapon?
 689         if (self.classname == "droppedweapon")
 690         {
 691                 self.reset = SUB_Remove;
 692                 // it's a dropped weapon
 693                 self.movetype = MOVETYPE_TOSS;
 694                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 695                 self.think = RemoveItem;
 696                 self.nextthink = time + 60;
 697                 // don't drop if in a NODROP zone (such as lava)
 698                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 699                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 700                 {
 701                         startitem_failed = TRUE;
 702                         remove(self);
 703                         return;
 704                 }
 705         }
 706         else
 707         {
 708                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 709                 {
 710                         startitem_failed = TRUE;
 711                         remove(self);
 712                         return;
 713                 }
 714
 715                 if(self.model != "")
 716                         itemmodel = self.model;
 717                 if(self.item_pickupsound != "")
 718                         pickupsound = self.item_pickupsound;
 719
 720                 self.reset = Item_Reset;
 721                 // it's a level item
 722                 if(self.spawnflags & 1)
 723                         self.noalign = 1;
 724                 if (self.noalign)
 725                         self.movetype = MOVETYPE_NONE;
 726                 else
 727                         self.movetype = MOVETYPE_TOSS;
 728                 // do item filtering according to game mode and other things
 729                 if (!self.noalign)
 730                 {
 731                         // first nudge it off the floor a little bit to avoid math errors
 732                         setorigin(self, self.origin + '0 0 1');
 733                         // set item size before we spawn a spawnfunc_waypoint
 734                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 735                                 setsize (self, '-16 -16 0', '16 16 48');
 736                         else
 737                                 setsize (self, '-16 -16 0', '16 16 32');
 738                         // note droptofloor returns FALSE if stuck/or would fall too far
 739                         droptofloor();
 740                         waypoint_spawnforitem(self);
 741                 }
 742
 743                 if(teams_matter)
 744                 {
 745                         if(self.notteam)
 746                         {
 747                                 print("removed non-teamplay ", self.classname, "\n");
 748                                 startitem_failed = TRUE;
 749                                 remove (self);
 750                                 return;
 751                         }
 752                 }
 753                 else
 754                 {
 755                         if(self.notfree)
 756                         {
 757                                 print("removed non-FFA ", self.classname, "\n");
 758                                 startitem_failed = TRUE;
 759                                 remove (self);
 760                                 return;
 761                         }
 762                 }
 763
 764                 if(self.notq3a)
 765                 {
 766                         // We aren't TA or something like that, so we keep the Q3A entities
 767                         print("removed non-Q3A ", self.classname, "\n");
 768                         startitem_failed = TRUE;
 769                         remove (self);
 770                         return;
 771                 }
 772
 773                 /*
 774                  * can't do it that way, as it would break maps
 775                  * TODO make a target_give like entity another way, that perhaps has
 776                  * the weapon name in a key
 777                 if(self.targetname)
 778                 {
 779                         // target_give not yet supported; maybe later
 780                         print("removed targeted ", self.classname, "\n");
 781                         startitem_failed = TRUE;
 782                         remove (self);
 783                         return;
 784                 }
 785                 */
 786
 787                 if(autocvar_spawn_debug >= 2)
 788                 {
 789                         entity otheritem;
 790                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 791                         {
 792                                 if(otheritem.is_item)
 793                                 {
 794                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 795                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 796                                         error("Mapper sucks.");
 797                                 }
 798                         }
 799                         self.is_item = TRUE;
 800                 }
 801
 802                 if(g_lms || g_ca)
 803                 {
 804                         startitem_failed = TRUE;
 805                         remove(self);
 806                         return;
 807                 }
 808                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 809                 {
 810                         startitem_failed = TRUE;
 811                         remove(self);
 812                         return;
 813                 }
 814                 else if (g_minstagib)
 815                 {
 816                         // don't remove dropped items and powerups
 817                         if (self.classname != "minstagib")
 818                         {
 819                                 startitem_failed = TRUE;
 820                                 remove (self);
 821                                 return;
 822                         }
 823                 }
 824                 else if (!autocvar_g_pickup_items && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 825                 {
 826                         startitem_failed = TRUE;
 827                         remove (self);
 828                         return;
 829                 }
 830
 831                 weaponsInMap |= weaponid;
 832
 833                 precache_model (itemmodel);
 834                 precache_sound (pickupsound);
 835
 836                 precache_sound ("misc/itemrespawncountdown.wav");
 837                 if(!g_minstagib && itemid == IT_STRENGTH)
 838                         precache_sound ("misc/strength_respawn.wav");
 839                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 840                         precache_sound ("misc/shield_respawn.wav");
 841                 else
 842                         precache_sound ("misc/itemrespawn.wav");
 843
 844                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 845                         self.target = "###item###"; // for finding the nearest item using find()
 846         }
 847
 848         self.bot_pickup = TRUE;
 849         self.bot_pickupevalfunc = pickupevalfunc;
 850         self.bot_pickupbasevalue = pickupbasevalue;
 851         self.mdl = itemmodel;
 852         self.item_pickupsound = pickupsound;
 853         // let mappers override respawntime
 854         if(!self.respawntime) // both set
 855         {
 856                 self.respawntime = defaultrespawntime;
 857                 self.respawntimejitter = defaultrespawntimejitter;
 858         }
 859         self.netname = itemname;
 860         self.flags = FL_ITEM | itemflags;
 861         self.touch = Item_Touch;
 862         setmodel (self, self.mdl); // precision set below
 863         self.effects |= EF_LOWPRECISION;
 864         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 865                 setsize (self, '-16 -16 0', '16 16 48');
 866         else
 867                 setsize (self, '-16 -16 0', '16 16 32');
 868         if(itemflags & FL_WEAPON)
 869                 self.modelflags |= MF_ROTATE;
 870
 871         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 872         if (itemflags & FL_WEAPON)
 873         {
 874                 // neutral team color for pickup weapons
 875                 self.colormap = 1024; // color shirt=0 pants=0 grey
 876         }
 877
 878         Item_Show(self, 1);
 879         self.state = 0;
 880         if(self.team)
 881         {
 882                 if(!self.cnt)
 883                         self.cnt = 1; // item probability weight
 884                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 885                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 886         }
 887         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 888                 Item_ScheduleInitialRespawn(self);
 889 }
 890
 891 /* replace items in minstagib
 892  * IT_STRENGTH   = invisibility
 893  * IT_NAILS      = extra lives
 894  * IT_INVINCIBLE = speed
 895  */
 896 void minstagib_items (float itemid)
 897 {
 898         local float rnd;
 899         self.classname = "minstagib";
 900
 901         // replace rocket launchers and nex guns with ammo cells
 902         if (itemid == IT_CELLS)
 903         {
 904                 self.ammo_cells = 1;
 905                 StartItem ("models/items/a_cells.md3",
 906                         "misc/itempickup.wav", 45, 0,
 907                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 908                 return;
 909         }
 910
 911         // randomize
 912         rnd = random() * 3;
 913         if (rnd <= 1)
 914                 itemid = IT_STRENGTH;
 915         else if (rnd <= 2)
 916                 itemid = IT_NAILS;
 917         else
 918                 itemid = IT_INVINCIBLE;
 919
 920         // replace with invis
 921         if (itemid == IT_STRENGTH)
 922         {
 923                 self.strength_finished = 30;
 924                 StartItem ("models/items/g_strength.md3",
 925                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 926                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 927         }
 928         // replace with extra lives
 929         if (itemid == IT_NAILS)
 930         {
 931                 self.max_health = 1;
 932                 StartItem ("models/items/g_h100.md3",
 933                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 934                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 935         }
 936         // replace with speed
 937         if (itemid == IT_INVINCIBLE)
 938         {
 939                 self.invincible_finished = 30;
 940                 StartItem ("models/items/g_invincible.md3",
 941                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 942                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 943         }
 944 }
 945
 946 float minst_no_auto_cells;
 947 void minst_remove_item (void) {
 948         if(minst_no_auto_cells)
 949                 remove(self);
 950 }
 951
 952 float weaponswapping;
 953 float internalteam;
 954
 955 void weapon_defaultspawnfunc(float wpn)
 956 {
 957         entity e;
 958         float t;
 959         var .float ammofield;
 960         string s;
 961         entity oldself;
 962         float i, j;
 963
 964         // set the respawntime in advance (so replaced weapons can copy it)
 965
 966         if(!self.respawntime)
 967         {
 968                 e = get_weaponinfo(wpn);
 969                 if(e.items == IT_SUPERWEAPON)
 970                 {
 971                         self.respawntime = g_pickup_respawntime_powerup;
 972                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 973                 }
 974                 else
 975                 {
 976                         self.respawntime = g_pickup_respawntime_weapon;
 977                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 978                 }
 979         }
 980
 981         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 982         {
 983                 e = get_weaponinfo(wpn);
 984                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 985                 if(s == "0")
 986                 {
 987                         remove(self);
 988                         startitem_failed = TRUE;
 989                         return;
 990                 }
 991                 t = tokenize_console(s);
 992                 if(t >= 2)
 993                 {
 994                         self.team = --internalteam;
 995                         oldself = self;
 996                         for(i = 1; i < t; ++i)
 997                         {
 998                                 s = argv(i);
 999                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1000                                 {
1001                                         e = get_weaponinfo(j);
1002                                         if(e.netname == s)
1003                                         {
1004                                                 self = spawn();
1005                                                 copyentity(oldself, self);
1006                                                 self.classname = "replacedweapon";
1007                                                 weapon_defaultspawnfunc(j);
1008                                                 break;
1009                                         }
1010                                 }
1011                                 if(j > WEP_LAST)
1012                                 {
1013                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1014                                 }
1015                         }
1016                         self = oldself;
1017                 }
1018                 if(t >= 1)
1019                 {
1020                         s = argv(0);
1021                         wpn = 0;
1022                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1023                         {
1024                                 e = get_weaponinfo(j);
1025                                 if(e.netname == s)
1026                                 {
1027                                         wpn = j;
1028                                         break;
1029                                 }
1030                         }
1031                         if(j > WEP_LAST)
1032                         {
1033                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1034                         }
1035                 }
1036                 if(wpn == 0)
1037                 {
1038                         remove(self);
1039                         startitem_failed = TRUE;
1040                         return;
1041                 }
1042         }
1043
1044         e = get_weaponinfo(wpn);
1045
1046         if(e.items && e.items != IT_SUPERWEAPON)
1047         {
1048                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1049                 {
1050                         if(e.items & j)
1051                         {
1052                                 ammofield = Item_CounterField(j);
1053                                 if(!self.ammofield)
1054                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1055                         }
1056                 }
1057         }
1058         else
1059         {
1060                 self.flags |= FL_NO_WEAPON_STAY;
1061         }
1062
1063         // weapon stay isn't supported for teamed weapons
1064         if(self.team)
1065                 self.flags |= FL_NO_WEAPON_STAY;
1066
1067         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1068         {
1069                 self.ammo_shells = 0;
1070                 self.ammo_nails = 0;
1071                 self.ammo_cells = 0;
1072                 self.ammo_rockets = 0;
1073                 // weapon stay 2: don't use ammo on weapon pickups; instead
1074                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1075         }
1076
1077         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1078         if (self.modelindex) // don't precache if self was removed
1079                 weapon_action(e.weapon, WR_PRECACHE);
1080 }
1081
1082 void spawnfunc_weapon_shotgun (void);
1083 void spawnfunc_weapon_uzi (void) {
1084         if(q3acompat_machineshotgunswap)
1085         if(self.classname != "droppedweapon")
1086         {
1087                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1088                 return;
1089         }
1090         weapon_defaultspawnfunc(WEP_UZI);
1091 }
1092
1093 void spawnfunc_weapon_shotgun (void) {
1094         if(q3acompat_machineshotgunswap)
1095         if(self.classname != "droppedweapon")
1096         {
1097                 weapon_defaultspawnfunc(WEP_UZI);
1098                 return;
1099         }
1100         weapon_defaultspawnfunc(WEP_SHOTGUN);
1101 }
1102
1103 void spawnfunc_weapon_nex (void)
1104 {
1105         if (g_minstagib)
1106         {
1107                 minstagib_items(IT_CELLS);
1108                 self.think = minst_remove_item;
1109                 self.nextthink = time;
1110                 return;
1111         }
1112         weapon_defaultspawnfunc(WEP_NEX);
1113 }
1114
1115 void spawnfunc_weapon_minstanex (void)
1116 {
1117         if (g_minstagib)
1118         {
1119                 minstagib_items(IT_CELLS);
1120                 self.think = minst_remove_item;
1121                 self.nextthink = time;
1122                 return;
1123         }
1124         weapon_defaultspawnfunc(WEP_MINSTANEX);
1125 }
1126
1127 void spawnfunc_weapon_rocketlauncher (void)
1128 {
1129         if (g_minstagib)
1130         {
1131                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1132                 self.think = minst_remove_item;
1133                 self.nextthink = time;
1134                 return;
1135         }
1136         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1137 }
1138
1139 void spawnfunc_item_rockets (void) {
1140         if(!self.ammo_rockets)
1141                 self.ammo_rockets = g_pickup_rockets;
1142         if(!self.pickup_anyway)
1143                 self.pickup_anyway = g_pickup_ammo_anyway;
1144         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1145 }
1146
1147 void spawnfunc_item_shells (void);
1148 void spawnfunc_item_bullets (void) {
1149         if(!weaponswapping)
1150         if(q3acompat_machineshotgunswap)
1151         if(self.classname != "droppedweapon")
1152         {
1153                 weaponswapping = TRUE;
1154                 spawnfunc_item_shells();
1155                 weaponswapping = FALSE;
1156                 return;
1157         }
1158
1159         if(!self.ammo_nails)
1160                 self.ammo_nails = g_pickup_nails;
1161         if(!self.pickup_anyway)
1162                 self.pickup_anyway = g_pickup_ammo_anyway;
1163         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1164 }
1165
1166 void spawnfunc_item_cells (void) {
1167         if(!self.ammo_cells)
1168                 self.ammo_cells = g_pickup_cells;
1169         if(!self.pickup_anyway)
1170                 self.pickup_anyway = g_pickup_ammo_anyway;
1171         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1172 }
1173
1174 void spawnfunc_item_shells (void) {
1175         if(!weaponswapping)
1176         if(q3acompat_machineshotgunswap)
1177         if(self.classname != "droppedweapon")
1178         {
1179                 weaponswapping = TRUE;
1180                 spawnfunc_item_bullets();
1181                 weaponswapping = FALSE;
1182                 return;
1183         }
1184
1185         if(!self.ammo_shells)
1186                 self.ammo_shells = g_pickup_shells;
1187         if(!self.pickup_anyway)
1188                 self.pickup_anyway = g_pickup_ammo_anyway;
1189         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1190 }
1191
1192 void spawnfunc_item_armor_small (void) {
1193         if(!self.armorvalue)
1194                 self.armorvalue = g_pickup_armorsmall;
1195         if(!self.max_armorvalue)
1196                 self.max_armorvalue = g_pickup_armorsmall_max;
1197         if(!self.pickup_anyway)
1198                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1199         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1200 }
1201
1202 void spawnfunc_item_armor_medium (void) {
1203         if(!self.armorvalue)
1204                 self.armorvalue = g_pickup_armormedium;
1205         if(!self.max_armorvalue)
1206                 self.max_armorvalue = g_pickup_armormedium_max;
1207         if(!self.pickup_anyway)
1208                 self.pickup_anyway = g_pickup_armormedium_anyway;
1209         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1210 }
1211
1212 void spawnfunc_item_armor_big (void) {
1213         if(!self.armorvalue)
1214                 self.armorvalue = g_pickup_armorbig;
1215         if(!self.max_armorvalue)
1216                 self.max_armorvalue = g_pickup_armorbig_max;
1217         if(!self.pickup_anyway)
1218                 self.pickup_anyway = g_pickup_armorbig_anyway;
1219         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1220 }
1221
1222 void spawnfunc_item_armor_large (void) {
1223         if(!self.armorvalue)
1224                 self.armorvalue = g_pickup_armorlarge;
1225         if(!self.max_armorvalue)
1226                 self.max_armorvalue = g_pickup_armorlarge_max;
1227         if(!self.pickup_anyway)
1228                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1229         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1230 }
1231
1232 void spawnfunc_item_health_small (void) {
1233         if(!self.max_health)
1234                 self.max_health = g_pickup_healthsmall_max;
1235         if(!self.health)
1236                 self.health = g_pickup_healthsmall;
1237         if(!self.pickup_anyway)
1238                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1239         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1240 }
1241
1242 void spawnfunc_item_health_medium (void) {
1243         if(!self.max_health)
1244                 self.max_health = g_pickup_healthmedium_max;
1245         if(!self.health)
1246                 self.health = g_pickup_healthmedium;
1247         if(!self.pickup_anyway)
1248                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1249         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1250 }
1251
1252 void spawnfunc_item_health_large (void) {
1253         if(!self.max_health)
1254                 self.max_health = g_pickup_healthlarge_max;
1255         if(!self.health)
1256                 self.health = g_pickup_healthlarge;
1257         if(!self.pickup_anyway)
1258                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1259         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1260 }
1261
1262 void spawnfunc_item_health_mega (void) {
1263         if(!autocvar_g_powerup_superhealth)
1264                 return;
1265
1266         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1267                 return;
1268
1269         if(g_minstagib) {
1270                 minstagib_items(IT_NAILS);
1271         } else {
1272                 if(!self.max_health)
1273                         self.max_health = g_pickup_healthmega_max;
1274                 if(!self.health)
1275                         self.health = g_pickup_healthmega;
1276                 if(!self.pickup_anyway)
1277                         self.pickup_anyway = g_pickup_healthmega_anyway;
1278                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1279         }
1280 }
1281
1282 // support old misnamed entities
1283 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1284 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1285 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1286 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1287 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1288
1289 void spawnfunc_item_strength (void) {
1290         if(!autocvar_g_powerup_strength)
1291                 return;
1292
1293         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1294                 return;
1295
1296         if(g_minstagib) {
1297                 minstagib_items(IT_STRENGTH);
1298         } else {
1299                 precache_sound("weapons/strength_fire.wav");
1300                 self.strength_finished = 30;
1301                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1302         }
1303 }
1304
1305 void spawnfunc_item_invincible (void) {
1306         if(!autocvar_g_powerup_shield)
1307                 return;
1308
1309         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1310                 return;
1311
1312         if(g_minstagib) {
1313                 minstagib_items(IT_INVINCIBLE);
1314         } else {
1315                 self.invincible_finished = 30;
1316                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1317         }
1318 }
1319
1320 void spawnfunc_item_minst_cells (void) {
1321         if (g_minstagib)
1322         {
1323                 minst_no_auto_cells = 1;
1324                 minstagib_items(IT_CELLS);
1325         }
1326         else
1327                 remove(self);
1328 }
1329
1330 // compatibility:
1331 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1332
1333 float GiveItems(entity e, float beginarg, float endarg);
1334 void target_items_use (void)
1335 {
1336         if(activator.classname == "droppedweapon")
1337         {
1338                 EXACTTRIGGER_TOUCH;
1339                 remove(activator);
1340                 return;
1341         }
1342
1343         if(activator.classname != "player")
1344                 return;
1345         if(activator.deadflag != DEAD_NO)
1346                 return;
1347         EXACTTRIGGER_TOUCH;
1348
1349         entity e;
1350         for(e = world; (e = find(e, classname, "droppedweapon")); )
1351                 if(e.enemy == activator)
1352                         remove(e);
1353
1354         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1355                 centerprint(activator, self.message);
1356 }
1357
1358 void spawnfunc_target_items (void)
1359 {
1360         float n, i, j;
1361         entity e;
1362
1363         self.use = target_items_use;
1364         if(!self.strength_finished)
1365                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1366         if(!self.invincible_finished)
1367                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1368
1369         precache_sound("misc/itempickup.wav");
1370         precache_sound("misc/megahealth.wav");
1371         precache_sound("misc/armor25.wav");
1372         precache_sound("misc/powerup.wav");
1373         precache_sound("misc/poweroff.wav");
1374         precache_sound("weapons/weaponpickup.wav");
1375
1376         n = tokenize_console(self.netname);
1377         if(argv(0) == "give")
1378         {
1379                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1380         }
1381         else
1382         {
1383                 for(i = 0; i < n; ++i)
1384                 {
1385                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1386                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1387                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1388                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1389                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1390                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1391                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1392                         else
1393                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1394                         {
1395                                 e = get_weaponinfo(j);
1396                                 if(argv(i) == e.netname)
1397                                 {
1398                                         self.weapons |= e.weapons;
1399                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1400                                                 weapon_action(e.weapon, WR_PRECACHE);
1401                                         break;
1402                                 }
1403                         }
1404                         if(j > WEP_LAST)
1405                                 print("target_items: invalid item ", argv(i), "\n");
1406                 }
1407
1408                 string itemprefix, valueprefix;
1409                 if(self.spawnflags == 0)
1410                 {
1411                         itemprefix = "";
1412                         valueprefix = "";
1413                 }
1414                 else if(self.spawnflags == 1)
1415                 {
1416                         itemprefix = "max ";
1417                         valueprefix = "max ";
1418                 }
1419                 else if(self.spawnflags == 2)
1420                 {
1421                         itemprefix = "min ";
1422                         valueprefix = "min ";
1423                 }
1424                 else if(self.spawnflags == 4)
1425                 {
1426                         itemprefix = "minus ";
1427                         valueprefix = "max ";
1428                 }
1429                 else
1430                         error("invalid spawnflags");
1431
1432                 self.netname = "";
1433                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1434                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1435                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1436                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1437                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1438                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1439                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1440                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1441                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1442                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1443                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1444                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1445                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1446                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1447                 {
1448                         e = get_weaponinfo(j);
1449                         if(e.weapons)
1450                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1451                 }
1452         }
1453         self.netname = strzone(self.netname);
1454         //print(self.netname, "\n");
1455
1456         n = tokenize_console(self.netname);
1457         for(i = 0; i < n; ++i)
1458         {
1459                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1460                 {
1461                         e = get_weaponinfo(j);
1462                         if(argv(i) == e.netname)
1463                         {
1464                                 weapon_action(e.weapon, WR_PRECACHE);
1465                                 break;
1466                         }
1467                 }
1468         }
1469 }
1470
1471 void spawnfunc_item_fuel(void)
1472 {
1473         if(!self.ammo_fuel)
1474                 self.ammo_fuel = g_pickup_fuel;
1475         if(!self.pickup_anyway)
1476                 self.pickup_anyway = g_pickup_ammo_anyway;
1477         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1478 }
1479
1480 void spawnfunc_item_fuel_regen(void)
1481 {
1482         if(start_items & IT_FUEL_REGEN)
1483         {
1484                 spawnfunc_item_fuel();
1485                 return;
1486         }
1487         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1488 }
1489
1490 void spawnfunc_item_jetpack(void)
1491 {
1492         if(g_grappling_hook)
1493                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1494         if(!self.ammo_fuel)
1495                 self.ammo_fuel = g_pickup_fuel_jetpack;
1496         if(start_items & IT_JETPACK)
1497         {
1498                 spawnfunc_item_fuel();
1499                 return;
1500         }
1501         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1502 }
1503
1504
1505 #define OP_SET 0
1506 #define OP_MIN 1
1507 #define OP_MAX 2
1508 #define OP_PLUS 3
1509 #define OP_MINUS 4
1510
1511 float GiveBit(entity e, .float fld, float bit, float op, float val)
1512 {
1513         float v0, v1;
1514         v0 = (e.fld & bit);
1515         switch(op)
1516         {
1517                 case OP_SET:
1518                         if(val > 0)
1519                                 e.fld |= bit;
1520                         else
1521                                 e.fld &~= bit;
1522                         break;
1523                 case OP_MIN:
1524                 case OP_PLUS:
1525                         if(val > 0)
1526                                 e.fld |= bit;
1527                         break;
1528                 case OP_MAX:
1529                         if(val <= 0)
1530                                 e.fld &~= bit;
1531                         break;
1532                 case OP_MINUS:
1533                         if(val > 0)
1534                                 e.fld &~= bit;
1535                         break;
1536         }
1537         v1 = (e.fld & bit);
1538         return (v0 != v1);
1539 }
1540
1541 float GiveValue(entity e, .float fld, float op, float val)
1542 {
1543         float v0, v1;
1544         v0 = e.fld;
1545         switch(op)
1546         {
1547                 case OP_SET:
1548                         e.fld = val;
1549                         break;
1550                 case OP_MIN:
1551                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1552                         break;
1553                 case OP_MAX:
1554                         e.fld = min(e.fld, val);
1555                         break;
1556                 case OP_PLUS:
1557                         e.fld += val;
1558                         break;
1559                 case OP_MINUS:
1560                         e.fld -= val;
1561                         break;
1562         }
1563         v1 = e.fld;
1564         return (v0 != v1);
1565 }
1566
1567 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1568 {
1569         if(v1 == v0)
1570                 return;
1571         if(v1 <= v0 - t)
1572         {
1573                 if(snd_decr != "")
1574                         sound (e, CHAN_AUTO, snd_decr, VOL_BASE, ATTN_NORM);
1575         }
1576         else if(v0 >= v0 + t)
1577         {
1578                 if(snd_incr != "")
1579                         sound (e, CHAN_AUTO, snd_incr, VOL_BASE, ATTN_NORM);
1580         }
1581 }
1582
1583 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1584 {
1585         if(v0 < v1)
1586                 e.rotfield = max(e.rotfield, time + rottime);
1587         else if(v0 > v1)
1588                 e.regenfield = max(e.regenfield, time + regentime);
1589 }
1590
1591 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1592 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1593 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1594 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1595
1596 float GiveItems(entity e, float beginarg, float endarg)
1597 {
1598         float got, i, j, val, op;
1599         float _switchweapon;
1600         entity wi;
1601         string cmd;
1602
1603         val = 999;
1604         op = OP_SET;
1605
1606         got = 0;
1607
1608         _switchweapon = FALSE;
1609         if (e.autoswitch)
1610                 if (e.switchweapon == w_getbestweapon(e))
1611                         _switchweapon = TRUE;
1612
1613         e.strength_finished = max(0, e.strength_finished - time);
1614         e.invincible_finished = max(0, e.invincible_finished - time);
1615
1616         PREGIVE(e, items);
1617         PREGIVE(e, weapons);
1618         PREGIVE(e, strength_finished);
1619         PREGIVE(e, invincible_finished);
1620         PREGIVE(e, ammo_nails);
1621         PREGIVE(e, ammo_cells);
1622         PREGIVE(e, ammo_shells);
1623         PREGIVE(e, ammo_rockets);
1624         PREGIVE(e, ammo_fuel);
1625         PREGIVE(e, armorvalue);
1626         PREGIVE(e, health);
1627
1628         for(i = beginarg; i < endarg; ++i)
1629         {
1630                 cmd = argv(i);
1631
1632                 if(cmd == "0" || stof(cmd))
1633                 {
1634                         val = stof(cmd);
1635                         continue;
1636                 }
1637                 switch(cmd)
1638                 {
1639                         case "no":
1640                                 op = OP_MAX;
1641                                 val = 0;
1642                                 continue;
1643                         case "max":
1644                                 op = OP_MAX;
1645                                 continue;
1646                         case "min":
1647                                 op = OP_MIN;
1648                                 continue;
1649                         case "plus":
1650                                 op = OP_PLUS;
1651                                 continue;
1652                         case "minus":
1653                                 op = OP_MINUS;
1654                                 continue;
1655                         case "ALL":
1656                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1657                                 got += GiveValue(e, strength_finished, op, time);
1658                                 got += GiveValue(e, invincible_finished, op, time);
1659                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1660                         case "all":
1661                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1662                                 got += GiveValue(e, health, op, val);
1663                                 got += GiveValue(e, armorvalue, op, val);
1664                         case "allweapons":
1665                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1666                                 {
1667                                         wi = get_weaponinfo(j);
1668                                         if(wi.weapons)
1669                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1670                                 }
1671                         case "allammo":
1672                                 got += GiveValue(e, ammo_cells, op, val);
1673                                 got += GiveValue(e, ammo_shells, op, val);
1674                                 got += GiveValue(e, ammo_nails, op, val);
1675                                 got += GiveValue(e, ammo_rockets, op, val);
1676                                 got += GiveValue(e, ammo_fuel, op, val);
1677                                 break;
1678                         case "unlimited_ammo":
1679                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1680                                 break;
1681                         case "unlimited_weapon_ammo":
1682                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1683                                 break;
1684                         case "unlimited_superweapons":
1685                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1686                                 break;
1687                         case "jetpack":
1688                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1689                                 break;
1690                         case "fuel_regen":
1691                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1692                                 break;
1693                         case "strength":
1694                                 got += GiveValue(e, strength_finished, op, val);
1695                                 break;
1696                         case "invincible":
1697                                 got += GiveValue(e, invincible_finished, op, val);
1698                                 break;
1699                         case "cells":
1700                                 got += GiveValue(e, ammo_cells, op, val);
1701                                 break;
1702                         case "shells":
1703                                 got += GiveValue(e, ammo_shells, op, val);
1704                                 break;
1705                         case "nails":
1706                         case "bullets":
1707                                 got += GiveValue(e, ammo_nails, op, val);
1708                                 break;
1709                         case "rockets":
1710                                 got += GiveValue(e, ammo_rockets, op, val);
1711                                 break;
1712                         case "health":
1713                                 got += GiveValue(e, health, op, val);
1714                                 break;
1715                         case "armor":
1716                                 got += GiveValue(e, armorvalue, op, val);
1717                                 break;
1718                         case "fuel":
1719                                 got += GiveValue(e, ammo_fuel, op, val);
1720                                 break;
1721                         default:
1722                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1723                                 {
1724                                         wi = get_weaponinfo(j);
1725                                         if(cmd == wi.netname)
1726                                         {
1727                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1728                                                 break;
1729                                         }
1730                                 }
1731                                 if(j > WEP_LAST)
1732                                         print("give: invalid item ", cmd, "\n");
1733                                 break;
1734                 }
1735                 val = 999;
1736                 op = OP_SET;
1737         }
1738
1739         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1740         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1741         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1742         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1743         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1744         {
1745                 wi = get_weaponinfo(j);
1746                 if(wi.weapons)
1747                 {
1748                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1749                         if not(save_weapons & wi.weapons)
1750                                 if(e.weapons & wi.weapons)
1751                                         weapon_action(wi.weapon, WR_PRECACHE);
1752                 }
1753         }
1754         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1755         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1756         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1757         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1758         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1759         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1760         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1761         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1762         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1763
1764         if (g_minstagib)
1765         {
1766                 e.health = bound(0, e.health, 100);
1767                 e.armorvalue = bound(0, e.armorvalue, 999);
1768         }
1769
1770         if(e.strength_finished <= 0)
1771                 e.strength_finished = 0;
1772         else
1773                 e.strength_finished += time;
1774         if(e.invincible_finished <= 0)
1775                 e.invincible_finished = 0;
1776         else
1777                 e.invincible_finished += time;
1778
1779         if not(e.weapons & W_WeaponBit(e.switchweapon))
1780                 _switchweapon = TRUE;
1781         if(_switchweapon)
1782                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1783
1784         return got;
1785 }