qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &~= ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271
 272 float have_pickup_item(void)
 273 {
 274         // minstagib: only allow filtered items
 275         if(g_minstagib)
 276                 if(self.classname != "minstagib")
 277                         return FALSE;
 278
 279         if(self.flags & FL_POWERUP)
 280         {
 281                 if(autocvar_g_powerups > 0)
 282                         return TRUE;
 283                 if(autocvar_g_powerups == 0)
 284                         return FALSE;
 285                 if(g_ca)
 286                         return FALSE;
 287                 if(g_arena)
 288                         return FALSE;
 289         }
 290         else
 291         {
 292                 if(autocvar_g_pickup_items > 0)
 293                         return TRUE;
 294                 if(autocvar_g_pickup_items == 0)
 295                         return FALSE;
 296                 if(g_ca)
 297                         return FALSE;
 298                 if(g_weaponarena)
 299                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
 300                                 return FALSE;
 301         }
 302         return TRUE;
 303 }
 304
 305 #define ITEM_RESPAWN_TICKS 10
 306
 307 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 308         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 309 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 310         // range: 10 .. respawntime + respawntimejitter
 311
 312 floatfield Item_CounterField(float it)
 313 {
 314         switch(it)
 315         {
 316                 case IT_SHELLS:      return ammo_shells;
 317                 case IT_NAILS:       return ammo_nails;
 318                 case IT_ROCKETS:     return ammo_rockets;
 319                 case IT_CELLS:       return ammo_cells;
 320                 case IT_FUEL:        return ammo_fuel;
 321                 case IT_5HP:         return health;
 322                 case IT_25HP:        return health;
 323                 case IT_HEALTH:      return health;
 324                 case IT_ARMOR_SHARD: return armorvalue;
 325                 case IT_ARMOR:       return armorvalue;
 326                 // add more things here (health, armor)
 327                 default:             error("requested item has no counter field");
 328         }
 329 #ifdef GMQCC
 330         // should never happen
 331         return health;
 332 #endif
 333 }
 334
 335 string Item_CounterFieldName(float it)
 336 {
 337         switch(it)
 338         {
 339                 case IT_SHELLS:      return "shells";
 340                 case IT_NAILS:       return "nails";
 341                 case IT_ROCKETS:     return "rockets";
 342                 case IT_CELLS:       return "cells";
 343                 case IT_FUEL:        return "fuel";
 344
 345                 // add more things here (health, armor)
 346                 default:             error("requested item has no counter field name");
 347         }
 348 #ifdef GMQCC
 349         // should never happen
 350         return string_null;
 351 #endif
 352 }
 353
 354 .float max_armorvalue;
 355 .float pickup_anyway;
 356 /*
 357 float Item_Customize()
 358 {
 359         if(self.spawnshieldtime)
 360                 return TRUE;
 361         if(!WEPSET_CONTAINS_ALL_EE(other, self))
 362         {
 363                 self.colormod = '0 0 0';
 364                 self.glowmod = self.colormod;
 365                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 366                 return TRUE;
 367         }
 368         else
 369         {
 370                 if(g_ghost_items)
 371                 {
 372                         self.colormod = stov(autocvar_g_ghost_items_color);
 373                         self.glowmod = self.colormod;
 374                         self.alpha = g_ghost_items;
 375                         return TRUE;
 376                 }
 377                 else
 378                         return FALSE;
 379         }
 380 }
 381 */
 382
 383 void Item_Show (entity e, float mode)
 384 {
 385         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 386         e.ItemStatus &~= ITS_STAYWEP;
 387         if (mode > 0)
 388         {
 389                 // make the item look normal, and be touchable
 390                 e.model = e.mdl;
 391                 e.solid = SOLID_TRIGGER;
 392                 e.spawnshieldtime = 1;
 393                 e.ItemStatus |= ITS_AVAILABLE;
 394         }
 395         else if (mode < 0)
 396         {
 397                 // hide the item completely
 398                 e.model = string_null;
 399                 e.solid = SOLID_NOT;
 400                 e.spawnshieldtime = 1;
 401                 e.ItemStatus &~= ITS_AVAILABLE;
 402         }
 403         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 404         {
 405                 // make the item translucent and not touchable
 406                 e.model = e.mdl;
 407                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 408                 e.effects |= EF_STARDUST;
 409                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 410                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 411         }
 412         else
 413         {
 414                 //setmodel(e, "null");
 415                 e.solid = SOLID_NOT;
 416                 e.colormod = '0 0 0';
 417                 e.glowmod = e.colormod;
 418                 e.spawnshieldtime = 1;
 419                 e.ItemStatus &~= ITS_AVAILABLE;
 420         }
 421
 422         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 423             e.ItemStatus |= ITS_POWERUP;
 424
 425         if (autocvar_g_nodepthtestitems)
 426                 e.effects |= EF_NODEPTHTEST;
 427
 428
 429     if (autocvar_g_fullbrightitems)
 430                 e.ItemStatus |= ITS_ALLOWFB;
 431
 432         if (autocvar_sv_simple_items)
 433         e.ItemStatus |= ITS_ALLOWSI;
 434
 435         // relink entity (because solid may have changed)
 436         setorigin(e, e.origin);
 437     e.SendFlags |= ISF_STATUS;
 438 }
 439
 440 void Item_Respawn (void)
 441 {
 442         Item_Show(self, 1);
 443         if(!g_minstagib && self.items == IT_STRENGTH)
 444                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 445         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 446                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 447         else
 448                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 449         setorigin (self, self.origin);
 450
 451         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 452         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 453 }
 454
 455 void Item_RespawnCountdown (void)
 456 {
 457         if(self.count >= ITEM_RESPAWN_TICKS)
 458         {
 459                 if(self.waypointsprite_attached)
 460                         WaypointSprite_Kill(self.waypointsprite_attached);
 461                 Item_Respawn();
 462         }
 463         else
 464         {
 465                 self.nextthink = time + 1;
 466                 self.count += 1;
 467                 if(self.count == 1)
 468                 {
 469                         string name;
 470                         vector rgb = '1 0 1';
 471                         name = string_null;
 472                         if(g_minstagib)
 473                         {
 474                                 switch(self.items)
 475                                 {
 476                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 477                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 478                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 479                                 }
 480                         }
 481                         else
 482                         {
 483                                 switch(self.items)
 484                                 {
 485                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 486                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 487                                 }
 488                         }
 489                         switch(self.items)
 490                         {
 491                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 492                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 493                         }
 494                         if(self.flags & FL_WEAPON)
 495                         {
 496                                 entity wi = get_weaponinfo(self.weapon);
 497                                 if(wi)
 498                                 {
 499                                         name = wi.model2;
 500                                         rgb = '1 0 0';
 501                                 }
 502                         }
 503                         if(name)
 504                         {
 505                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 506                                 if(self.waypointsprite_attached)
 507                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 508                         }
 509                         else
 510                         {
 511                                 print("Unknown powerup-marked item is wanting to respawn\n");
 512                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 513                         }
 514                 }
 515                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 516                 if(self.waypointsprite_attached)
 517                 {
 518                         WaypointSprite_Ping(self.waypointsprite_attached);
 519                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 520                 }
 521         }
 522 }
 523
 524 void Item_ScheduleRespawnIn(entity e, float t)
 525 {
 526         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 527         {
 528                 e.think = Item_RespawnCountdown;
 529                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 530                 e.count = 0;
 531         }
 532         else
 533         {
 534                 e.think = Item_Respawn;
 535                 e.nextthink = time + t;
 536         }
 537 }
 538
 539 void Item_ScheduleRespawn(entity e)
 540 {
 541         if(e.respawntime > 0)
 542         {
 543                 Item_Show(e, 0);
 544                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 545         }
 546         else // if respawntime is -1, this item does not respawn
 547                 Item_Show(e, -1);
 548 }
 549
 550 void Item_ScheduleInitialRespawn(entity e)
 551 {
 552         Item_Show(e, 0);
 553         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 554 }
 555
 556 float ITEM_MODE_NONE = 0;
 557 float ITEM_MODE_HEALTH = 1;
 558 float ITEM_MODE_ARMOR = 2;
 559 float ITEM_MODE_FUEL = 3;
 560 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 561 {
 562         if (!item.ammofield)
 563                 return FALSE;
 564
 565         if (item.spawnshieldtime)
 566         {
 567                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 568                 {
 569                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 570                         goto YEAH;
 571                 }
 572         }
 573         else if(g_weapon_stay == 2)
 574         {
 575                 float mi = min(item.ammofield, ammomax);
 576                 if (player.ammofield < mi)
 577                 {
 578                         player.ammofield = mi;
 579                         goto YEAH;
 580                 }
 581         }
 582
 583         return FALSE;
 584
 585 :YEAH
 586         switch(mode)
 587         {
 588                 case ITEM_MODE_FUEL:
 589                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 590                         break;
 591                 case ITEM_MODE_HEALTH:
 592                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 593                         break;
 594                 case ITEM_MODE_ARMOR:
 595                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 596                         break;
 597                 default:
 598                         break;
 599         }
 600         return TRUE;
 601 }
 602
 603 float Item_GiveTo(entity item, entity player)
 604 {
 605         float _switchweapon;
 606         float pickedup;
 607         float it;
 608         float i;
 609
 610         // if nothing happens to player, just return without taking the item
 611         pickedup = FALSE;
 612         _switchweapon = FALSE;
 613
 614         if (g_minstagib)
 615         {
 616                 float prevcells = player.ammo_cells;
 617
 618                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 619                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 620
 621                 if(player.ammo_cells > prevcells)
 622                 {
 623                         _switchweapon = TRUE;
 624
 625                         // play some cool sounds ;)
 626                         if (clienttype(player) == CLIENTTYPE_REAL)
 627                         {
 628                                 if(player.health <= 5)
 629                                         Send_Notification(NOTIF_ONE, player, MSG_ANNCE, ANNCE_MINSTAGIB_LASTSECOND);
 630                                 else if(player.health < 50)
 631                                         Send_Notification(NOTIF_ONE, player, MSG_ANNCE, ANNCE_MINSTAGIB_NARROWLY);
 632                         }
 633                         // sound not available
 634                         // else if(item.items == IT_CELLS)
 635                         //      AnnounceTo(player, "ammo");
 636
 637                         if (WEPSET_CONTAINS_EW(item, WEP_MINSTANEX))
 638                                 W_GiveWeapon (player, WEP_MINSTANEX);
 639                         player.health = 100;
 640                 }
 641
 642                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 643                 {
 644                         pickedup = TRUE;
 645                         player.items |= it;
 646                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 647                 }
 648
 649                 // extralife powerup
 650                 if (item.max_health)
 651                 {
 652                         pickedup = TRUE;
 653                         // sound not available
 654                         // AnnounceTo(player, "_lives");
 655                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 656                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_EXTRALIVES);
 657                 }
 658
 659                 // invis powerup
 660                 if (item.strength_finished)
 661                 {
 662                         pickedup = TRUE;
 663                         // sound not available
 664                         // AnnounceTo(player, "invisible");
 665                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 666                 }
 667
 668                 // speed powerup
 669                 if (item.invincible_finished)
 670                 {
 671                         pickedup = TRUE;
 672                         // sound not available
 673                         // AnnounceTo(player, "speed");
 674                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 675                 }
 676         }
 677         else
 678         {
 679                 // in case the player has autoswitch enabled do the following:
 680                 // if the player is using their best weapon before items are given, they
 681                 // probably want to switch to an even better weapon after items are given
 682                 if (player.autoswitch)
 683                 if (player.switchweapon == w_getbestweapon(player))
 684                         _switchweapon = TRUE;
 685
 686                 if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 687                         _switchweapon = TRUE;
 688
 689                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 690                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 691                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 692                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 693                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 694                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 695                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 696
 697                 if (item.flags & FL_WEAPON)
 698                 {
 699                         WEPSET_DECLARE_A(it);
 700                         WEPSET_COPY_AE(it, item);
 701                         WEPSET_ANDNOT_AE(it, player);
 702
 703                         if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 704                         {
 705                                 pickedup = TRUE;
 706                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 707                                         if(WEPSET_CONTAINS_AW(it, i))
 708                                                 W_GiveWeapon(player, i);
 709                         }
 710                 }
 711
 712                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 713                 {
 714                         pickedup = TRUE;
 715                         player.items |= it;
 716                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 717                 }
 718
 719                 if (item.strength_finished)
 720                 {
 721                         pickedup = TRUE;
 722                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 723                 }
 724                 if (item.invincible_finished)
 725                 {
 726                         pickedup = TRUE;
 727                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 728                 }
 729                 if (item.superweapons_finished)
 730                 {
 731                         pickedup = TRUE;
 732                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 733                 }
 734         }
 735
 736 :skip
 737         // always eat teamed entities
 738         if(item.team)
 739                 pickedup = TRUE;
 740
 741         if (!pickedup)
 742                 return 0;
 743
 744         if (_switchweapon)
 745                 if (player.switchweapon != w_getbestweapon(player))
 746                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 747
 748         return 1;
 749 }
 750
 751 void Item_Touch (void)
 752 {
 753         entity e, head;
 754
 755         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 756         if(self.classname == "droppedweapon")
 757         {
 758                 if (ITEM_TOUCH_NEEDKILL())
 759                 {
 760                         remove(self);
 761                         return;
 762                 }
 763         }
 764
 765         if (other.classname != "player")
 766                 return;
 767         if (other.deadflag)
 768                 return;
 769         if (self.solid != SOLID_TRIGGER)
 770                 return;
 771         if (self.owner == other)
 772                 return;
 773         if(MUTATOR_CALLHOOK(ItemTouch))
 774                 return;
 775
 776         if (self.classname == "droppedweapon")
 777         {
 778                 self.strength_finished = max(0, self.strength_finished - time);
 779                 self.invincible_finished = max(0, self.invincible_finished - time);
 780                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 781         }
 782
 783         if(!Item_GiveTo(self, other))
 784         {
 785                 if (self.classname == "droppedweapon")
 786                 {
 787                         // undo what we did above
 788                         self.strength_finished += time;
 789                         self.invincible_finished += time;
 790                         self.superweapons_finished += time;
 791                 }
 792                 return;
 793         }
 794
 795         other.last_pickup = time;
 796
 797         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 798         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 799
 800         if (self.classname == "droppedweapon")
 801                 remove (self);
 802         else if not(self.spawnshieldtime)
 803                 return;
 804         else
 805         {
 806                 if(self.team)
 807                 {
 808                         RandomSelection_Init();
 809                         for(head = world; (head = findfloat(head, team, self.team)); )
 810                         {
 811                                 if(head.flags & FL_ITEM)
 812                                 {
 813                                         Item_Show(head, -1);
 814                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 815                                 }
 816                         }
 817                         e = RandomSelection_chosen_ent;
 818
 819                 }
 820                 else
 821                         e = self;
 822                 Item_ScheduleRespawn(e);
 823         }
 824 }
 825
 826 void Item_Reset()
 827 {
 828         Item_Show(self, !self.state);
 829         setorigin (self, self.origin);
 830
 831         if(self.classname != "droppedweapon")
 832         {
 833                 self.think = func_null;
 834                 self.nextthink = 0;
 835
 836                 if(self.waypointsprite_attached)
 837                         WaypointSprite_Kill(self.waypointsprite_attached);
 838
 839                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 840                         Item_ScheduleInitialRespawn(self);
 841         }
 842 }
 843
 844 void Item_FindTeam()
 845 {
 846         entity head, e;
 847
 848         if(self.effects & EF_NODRAW)
 849         {
 850                 // marker for item team search
 851                 dprint("Initializing item team ", ftos(self.team), "\n");
 852                 RandomSelection_Init();
 853                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 854                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 855                 e = RandomSelection_chosen_ent;
 856                 e.state = 0;
 857                 Item_Show(e, 1);
 858
 859                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 860                 {
 861                         if(head != e)
 862                         {
 863                                 // make it a non-spawned item
 864                                 Item_Show(head, -1);
 865                                 head.state = 1; // state 1 = initially hidden item
 866                         }
 867                         head.effects &~= EF_NODRAW;
 868                 }
 869
 870                 Item_Reset();
 871         }
 872 }
 873
 874 // Savage: used for item garbage-collection
 875 // TODO: perhaps nice special effect?
 876 void RemoveItem(void)
 877 {
 878         remove(self);
 879 }
 880
 881 // pickup evaluation functions
 882 // these functions decide how desirable an item is to the bots
 883
 884 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 885
 886 float weapon_pickupevalfunc(entity player, entity item)
 887 {
 888         float c, j, position;
 889
 890         // See if I have it already
 891         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 892         {
 893                 // If I can pick it up
 894                 if(!item.spawnshieldtime)
 895                         c = 0;
 896                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 897                 {
 898                         // Skilled bots will grab more
 899                         c = bound(0, skill / 10, 1) * 0.5;
 900                 }
 901                 else
 902                         c = 0;
 903         }
 904         else
 905                 c = 1;
 906
 907         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 908         if( bot_custom_weapon && c )
 909         {
 910                 // Find the highest position on any range
 911                 position = -1;
 912                 for(j = 0; j < WEP_LAST ; ++j){
 913                         if(
 914                                         bot_weapons_far[j] == item.weapon ||
 915                                         bot_weapons_mid[j] == item.weapon ||
 916                                         bot_weapons_close[j] == item.weapon
 917                           )
 918                         {
 919                                 position = j;
 920                                 break;
 921                         }
 922                 }
 923
 924                 // Rate it
 925                 if (position >= 0 )
 926                 {
 927                         position = WEP_LAST - position;
 928                         // item.bot_pickupbasevalue is overwritten here
 929                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 930                 }
 931         }
 932
 933         return item.bot_pickupbasevalue * c;
 934 }
 935
 936 float commodity_pickupevalfunc(entity player, entity item)
 937 {
 938         float c, i;
 939         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 940         entity wi;
 941         c = 0;
 942
 943         // Detect needed ammo
 944         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 945         {
 946                 wi = get_weaponinfo(i);
 947
 948                 if not(WEPSET_CONTAINS_EW(player, i))
 949                         continue;
 950
 951                 if(wi.items & IT_SHELLS)
 952                         need_shells = TRUE;
 953                 else if(wi.items & IT_NAILS)
 954                         need_nails = TRUE;
 955                 else if(wi.items & IT_ROCKETS)
 956                         need_rockets = TRUE;
 957                 else if(wi.items & IT_CELLS)
 958                         need_cells = TRUE;
 959                 else if(wi.items & IT_FUEL)
 960                         need_cells = TRUE;
 961         }
 962
 963         // TODO: figure out if the player even has the weapon this ammo is for?
 964         // may not affect strategy much though...
 965         // find out how much more ammo/armor/health the player can hold
 966         if (need_shells)
 967         if (item.ammo_shells)
 968         if (player.ammo_shells < g_pickup_shells_max)
 969                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 970         if (need_nails)
 971         if (item.ammo_nails)
 972         if (player.ammo_nails < g_pickup_nails_max)
 973                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 974         if (need_rockets)
 975         if (item.ammo_rockets)
 976         if (player.ammo_rockets < g_pickup_rockets_max)
 977                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 978         if (need_cells)
 979         if (item.ammo_cells)
 980         if (player.ammo_cells < g_pickup_cells_max)
 981                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 982         if (need_fuel)
 983         if (item.ammo_fuel)
 984         if (player.ammo_fuel < g_pickup_fuel_max)
 985                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 986         if (item.armorvalue)
 987         if (player.armorvalue < item.max_armorvalue)
 988                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 989         if (item.health)
 990         if (player.health < item.max_health)
 991                 c = c + max(0, 1 - player.health / item.max_health);
 992
 993         return item.bot_pickupbasevalue * c;
 994 }
 995
 996 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 997 {
 998         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 999                 RemoveItem();
1000 }
1001
1002 .float is_item;
1003 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
1004 {
1005         startitem_failed = FALSE;
1006
1007         if(self.model == "")
1008                 self.model = itemmodel;
1009
1010         if(self.model == "")
1011     {
1012         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
1013         return;
1014     }
1015
1016         if(self.item_pickupsound == "")
1017                 self.item_pickupsound = pickupsound;
1018
1019         if(!self.respawntime) // both need to be set
1020         {
1021                 self.respawntime = defaultrespawntime;
1022                 self.respawntimejitter = defaultrespawntimejitter;
1023         }
1024
1025         self.items = itemid;
1026         self.weapon = weaponid;
1027
1028         if(weaponid)
1029                 WEPSET_COPY_EW(self, weaponid);
1030
1031         self.flags = FL_ITEM | itemflags;
1032
1033         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
1034         {
1035                 startitem_failed = TRUE;
1036                 remove(self);
1037                 return;
1038         }
1039
1040         // is it a dropped weapon?
1041         if (self.classname == "droppedweapon")
1042         {
1043                 self.reset = SUB_Remove;
1044                 // it's a dropped weapon
1045                 self.movetype = MOVETYPE_TOSS;
1046
1047                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1048                 self.think = RemoveItem;
1049                 self.nextthink = time + 20;
1050
1051                 self.takedamage = DAMAGE_YES;
1052                 self.event_damage = Item_Damage;
1053
1054                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1055                 /*
1056                 if(self.items == 0)
1057                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
1058                 if(self.ammo_nails == 0)
1059                 if(self.ammo_cells == 0)
1060                 if(self.ammo_rockets == 0)
1061                 if(self.ammo_shells == 0)
1062                 if(self.ammo_fuel == 0)
1063                 if(self.health == 0)
1064                 if(self.armorvalue == 0)
1065                 */
1066                 {
1067                         // if item is worthless after a timer, have it expire then
1068                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1069                 }
1070
1071                 // don't drop if in a NODROP zone (such as lava)
1072                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1073                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1074                 {
1075                         startitem_failed = TRUE;
1076                         remove(self);
1077                         return;
1078                 }
1079         }
1080         else
1081         {
1082                 if(!have_pickup_item())
1083                 {
1084                         startitem_failed = TRUE;
1085                         remove (self);
1086                         return;
1087                 }
1088
1089                 if(self.angles != '0 0 0')
1090             self.SendFlags |= ISF_ANGLES;
1091
1092                 self.reset = Item_Reset;
1093                 // it's a level item
1094                 if(self.spawnflags & 1)
1095                         self.noalign = 1;
1096                 if (self.noalign)
1097                         self.movetype = MOVETYPE_NONE;
1098                 else
1099                         self.movetype = MOVETYPE_TOSS;
1100                 // do item filtering according to game mode and other things
1101                 if (!self.noalign)
1102                 {
1103                         // first nudge it off the floor a little bit to avoid math errors
1104                         setorigin(self, self.origin + '0 0 1');
1105                         // set item size before we spawn a spawnfunc_waypoint
1106                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1107                                 setsize (self, '-16 -16 0', '16 16 48');
1108                         else
1109                                 setsize (self, '-16 -16 0', '16 16 32');
1110                         // note droptofloor returns FALSE if stuck/or would fall too far
1111                         droptofloor();
1112                         waypoint_spawnforitem(self);
1113                 }
1114
1115                 /*
1116                  * can't do it that way, as it would break maps
1117                  * TODO make a target_give like entity another way, that perhaps has
1118                  * the weapon name in a key
1119                 if(self.targetname)
1120                 {
1121                         // target_give not yet supported; maybe later
1122                         print("removed targeted ", self.classname, "\n");
1123                         startitem_failed = TRUE;
1124                         remove (self);
1125                         return;
1126                 }
1127                 */
1128
1129                 if(autocvar_spawn_debug >= 2)
1130                 {
1131                         entity otheritem;
1132                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1133                         {
1134                             // why not flags & fl_item?
1135                                 if(otheritem.is_item)
1136                                 {
1137                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1138                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1139                                         error("Mapper sucks.");
1140                                 }
1141                         }
1142                         self.is_item = TRUE;
1143                 }
1144
1145                 WEPSET_OR_AW(weaponsInMap, weaponid);
1146
1147                 precache_model (self.model);
1148                 precache_sound (self.item_pickupsound);
1149
1150                 precache_sound ("misc/itemrespawncountdown.wav");
1151                 if(!g_minstagib && itemid == IT_STRENGTH)
1152                         precache_sound ("misc/strength_respawn.wav");
1153                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
1154                         precache_sound ("misc/shield_respawn.wav");
1155                 else
1156                         precache_sound ("misc/itemrespawn.wav");
1157
1158                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1159                         self.target = "###item###"; // for finding the nearest item using find()
1160         }
1161
1162         self.bot_pickup = TRUE;
1163         self.bot_pickupevalfunc = pickupevalfunc;
1164         self.bot_pickupbasevalue = pickupbasevalue;
1165         self.mdl = self.model;
1166         self.netname = itemname;
1167         self.touch = Item_Touch;
1168         setmodel(self, "null"); // precision set below
1169         //self.effects |= EF_LOWPRECISION;
1170
1171         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1172     {
1173         self.pos1 = '-16 -16 0';
1174         self.pos2 = '16 16 48';
1175     }
1176         else
1177     {
1178         self.pos1 = '-16 -16 0';
1179         self.pos2 = '16 16 32';
1180     }
1181     setsize (self, self.pos1, self.pos2);
1182
1183     if(itemflags & FL_POWERUP)
1184         self.ItemStatus |= ITS_ANIMATE1;
1185
1186         if(self.armorvalue || self.health)
1187         self.ItemStatus |= ITS_ANIMATE2;
1188
1189         if(itemflags & FL_WEAPON)
1190         {
1191                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1192             self.colormap = 1024; // color shirt=0 pants=0 grey
1193         else
1194             self.gravity = 1;
1195
1196                 self.ItemStatus |= ITS_ANIMATE1;
1197                 self.ItemStatus |= ISF_COLORMAP;
1198         }
1199
1200         self.state = 0;
1201         if(self.team) // broken, no idea why.
1202         {
1203                 if(!self.cnt)
1204                         self.cnt = 1; // item probability weight
1205
1206                 self.effects |= EF_NODRAW; // marker for item team search
1207                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1208         }
1209         else
1210                 Item_Reset();
1211
1212     Net_LinkEntity(self, FALSE, 0, ItemSend);
1213
1214         // call this hook after everything else has been done
1215         if(MUTATOR_CALLHOOK(Item_Spawn))
1216         {
1217                 startitem_failed = TRUE;
1218                 remove(self);
1219                 return;
1220         }
1221 }
1222
1223 /* replace items in minstagib
1224  * IT_STRENGTH   = invisibility
1225  * IT_NAILS      = extra lives
1226  * IT_INVINCIBLE = speed
1227  */
1228 void minstagib_items (float itemid) // will be deleted soon.
1229 {
1230         float rnd;
1231         self.classname = "minstagib"; // ...?
1232
1233         // replace rocket launchers and nex guns with ammo cells
1234         if (itemid == IT_CELLS)
1235         {
1236                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1237                 StartItem ("models/items/a_cells.md3",
1238                         "misc/itempickup.wav", 45, 0,
1239                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
1240                 return;
1241         }
1242
1243         // randomize
1244         rnd = random() * 3;
1245         if (rnd <= 1)
1246                 itemid = IT_STRENGTH;
1247         else if (rnd <= 2)
1248                 itemid = IT_NAILS;
1249         else
1250                 itemid = IT_INVINCIBLE;
1251
1252         // replace with invis
1253         if (itemid == IT_STRENGTH)
1254         {
1255                 if(!self.strength_finished)
1256                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1257                 StartItem ("models/items/g_strength.md3",
1258                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1259                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
1260         }
1261         // replace with extra lives
1262         if (itemid == IT_NAILS)
1263         {
1264                 self.max_health = 1;
1265                 StartItem ("models/items/g_h100.md3",
1266                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1267                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1268         }
1269         // replace with speed
1270         if (itemid == IT_INVINCIBLE)
1271         {
1272                 if(!self.invincible_finished)
1273                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1274                 StartItem ("models/items/g_invincible.md3",
1275                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1276                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
1277         }
1278 }
1279
1280 float minst_no_auto_cells;
1281 void minst_remove_item (void) {
1282         if(minst_no_auto_cells)
1283                 remove(self);
1284 }
1285
1286 float weaponswapping;
1287 float internalteam;
1288
1289 void weapon_defaultspawnfunc(float wpn)
1290 {
1291         entity e;
1292         float t;
1293         var .float ammofield;
1294         string s;
1295         entity oldself;
1296         float i, j;
1297         float f;
1298
1299         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1300         {
1301                 e = get_weaponinfo(wpn);
1302
1303                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1304                 {
1305                         print("Attempted to spawn a mutator-blocked weapon; these guns will in the future require a mutator\n");
1306                         /*
1307                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1308                         startitem_failed = TRUE;
1309                         return;
1310                         */
1311                 }
1312
1313                 s = W_Apply_Weaponreplace(e.netname);
1314                 ret_string = s;
1315                 other = e;
1316                 MUTATOR_CALLHOOK(SetWeaponreplace);
1317                 s = ret_string;
1318                 if(s == "")
1319                 {
1320                         remove(self);
1321                         startitem_failed = TRUE;
1322                         return;
1323                 }
1324                 t = tokenize_console(s);
1325                 if(t >= 2)
1326                 {
1327                         self.team = --internalteam;
1328                         oldself = self;
1329                         for(i = 1; i < t; ++i)
1330                         {
1331                                 s = argv(i);
1332                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1333                                 {
1334                                         e = get_weaponinfo(j);
1335                                         if(e.netname == s)
1336                                         {
1337                                                 self = spawn();
1338                                                 copyentity(oldself, self);
1339                                                 self.classname = "replacedweapon";
1340                                                 weapon_defaultspawnfunc(j);
1341                                                 break;
1342                                         }
1343                                 }
1344                                 if(j > WEP_LAST)
1345                                 {
1346                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1347                                 }
1348                         }
1349                         self = oldself;
1350                 }
1351                 if(t >= 1) // always the case!
1352                 {
1353                         s = argv(0);
1354                         wpn = 0;
1355                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1356                         {
1357                                 e = get_weaponinfo(j);
1358                                 if(e.netname == s)
1359                                 {
1360                                         wpn = j;
1361                                         break;
1362                                 }
1363                         }
1364                         if(j > WEP_LAST)
1365                         {
1366                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1367                         }
1368                 }
1369                 if(wpn == 0)
1370                 {
1371                         remove(self);
1372                         startitem_failed = TRUE;
1373                         return;
1374                 }
1375         }
1376
1377         e = get_weaponinfo(wpn);
1378
1379         if(!self.respawntime)
1380         {
1381                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1382                 {
1383                         self.respawntime = g_pickup_respawntime_superweapon;
1384                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1385                 }
1386                 else
1387                 {
1388                         self.respawntime = g_pickup_respawntime_weapon;
1389                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1390                 }
1391         }
1392
1393         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1394                 if(!self.superweapons_finished)
1395                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1396
1397         if(e.items)
1398         {
1399                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1400                 {
1401                         if(e.items & j)
1402                         {
1403                                 ammofield = Item_CounterField(j);
1404                                 if(!self.ammofield)
1405                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1406                         }
1407                 }
1408         }
1409
1410         // pickup anyway
1411         if(g_pickup_weapons_anyway)
1412                 self.pickup_anyway = TRUE;
1413
1414         f = FL_WEAPON;
1415
1416         // no weapon-stay on superweapons
1417         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1418                 f |= FL_NO_WEAPON_STAY;
1419
1420         // weapon stay isn't supported for teamed weapons
1421         if(self.team)
1422                 f |= FL_NO_WEAPON_STAY;
1423
1424         // stupid minstagib hack, don't ask
1425         if(g_minstagib)
1426                 if(self.ammo_cells)
1427                         self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1428
1429         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1430         if (self.modelindex) // don't precache if self was removed
1431                 weapon_action(e.weapon, WR_PRECACHE);
1432 }
1433
1434 void spawnfunc_weapon_shotgun (void);
1435 void spawnfunc_weapon_uzi (void) {
1436         if(autocvar_sv_q3acompat_machineshotgunswap)
1437         if(self.classname != "droppedweapon")
1438         {
1439                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1440                 return;
1441         }
1442         weapon_defaultspawnfunc(WEP_UZI);
1443 }
1444
1445 void spawnfunc_weapon_shotgun (void) {
1446         if(autocvar_sv_q3acompat_machineshotgunswap)
1447         if(self.classname != "droppedweapon")
1448         {
1449                 weapon_defaultspawnfunc(WEP_UZI);
1450                 return;
1451         }
1452         weapon_defaultspawnfunc(WEP_SHOTGUN);
1453 }
1454
1455 void spawnfunc_weapon_nex (void)
1456 {
1457         if (g_minstagib)
1458         {
1459                 minstagib_items(IT_CELLS);
1460                 self.think = minst_remove_item;
1461                 self.nextthink = time;
1462                 return;
1463         }
1464         weapon_defaultspawnfunc(WEP_NEX);
1465 }
1466
1467 void spawnfunc_weapon_minstanex (void)
1468 {
1469         if (g_minstagib)
1470         {
1471                 minstagib_items(IT_CELLS);
1472                 self.think = minst_remove_item;
1473                 self.nextthink = time;
1474                 return;
1475         }
1476         weapon_defaultspawnfunc(WEP_MINSTANEX);
1477 }
1478
1479 void spawnfunc_weapon_rocketlauncher (void)
1480 {
1481         if (g_minstagib)
1482         {
1483                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1484                 self.think = minst_remove_item;
1485                 self.nextthink = time;
1486                 return;
1487         }
1488         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1489 }
1490
1491 void spawnfunc_item_rockets (void) {
1492         if(!self.ammo_rockets)
1493                 self.ammo_rockets = g_pickup_rockets;
1494         if(!self.pickup_anyway)
1495                 self.pickup_anyway = g_pickup_ammo_anyway;
1496         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1497 }
1498
1499 void spawnfunc_item_shells (void);
1500 void spawnfunc_item_bullets (void) {
1501         if(!weaponswapping)
1502         if(autocvar_sv_q3acompat_machineshotgunswap)
1503         if(self.classname != "droppedweapon")
1504         {
1505                 weaponswapping = TRUE;
1506                 spawnfunc_item_shells();
1507                 weaponswapping = FALSE;
1508                 return;
1509         }
1510
1511         if(!self.ammo_nails)
1512                 self.ammo_nails = g_pickup_nails;
1513         if(!self.pickup_anyway)
1514                 self.pickup_anyway = g_pickup_ammo_anyway;
1515         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1516 }
1517
1518 void spawnfunc_item_cells (void) {
1519         if(!self.ammo_cells)
1520                 self.ammo_cells = g_pickup_cells;
1521         if(!self.pickup_anyway)
1522                 self.pickup_anyway = g_pickup_ammo_anyway;
1523         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1524 }
1525
1526 void spawnfunc_item_shells (void) {
1527         if(!weaponswapping)
1528         if(autocvar_sv_q3acompat_machineshotgunswap)
1529         if(self.classname != "droppedweapon")
1530         {
1531                 weaponswapping = TRUE;
1532                 spawnfunc_item_bullets();
1533                 weaponswapping = FALSE;
1534                 return;
1535         }
1536
1537         if(!self.ammo_shells)
1538                 self.ammo_shells = g_pickup_shells;
1539         if(!self.pickup_anyway)
1540                 self.pickup_anyway = g_pickup_ammo_anyway;
1541         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1542 }
1543
1544 void spawnfunc_item_armor_small (void) {
1545         if(!self.armorvalue)
1546                 self.armorvalue = g_pickup_armorsmall;
1547         if(!self.max_armorvalue)
1548                 self.max_armorvalue = g_pickup_armorsmall_max;
1549         if(!self.pickup_anyway)
1550                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1551         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1552 }
1553
1554 void spawnfunc_item_armor_medium (void) {
1555         if(!self.armorvalue)
1556                 self.armorvalue = g_pickup_armormedium;
1557         if(!self.max_armorvalue)
1558                 self.max_armorvalue = g_pickup_armormedium_max;
1559         if(!self.pickup_anyway)
1560                 self.pickup_anyway = g_pickup_armormedium_anyway;
1561         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1562 }
1563
1564 void spawnfunc_item_armor_big (void) {
1565         if(!self.armorvalue)
1566                 self.armorvalue = g_pickup_armorbig;
1567         if(!self.max_armorvalue)
1568                 self.max_armorvalue = g_pickup_armorbig_max;
1569         if(!self.pickup_anyway)
1570                 self.pickup_anyway = g_pickup_armorbig_anyway;
1571         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1572 }
1573
1574 void spawnfunc_item_armor_large (void) {
1575         if(!self.armorvalue)
1576                 self.armorvalue = g_pickup_armorlarge;
1577         if(!self.max_armorvalue)
1578                 self.max_armorvalue = g_pickup_armorlarge_max;
1579         if(!self.pickup_anyway)
1580                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1581         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1582 }
1583
1584 void spawnfunc_item_health_small (void) {
1585         if(!self.max_health)
1586                 self.max_health = g_pickup_healthsmall_max;
1587         if(!self.health)
1588                 self.health = g_pickup_healthsmall;
1589         if(!self.pickup_anyway)
1590                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1591         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1592 }
1593
1594 void spawnfunc_item_health_medium (void) {
1595         if(!self.max_health)
1596                 self.max_health = g_pickup_healthmedium_max;
1597         if(!self.health)
1598                 self.health = g_pickup_healthmedium;
1599         if(!self.pickup_anyway)
1600                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1601         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1602 }
1603
1604 void spawnfunc_item_health_large (void) {
1605         if(!self.max_health)
1606                 self.max_health = g_pickup_healthlarge_max;
1607         if(!self.health)
1608                 self.health = g_pickup_healthlarge;
1609         if(!self.pickup_anyway)
1610                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1611         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1612 }
1613
1614 void spawnfunc_item_health_mega (void) {
1615         if(g_minstagib) {
1616                 minstagib_items(IT_NAILS);
1617         } else {
1618                 if(!self.max_health)
1619                         self.max_health = g_pickup_healthmega_max;
1620                 if(!self.health)
1621                         self.health = g_pickup_healthmega;
1622                 if(!self.pickup_anyway)
1623                         self.pickup_anyway = g_pickup_healthmega_anyway;
1624                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1625         }
1626 }
1627
1628 // support old misnamed entities
1629 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1630 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1631 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1632 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1633 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1634
1635 void spawnfunc_item_strength (void) {
1636         if(g_minstagib) {
1637                 minstagib_items(IT_STRENGTH);
1638         } else {
1639                 precache_sound("weapons/strength_fire.wav");
1640                 if(!self.strength_finished)
1641                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1642                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1643         }
1644 }
1645
1646 void spawnfunc_item_invincible (void) {
1647         if(g_minstagib) {
1648                 minstagib_items(IT_INVINCIBLE);
1649         } else {
1650                 if(!self.invincible_finished)
1651                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1652                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1653         }
1654 }
1655
1656 void spawnfunc_item_minst_cells (void) {
1657         if (g_minstagib)
1658         {
1659                 minst_no_auto_cells = TRUE;
1660                 minstagib_items(IT_CELLS);
1661         }
1662         else
1663                 remove(self);
1664 }
1665
1666 // compatibility:
1667 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1668
1669 float GiveItems(entity e, float beginarg, float endarg);
1670 void target_items_use (void)
1671 {
1672         if(activator.classname == "droppedweapon")
1673         {
1674                 EXACTTRIGGER_TOUCH;
1675                 remove(activator);
1676                 return;
1677         }
1678
1679         if(activator.classname != "player")
1680                 return;
1681         if(activator.deadflag != DEAD_NO)
1682                 return;
1683         EXACTTRIGGER_TOUCH;
1684
1685         entity e;
1686         for(e = world; (e = find(e, classname, "droppedweapon")); )
1687                 if(e.enemy == activator)
1688                         remove(e);
1689
1690         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1691                 centerprint(activator, self.message);
1692 }
1693
1694 void spawnfunc_target_items (void)
1695 {
1696         float n, i, j;
1697         entity e;
1698
1699         self.use = target_items_use;
1700         if(!self.strength_finished)
1701                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1702         if(!self.invincible_finished)
1703                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1704         if(!self.superweapons_finished)
1705                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1706
1707         precache_sound("misc/itempickup.wav");
1708         precache_sound("misc/megahealth.wav");
1709         precache_sound("misc/armor25.wav");
1710         precache_sound("misc/powerup.wav");
1711         precache_sound("misc/poweroff.wav");
1712         precache_sound("weapons/weaponpickup.wav");
1713
1714         n = tokenize_console(self.netname);
1715         if(argv(0) == "give")
1716         {
1717                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1718         }
1719         else
1720         {
1721                 for(i = 0; i < n; ++i)
1722                 {
1723                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1724                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1725                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1726                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1727                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1728                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1729                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1730                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1731                         else
1732                         {
1733                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1734                                 {
1735                                         e = get_weaponinfo(j);
1736                                         if(argv(i) == e.netname)
1737                                         {
1738                                                 WEPSET_OR_EW(self, j);
1739                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1740                                                         weapon_action(e.weapon, WR_PRECACHE);
1741                                                 break;
1742                                         }
1743                                 }
1744                                 if(j > WEP_LAST)
1745                                         print("target_items: invalid item ", argv(i), "\n");
1746                         }
1747                 }
1748
1749                 string itemprefix, valueprefix;
1750                 if(self.spawnflags == 0)
1751                 {
1752                         itemprefix = "";
1753                         valueprefix = "";
1754                 }
1755                 else if(self.spawnflags == 1)
1756                 {
1757                         itemprefix = "max ";
1758                         valueprefix = "max ";
1759                 }
1760                 else if(self.spawnflags == 2)
1761                 {
1762                         itemprefix = "min ";
1763                         valueprefix = "min ";
1764                 }
1765                 else if(self.spawnflags == 4)
1766                 {
1767                         itemprefix = "minus ";
1768                         valueprefix = "max ";
1769                 }
1770                 else
1771                 {
1772                         error("invalid spawnflags");
1773 #ifdef GMQCC
1774                         itemprefix = string_null;
1775                         valueprefix = string_null;
1776 #endif
1777                 }
1778
1779                 self.netname = "";
1780                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1781                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1782                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1783                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1784                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1785                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1786                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1787                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1788                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1789                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1790                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1791                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1792                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1793                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1794                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1795                 {
1796                         e = get_weaponinfo(j);
1797                         if(e.weapon)
1798                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1799                 }
1800         }
1801         self.netname = strzone(self.netname);
1802         //print(self.netname, "\n");
1803
1804         n = tokenize_console(self.netname);
1805         for(i = 0; i < n; ++i)
1806         {
1807                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1808                 {
1809                         e = get_weaponinfo(j);
1810                         if(argv(i) == e.netname)
1811                         {
1812                                 weapon_action(e.weapon, WR_PRECACHE);
1813                                 break;
1814                         }
1815                 }
1816         }
1817 }
1818
1819 void spawnfunc_item_fuel(void)
1820 {
1821         if(!self.ammo_fuel)
1822                 self.ammo_fuel = g_pickup_fuel;
1823         if(!self.pickup_anyway)
1824                 self.pickup_anyway = g_pickup_ammo_anyway;
1825         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1826 }
1827
1828 void spawnfunc_item_fuel_regen(void)
1829 {
1830         if(start_items & IT_FUEL_REGEN)
1831         {
1832                 spawnfunc_item_fuel();
1833                 return;
1834         }
1835         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1836 }
1837
1838 void spawnfunc_item_jetpack(void)
1839 {
1840         if(g_grappling_hook)
1841                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1842         if(!self.ammo_fuel)
1843                 self.ammo_fuel = g_pickup_fuel_jetpack;
1844         if(start_items & IT_JETPACK)
1845         {
1846                 spawnfunc_item_fuel();
1847                 return;
1848         }
1849         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1850 }
1851
1852
1853 #define OP_SET 0
1854 #define OP_MIN 1
1855 #define OP_MAX 2
1856 #define OP_PLUS 3
1857 #define OP_MINUS 4
1858
1859 float GiveWeapon(entity e, float wpn, float op, float val)
1860 {
1861         float v0, v1;
1862         v0 = WEPSET_CONTAINS_EW(e, wpn);
1863         switch(op)
1864         {
1865                 case OP_SET:
1866                         if(val > 0)
1867                                 WEPSET_OR_EW(e, wpn);
1868                         else
1869                                 WEPSET_ANDNOT_EW(e, wpn);
1870                         break;
1871                 case OP_MIN:
1872                 case OP_PLUS:
1873                         if(val > 0)
1874                                 WEPSET_OR_EW(e, wpn);
1875                         break;
1876                 case OP_MAX:
1877                         if(val <= 0)
1878                                 WEPSET_ANDNOT_EW(e, wpn);
1879                         break;
1880                 case OP_MINUS:
1881                         if(val > 0)
1882                                 WEPSET_ANDNOT_EW(e, wpn);
1883                         break;
1884         }
1885         v1 = WEPSET_CONTAINS_EW(e, wpn);
1886         return (v0 != v1);
1887 }
1888
1889 float GiveBit(entity e, .float fld, float bit, float op, float val)
1890 {
1891         float v0, v1;
1892         v0 = (e.fld & bit);
1893         switch(op)
1894         {
1895                 case OP_SET:
1896                         if(val > 0)
1897                                 e.fld |= bit;
1898                         else
1899                                 e.fld &~= bit;
1900                         break;
1901                 case OP_MIN:
1902                 case OP_PLUS:
1903                         if(val > 0)
1904                                 e.fld |= bit;
1905                         break;
1906                 case OP_MAX:
1907                         if(val <= 0)
1908                                 e.fld &~= bit;
1909                         break;
1910                 case OP_MINUS:
1911                         if(val > 0)
1912                                 e.fld &~= bit;
1913                         break;
1914         }
1915         v1 = (e.fld & bit);
1916         return (v0 != v1);
1917 }
1918
1919 float GiveValue(entity e, .float fld, float op, float val)
1920 {
1921         float v0, v1;
1922         v0 = e.fld;
1923         switch(op)
1924         {
1925                 case OP_SET:
1926                         e.fld = val;
1927                         break;
1928                 case OP_MIN:
1929                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1930                         break;
1931                 case OP_MAX:
1932                         e.fld = min(e.fld, val);
1933                         break;
1934                 case OP_PLUS:
1935                         e.fld += val;
1936                         break;
1937                 case OP_MINUS:
1938                         e.fld -= val;
1939                         break;
1940         }
1941         v1 = e.fld;
1942         return (v0 != v1);
1943 }
1944
1945 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1946 {
1947         if(v1 == v0)
1948                 return;
1949         if(v1 <= v0 - t)
1950         {
1951                 if(snd_decr != "")
1952                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1953         }
1954         else if(v0 >= v0 + t)
1955         {
1956                 if(snd_incr != "")
1957                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1958         }
1959 }
1960
1961 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1962 {
1963         if(v0 < v1)
1964                 e.rotfield = max(e.rotfield, time + rottime);
1965         else if(v0 > v1)
1966                 e.regenfield = max(e.regenfield, time + regentime);
1967 }
1968
1969 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1970 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1971 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1972 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1973 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1974 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1975
1976 float GiveItems(entity e, float beginarg, float endarg)
1977 {
1978         float got, i, j, val, op;
1979         float _switchweapon;
1980         entity wi;
1981         string cmd;
1982
1983         val = 999;
1984         op = OP_SET;
1985
1986         got = 0;
1987
1988         _switchweapon = FALSE;
1989         if (e.autoswitch)
1990                 if (e.switchweapon == w_getbestweapon(e))
1991                         _switchweapon = TRUE;
1992
1993         e.strength_finished = max(0, e.strength_finished - time);
1994         e.invincible_finished = max(0, e.invincible_finished - time);
1995         e.superweapons_finished = max(0, e.superweapons_finished - time);
1996
1997         PREGIVE(e, items);
1998         PREGIVE_WEAPONS(e);
1999         PREGIVE(e, strength_finished);
2000         PREGIVE(e, invincible_finished);
2001         PREGIVE(e, superweapons_finished);
2002         PREGIVE(e, ammo_nails);
2003         PREGIVE(e, ammo_cells);
2004         PREGIVE(e, ammo_shells);
2005         PREGIVE(e, ammo_rockets);
2006         PREGIVE(e, ammo_fuel);
2007         PREGIVE(e, armorvalue);
2008         PREGIVE(e, health);
2009
2010         for(i = beginarg; i < endarg; ++i)
2011         {
2012                 cmd = argv(i);
2013
2014                 if(cmd == "0" || stof(cmd))
2015                 {
2016                         val = stof(cmd);
2017                         continue;
2018                 }
2019                 switch(cmd)
2020                 {
2021                         case "no":
2022                                 op = OP_MAX;
2023                                 val = 0;
2024                                 continue;
2025                         case "max":
2026                                 op = OP_MAX;
2027                                 continue;
2028                         case "min":
2029                                 op = OP_MIN;
2030                                 continue;
2031                         case "plus":
2032                                 op = OP_PLUS;
2033                                 continue;
2034                         case "minus":
2035                                 op = OP_MINUS;
2036                                 continue;
2037                         case "ALL":
2038                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
2039                                 got += GiveValue(e, strength_finished, op, val);
2040                                 got += GiveValue(e, invincible_finished, op, val);
2041                                 got += GiveValue(e, superweapons_finished, op, val);
2042                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
2043                         case "all":
2044                                 got += GiveBit(e, items, IT_JETPACK, op, val);
2045                                 got += GiveValue(e, health, op, val);
2046                                 got += GiveValue(e, armorvalue, op, val);
2047                         case "allweapons":
2048                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2049                                 {
2050                                         wi = get_weaponinfo(j);
2051                                         if(wi.weapon)
2052                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
2053                                                         got += GiveWeapon(e, j, op, val);
2054                                 }
2055                         case "allammo":
2056                                 got += GiveValue(e, ammo_cells, op, val);
2057                                 got += GiveValue(e, ammo_shells, op, val);
2058                                 got += GiveValue(e, ammo_nails, op, val);
2059                                 got += GiveValue(e, ammo_rockets, op, val);
2060                                 got += GiveValue(e, ammo_fuel, op, val);
2061                                 break;
2062                         case "unlimited_ammo":
2063                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
2064                                 break;
2065                         case "unlimited_weapon_ammo":
2066                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
2067                                 break;
2068                         case "unlimited_superweapons":
2069                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
2070                                 break;
2071                         case "jetpack":
2072                                 got += GiveBit(e, items, IT_JETPACK, op, val);
2073                                 break;
2074                         case "fuel_regen":
2075                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
2076                                 break;
2077                         case "strength":
2078                                 got += GiveValue(e, strength_finished, op, val);
2079                                 break;
2080                         case "invincible":
2081                                 got += GiveValue(e, invincible_finished, op, val);
2082                                 break;
2083                         case "superweapons":
2084                                 got += GiveValue(e, superweapons_finished, op, val);
2085                                 break;
2086                         case "cells":
2087                                 got += GiveValue(e, ammo_cells, op, val);
2088                                 break;
2089                         case "shells":
2090                                 got += GiveValue(e, ammo_shells, op, val);
2091                                 break;
2092                         case "nails":
2093                         case "bullets":
2094                                 got += GiveValue(e, ammo_nails, op, val);
2095                                 break;
2096                         case "rockets":
2097                                 got += GiveValue(e, ammo_rockets, op, val);
2098                                 break;
2099                         case "health":
2100                                 got += GiveValue(e, health, op, val);
2101                                 break;
2102                         case "armor":
2103                                 got += GiveValue(e, armorvalue, op, val);
2104                                 break;
2105                         case "fuel":
2106                                 got += GiveValue(e, ammo_fuel, op, val);
2107                                 break;
2108                         default:
2109                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2110                                 {
2111                                         wi = get_weaponinfo(j);
2112                                         if(cmd == wi.netname)
2113                                         {
2114                                                 got += GiveWeapon(e, j, op, val);
2115                                                 break;
2116                                         }
2117                                 }
2118                                 if(j > WEP_LAST)
2119                                         print("give: invalid item ", cmd, "\n");
2120                                 break;
2121                 }
2122                 val = 999;
2123                 op = OP_SET;
2124         }
2125
2126         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
2127         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
2128         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
2129         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
2130         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2131         {
2132                 wi = get_weaponinfo(j);
2133                 if(wi.weapon)
2134                 {
2135                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
2136                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
2137                                 if(WEPSET_CONTAINS_EW(e, j))
2138                                         weapon_action(wi.weapon, WR_PRECACHE);
2139                 }
2140         }
2141         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
2142         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
2143         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
2144         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
2145         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
2146         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
2147         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
2148         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
2149         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
2150
2151         if(e.superweapons_finished <= 0)
2152                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
2153                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2154
2155         if (g_minstagib)
2156         {
2157                 e.health = bound(0, e.health, 100);
2158                 e.armorvalue = bound(0, e.armorvalue, 999);
2159         }
2160
2161         if(e.strength_finished <= 0)
2162                 e.strength_finished = 0;
2163         else
2164                 e.strength_finished += time;
2165         if(e.invincible_finished <= 0)
2166                 e.invincible_finished = 0;
2167         else
2168                 e.invincible_finished += time;
2169         if(e.superweapons_finished <= 0)
2170                 e.superweapons_finished = 0;
2171         else
2172                 e.superweapons_finished += time;
2173
2174         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
2175                 _switchweapon = TRUE;
2176         if(_switchweapon)
2177                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
2178
2179         return got;
2180 }
2181 #endif