qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &~= ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271
 272 float have_pickup_item(void)
 273 {
 274         // minstagib: only allow filtered items
 275         if(g_minstagib)
 276                 if(self.classname != "minstagib")
 277                         return FALSE;
 278
 279         if(self.flags & FL_POWERUP)
 280         {
 281                 if(autocvar_g_powerups > 0)
 282                         return TRUE;
 283                 if(autocvar_g_powerups == 0)
 284                         return FALSE;
 285                 if(g_ca)
 286                         return FALSE;
 287                 if(g_arena)
 288                         return FALSE;
 289         }
 290         else
 291         {
 292                 if(autocvar_g_pickup_items > 0)
 293                         return TRUE;
 294                 if(autocvar_g_pickup_items == 0)
 295                         return FALSE;
 296                 if(g_ca)
 297                         return FALSE;
 298                 if(g_weaponarena)
 299                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
 300                                 return FALSE;
 301         }
 302         return TRUE;
 303 }
 304
 305 #define ITEM_RESPAWN_TICKS 10
 306
 307 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 308         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 309 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 310         // range: 10 .. respawntime + respawntimejitter
 311
 312 floatfield Item_CounterField(float it)
 313 {
 314         switch(it)
 315         {
 316                 case IT_SHELLS:      return ammo_shells;
 317                 case IT_NAILS:       return ammo_nails;
 318                 case IT_ROCKETS:     return ammo_rockets;
 319                 case IT_CELLS:       return ammo_cells;
 320                 case IT_FUEL:        return ammo_fuel;
 321                 case IT_5HP:         return health;
 322                 case IT_25HP:        return health;
 323                 case IT_HEALTH:      return health;
 324                 case IT_ARMOR_SHARD: return armorvalue;
 325                 case IT_ARMOR:       return armorvalue;
 326                 // add more things here (health, armor)
 327                 default:             error("requested item has no counter field");
 328         }
 329 #ifdef GMQCC
 330         // should never happen
 331         return health;
 332 #endif
 333 }
 334
 335 string Item_CounterFieldName(float it)
 336 {
 337         switch(it)
 338         {
 339                 case IT_SHELLS:      return "shells";
 340                 case IT_NAILS:       return "nails";
 341                 case IT_ROCKETS:     return "rockets";
 342                 case IT_CELLS:       return "cells";
 343                 case IT_FUEL:        return "fuel";
 344
 345                 // add more things here (health, armor)
 346                 default:             error("requested item has no counter field name");
 347         }
 348 #ifdef GMQCC
 349         // should never happen
 350         return string_null;
 351 #endif
 352 }
 353
 354 .float max_armorvalue;
 355 .float pickup_anyway;
 356 /*
 357 float Item_Customize()
 358 {
 359         if(self.spawnshieldtime)
 360                 return TRUE;
 361         if(!WEPSET_CONTAINS_ALL_EE(other, self))
 362         {
 363                 self.colormod = '0 0 0';
 364                 self.glowmod = self.colormod;
 365                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 366                 return TRUE;
 367         }
 368         else
 369         {
 370                 if(g_ghost_items)
 371                 {
 372                         self.colormod = stov(autocvar_g_ghost_items_color);
 373                         self.glowmod = self.colormod;
 374                         self.alpha = g_ghost_items;
 375                         return TRUE;
 376                 }
 377                 else
 378                         return FALSE;
 379         }
 380 }
 381 */
 382
 383 void Item_Show (entity e, float mode)
 384 {
 385         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 386         e.ItemStatus &~= ITS_STAYWEP;
 387         if (mode > 0)
 388         {
 389                 // make the item look normal, and be touchable
 390                 e.model = e.mdl;
 391                 e.solid = SOLID_TRIGGER;
 392                 e.spawnshieldtime = 1;
 393                 e.ItemStatus |= ITS_AVAILABLE;
 394         }
 395         else if (mode < 0)
 396         {
 397                 // hide the item completely
 398                 e.model = string_null;
 399                 e.solid = SOLID_NOT;
 400                 e.spawnshieldtime = 1;
 401                 e.ItemStatus &~= ITS_AVAILABLE;
 402         }
 403         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 404         {
 405                 // make the item translucent and not touchable
 406                 e.model = e.mdl;
 407                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 408                 e.effects |= EF_STARDUST;
 409                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 410                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 411         }
 412         else
 413         {
 414                 //setmodel(e, "null");
 415                 e.solid = SOLID_NOT;
 416                 e.colormod = '0 0 0';
 417                 e.glowmod = e.colormod;
 418                 e.spawnshieldtime = 1;
 419                 e.ItemStatus &~= ITS_AVAILABLE;
 420         }
 421
 422         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 423             e.ItemStatus |= ITS_POWERUP;
 424
 425         if (autocvar_g_nodepthtestitems)
 426                 e.effects |= EF_NODEPTHTEST;
 427
 428
 429     if (autocvar_g_fullbrightitems)
 430                 e.ItemStatus |= ITS_ALLOWFB;
 431
 432         if (autocvar_sv_simple_items)
 433         e.ItemStatus |= ITS_ALLOWSI;
 434
 435         // relink entity (because solid may have changed)
 436         setorigin(e, e.origin);
 437     e.SendFlags |= ISF_STATUS;
 438 }
 439
 440 void Item_Respawn (void)
 441 {
 442         Item_Show(self, 1);
 443         if(!g_minstagib && self.items == IT_STRENGTH)
 444                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 445         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 446                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 447         else
 448                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 449         setorigin (self, self.origin);
 450
 451         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 452         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 453 }
 454
 455 void Item_RespawnCountdown (void)
 456 {
 457         if(self.count >= ITEM_RESPAWN_TICKS)
 458         {
 459                 if(self.waypointsprite_attached)
 460                         WaypointSprite_Kill(self.waypointsprite_attached);
 461                 Item_Respawn();
 462         }
 463         else
 464         {
 465                 self.nextthink = time + 1;
 466                 self.count += 1;
 467                 if(self.count == 1)
 468                 {
 469                         string name;
 470                         vector rgb = '1 0 1';
 471                         name = string_null;
 472                         if(g_minstagib)
 473                         {
 474                                 switch(self.items)
 475                                 {
 476                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 477                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 478                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 479                                 }
 480                         }
 481                         else
 482                         {
 483                                 switch(self.items)
 484                                 {
 485                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 486                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 487                                 }
 488                         }
 489                         switch(self.items)
 490                         {
 491                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 492                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 493                         }
 494                         if(self.flags & FL_WEAPON)
 495                         {
 496                                 entity wi = get_weaponinfo(self.weapon);
 497                                 if(wi)
 498                                 {
 499                                         name = wi.model2;
 500                                         rgb = '1 0 0';
 501                                 }
 502                         }
 503                         if(name)
 504                         {
 505                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 506                                 if(self.waypointsprite_attached)
 507                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 508                         }
 509                         else
 510                         {
 511                                 print("Unknown powerup-marked item is wanting to respawn\n");
 512                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 513                         }
 514                 }
 515                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 516                 if(self.waypointsprite_attached)
 517                 {
 518                         WaypointSprite_Ping(self.waypointsprite_attached);
 519                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 520                 }
 521         }
 522 }
 523
 524 void Item_ScheduleRespawnIn(entity e, float t)
 525 {
 526         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 527         {
 528                 e.think = Item_RespawnCountdown;
 529                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 530                 e.count = 0;
 531         }
 532         else
 533         {
 534                 e.think = Item_Respawn;
 535                 e.nextthink = time + t;
 536         }
 537 }
 538
 539 void Item_ScheduleRespawn(entity e)
 540 {
 541         if(e.respawntime > 0)
 542         {
 543                 Item_Show(e, 0);
 544                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 545         }
 546         else // if respawntime is -1, this item does not respawn
 547                 Item_Show(e, -1);
 548 }
 549
 550 void Item_ScheduleInitialRespawn(entity e)
 551 {
 552         Item_Show(e, 0);
 553         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 554 }
 555
 556 float ITEM_MODE_NONE = 0;
 557 float ITEM_MODE_HEALTH = 1;
 558 float ITEM_MODE_ARMOR = 2;
 559 float ITEM_MODE_FUEL = 3;
 560 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 561 {
 562         if (!item.ammofield)
 563                 return FALSE;
 564
 565         if (item.spawnshieldtime)
 566         {
 567                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 568                 {
 569                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 570                         goto YEAH;
 571                 }
 572         }
 573         else if(g_weapon_stay == 2)
 574         {
 575                 float mi = min(item.ammofield, ammomax);
 576                 if (player.ammofield < mi)
 577                 {
 578                         player.ammofield = mi;
 579                         goto YEAH;
 580                 }
 581         }
 582
 583         return FALSE;
 584
 585 :YEAH
 586         switch(mode)
 587         {
 588                 case ITEM_MODE_FUEL:
 589                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 590                         break;
 591                 case ITEM_MODE_HEALTH:
 592                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 593                         break;
 594                 case ITEM_MODE_ARMOR:
 595                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 596                         break;
 597                 default:
 598                         break;
 599         }
 600         return TRUE;
 601 }
 602
 603 float Item_GiveTo(entity item, entity player)
 604 {
 605         float _switchweapon;
 606         float pickedup;
 607         float it;
 608         float i;
 609
 610         // if nothing happens to player, just return without taking the item
 611         pickedup = FALSE;
 612         _switchweapon = FALSE;
 613
 614         if (g_minstagib)
 615         {
 616                 float prevcells = player.ammo_cells;
 617
 618                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 619                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 620
 621                 if(player.ammo_cells > prevcells)
 622                 {
 623                         _switchweapon = TRUE;
 624
 625                         // play some cool sounds ;)
 626                         if (clienttype(player) == CLIENTTYPE_REAL)
 627                         {
 628                                 if(player.health <= 5)
 629                                         Send_Notification(NOTIF_ONE, player, MSG_ANNCE, ANNCE_MINSTAGIB_LASTSECOND);
 630                                 else if(player.health < 50)
 631                                         Send_Notification(NOTIF_ONE, player, MSG_ANNCE, ANNCE_MINSTAGIB_NARROWLY);
 632                         }
 633                         // sound not available
 634                         // else if(item.items == IT_CELLS)
 635                         //      AnnounceTo(player, "ammo");
 636
 637                         if (WEPSET_CONTAINS_EW(item, WEP_MINSTANEX))
 638                                 W_GiveWeapon (player, WEP_MINSTANEX);
 639                         player.health = 100;
 640                 }
 641
 642                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 643                 {
 644                         pickedup = TRUE;
 645                         player.items |= it;
 646                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 647                 }
 648
 649                 // extralife powerup
 650                 if (item.max_health)
 651                 {
 652                         pickedup = TRUE;
 653                         // sound not available
 654                         // AnnounceTo(player, "_lives");
 655                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 656                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_EXTRALIVES);
 657                 }
 658
 659                 // invis powerup
 660                 if (item.strength_finished)
 661                 {
 662                         pickedup = TRUE;
 663                         // sound not available
 664                         // AnnounceTo(player, "invisible");
 665                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 666                 }
 667
 668                 // speed powerup
 669                 if (item.invincible_finished)
 670                 {
 671                         pickedup = TRUE;
 672                         // sound not available
 673                         // AnnounceTo(player, "speed");
 674                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 675                 }
 676         }
 677         else
 678         {
 679                 // in case the player has autoswitch enabled do the following:
 680                 // if the player is using their best weapon before items are given, they
 681                 // probably want to switch to an even better weapon after items are given
 682                 if (player.autoswitch)
 683                 if (player.switchweapon == w_getbestweapon(player))
 684                         _switchweapon = TRUE;
 685
 686                 if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 687                         _switchweapon = TRUE;
 688
 689                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 690                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 691                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 692                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 693                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 694                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 695                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 696
 697                 if (item.flags & FL_WEAPON)
 698                 {
 699                         WEPSET_DECLARE_A(it);
 700                         WEPSET_COPY_AE(it, item);
 701                         WEPSET_ANDNOT_AE(it, player);
 702
 703                         if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 704                         {
 705                                 pickedup = TRUE;
 706                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 707                                         if(WEPSET_CONTAINS_AW(it, i))
 708                                                 W_GiveWeapon(player, i);
 709                         }
 710                 }
 711
 712                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 713                 {
 714                         pickedup = TRUE;
 715                         player.items |= it;
 716                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 717                 }
 718
 719                 if (item.strength_finished)
 720                 {
 721                         pickedup = TRUE;
 722                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 723                 }
 724                 if (item.invincible_finished)
 725                 {
 726                         pickedup = TRUE;
 727                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 728                 }
 729                 if (item.superweapons_finished)
 730                 {
 731                         pickedup = TRUE;
 732                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 733                 }
 734         }
 735
 736 :skip
 737         // always eat teamed entities
 738         if(item.team)
 739                 pickedup = TRUE;
 740
 741         if (!pickedup)
 742                 return 0;
 743
 744         if (_switchweapon)
 745                 if (player.switchweapon != w_getbestweapon(player))
 746                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 747
 748         return 1;
 749 }
 750
 751 void Item_Touch (void)
 752 {
 753         entity e, head;
 754
 755         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 756         if(self.classname == "droppedweapon")
 757         {
 758                 if (ITEM_TOUCH_NEEDKILL())
 759                 {
 760                         remove(self);
 761                         return;
 762                 }
 763         }
 764
 765         if (other.classname != "player")
 766                 return;
 767         if (other.frozen)
 768                 return;
 769         if (other.deadflag)
 770                 return;
 771         if (self.solid != SOLID_TRIGGER)
 772                 return;
 773         if (self.owner == other)
 774                 return;
 775         if(MUTATOR_CALLHOOK(ItemTouch))
 776                 return;
 777
 778         if (self.classname == "droppedweapon")
 779         {
 780                 self.strength_finished = max(0, self.strength_finished - time);
 781                 self.invincible_finished = max(0, self.invincible_finished - time);
 782                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 783         }
 784
 785         if(!Item_GiveTo(self, other))
 786         {
 787                 if (self.classname == "droppedweapon")
 788                 {
 789                         // undo what we did above
 790                         self.strength_finished += time;
 791                         self.invincible_finished += time;
 792                         self.superweapons_finished += time;
 793                 }
 794                 return;
 795         }
 796
 797         other.last_pickup = time;
 798
 799         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 800         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 801
 802         if (self.classname == "droppedweapon")
 803                 remove (self);
 804         else if not(self.spawnshieldtime)
 805                 return;
 806         else
 807         {
 808                 if(self.team)
 809                 {
 810                         RandomSelection_Init();
 811                         for(head = world; (head = findfloat(head, team, self.team)); )
 812                         {
 813                                 if(head.flags & FL_ITEM)
 814                                 {
 815                                         Item_Show(head, -1);
 816                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 817                                 }
 818                         }
 819                         e = RandomSelection_chosen_ent;
 820
 821                 }
 822                 else
 823                         e = self;
 824                 Item_ScheduleRespawn(e);
 825         }
 826 }
 827
 828 void Item_Reset()
 829 {
 830         Item_Show(self, !self.state);
 831         setorigin (self, self.origin);
 832
 833         if(self.classname != "droppedweapon")
 834         {
 835                 self.think = func_null;
 836                 self.nextthink = 0;
 837
 838                 if(self.waypointsprite_attached)
 839                         WaypointSprite_Kill(self.waypointsprite_attached);
 840
 841                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 842                         Item_ScheduleInitialRespawn(self);
 843         }
 844 }
 845
 846 void Item_FindTeam()
 847 {
 848         entity head, e;
 849
 850         if(self.effects & EF_NODRAW)
 851         {
 852                 // marker for item team search
 853                 dprint("Initializing item team ", ftos(self.team), "\n");
 854                 RandomSelection_Init();
 855                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 856                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 857                 e = RandomSelection_chosen_ent;
 858                 e.state = 0;
 859                 Item_Show(e, 1);
 860
 861                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 862                 {
 863                         if(head != e)
 864                         {
 865                                 // make it a non-spawned item
 866                                 Item_Show(head, -1);
 867                                 head.state = 1; // state 1 = initially hidden item
 868                         }
 869                         head.effects &~= EF_NODRAW;
 870                 }
 871
 872                 Item_Reset();
 873         }
 874 }
 875
 876 // Savage: used for item garbage-collection
 877 // TODO: perhaps nice special effect?
 878 void RemoveItem(void)
 879 {
 880         remove(self);
 881 }
 882
 883 // pickup evaluation functions
 884 // these functions decide how desirable an item is to the bots
 885
 886 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 887
 888 float weapon_pickupevalfunc(entity player, entity item)
 889 {
 890         float c, j, position;
 891
 892         // See if I have it already
 893         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 894         {
 895                 // If I can pick it up
 896                 if(!item.spawnshieldtime)
 897                         c = 0;
 898                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 899                 {
 900                         // Skilled bots will grab more
 901                         c = bound(0, skill / 10, 1) * 0.5;
 902                 }
 903                 else
 904                         c = 0;
 905         }
 906         else
 907                 c = 1;
 908
 909         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 910         if( bot_custom_weapon && c )
 911         {
 912                 // Find the highest position on any range
 913                 position = -1;
 914                 for(j = 0; j < WEP_LAST ; ++j){
 915                         if(
 916                                         bot_weapons_far[j] == item.weapon ||
 917                                         bot_weapons_mid[j] == item.weapon ||
 918                                         bot_weapons_close[j] == item.weapon
 919                           )
 920                         {
 921                                 position = j;
 922                                 break;
 923                         }
 924                 }
 925
 926                 // Rate it
 927                 if (position >= 0 )
 928                 {
 929                         position = WEP_LAST - position;
 930                         // item.bot_pickupbasevalue is overwritten here
 931                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 932                 }
 933         }
 934
 935         return item.bot_pickupbasevalue * c;
 936 }
 937
 938 float commodity_pickupevalfunc(entity player, entity item)
 939 {
 940         float c, i;
 941         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 942         entity wi;
 943         c = 0;
 944
 945         // Detect needed ammo
 946         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 947         {
 948                 wi = get_weaponinfo(i);
 949
 950                 if not(WEPSET_CONTAINS_EW(player, i))
 951                         continue;
 952
 953                 if(wi.items & IT_SHELLS)
 954                         need_shells = TRUE;
 955                 else if(wi.items & IT_NAILS)
 956                         need_nails = TRUE;
 957                 else if(wi.items & IT_ROCKETS)
 958                         need_rockets = TRUE;
 959                 else if(wi.items & IT_CELLS)
 960                         need_cells = TRUE;
 961                 else if(wi.items & IT_FUEL)
 962                         need_cells = TRUE;
 963         }
 964
 965         // TODO: figure out if the player even has the weapon this ammo is for?
 966         // may not affect strategy much though...
 967         // find out how much more ammo/armor/health the player can hold
 968         if (need_shells)
 969         if (item.ammo_shells)
 970         if (player.ammo_shells < g_pickup_shells_max)
 971                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 972         if (need_nails)
 973         if (item.ammo_nails)
 974         if (player.ammo_nails < g_pickup_nails_max)
 975                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 976         if (need_rockets)
 977         if (item.ammo_rockets)
 978         if (player.ammo_rockets < g_pickup_rockets_max)
 979                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 980         if (need_cells)
 981         if (item.ammo_cells)
 982         if (player.ammo_cells < g_pickup_cells_max)
 983                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 984         if (need_fuel)
 985         if (item.ammo_fuel)
 986         if (player.ammo_fuel < g_pickup_fuel_max)
 987                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 988         if (item.armorvalue)
 989         if (player.armorvalue < item.max_armorvalue)
 990                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 991         if (item.health)
 992         if (player.health < item.max_health)
 993                 c = c + max(0, 1 - player.health / item.max_health);
 994
 995         return item.bot_pickupbasevalue * c;
 996 }
 997
 998 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 999 {
1000         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1001                 RemoveItem();
1002 }
1003
1004 .float is_item;
1005 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
1006 {
1007         startitem_failed = FALSE;
1008
1009         if(self.model == "")
1010                 self.model = itemmodel;
1011
1012         if(self.model == "")
1013     {
1014         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
1015         return;
1016     }
1017
1018         if(self.item_pickupsound == "")
1019                 self.item_pickupsound = pickupsound;
1020
1021         if(!self.respawntime) // both need to be set
1022         {
1023                 self.respawntime = defaultrespawntime;
1024                 self.respawntimejitter = defaultrespawntimejitter;
1025         }
1026
1027         self.items = itemid;
1028         self.weapon = weaponid;
1029
1030         if(weaponid)
1031                 WEPSET_COPY_EW(self, weaponid);
1032
1033         self.flags = FL_ITEM | itemflags;
1034
1035         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
1036         {
1037                 startitem_failed = TRUE;
1038                 remove(self);
1039                 return;
1040         }
1041
1042         // is it a dropped weapon?
1043         if (self.classname == "droppedweapon")
1044         {
1045                 self.reset = SUB_Remove;
1046                 // it's a dropped weapon
1047                 self.movetype = MOVETYPE_TOSS;
1048
1049                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1050                 self.think = RemoveItem;
1051                 self.nextthink = time + 20;
1052
1053                 self.takedamage = DAMAGE_YES;
1054                 self.event_damage = Item_Damage;
1055
1056                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1057                 /*
1058                 if(self.items == 0)
1059                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
1060                 if(self.ammo_nails == 0)
1061                 if(self.ammo_cells == 0)
1062                 if(self.ammo_rockets == 0)
1063                 if(self.ammo_shells == 0)
1064                 if(self.ammo_fuel == 0)
1065                 if(self.health == 0)
1066                 if(self.armorvalue == 0)
1067                 */
1068                 {
1069                         // if item is worthless after a timer, have it expire then
1070                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1071                 }
1072
1073                 // don't drop if in a NODROP zone (such as lava)
1074                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1075                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1076                 {
1077                         startitem_failed = TRUE;
1078                         remove(self);
1079                         return;
1080                 }
1081         }
1082         else
1083         {
1084                 if(!have_pickup_item())
1085                 {
1086                         startitem_failed = TRUE;
1087                         remove (self);
1088                         return;
1089                 }
1090
1091                 if(self.angles != '0 0 0')
1092             self.SendFlags |= ISF_ANGLES;
1093
1094                 self.reset = Item_Reset;
1095                 // it's a level item
1096                 if(self.spawnflags & 1)
1097                         self.noalign = 1;
1098                 if (self.noalign)
1099                         self.movetype = MOVETYPE_NONE;
1100                 else
1101                         self.movetype = MOVETYPE_TOSS;
1102                 // do item filtering according to game mode and other things
1103                 if (!self.noalign)
1104                 {
1105                         // first nudge it off the floor a little bit to avoid math errors
1106                         setorigin(self, self.origin + '0 0 1');
1107                         // set item size before we spawn a spawnfunc_waypoint
1108                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1109                                 setsize (self, '-16 -16 0', '16 16 48');
1110                         else
1111                                 setsize (self, '-16 -16 0', '16 16 32');
1112                         // note droptofloor returns FALSE if stuck/or would fall too far
1113                         droptofloor();
1114                         waypoint_spawnforitem(self);
1115                 }
1116
1117                 /*
1118                  * can't do it that way, as it would break maps
1119                  * TODO make a target_give like entity another way, that perhaps has
1120                  * the weapon name in a key
1121                 if(self.targetname)
1122                 {
1123                         // target_give not yet supported; maybe later
1124                         print("removed targeted ", self.classname, "\n");
1125                         startitem_failed = TRUE;
1126                         remove (self);
1127                         return;
1128                 }
1129                 */
1130
1131                 if(autocvar_spawn_debug >= 2)
1132                 {
1133                         entity otheritem;
1134                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1135                         {
1136                             // why not flags & fl_item?
1137                                 if(otheritem.is_item)
1138                                 {
1139                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1140                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1141                                         error("Mapper sucks.");
1142                                 }
1143                         }
1144                         self.is_item = TRUE;
1145                 }
1146
1147                 WEPSET_OR_AW(weaponsInMap, weaponid);
1148
1149                 precache_model (self.model);
1150                 precache_sound (self.item_pickupsound);
1151
1152                 precache_sound ("misc/itemrespawncountdown.wav");
1153                 if(!g_minstagib && itemid == IT_STRENGTH)
1154                         precache_sound ("misc/strength_respawn.wav");
1155                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
1156                         precache_sound ("misc/shield_respawn.wav");
1157                 else
1158                         precache_sound ("misc/itemrespawn.wav");
1159
1160                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1161                         self.target = "###item###"; // for finding the nearest item using find()
1162         }
1163
1164         self.bot_pickup = TRUE;
1165         self.bot_pickupevalfunc = pickupevalfunc;
1166         self.bot_pickupbasevalue = pickupbasevalue;
1167         self.mdl = self.model;
1168         self.netname = itemname;
1169         self.touch = Item_Touch;
1170         setmodel(self, "null"); // precision set below
1171         //self.effects |= EF_LOWPRECISION;
1172
1173         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1174     {
1175         self.pos1 = '-16 -16 0';
1176         self.pos2 = '16 16 48';
1177     }
1178         else
1179     {
1180         self.pos1 = '-16 -16 0';
1181         self.pos2 = '16 16 32';
1182     }
1183     setsize (self, self.pos1, self.pos2);
1184
1185     if(itemflags & FL_POWERUP)
1186         self.ItemStatus |= ITS_ANIMATE1;
1187
1188         if(self.armorvalue || self.health)
1189         self.ItemStatus |= ITS_ANIMATE2;
1190
1191         if(itemflags & FL_WEAPON)
1192         {
1193                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1194             self.colormap = 1024; // color shirt=0 pants=0 grey
1195         else
1196             self.gravity = 1;
1197
1198                 self.ItemStatus |= ITS_ANIMATE1;
1199                 self.ItemStatus |= ISF_COLORMAP;
1200         }
1201
1202         self.state = 0;
1203         if(self.team) // broken, no idea why.
1204         {
1205                 if(!self.cnt)
1206                         self.cnt = 1; // item probability weight
1207
1208                 self.effects |= EF_NODRAW; // marker for item team search
1209                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1210         }
1211         else
1212                 Item_Reset();
1213
1214     Net_LinkEntity(self, FALSE, 0, ItemSend);
1215
1216         // call this hook after everything else has been done
1217         if(MUTATOR_CALLHOOK(Item_Spawn))
1218         {
1219                 startitem_failed = TRUE;
1220                 remove(self);
1221                 return;
1222         }
1223 }
1224
1225 /* replace items in minstagib
1226  * IT_STRENGTH   = invisibility
1227  * IT_NAILS      = extra lives
1228  * IT_INVINCIBLE = speed
1229  */
1230 void minstagib_items (float itemid) // will be deleted soon.
1231 {
1232         float rnd;
1233         self.classname = "minstagib"; // ...?
1234
1235         // replace rocket launchers and nex guns with ammo cells
1236         if (itemid == IT_CELLS)
1237         {
1238                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1239                 StartItem ("models/items/a_cells.md3",
1240                         "misc/itempickup.wav", 45, 0,
1241                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
1242                 return;
1243         }
1244
1245         // randomize
1246         rnd = random() * 3;
1247         if (rnd <= 1)
1248                 itemid = IT_STRENGTH;
1249         else if (rnd <= 2)
1250                 itemid = IT_NAILS;
1251         else
1252                 itemid = IT_INVINCIBLE;
1253
1254         // replace with invis
1255         if (itemid == IT_STRENGTH)
1256         {
1257                 if(!self.strength_finished)
1258                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1259                 StartItem ("models/items/g_strength.md3",
1260                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1261                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
1262         }
1263         // replace with extra lives
1264         if (itemid == IT_NAILS)
1265         {
1266                 self.max_health = 1;
1267                 StartItem ("models/items/g_h100.md3",
1268                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1269                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1270         }
1271         // replace with speed
1272         if (itemid == IT_INVINCIBLE)
1273         {
1274                 if(!self.invincible_finished)
1275                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1276                 StartItem ("models/items/g_invincible.md3",
1277                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1278                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
1279         }
1280 }
1281
1282 float minst_no_auto_cells;
1283 void minst_remove_item (void) {
1284         if(minst_no_auto_cells)
1285                 remove(self);
1286 }
1287
1288 float weaponswapping;
1289 float internalteam;
1290
1291 void weapon_defaultspawnfunc(float wpn)
1292 {
1293         entity e;
1294         float t;
1295         var .float ammofield;
1296         string s;
1297         entity oldself;
1298         float i, j;
1299         float f;
1300
1301         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1302         {
1303                 e = get_weaponinfo(wpn);
1304
1305                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1306                 {
1307                         print("Attempted to spawn a mutator-blocked weapon; these guns will in the future require a mutator\n");
1308                         /*
1309                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1310                         startitem_failed = TRUE;
1311                         return;
1312                         */
1313                 }
1314
1315                 s = W_Apply_Weaponreplace(e.netname);
1316                 ret_string = s;
1317                 other = e;
1318                 MUTATOR_CALLHOOK(SetWeaponreplace);
1319                 s = ret_string;
1320                 if(s == "")
1321                 {
1322                         remove(self);
1323                         startitem_failed = TRUE;
1324                         return;
1325                 }
1326                 t = tokenize_console(s);
1327                 if(t >= 2)
1328                 {
1329                         self.team = --internalteam;
1330                         oldself = self;
1331                         for(i = 1; i < t; ++i)
1332                         {
1333                                 s = argv(i);
1334                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1335                                 {
1336                                         e = get_weaponinfo(j);
1337                                         if(e.netname == s)
1338                                         {
1339                                                 self = spawn();
1340                                                 copyentity(oldself, self);
1341                                                 self.classname = "replacedweapon";
1342                                                 weapon_defaultspawnfunc(j);
1343                                                 break;
1344                                         }
1345                                 }
1346                                 if(j > WEP_LAST)
1347                                 {
1348                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1349                                 }
1350                         }
1351                         self = oldself;
1352                 }
1353                 if(t >= 1) // always the case!
1354                 {
1355                         s = argv(0);
1356                         wpn = 0;
1357                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1358                         {
1359                                 e = get_weaponinfo(j);
1360                                 if(e.netname == s)
1361                                 {
1362                                         wpn = j;
1363                                         break;
1364                                 }
1365                         }
1366                         if(j > WEP_LAST)
1367                         {
1368                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1369                         }
1370                 }
1371                 if(wpn == 0)
1372                 {
1373                         remove(self);
1374                         startitem_failed = TRUE;
1375                         return;
1376                 }
1377         }
1378
1379         e = get_weaponinfo(wpn);
1380
1381         if(!self.respawntime)
1382         {
1383                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1384                 {
1385                         self.respawntime = g_pickup_respawntime_superweapon;
1386                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1387                 }
1388                 else
1389                 {
1390                         self.respawntime = g_pickup_respawntime_weapon;
1391                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1392                 }
1393         }
1394
1395         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1396                 if(!self.superweapons_finished)
1397                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1398
1399         if(e.items)
1400         {
1401                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1402                 {
1403                         if(e.items & j)
1404                         {
1405                                 ammofield = Item_CounterField(j);
1406                                 if(!self.ammofield)
1407                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1408                         }
1409                 }
1410         }
1411
1412         // pickup anyway
1413         if(g_pickup_weapons_anyway)
1414                 self.pickup_anyway = TRUE;
1415
1416         f = FL_WEAPON;
1417
1418         // no weapon-stay on superweapons
1419         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1420                 f |= FL_NO_WEAPON_STAY;
1421
1422         // weapon stay isn't supported for teamed weapons
1423         if(self.team)
1424                 f |= FL_NO_WEAPON_STAY;
1425
1426         // stupid minstagib hack, don't ask
1427         if(g_minstagib)
1428                 if(self.ammo_cells)
1429                         self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1430
1431         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1432         if (self.modelindex) // don't precache if self was removed
1433                 weapon_action(e.weapon, WR_PRECACHE);
1434 }
1435
1436 void spawnfunc_weapon_shotgun (void);
1437 void spawnfunc_weapon_uzi (void) {
1438         if(autocvar_sv_q3acompat_machineshotgunswap)
1439         if(self.classname != "droppedweapon")
1440         {
1441                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1442                 return;
1443         }
1444         weapon_defaultspawnfunc(WEP_UZI);
1445 }
1446
1447 void spawnfunc_weapon_shotgun (void) {
1448         if(autocvar_sv_q3acompat_machineshotgunswap)
1449         if(self.classname != "droppedweapon")
1450         {
1451                 weapon_defaultspawnfunc(WEP_UZI);
1452                 return;
1453         }
1454         weapon_defaultspawnfunc(WEP_SHOTGUN);
1455 }
1456
1457 void spawnfunc_weapon_nex (void)
1458 {
1459         if (g_minstagib)
1460         {
1461                 minstagib_items(IT_CELLS);
1462                 self.think = minst_remove_item;
1463                 self.nextthink = time;
1464                 return;
1465         }
1466         weapon_defaultspawnfunc(WEP_NEX);
1467 }
1468
1469 void spawnfunc_weapon_minstanex (void)
1470 {
1471         if (g_minstagib)
1472         {
1473                 minstagib_items(IT_CELLS);
1474                 self.think = minst_remove_item;
1475                 self.nextthink = time;
1476                 return;
1477         }
1478         weapon_defaultspawnfunc(WEP_MINSTANEX);
1479 }
1480
1481 void spawnfunc_weapon_rocketlauncher (void)
1482 {
1483         if (g_minstagib)
1484         {
1485                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1486                 self.think = minst_remove_item;
1487                 self.nextthink = time;
1488                 return;
1489         }
1490         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1491 }
1492
1493 void spawnfunc_item_rockets (void) {
1494         if(!self.ammo_rockets)
1495                 self.ammo_rockets = g_pickup_rockets;
1496         if(!self.pickup_anyway)
1497                 self.pickup_anyway = g_pickup_ammo_anyway;
1498         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1499 }
1500
1501 void spawnfunc_item_shells (void);
1502 void spawnfunc_item_bullets (void) {
1503         if(!weaponswapping)
1504         if(autocvar_sv_q3acompat_machineshotgunswap)
1505         if(self.classname != "droppedweapon")
1506         {
1507                 weaponswapping = TRUE;
1508                 spawnfunc_item_shells();
1509                 weaponswapping = FALSE;
1510                 return;
1511         }
1512
1513         if(!self.ammo_nails)
1514                 self.ammo_nails = g_pickup_nails;
1515         if(!self.pickup_anyway)
1516                 self.pickup_anyway = g_pickup_ammo_anyway;
1517         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1518 }
1519
1520 void spawnfunc_item_cells (void) {
1521         if(!self.ammo_cells)
1522                 self.ammo_cells = g_pickup_cells;
1523         if(!self.pickup_anyway)
1524                 self.pickup_anyway = g_pickup_ammo_anyway;
1525         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1526 }
1527
1528 void spawnfunc_item_shells (void) {
1529         if(!weaponswapping)
1530         if(autocvar_sv_q3acompat_machineshotgunswap)
1531         if(self.classname != "droppedweapon")
1532         {
1533                 weaponswapping = TRUE;
1534                 spawnfunc_item_bullets();
1535                 weaponswapping = FALSE;
1536                 return;
1537         }
1538
1539         if(!self.ammo_shells)
1540                 self.ammo_shells = g_pickup_shells;
1541         if(!self.pickup_anyway)
1542                 self.pickup_anyway = g_pickup_ammo_anyway;
1543         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1544 }
1545
1546 void spawnfunc_item_armor_small (void) {
1547         if(!self.armorvalue)
1548                 self.armorvalue = g_pickup_armorsmall;
1549         if(!self.max_armorvalue)
1550                 self.max_armorvalue = g_pickup_armorsmall_max;
1551         if(!self.pickup_anyway)
1552                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1553         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1554 }
1555
1556 void spawnfunc_item_armor_medium (void) {
1557         if(!self.armorvalue)
1558                 self.armorvalue = g_pickup_armormedium;
1559         if(!self.max_armorvalue)
1560                 self.max_armorvalue = g_pickup_armormedium_max;
1561         if(!self.pickup_anyway)
1562                 self.pickup_anyway = g_pickup_armormedium_anyway;
1563         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1564 }
1565
1566 void spawnfunc_item_armor_big (void) {
1567         if(!self.armorvalue)
1568                 self.armorvalue = g_pickup_armorbig;
1569         if(!self.max_armorvalue)
1570                 self.max_armorvalue = g_pickup_armorbig_max;
1571         if(!self.pickup_anyway)
1572                 self.pickup_anyway = g_pickup_armorbig_anyway;
1573         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1574 }
1575
1576 void spawnfunc_item_armor_large (void) {
1577         if(!self.armorvalue)
1578                 self.armorvalue = g_pickup_armorlarge;
1579         if(!self.max_armorvalue)
1580                 self.max_armorvalue = g_pickup_armorlarge_max;
1581         if(!self.pickup_anyway)
1582                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1583         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1584 }
1585
1586 void spawnfunc_item_health_small (void) {
1587         if(!self.max_health)
1588                 self.max_health = g_pickup_healthsmall_max;
1589         if(!self.health)
1590                 self.health = g_pickup_healthsmall;
1591         if(!self.pickup_anyway)
1592                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1593         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1594 }
1595
1596 void spawnfunc_item_health_medium (void) {
1597         if(!self.max_health)
1598                 self.max_health = g_pickup_healthmedium_max;
1599         if(!self.health)
1600                 self.health = g_pickup_healthmedium;
1601         if(!self.pickup_anyway)
1602                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1603         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1604 }
1605
1606 void spawnfunc_item_health_large (void) {
1607         if(!self.max_health)
1608                 self.max_health = g_pickup_healthlarge_max;
1609         if(!self.health)
1610                 self.health = g_pickup_healthlarge;
1611         if(!self.pickup_anyway)
1612                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1613         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1614 }
1615
1616 void spawnfunc_item_health_mega (void) {
1617         if(g_minstagib) {
1618                 minstagib_items(IT_NAILS);
1619         } else {
1620                 if(!self.max_health)
1621                         self.max_health = g_pickup_healthmega_max;
1622                 if(!self.health)
1623                         self.health = g_pickup_healthmega;
1624                 if(!self.pickup_anyway)
1625                         self.pickup_anyway = g_pickup_healthmega_anyway;
1626                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1627         }
1628 }
1629
1630 // support old misnamed entities
1631 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1632 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1633 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1634 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1635 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1636
1637 void spawnfunc_item_strength (void) {
1638         if(g_minstagib) {
1639                 minstagib_items(IT_STRENGTH);
1640         } else {
1641                 precache_sound("weapons/strength_fire.wav");
1642                 if(!self.strength_finished)
1643                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1644                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1645         }
1646 }
1647
1648 void spawnfunc_item_invincible (void) {
1649         if(g_minstagib) {
1650                 minstagib_items(IT_INVINCIBLE);
1651         } else {
1652                 if(!self.invincible_finished)
1653                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1654                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1655         }
1656 }
1657
1658 void spawnfunc_item_minst_cells (void) {
1659         if (g_minstagib)
1660         {
1661                 minst_no_auto_cells = TRUE;
1662                 minstagib_items(IT_CELLS);
1663         }
1664         else
1665                 remove(self);
1666 }
1667
1668 // compatibility:
1669 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1670
1671 float GiveItems(entity e, float beginarg, float endarg);
1672 void target_items_use (void)
1673 {
1674         if(activator.classname == "droppedweapon")
1675         {
1676                 EXACTTRIGGER_TOUCH;
1677                 remove(activator);
1678                 return;
1679         }
1680
1681         if(activator.classname != "player")
1682                 return;
1683         if(activator.deadflag != DEAD_NO)
1684                 return;
1685         EXACTTRIGGER_TOUCH;
1686
1687         entity e;
1688         for(e = world; (e = find(e, classname, "droppedweapon")); )
1689                 if(e.enemy == activator)
1690                         remove(e);
1691
1692         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1693                 centerprint(activator, self.message);
1694 }
1695
1696 void spawnfunc_target_items (void)
1697 {
1698         float n, i, j;
1699         entity e;
1700
1701         self.use = target_items_use;
1702         if(!self.strength_finished)
1703                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1704         if(!self.invincible_finished)
1705                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1706         if(!self.superweapons_finished)
1707                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1708
1709         precache_sound("misc/itempickup.wav");
1710         precache_sound("misc/megahealth.wav");
1711         precache_sound("misc/armor25.wav");
1712         precache_sound("misc/powerup.wav");
1713         precache_sound("misc/poweroff.wav");
1714         precache_sound("weapons/weaponpickup.wav");
1715
1716         n = tokenize_console(self.netname);
1717         if(argv(0) == "give")
1718         {
1719                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1720         }
1721         else
1722         {
1723                 for(i = 0; i < n; ++i)
1724                 {
1725                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1726                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1727                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1728                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1729                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1730                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1731                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1732                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1733                         else
1734                         {
1735                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1736                                 {
1737                                         e = get_weaponinfo(j);
1738                                         if(argv(i) == e.netname)
1739                                         {
1740                                                 WEPSET_OR_EW(self, j);
1741                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1742                                                         weapon_action(e.weapon, WR_PRECACHE);
1743                                                 break;
1744                                         }
1745                                 }
1746                                 if(j > WEP_LAST)
1747                                         print("target_items: invalid item ", argv(i), "\n");
1748                         }
1749                 }
1750
1751                 string itemprefix, valueprefix;
1752                 if(self.spawnflags == 0)
1753                 {
1754                         itemprefix = "";
1755                         valueprefix = "";
1756                 }
1757                 else if(self.spawnflags == 1)
1758                 {
1759                         itemprefix = "max ";
1760                         valueprefix = "max ";
1761                 }
1762                 else if(self.spawnflags == 2)
1763                 {
1764                         itemprefix = "min ";
1765                         valueprefix = "min ";
1766                 }
1767                 else if(self.spawnflags == 4)
1768                 {
1769                         itemprefix = "minus ";
1770                         valueprefix = "max ";
1771                 }
1772                 else
1773                 {
1774                         error("invalid spawnflags");
1775 #ifdef GMQCC
1776                         itemprefix = string_null;
1777                         valueprefix = string_null;
1778 #endif
1779                 }
1780
1781                 self.netname = "";
1782                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1783                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1784                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1785                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1786                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1787                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1788                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1789                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1790                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1791                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1792                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1793                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1794                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1795                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1796                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1797                 {
1798                         e = get_weaponinfo(j);
1799                         if(e.weapon)
1800                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1801                 }
1802         }
1803         self.netname = strzone(self.netname);
1804         //print(self.netname, "\n");
1805
1806         n = tokenize_console(self.netname);
1807         for(i = 0; i < n; ++i)
1808         {
1809                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1810                 {
1811                         e = get_weaponinfo(j);
1812                         if(argv(i) == e.netname)
1813                         {
1814                                 weapon_action(e.weapon, WR_PRECACHE);
1815                                 break;
1816                         }
1817                 }
1818         }
1819 }
1820
1821 void spawnfunc_item_fuel(void)
1822 {
1823         if(!self.ammo_fuel)
1824                 self.ammo_fuel = g_pickup_fuel;
1825         if(!self.pickup_anyway)
1826                 self.pickup_anyway = g_pickup_ammo_anyway;
1827         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1828 }
1829
1830 void spawnfunc_item_fuel_regen(void)
1831 {
1832         if(start_items & IT_FUEL_REGEN)
1833         {
1834                 spawnfunc_item_fuel();
1835                 return;
1836         }
1837         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1838 }
1839
1840 void spawnfunc_item_jetpack(void)
1841 {
1842         if(g_grappling_hook)
1843                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1844         if(!self.ammo_fuel)
1845                 self.ammo_fuel = g_pickup_fuel_jetpack;
1846         if(start_items & IT_JETPACK)
1847         {
1848                 spawnfunc_item_fuel();
1849                 return;
1850         }
1851         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1852 }
1853
1854
1855 #define OP_SET 0
1856 #define OP_MIN 1
1857 #define OP_MAX 2
1858 #define OP_PLUS 3
1859 #define OP_MINUS 4
1860
1861 float GiveWeapon(entity e, float wpn, float op, float val)
1862 {
1863         float v0, v1;
1864         v0 = WEPSET_CONTAINS_EW(e, wpn);
1865         switch(op)
1866         {
1867                 case OP_SET:
1868                         if(val > 0)
1869                                 WEPSET_OR_EW(e, wpn);
1870                         else
1871                                 WEPSET_ANDNOT_EW(e, wpn);
1872                         break;
1873                 case OP_MIN:
1874                 case OP_PLUS:
1875                         if(val > 0)
1876                                 WEPSET_OR_EW(e, wpn);
1877                         break;
1878                 case OP_MAX:
1879                         if(val <= 0)
1880                                 WEPSET_ANDNOT_EW(e, wpn);
1881                         break;
1882                 case OP_MINUS:
1883                         if(val > 0)
1884                                 WEPSET_ANDNOT_EW(e, wpn);
1885                         break;
1886         }
1887         v1 = WEPSET_CONTAINS_EW(e, wpn);
1888         return (v0 != v1);
1889 }
1890
1891 float GiveBit(entity e, .float fld, float bit, float op, float val)
1892 {
1893         float v0, v1;
1894         v0 = (e.fld & bit);
1895         switch(op)
1896         {
1897                 case OP_SET:
1898                         if(val > 0)
1899                                 e.fld |= bit;
1900                         else
1901                                 e.fld &~= bit;
1902                         break;
1903                 case OP_MIN:
1904                 case OP_PLUS:
1905                         if(val > 0)
1906                                 e.fld |= bit;
1907                         break;
1908                 case OP_MAX:
1909                         if(val <= 0)
1910                                 e.fld &~= bit;
1911                         break;
1912                 case OP_MINUS:
1913                         if(val > 0)
1914                                 e.fld &~= bit;
1915                         break;
1916         }
1917         v1 = (e.fld & bit);
1918         return (v0 != v1);
1919 }
1920
1921 float GiveValue(entity e, .float fld, float op, float val)
1922 {
1923         float v0, v1;
1924         v0 = e.fld;
1925         switch(op)
1926         {
1927                 case OP_SET:
1928                         e.fld = val;
1929                         break;
1930                 case OP_MIN:
1931                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1932                         break;
1933                 case OP_MAX:
1934                         e.fld = min(e.fld, val);
1935                         break;
1936                 case OP_PLUS:
1937                         e.fld += val;
1938                         break;
1939                 case OP_MINUS:
1940                         e.fld -= val;
1941                         break;
1942         }
1943         v1 = e.fld;
1944         return (v0 != v1);
1945 }
1946
1947 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1948 {
1949         if(v1 == v0)
1950                 return;
1951         if(v1 <= v0 - t)
1952         {
1953                 if(snd_decr != "")
1954                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1955         }
1956         else if(v0 >= v0 + t)
1957         {
1958                 if(snd_incr != "")
1959                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1960         }
1961 }
1962
1963 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1964 {
1965         if(v0 < v1)
1966                 e.rotfield = max(e.rotfield, time + rottime);
1967         else if(v0 > v1)
1968                 e.regenfield = max(e.regenfield, time + regentime);
1969 }
1970
1971 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1972 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1973 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1974 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1975 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1976 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1977
1978 float GiveItems(entity e, float beginarg, float endarg)
1979 {
1980         float got, i, j, val, op;
1981         float _switchweapon;
1982         entity wi;
1983         string cmd;
1984
1985         val = 999;
1986         op = OP_SET;
1987
1988         got = 0;
1989
1990         _switchweapon = FALSE;
1991         if (e.autoswitch)
1992                 if (e.switchweapon == w_getbestweapon(e))
1993                         _switchweapon = TRUE;
1994
1995         e.strength_finished = max(0, e.strength_finished - time);
1996         e.invincible_finished = max(0, e.invincible_finished - time);
1997         e.superweapons_finished = max(0, e.superweapons_finished - time);
1998
1999         PREGIVE(e, items);
2000         PREGIVE_WEAPONS(e);
2001         PREGIVE(e, strength_finished);
2002         PREGIVE(e, invincible_finished);
2003         PREGIVE(e, superweapons_finished);
2004         PREGIVE(e, ammo_nails);
2005         PREGIVE(e, ammo_cells);
2006         PREGIVE(e, ammo_shells);
2007         PREGIVE(e, ammo_rockets);
2008         PREGIVE(e, ammo_fuel);
2009         PREGIVE(e, armorvalue);
2010         PREGIVE(e, health);
2011
2012         for(i = beginarg; i < endarg; ++i)
2013         {
2014                 cmd = argv(i);
2015
2016                 if(cmd == "0" || stof(cmd))
2017                 {
2018                         val = stof(cmd);
2019                         continue;
2020                 }
2021                 switch(cmd)
2022                 {
2023                         case "no":
2024                                 op = OP_MAX;
2025                                 val = 0;
2026                                 continue;
2027                         case "max":
2028                                 op = OP_MAX;
2029                                 continue;
2030                         case "min":
2031                                 op = OP_MIN;
2032                                 continue;
2033                         case "plus":
2034                                 op = OP_PLUS;
2035                                 continue;
2036                         case "minus":
2037                                 op = OP_MINUS;
2038                                 continue;
2039                         case "ALL":
2040                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
2041                                 got += GiveValue(e, strength_finished, op, val);
2042                                 got += GiveValue(e, invincible_finished, op, val);
2043                                 got += GiveValue(e, superweapons_finished, op, val);
2044                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
2045                         case "all":
2046                                 got += GiveBit(e, items, IT_JETPACK, op, val);
2047                                 got += GiveValue(e, health, op, val);
2048                                 got += GiveValue(e, armorvalue, op, val);
2049                         case "allweapons":
2050                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2051                                 {
2052                                         wi = get_weaponinfo(j);
2053                                         if(wi.weapon)
2054                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
2055                                                         got += GiveWeapon(e, j, op, val);
2056                                 }
2057                         case "allammo":
2058                                 got += GiveValue(e, ammo_cells, op, val);
2059                                 got += GiveValue(e, ammo_shells, op, val);
2060                                 got += GiveValue(e, ammo_nails, op, val);
2061                                 got += GiveValue(e, ammo_rockets, op, val);
2062                                 got += GiveValue(e, ammo_fuel, op, val);
2063                                 break;
2064                         case "unlimited_ammo":
2065                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
2066                                 break;
2067                         case "unlimited_weapon_ammo":
2068                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
2069                                 break;
2070                         case "unlimited_superweapons":
2071                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
2072                                 break;
2073                         case "jetpack":
2074                                 got += GiveBit(e, items, IT_JETPACK, op, val);
2075                                 break;
2076                         case "fuel_regen":
2077                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
2078                                 break;
2079                         case "strength":
2080                                 got += GiveValue(e, strength_finished, op, val);
2081                                 break;
2082                         case "invincible":
2083                                 got += GiveValue(e, invincible_finished, op, val);
2084                                 break;
2085                         case "superweapons":
2086                                 got += GiveValue(e, superweapons_finished, op, val);
2087                                 break;
2088                         case "cells":
2089                                 got += GiveValue(e, ammo_cells, op, val);
2090                                 break;
2091                         case "shells":
2092                                 got += GiveValue(e, ammo_shells, op, val);
2093                                 break;
2094                         case "nails":
2095                         case "bullets":
2096                                 got += GiveValue(e, ammo_nails, op, val);
2097                                 break;
2098                         case "rockets":
2099                                 got += GiveValue(e, ammo_rockets, op, val);
2100                                 break;
2101                         case "health":
2102                                 got += GiveValue(e, health, op, val);
2103                                 break;
2104                         case "armor":
2105                                 got += GiveValue(e, armorvalue, op, val);
2106                                 break;
2107                         case "fuel":
2108                                 got += GiveValue(e, ammo_fuel, op, val);
2109                                 break;
2110                         default:
2111                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2112                                 {
2113                                         wi = get_weaponinfo(j);
2114                                         if(cmd == wi.netname)
2115                                         {
2116                                                 got += GiveWeapon(e, j, op, val);
2117                                                 break;
2118                                         }
2119                                 }
2120                                 if(j > WEP_LAST)
2121                                         print("give: invalid item ", cmd, "\n");
2122                                 break;
2123                 }
2124                 val = 999;
2125                 op = OP_SET;
2126         }
2127
2128         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
2129         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
2130         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
2131         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
2132         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2133         {
2134                 wi = get_weaponinfo(j);
2135                 if(wi.weapon)
2136                 {
2137                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
2138                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
2139                                 if(WEPSET_CONTAINS_EW(e, j))
2140                                         weapon_action(wi.weapon, WR_PRECACHE);
2141                 }
2142         }
2143         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
2144         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
2145         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
2146         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
2147         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
2148         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
2149         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
2150         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
2151         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
2152
2153         if(e.superweapons_finished <= 0)
2154                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
2155                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2156
2157         if (g_minstagib)
2158         {
2159                 e.health = bound(0, e.health, 100);
2160                 e.armorvalue = bound(0, e.armorvalue, 999);
2161         }
2162
2163         if(e.strength_finished <= 0)
2164                 e.strength_finished = 0;
2165         else
2166                 e.strength_finished += time;
2167         if(e.invincible_finished <= 0)
2168                 e.invincible_finished = 0;
2169         else
2170                 e.invincible_finished += time;
2171         if(e.superweapons_finished <= 0)
2172                 e.superweapons_finished = 0;
2173         else
2174                 e.superweapons_finished += time;
2175
2176         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
2177                 _switchweapon = TRUE;
2178         if(_switchweapon)
2179                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
2180
2181         return got;
2182 }
2183 #endif