qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6
   7     #include "bot/bot.qh"
   8     #include "bot/waypoints.qh"
   9
  10     #include "mutators/mutators_include.qh"
  11
  12     #include "weapons/common.qh"
  13     #include "weapons/selection.qh"
  14     #include "weapons/weaponsystem.qh"
  15
  16     #include "../common/constants.qh"
  17     #include "../common/deathtypes.qh"
  18     #include "../common/notifications.qh"
  19         #include "../common/triggers/subs.qh"
  20     #include "../common/util.qh"
  21
  22     #include "../common/monsters/all.qh"
  23
  24     #include "../common/weapons/all.qh"
  25
  26     #include "../lib/warpzone/util_server.qh"
  27 #endif
  28
  29 #ifdef CSQC
  30 void ItemDraw(entity self)
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple(entity this)
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void Item_PreDraw()
  78 {SELFPARAM();
  79         vector org;
  80         float alph;
  81         org = getpropertyvec(VF_ORIGIN);
  82         if(!checkpvs(org, self)) // this makes sense as long as we don't support recursive warpzones
  83                 alph = 0;
  84         else if(self.fade_start)
  85                 alph = bound(0, (self.fade_end - vlen(org - self.origin - 0.5 * (self.mins + self.maxs))) / (self.fade_end - self.fade_start), 1);
  86         else
  87                 alph = 1;
  88         //printf("%v <-> %v\n", view_origin, self.origin + 0.5 * (self.mins + self.maxs));
  89         if(self.ItemStatus & ITS_AVAILABLE)
  90                 self.alpha = alph;
  91         if(alph <= 0)
  92                 self.drawmask = 0;
  93         else
  94                 self.drawmask = MASK_NORMAL;
  95 }
  96
  97 void ItemRead(float _IsNew)
  98 {SELFPARAM();
  99     int sf = ReadByte();
 100
 101     if(sf & ISF_LOCATION)
 102     {
 103         self.origin_x = ReadCoord();
 104         self.origin_y = ReadCoord();
 105         self.origin_z = ReadCoord();
 106         setorigin(self, self.origin);
 107         self.oldorigin = self.origin;
 108     }
 109
 110     if(sf & ISF_ANGLES)
 111     {
 112         self.angles_x = ReadAngle();
 113         self.angles_y = ReadAngle();
 114         self.angles_z = ReadAngle();
 115         self.move_angles = self.angles;
 116     }
 117
 118     if(sf & ISF_SIZE)
 119     {
 120         float use_bigsize = ReadByte();
 121         setsize(self, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 122     }
 123
 124     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 125     {
 126         self.ItemStatus = ReadByte();
 127
 128         if(self.ItemStatus & ITS_AVAILABLE)
 129         {
 130             self.alpha = 1;
 131             self.colormod = self.glowmod = '1 1 1';
 132         }
 133         else
 134         {
 135             if (autocvar_cl_ghost_items_color)
 136             {
 137                 self.alpha = autocvar_cl_ghost_items;
 138                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 139             }
 140             else
 141                 self.alpha = -1;
 142         }
 143
 144         if(autocvar_cl_fullbright_items)
 145             if(self.ItemStatus & ITS_ALLOWFB)
 146                 self.effects |= EF_FULLBRIGHT;
 147
 148         if(self.ItemStatus & ITS_STAYWEP)
 149         {
 150             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 151             self.alpha = autocvar_cl_weapon_stay_alpha;
 152
 153         }
 154
 155         if(self.ItemStatus & ITS_POWERUP)
 156         {
 157             if(self.ItemStatus & ITS_AVAILABLE)
 158                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 159             else
 160                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 161         }
 162     }
 163
 164     if(sf & ISF_MODEL)
 165     {
 166         self.drawmask  = MASK_NORMAL;
 167                 self.move_movetype = self.movetype = MOVETYPE_TOSS;
 168         self.draw       = ItemDraw;
 169
 170         self.fade_end = ReadShort();
 171         self.fade_start = ReadShort();
 172         if(self.fade_start && !autocvar_cl_items_nofade)
 173                 self.predraw = Item_PreDraw;
 174
 175         if(self.mdl)
 176             strunzone(self.mdl);
 177
 178         self.mdl = "";
 179         string _fn = ReadString();
 180
 181         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 182         {
 183             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 184             self.draw = ItemDrawSimple;
 185
 186             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 187                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 188             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 189                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 190             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 191                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 192             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 193                 self.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 194             else
 195             {
 196                 self.draw = ItemDraw;
 197                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it\n");
 198             }
 199         }
 200
 201         if(self.draw != ItemDrawSimple)
 202             self.mdl = strzone(_fn);
 203
 204
 205         if(self.mdl == "")
 206             LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 207
 208         precache_model(self.mdl);
 209         _setmodel(self, self.mdl);
 210     }
 211
 212     if(sf & ISF_COLORMAP)
 213         self.colormap = ReadShort();
 214
 215     if(sf & ISF_DROP)
 216     {
 217         self.gravity = 1;
 218         //self.move_angles = '0 0 0';
 219         self.move_movetype = MOVETYPE_TOSS;
 220         self.move_velocity_x = ReadCoord();
 221         self.move_velocity_y = ReadCoord();
 222         self.move_velocity_z = ReadCoord();
 223         self.velocity = self.move_velocity;
 224         self.move_origin = self.oldorigin;
 225
 226         if(!self.move_time)
 227         {
 228             self.move_time = time;
 229             self.spawntime = time;
 230         }
 231         else
 232             self.move_time = max(self.move_time, time);
 233     }
 234
 235     if(autocvar_cl_animate_items)
 236     {
 237         if(self.ItemStatus & ITS_ANIMATE1)
 238             self.move_avelocity = '0 180 0';
 239
 240         if(self.ItemStatus & ITS_ANIMATE2)
 241             self.move_avelocity = '0 -90 0';
 242     }
 243 }
 244
 245 #endif
 246
 247 #ifdef SVQC
 248 bool ItemSend(entity this, entity to, int sf)
 249 {
 250         if(self.gravity)
 251                 sf |= ISF_DROP;
 252         else
 253                 sf &= ~ISF_DROP;
 254
 255         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 256         WriteByte(MSG_ENTITY, sf);
 257
 258         //WriteByte(MSG_ENTITY, self.cnt);
 259         if(sf & ISF_LOCATION)
 260         {
 261                 WriteCoord(MSG_ENTITY, self.origin.x);
 262                 WriteCoord(MSG_ENTITY, self.origin.y);
 263                 WriteCoord(MSG_ENTITY, self.origin.z);
 264         }
 265
 266         if(sf & ISF_ANGLES)
 267         {
 268                 WriteAngle(MSG_ENTITY, self.angles_x);
 269                 WriteAngle(MSG_ENTITY, self.angles_y);
 270                 WriteAngle(MSG_ENTITY, self.angles_z);
 271         }
 272
 273         if(sf & ISF_SIZE)
 274         {
 275                 Pickup p = this.itemdef;
 276                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 277         }
 278
 279         if(sf & ISF_STATUS)
 280                 WriteByte(MSG_ENTITY, self.ItemStatus);
 281
 282         if(sf & ISF_MODEL)
 283         {
 284                 WriteShort(MSG_ENTITY, self.fade_end);
 285                 WriteShort(MSG_ENTITY, self.fade_start);
 286
 287                 if(self.mdl == "")
 288                         LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 289
 290                 WriteString(MSG_ENTITY, self.mdl);
 291         }
 292
 293
 294         if(sf & ISF_COLORMAP)
 295                 WriteShort(MSG_ENTITY, self.colormap);
 296
 297         if(sf & ISF_DROP)
 298         {
 299                 WriteCoord(MSG_ENTITY, self.velocity.x);
 300                 WriteCoord(MSG_ENTITY, self.velocity.y);
 301                 WriteCoord(MSG_ENTITY, self.velocity.z);
 302         }
 303
 304         return true;
 305 }
 306
 307 void ItemUpdate(entity item)
 308 {
 309         item.SendFlags |= ISF_LOCATION;
 310 }
 311
 312 bool have_pickup_item(entity this)
 313 {
 314         if(this.itemdef.instanceOfPowerup)
 315         {
 316                 if(autocvar_g_powerups > 0)
 317                         return true;
 318                 if(autocvar_g_powerups == 0)
 319                         return false;
 320         }
 321         else
 322         {
 323                 if(autocvar_g_pickup_items > 0)
 324                         return true;
 325                 if(autocvar_g_pickup_items == 0)
 326                         return false;
 327                 if(g_weaponarena)
 328                         if(this.weapons || (this.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 329                                 return false;
 330         }
 331         return true;
 332 }
 333
 334 /*
 335 float Item_Customize()
 336 {
 337         if(self.spawnshieldtime)
 338                 return true;
 339         if(self.weapons & ~other.weapons)
 340         {
 341                 self.colormod = '0 0 0';
 342                 self.glowmod = self.colormod;
 343                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 344                 return true;
 345         }
 346         else
 347         {
 348                 if(g_ghost_items)
 349                 {
 350                         self.colormod = stov(autocvar_g_ghost_items_color);
 351                         self.glowmod = self.colormod;
 352                         self.alpha = g_ghost_items;
 353                         return true;
 354                 }
 355                 else
 356                         return false;
 357         }
 358 }
 359 */
 360
 361 void Item_Show (entity e, float mode)
 362 {
 363         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 364         e.ItemStatus &= ~ITS_STAYWEP;
 365         if (mode > 0)
 366         {
 367                 // make the item look normal, and be touchable
 368                 e.model = e.mdl;
 369                 e.solid = SOLID_TRIGGER;
 370                 e.spawnshieldtime = 1;
 371                 e.ItemStatus |= ITS_AVAILABLE;
 372         }
 373         else if (mode < 0)
 374         {
 375                 // hide the item completely
 376                 e.model = string_null;
 377                 e.solid = SOLID_NOT;
 378                 e.spawnshieldtime = 1;
 379                 e.ItemStatus &= ~ITS_AVAILABLE;
 380         }
 381         else {
 382         entity def = e.itemdef;
 383         bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 384                 || e.team // weapon stay isn't supported for teamed weapons
 385                 ;
 386         if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 387         {
 388                 // make the item translucent and not touchable
 389                 e.model = e.mdl;
 390                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 391                 e.effects |= EF_STARDUST;
 392                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 393                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 394         }
 395         else
 396         {
 397                 //setmodel(e, "null");
 398                 e.solid = SOLID_NOT;
 399                 e.colormod = '0 0 0';
 400                 e.glowmod = e.colormod;
 401                 e.spawnshieldtime = 1;
 402                 e.ItemStatus &= ~ITS_AVAILABLE;
 403         }}
 404
 405         if (e.items & ITEM_Strength.m_itemid || e.items & ITEM_Shield.m_itemid)
 406                 e.ItemStatus |= ITS_POWERUP;
 407
 408         if (autocvar_g_nodepthtestitems)
 409                 e.effects |= EF_NODEPTHTEST;
 410
 411
 412         if (autocvar_g_fullbrightitems)
 413                 e.ItemStatus |= ITS_ALLOWFB;
 414
 415         if (autocvar_sv_simple_items)
 416                 e.ItemStatus |= ITS_ALLOWSI;
 417
 418         // relink entity (because solid may have changed)
 419         setorigin(e, e.origin);
 420         e.SendFlags |= ISF_STATUS;
 421 }
 422
 423 void Item_Think()
 424 {SELFPARAM();
 425         self.nextthink = time;
 426         if(self.origin != self.oldorigin)
 427         {
 428                 self.oldorigin = self.origin;
 429                 ItemUpdate(self);
 430         }
 431 }
 432
 433 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 434 bool Item_ItemsTime_Allow(GameItem it, WepSet _weapons);
 435 float Item_ItemsTime_UpdateTime(entity e, float t);
 436 void Item_ItemsTime_SetTime(entity e, float t);
 437 void Item_ItemsTime_SetTimesForAllPlayers();
 438
 439 void Item_Respawn (void)
 440 {SELFPARAM();
 441         Item_Show(self, 1);
 442         // this is ugly...
 443         if(self.items == ITEM_Strength.m_itemid)
 444                 sound (self, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTEN_NORM);   // play respawn sound
 445         else if(self.items == ITEM_Shield.m_itemid)
 446                 sound (self, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTEN_NORM);     // play respawn sound
 447         else
 448                 sound (self, CH_TRIGGER, SND_ITEMRESPAWN, VOL_BASE, ATTEN_NORM);        // play respawn sound
 449         setorigin (self, self.origin);
 450
 451     if (Item_ItemsTime_Allow(self.itemdef, self.weapons))
 452         {
 453                 float t = Item_ItemsTime_UpdateTime(self, 0);
 454                 Item_ItemsTime_SetTime(self, t);
 455                 Item_ItemsTime_SetTimesForAllPlayers();
 456         }
 457
 458         self.think = Item_Think;
 459         self.nextthink = time;
 460
 461         //Send_Effect(EFFECT_ITEM_RESPAWN, self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 462         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 463 }
 464
 465 void Item_RespawnCountdown (void)
 466 {SELFPARAM();
 467         if(self.count >= ITEM_RESPAWN_TICKS)
 468         {
 469                 if(self.waypointsprite_attached)
 470                         WaypointSprite_Kill(self.waypointsprite_attached);
 471                 Item_Respawn();
 472         }
 473         else
 474         {
 475                 self.nextthink = time + 1;
 476                 self.count += 1;
 477                 if(self.count == 1)
 478                 {
 479                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 480                         do {
 481                                 {
 482                                         entity wi = get_weaponinfo(self.weapon);
 483                                         if (wi.m_id) {
 484                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_Weapon);
 485                                                 wp.wp_extra = wi.m_id;
 486                                                 break;
 487                                         }
 488                                 }
 489                                 {
 490                                         entity ii = self.itemdef;
 491                                         if (ii.m_id) {
 492                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_Item);
 493                                                 wp.wp_extra = ii.m_id;
 494                                                 break;
 495                                         }
 496                                 }
 497                         } while (0);
 498             if(self.waypointsprite_attached)
 499             {
 500                 GameItem def = self.itemdef;
 501                 if (Item_ItemsTime_SpectatorOnly(def))
 502                     WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 503                 WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 504             }
 505                 }
 506
 507                 if(self.waypointsprite_attached)
 508                 {
 509                         setself(self.waypointsprite_attached);
 510                         entity e;
 511                         FOR_EACH_REALCLIENT(e)
 512                                 if(self.waypointsprite_visible_for_player(e))
 513                                 {
 514                                         msg_entity = e;
 515                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 516                                 }
 517                         setself(this);
 518
 519                         WaypointSprite_Ping(self.waypointsprite_attached);
 520                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 521                 }
 522                 else
 523                         sound(self, CH_TRIGGER, SND_ITEMRESPAWNCOUNTDOWN, VOL_BASE, ATTEN_NORM);        // play respawn sound
 524         }
 525 }
 526
 527 void Item_RespawnThink()
 528 {SELFPARAM();
 529         self.nextthink = time;
 530         if(self.origin != self.oldorigin)
 531         {
 532                 self.oldorigin = self.origin;
 533                 ItemUpdate(self);
 534         }
 535
 536         if(time >= self.wait)
 537                 Item_Respawn();
 538 }
 539
 540 void Item_ScheduleRespawnIn(entity e, float t)
 541 {
 542         if (Item_ItemsTime_Allow(e.itemdef, e.weapons))
 543         {
 544                 e.think = Item_RespawnCountdown;
 545                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 546                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 547                 e.count = 0;
 548                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 549                 Item_ItemsTime_SetTime(e, t);
 550                 Item_ItemsTime_SetTimesForAllPlayers();
 551         }
 552         else
 553         {
 554                 e.think = Item_RespawnThink;
 555                 e.nextthink = time;
 556                 e.scheduledrespawntime = time + t;
 557                 e.wait = time + t;
 558         }
 559 }
 560
 561 void Item_ScheduleRespawn(entity e)
 562 {
 563         if(e.respawntime > 0)
 564         {
 565                 Item_Show(e, 0);
 566                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 567         }
 568         else // if respawntime is -1, this item does not respawn
 569                 Item_Show(e, -1);
 570 }
 571
 572 void Item_ScheduleInitialRespawn(entity e)
 573 {
 574         Item_Show(e, 0);
 575         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 576 }
 577
 578 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 579 {
 580         if (!item.(ammotype))
 581                 return false;
 582
 583         if (item.spawnshieldtime)
 584         {
 585                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 586                 {
 587                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 588                         goto YEAH;
 589                 }
 590         }
 591         else if(g_weapon_stay == 2)
 592         {
 593                 float mi = min(item.(ammotype), ammomax);
 594                 if (player.(ammotype) < mi)
 595                 {
 596                         player.(ammotype) = mi;
 597                         goto YEAH;
 598                 }
 599         }
 600
 601         return false;
 602
 603 :YEAH
 604         switch(mode)
 605         {
 606                 case ITEM_MODE_FUEL:
 607                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 608                         break;
 609                 case ITEM_MODE_HEALTH:
 610                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 611                         break;
 612                 case ITEM_MODE_ARMOR:
 613                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 614                         break;
 615                 default:
 616                         break;
 617         }
 618         return true;
 619 }
 620
 621 float Item_GiveTo(entity item, entity player)
 622 {
 623         float _switchweapon;
 624         float pickedup;
 625         float it;
 626         float i;
 627
 628         // if nothing happens to player, just return without taking the item
 629         pickedup = false;
 630         _switchweapon = false;
 631         // in case the player has autoswitch enabled do the following:
 632         // if the player is using their best weapon before items are given, they
 633         // probably want to switch to an even better weapon after items are given
 634         if (player.autoswitch)
 635         if (player.switchweapon == w_getbestweapon(player))
 636                 _switchweapon = true;
 637
 638         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 639                 _switchweapon = true;
 640
 641         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 642         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 643         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 644         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 645         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 646         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 647         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 648         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 649
 650         if (item.itemdef.instanceOfWeaponPickup)
 651         {
 652                 WepSet it;
 653                 it = item.weapons;
 654                 it &= ~player.weapons;
 655
 656                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 657                 {
 658                         pickedup = true;
 659                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 660                         if(it & WepSet_FromWeapon(i))
 661                         {
 662                                 W_DropEvent(wr_pickup, player, i, item);
 663                                 W_GiveWeapon(player, i);
 664                         }
 665                 }
 666         }
 667
 668         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 669         {
 670                 pickedup = true;
 671                 player.items |= it;
 672                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 673         }
 674
 675         if (item.strength_finished)
 676         {
 677                 pickedup = true;
 678                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 679         }
 680         if (item.invincible_finished)
 681         {
 682                 pickedup = true;
 683                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 684         }
 685         if (item.superweapons_finished)
 686         {
 687                 pickedup = true;
 688                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 689         }
 690
 691 :skip
 692
 693         // always eat teamed entities
 694         if(item.team)
 695                 pickedup = true;
 696
 697         if (!pickedup)
 698                 return 0;
 699
 700         // crude hack to enforce switching weapons
 701         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 702         {
 703                 W_SwitchWeapon_Force(player, item.weapon);
 704                 return 1;
 705         }
 706
 707         if (_switchweapon)
 708                 if (player.switchweapon != w_getbestweapon(player))
 709                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 710
 711         return 1;
 712 }
 713
 714 void Item_Touch (void)
 715 {SELFPARAM();
 716         entity e, head;
 717
 718         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 719         if(self.classname == "droppedweapon")
 720         {
 721                 if (ITEM_TOUCH_NEEDKILL())
 722                 {
 723                         remove(self);
 724                         return;
 725                 }
 726         }
 727
 728         if(!(other.flags & FL_PICKUPITEMS)
 729         || other.frozen
 730         || other.deadflag
 731         || (self.solid != SOLID_TRIGGER)
 732         || (self.owner == other)
 733         || (time < self.item_spawnshieldtime)
 734         ) { return;}
 735
 736         switch(MUTATOR_CALLHOOK(ItemTouch, self, other))
 737         {
 738                 case MUT_ITEMTOUCH_RETURN: { return; }
 739                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 740         }
 741
 742         if (self.classname == "droppedweapon")
 743         {
 744                 self.strength_finished = max(0, self.strength_finished - time);
 745                 self.invincible_finished = max(0, self.invincible_finished - time);
 746                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 747         }
 748         entity it = self.itemdef;
 749         bool gave = (it && it.instanceOfPickup) ? ITEM_HANDLE(Pickup, it, self, other) : Item_GiveTo(self, other);
 750         if (!gave)
 751         {
 752                 if (self.classname == "droppedweapon")
 753                 {
 754                         // undo what we did above
 755                         self.strength_finished += time;
 756                         self.invincible_finished += time;
 757                         self.superweapons_finished += time;
 758                 }
 759                 return;
 760         }
 761
 762         :pickup
 763
 764         other.last_pickup = time;
 765
 766         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 767         _sound (other, CH_TRIGGER, (self.item_pickupsound ? self.item_pickupsound : self.item_pickupsound_ent.sound_str()), VOL_BASE, ATTEN_NORM);
 768
 769         if (self.classname == "droppedweapon")
 770                 remove (self);
 771         else if (self.spawnshieldtime)
 772         {
 773                 if(self.team)
 774                 {
 775                         RandomSelection_Init();
 776                         for(head = world; (head = findfloat(head, team, self.team)); )
 777                         {
 778                                 if(head.flags & FL_ITEM)
 779                                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 780                                 {
 781                                         Item_Show(head, -1);
 782                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 783                                 }
 784                         }
 785                         e = RandomSelection_chosen_ent;
 786
 787                 }
 788                 else
 789                         e = self;
 790                 Item_ScheduleRespawn(e);
 791         }
 792 }
 793
 794 void Item_Reset(entity this)
 795 {
 796         Item_Show(this, !this.state);
 797         setorigin(this, this.origin);
 798
 799         if (this.classname != "droppedweapon")
 800         {
 801                 this.think = Item_Think;
 802                 this.nextthink = time;
 803
 804                 if (this.waypointsprite_attached)
 805                         WaypointSprite_Kill(this.waypointsprite_attached);
 806
 807                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 808                         Item_ScheduleInitialRespawn(this);
 809         }
 810 }
 811 void Item_Reset_self() { SELFPARAM(); Item_Reset(this); }
 812
 813 void Item_FindTeam()
 814 {SELFPARAM();
 815         entity head, e;
 816
 817         if(self.effects & EF_NODRAW)
 818         {
 819                 // marker for item team search
 820                 LOG_TRACE("Initializing item team ", ftos(self.team), "\n");
 821                 RandomSelection_Init();
 822                 for(head = world; (head = findfloat(head, team, self.team)); )
 823                 if(head.flags & FL_ITEM)
 824                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 825                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 826                 e = RandomSelection_chosen_ent;
 827                 e.state = 0;
 828                 Item_Show(e, 1);
 829
 830                 for(head = world; (head = findfloat(head, team, self.team)); )
 831                 if(head.flags & FL_ITEM)
 832                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 833                 {
 834                         if(head != e)
 835                         {
 836                                 // make it a non-spawned item
 837                                 Item_Show(head, -1);
 838                                 head.state = 1; // state 1 = initially hidden item
 839                         }
 840                         head.effects &= ~EF_NODRAW;
 841                 }
 842
 843                 Item_Reset(self);
 844         }
 845 }
 846
 847 // Savage: used for item garbage-collection
 848 // TODO: perhaps nice special effect?
 849 void RemoveItem(void)
 850 {SELFPARAM();
 851         if(wasfreed(self) || !self) { return; }
 852         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 853         remove(self);
 854 }
 855
 856 // pickup evaluation functions
 857 // these functions decide how desirable an item is to the bots
 858
 859 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 860
 861 float weapon_pickupevalfunc(entity player, entity item)
 862 {
 863         float c;
 864
 865         // See if I have it already
 866         if(item.weapons & ~player.weapons)
 867         {
 868                 // If I can pick it up
 869                 if(!item.spawnshieldtime)
 870                         c = 0;
 871                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 872                 {
 873                         // Skilled bots will grab more
 874                         c = bound(0, skill / 10, 1) * 0.5;
 875                 }
 876                 else
 877                         c = 0;
 878         }
 879         else
 880                 c = 1;
 881
 882         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 883         if( bot_custom_weapon && c )
 884         {
 885                 // Find the highest position on any range
 886                 int position = -1;
 887                 for (int j = 0; j < WEP_LAST ; ++j){
 888                         if(
 889                                         bot_weapons_far[j] == item.weapon ||
 890                                         bot_weapons_mid[j] == item.weapon ||
 891                                         bot_weapons_close[j] == item.weapon
 892                           )
 893                         {
 894                                 position = j;
 895                                 break;
 896                         }
 897                 }
 898
 899                 // Rate it
 900                 if (position >= 0 )
 901                 {
 902                         position = WEP_LAST - position;
 903                         // item.bot_pickupbasevalue is overwritten here
 904                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 905                 }
 906         }
 907
 908         return item.bot_pickupbasevalue * c;
 909 }
 910
 911 float commodity_pickupevalfunc(entity player, entity item)
 912 {
 913         float c, i;
 914         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 915         entity wi;
 916         c = 0;
 917
 918         // Detect needed ammo
 919         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 920         {
 921                 wi = get_weaponinfo(i);
 922
 923                 if (!(player.weapons & WepSet_FromWeapon(i)))
 924                         continue;
 925
 926                 if(wi.items & ITEM_Shells.m_itemid)
 927                         need_shells = true;
 928                 else if(wi.items & ITEM_Bullets.m_itemid)
 929                         need_nails = true;
 930                 else if(wi.items & ITEM_Rockets.m_itemid)
 931                         need_rockets = true;
 932                 else if(wi.items & ITEM_Cells.m_itemid)
 933                         need_cells = true;
 934                 else if(wi.items & ITEM_Plasma.m_itemid)
 935                         need_plasma = true;
 936                 else if(wi.items & ITEM_JetpackFuel.m_itemid)
 937                         need_fuel = true;
 938         }
 939
 940         // TODO: figure out if the player even has the weapon this ammo is for?
 941         // may not affect strategy much though...
 942         // find out how much more ammo/armor/health the player can hold
 943         if (need_shells)
 944         if (item.ammo_shells)
 945         if (player.ammo_shells < g_pickup_shells_max)
 946                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 947         if (need_nails)
 948         if (item.ammo_nails)
 949         if (player.ammo_nails < g_pickup_nails_max)
 950                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 951         if (need_rockets)
 952         if (item.ammo_rockets)
 953         if (player.ammo_rockets < g_pickup_rockets_max)
 954                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 955         if (need_cells)
 956         if (item.ammo_cells)
 957         if (player.ammo_cells < g_pickup_cells_max)
 958                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 959         if (need_plasma)
 960         if (item.ammo_plasma)
 961         if (player.ammo_plasma < g_pickup_plasma_max)
 962                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
 963         if (need_fuel)
 964         if (item.ammo_fuel)
 965         if (player.ammo_fuel < g_pickup_fuel_max)
 966                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 967         if (item.armorvalue)
 968         if (player.armorvalue < item.max_armorvalue)
 969                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 970         if (item.health)
 971         if (player.health < item.max_health)
 972                 c = c + max(0, 1 - player.health / item.max_health);
 973
 974         return item.bot_pickupbasevalue * c;
 975 }
 976
 977 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 978 {
 979         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 980                 RemoveItem();
 981 }
 982
 983 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
 984 {
 985         string itemname = def.m_name;
 986         Model itemmodel = def.m_model;
 987     Sound pickupsound = def.m_sound;
 988         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
 989         float pickupbasevalue = def.m_botvalue;
 990         int itemflags = def.m_itemflags;
 991
 992         startitem_failed = false;
 993
 994         this.item_model_ent = itemmodel;
 995     this.item_pickupsound_ent = pickupsound;
 996
 997         if(!this.respawntime) // both need to be set
 998         {
 999                 this.respawntime = defaultrespawntime;
1000                 this.respawntimejitter = defaultrespawntimejitter;
1001         }
1002
1003         int itemid = def.m_itemid;
1004         this.items = itemid;
1005         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1006         this.weapon = weaponid;
1007
1008         if(!this.fade_end)
1009         {
1010                 this.fade_start = autocvar_g_items_mindist;
1011                 this.fade_end = autocvar_g_items_maxdist;
1012         }
1013
1014         if(weaponid)
1015                 this.weapons = WepSet_FromWeapon(weaponid);
1016
1017         this.flags = FL_ITEM | itemflags;
1018
1019         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1020         {
1021                 startitem_failed = true;
1022                 remove(this);
1023                 return;
1024         }
1025
1026         // is it a dropped weapon?
1027         if (this.classname == "droppedweapon")
1028         {
1029                 this.reset = SUB_Remove;
1030                 // it's a dropped weapon
1031                 this.movetype = MOVETYPE_TOSS;
1032
1033                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1034                 this.think = RemoveItem;
1035                 this.nextthink = time + 20;
1036
1037                 this.takedamage = DAMAGE_YES;
1038                 this.event_damage = Item_Damage;
1039
1040                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1041                 /*
1042                 if(this.items == 0)
1043                 if(!(this.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
1044                 if(this.ammo_nails == 0)
1045                 if(this.ammo_cells == 0)
1046                 if(this.ammo_rockets == 0)
1047                 if(this.ammo_shells == 0)
1048                 if(this.ammo_fuel == 0)
1049                 if(this.health == 0)
1050                 if(this.armorvalue == 0)
1051                 */
1052                 {
1053                         // if item is worthless after a timer, have it expire then
1054                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1055                 }
1056
1057                 // don't drop if in a NODROP zone (such as lava)
1058                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1059                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1060                 {
1061                         startitem_failed = true;
1062                         remove(this);
1063                         return;
1064                 }
1065         }
1066         else
1067         {
1068                 if(!have_pickup_item(this))
1069                 {
1070                         startitem_failed = true;
1071                         remove (this);
1072                         return;
1073                 }
1074
1075                 if(this.angles != '0 0 0')
1076                         this.SendFlags |= ISF_ANGLES;
1077
1078                 this.reset = Item_Reset_self;
1079                 // it's a level item
1080                 if(this.spawnflags & 1)
1081                         this.noalign = 1;
1082                 if (this.noalign)
1083                         this.movetype = MOVETYPE_NONE;
1084                 else
1085                         this.movetype = MOVETYPE_TOSS;
1086                 // do item filtering according to game mode and other things
1087                 if (!this.noalign)
1088                 {
1089                         // first nudge it off the floor a little bit to avoid math errors
1090                         setorigin(this, this.origin + '0 0 1');
1091                         // set item size before we spawn a spawnfunc_waypoint
1092                         setsize(this, def.m_mins, def.m_maxs);
1093                         this.SendFlags |= ISF_SIZE;
1094                         // note droptofloor returns false if stuck/or would fall too far
1095                         WITH(entity, self, this, droptofloor());
1096                         waypoint_spawnforitem(this);
1097                 }
1098
1099                 /*
1100                  * can't do it that way, as it would break maps
1101                  * TODO make a target_give like entity another way, that perhaps has
1102                  * the weapon name in a key
1103                 if(this.targetname)
1104                 {
1105                         // target_give not yet supported; maybe later
1106                         print("removed targeted ", this.classname, "\n");
1107                         startitem_failed = true;
1108                         remove (this);
1109                         return;
1110                 }
1111                 */
1112
1113                 if(autocvar_spawn_debug >= 2)
1114                 {
1115                         for(entity otheritem = findradius(this.origin, 3); otheritem; otheritem = otheritem.chain)
1116                         {
1117                             // why not flags & fl_item?
1118                                 if(otheritem.is_item)
1119                                 {
1120                                         LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1121                                         LOG_TRACE(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1122                                         error("Mapper sucks.");
1123                                 }
1124                         }
1125                         this.is_item = true;
1126                 }
1127
1128                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1129
1130                 precache_model(this.model);
1131                 precache_sound(this.item_pickupsound);
1132
1133                 if (   def.instanceOfPowerup
1134                         || def.instanceOfWeaponPickup
1135                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1136                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1137                         || (itemid & (IT_KEY1 | IT_KEY2))
1138                 ) this.target = "###item###"; // for finding the nearest item using find()
1139
1140                 Item_ItemsTime_SetTime(this, 0);
1141         }
1142
1143         this.bot_pickup = true;
1144         this.bot_pickupevalfunc = pickupevalfunc;
1145         this.bot_pickupbasevalue = pickupbasevalue;
1146         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1147         this.netname = itemname;
1148         this.touch = Item_Touch;
1149         setmodel(this, MDL_Null); // precision set below
1150         //this.effects |= EF_LOWPRECISION;
1151
1152         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1153
1154         this.SendFlags |= ISF_SIZE;
1155
1156         if(def.instanceOfPowerup)
1157                 this.ItemStatus |= ITS_ANIMATE1;
1158
1159         if(this.armorvalue || this.health)
1160                 this.ItemStatus |= ITS_ANIMATE2;
1161
1162         if(def.instanceOfWeaponPickup)
1163         {
1164                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1165                         this.colormap = 1024; // color shirt=0 pants=0 grey
1166                 else
1167                         this.gravity = 1;
1168
1169                 this.ItemStatus |= ITS_ANIMATE1;
1170                 this.ItemStatus |= ISF_COLORMAP;
1171         }
1172
1173         this.state = 0;
1174         if(this.team) // broken, no idea why.
1175         {
1176                 if(!this.cnt)
1177                         this.cnt = 1; // item probability weight
1178
1179                 this.effects |= EF_NODRAW; // marker for item team search
1180                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1181         }
1182         else
1183                 Item_Reset(this);
1184
1185         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1186
1187         // call this hook after everything else has been done
1188         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1189         {
1190                 startitem_failed = true;
1191                 remove(this);
1192                 return;
1193         }
1194 }
1195
1196 void StartItem(entity this, GameItem def)
1197 {
1198     _StartItem(
1199         this,
1200         this.itemdef = def,
1201         def.m_respawntime(), // defaultrespawntime
1202         def.m_respawntimejitter() // defaultrespawntimejitter
1203         );
1204 }
1205
1206 spawnfunc(item_rockets)
1207 {
1208         if(!self.ammo_rockets)
1209                 self.ammo_rockets = g_pickup_rockets;
1210         if(!self.pickup_anyway)
1211                 self.pickup_anyway = g_pickup_ammo_anyway;
1212     StartItem(this, ITEM_Rockets);
1213 }
1214
1215 spawnfunc(item_bullets)
1216 {
1217         if(!weaponswapping)
1218         if(autocvar_sv_q3acompat_machineshotgunswap)
1219         if(self.classname != "droppedweapon")
1220         {
1221                 weaponswapping = true;
1222                 spawnfunc_item_shells(this);
1223                 weaponswapping = false;
1224                 return;
1225         }
1226
1227         if(!self.ammo_nails)
1228                 self.ammo_nails = g_pickup_nails;
1229         if(!self.pickup_anyway)
1230                 self.pickup_anyway = g_pickup_ammo_anyway;
1231     StartItem(this, ITEM_Bullets);
1232 }
1233
1234 spawnfunc(item_cells)
1235 {
1236         if(!self.ammo_cells)
1237                 self.ammo_cells = g_pickup_cells;
1238         if(!self.pickup_anyway)
1239                 self.pickup_anyway = g_pickup_ammo_anyway;
1240         StartItem(this, ITEM_Cells);
1241 }
1242
1243 spawnfunc(item_plasma)
1244 {
1245         if(!self.ammo_plasma)
1246                 self.ammo_plasma = g_pickup_plasma;
1247         if(!self.pickup_anyway)
1248                 self.pickup_anyway = g_pickup_ammo_anyway;
1249         StartItem(this, ITEM_Plasma);
1250 }
1251
1252 spawnfunc(item_shells)
1253 {
1254         if(!weaponswapping)
1255         if(autocvar_sv_q3acompat_machineshotgunswap)
1256         if(self.classname != "droppedweapon")
1257         {
1258                 weaponswapping = true;
1259                 spawnfunc_item_bullets(this);
1260                 weaponswapping = false;
1261                 return;
1262         }
1263
1264         if(!self.ammo_shells)
1265                 self.ammo_shells = g_pickup_shells;
1266         if(!self.pickup_anyway)
1267                 self.pickup_anyway = g_pickup_ammo_anyway;
1268         StartItem(this, ITEM_Shells);
1269 }
1270
1271 spawnfunc(item_armor_small)
1272 {
1273         if(!self.armorvalue)
1274                 self.armorvalue = g_pickup_armorsmall;
1275         if(!self.max_armorvalue)
1276                 self.max_armorvalue = g_pickup_armorsmall_max;
1277         if(!self.pickup_anyway)
1278                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1279         StartItem(this, ITEM_ArmorSmall);
1280 }
1281
1282 spawnfunc(item_armor_medium)
1283 {
1284         if(!self.armorvalue)
1285                 self.armorvalue = g_pickup_armormedium;
1286         if(!self.max_armorvalue)
1287                 self.max_armorvalue = g_pickup_armormedium_max;
1288         if(!self.pickup_anyway)
1289                 self.pickup_anyway = g_pickup_armormedium_anyway;
1290         StartItem(this, ITEM_ArmorMedium);
1291 }
1292
1293 spawnfunc(item_armor_big)
1294 {
1295         if(!self.armorvalue)
1296                 self.armorvalue = g_pickup_armorbig;
1297         if(!self.max_armorvalue)
1298                 self.max_armorvalue = g_pickup_armorbig_max;
1299         if(!self.pickup_anyway)
1300                 self.pickup_anyway = g_pickup_armorbig_anyway;
1301         StartItem(this, ITEM_ArmorLarge);
1302 }
1303
1304 spawnfunc(item_armor_large)
1305 {
1306         if(!self.armorvalue)
1307                 self.armorvalue = g_pickup_armorlarge;
1308         if(!self.max_armorvalue)
1309                 self.max_armorvalue = g_pickup_armorlarge_max;
1310         if(!self.pickup_anyway)
1311                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1312         StartItem(this, ITEM_ArmorMega);
1313 }
1314
1315 spawnfunc(item_health_small)
1316 {
1317         if(!self.max_health)
1318                 self.max_health = g_pickup_healthsmall_max;
1319         if(!self.health)
1320                 self.health = g_pickup_healthsmall;
1321         if(!self.pickup_anyway)
1322                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1323         StartItem(this, ITEM_HealthSmall);
1324 }
1325
1326 spawnfunc(item_health_medium)
1327 {
1328         if(!self.max_health)
1329                 self.max_health = g_pickup_healthmedium_max;
1330         if(!self.health)
1331                 self.health = g_pickup_healthmedium;
1332         if(!self.pickup_anyway)
1333                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1334     StartItem(this, ITEM_HealthMedium);
1335 }
1336
1337 spawnfunc(item_health_large)
1338 {
1339         if(!self.max_health)
1340                 self.max_health = g_pickup_healthlarge_max;
1341         if(!self.health)
1342                 self.health = g_pickup_healthlarge;
1343         if(!self.pickup_anyway)
1344                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1345         StartItem(this, ITEM_HealthLarge);
1346 }
1347
1348 spawnfunc(item_health_mega)
1349 {
1350     if(!self.max_health)
1351         self.max_health = g_pickup_healthmega_max;
1352     if(!self.health)
1353         self.health = g_pickup_healthmega;
1354     if(!self.pickup_anyway)
1355         self.pickup_anyway = g_pickup_healthmega_anyway;
1356     StartItem(this, ITEM_HealthMega);
1357 }
1358
1359 // support old misnamed entities
1360 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1361 spawnfunc(item_armor25) { spawnfunc_item_armor_large(this); }
1362 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1363 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1364 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1365
1366 spawnfunc(item_strength)
1367 {
1368                 if(!self.strength_finished)
1369                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1370                 StartItem(this, ITEM_Strength);
1371 }
1372
1373 spawnfunc(item_invincible)
1374 {
1375                 if(!self.invincible_finished)
1376                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1377                 StartItem(this, ITEM_Shield);
1378 }
1379
1380 // compatibility:
1381 spawnfunc(item_quad) { self.classname = "item_strength";spawnfunc_item_strength(this);}
1382
1383 void target_items_use()
1384 {SELFPARAM();
1385         if(activator.classname == "droppedweapon")
1386         {
1387                 EXACTTRIGGER_TOUCH;
1388                 remove(activator);
1389                 return;
1390         }
1391
1392         if (!IS_PLAYER(activator))
1393                 return;
1394         if(activator.deadflag != DEAD_NO)
1395                 return;
1396         EXACTTRIGGER_TOUCH;
1397
1398         entity e;
1399         for(e = world; (e = find(e, classname, "droppedweapon")); )
1400                 if(e.enemy == activator)
1401                         remove(e);
1402
1403         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1404                 centerprint(activator, self.message);
1405 }
1406
1407 spawnfunc(target_items)
1408 {
1409         float n, i, j;
1410         entity e;
1411         string s;
1412
1413         self.use = target_items_use;
1414         if(!self.strength_finished)
1415                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1416         if(!self.invincible_finished)
1417                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1418         if(!self.superweapons_finished)
1419                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1420
1421         n = tokenize_console(self.netname);
1422         if(argv(0) == "give")
1423         {
1424                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1425         }
1426         else
1427         {
1428                 for(i = 0; i < n; ++i)
1429                 {
1430                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1431                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1432                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1433                         else if(argv(i) == "strength")               self.items |= ITEM_Strength.m_itemid;
1434                         else if(argv(i) == "invincible")             self.items |= ITEM_Shield.m_itemid;
1435                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1436                         else if(argv(i) == "jetpack")                self.items |= ITEM_Jetpack.m_itemid;
1437                         else if(argv(i) == "fuel_regen")             self.items |= ITEM_JetpackRegen.m_itemid;
1438                         else
1439                         {
1440                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1441                                 {
1442                                         e = get_weaponinfo(j);
1443                                         s = W_UndeprecateName(argv(i));
1444                                         if(s == e.netname)
1445                                         {
1446                                                 self.weapons |= WepSet_FromWeapon(j);
1447                                                 if(self.spawnflags == 0 || self.spawnflags == 2) {
1448                                                         Weapon w = get_weaponinfo(e.weapon);
1449                                                         w.wr_init(w);
1450                                                 }
1451                                                 break;
1452                                         }
1453                                 }
1454                                 if(j > WEP_LAST)
1455                                         LOG_INFO("target_items: invalid item ", argv(i), "\n");
1456                         }
1457                 }
1458
1459                 string itemprefix, valueprefix;
1460                 if(self.spawnflags == 0)
1461                 {
1462                         itemprefix = "";
1463                         valueprefix = "";
1464                 }
1465                 else if(self.spawnflags == 1)
1466                 {
1467                         itemprefix = "max ";
1468                         valueprefix = "max ";
1469                 }
1470                 else if(self.spawnflags == 2)
1471                 {
1472                         itemprefix = "min ";
1473                         valueprefix = "min ";
1474                 }
1475                 else if(self.spawnflags == 4)
1476                 {
1477                         itemprefix = "minus ";
1478                         valueprefix = "max ";
1479                 }
1480                 else
1481                 {
1482                         error("invalid spawnflags");
1483                         itemprefix = valueprefix = string_null;
1484                 }
1485
1486                 self.netname = "";
1487                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1488                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1489                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & ITEM_Strength.m_itemid), "strength");
1490                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & ITEM_Shield.m_itemid), "invincible");
1491                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1492                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_Jetpack.m_itemid), "jetpack");
1493                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1494                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1495                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1496                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1497                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1498                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1499                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1500                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1501                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1502                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1503                 {
1504                         e = get_weaponinfo(j);
1505                         if(e.weapon)
1506                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1507                 }
1508         }
1509         self.netname = strzone(self.netname);
1510         //print(self.netname, "\n");
1511
1512         n = tokenize_console(self.netname);
1513         for(i = 0; i < n; ++i)
1514         {
1515                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1516                 {
1517                         e = get_weaponinfo(j);
1518                         if(argv(i) == e.netname)
1519                         {
1520                                 Weapon w = get_weaponinfo(e.weapon);
1521                                 w.wr_init(w);
1522                                 break;
1523                         }
1524                 }
1525         }
1526 }
1527
1528 spawnfunc(item_fuel)
1529 {
1530         if(!self.ammo_fuel)
1531                 self.ammo_fuel = g_pickup_fuel;
1532         if(!self.pickup_anyway)
1533                 self.pickup_anyway = g_pickup_ammo_anyway;
1534         StartItem(this, ITEM_JetpackFuel);
1535 }
1536
1537 spawnfunc(item_fuel_regen)
1538 {
1539         if(start_items & ITEM_JetpackRegen.m_itemid)
1540         {
1541                 spawnfunc_item_fuel(this);
1542                 return;
1543         }
1544         StartItem(this, ITEM_JetpackRegen);
1545 }
1546
1547 spawnfunc(item_jetpack)
1548 {
1549         if(!self.ammo_fuel)
1550                 self.ammo_fuel = g_pickup_fuel_jetpack;
1551         if(start_items & ITEM_Jetpack.m_itemid)
1552         {
1553                 spawnfunc_item_fuel(this);
1554                 return;
1555         }
1556         StartItem(this, ITEM_Jetpack);
1557 }
1558
1559 float GiveWeapon(entity e, float wpn, float op, float val)
1560 {
1561         WepSet v0, v1;
1562         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1563         switch(op)
1564         {
1565                 case OP_SET:
1566                         if(val > 0)
1567                                 e.weapons |= WepSet_FromWeapon(wpn);
1568                         else
1569                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1570                         break;
1571                 case OP_MIN:
1572                 case OP_PLUS:
1573                         if(val > 0)
1574                                 e.weapons |= WepSet_FromWeapon(wpn);
1575                         break;
1576                 case OP_MAX:
1577                         if(val <= 0)
1578                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1579                         break;
1580                 case OP_MINUS:
1581                         if(val > 0)
1582                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1583                         break;
1584         }
1585         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1586         return (v0 != v1);
1587 }
1588
1589 float GiveBit(entity e, .float fld, float bit, float op, float val)
1590 {
1591         float v0, v1;
1592         v0 = (e.(fld) & bit);
1593         switch(op)
1594         {
1595                 case OP_SET:
1596                         if(val > 0)
1597                                 e.(fld) |= bit;
1598                         else
1599                                 e.(fld) &= ~bit;
1600                         break;
1601                 case OP_MIN:
1602                 case OP_PLUS:
1603                         if(val > 0)
1604                                 e.(fld) |= bit;
1605                         break;
1606                 case OP_MAX:
1607                         if(val <= 0)
1608                                 e.(fld) &= ~bit;
1609                         break;
1610                 case OP_MINUS:
1611                         if(val > 0)
1612                                 e.(fld) &= ~bit;
1613                         break;
1614         }
1615         v1 = (e.(fld) & bit);
1616         return (v0 != v1);
1617 }
1618
1619 float GiveValue(entity e, .float fld, float op, float val)
1620 {
1621         float v0, v1;
1622         v0 = e.(fld);
1623         switch(op)
1624         {
1625                 case OP_SET:
1626                         e.(fld) = val;
1627                         break;
1628                 case OP_MIN:
1629                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1630                         break;
1631                 case OP_MAX:
1632                         e.(fld) = min(e.(fld), val);
1633                         break;
1634                 case OP_PLUS:
1635                         e.(fld) += val;
1636                         break;
1637                 case OP_MINUS:
1638                         e.(fld) -= val;
1639                         break;
1640         }
1641         v1 = e.(fld);
1642         return (v0 != v1);
1643 }
1644
1645 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1646 {
1647         if(v1 == v0)
1648                 return;
1649         if(v1 <= v0 - t)
1650         {
1651                 if(snd_decr != "")
1652                         _sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1653         }
1654         else if(v0 >= v0 + t)
1655         {
1656                 if(snd_incr != "")
1657                         _sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1658         }
1659 }
1660
1661 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1662 {
1663         if(v0 < v1)
1664                 e.(rotfield) = max(e.(rotfield), time + rottime);
1665         else if(v0 > v1)
1666                 e.(regenfield) = max(e.(regenfield), time + regentime);
1667 }
1668 float GiveItems(entity e, float beginarg, float endarg)
1669 {SELFPARAM();
1670         float got, i, j, val, op;
1671         float _switchweapon;
1672         entity wi;
1673         string cmd;
1674
1675         val = 999;
1676         op = OP_SET;
1677
1678         got = 0;
1679
1680         _switchweapon = false;
1681         if (e.autoswitch)
1682                 if (e.switchweapon == w_getbestweapon(e))
1683                         _switchweapon = true;
1684
1685         e.strength_finished = max(0, e.strength_finished - time);
1686         e.invincible_finished = max(0, e.invincible_finished - time);
1687         e.superweapons_finished = max(0, e.superweapons_finished - time);
1688
1689         PREGIVE(e, items);
1690         PREGIVE_WEAPONS(e);
1691         PREGIVE(e, strength_finished);
1692         PREGIVE(e, invincible_finished);
1693         PREGIVE(e, superweapons_finished);
1694         PREGIVE(e, ammo_nails);
1695         PREGIVE(e, ammo_cells);
1696         PREGIVE(e, ammo_plasma);
1697         PREGIVE(e, ammo_shells);
1698         PREGIVE(e, ammo_rockets);
1699         PREGIVE(e, ammo_fuel);
1700         PREGIVE(e, armorvalue);
1701         PREGIVE(e, health);
1702
1703         for(i = beginarg; i < endarg; ++i)
1704         {
1705                 cmd = argv(i);
1706
1707                 if(cmd == "0" || stof(cmd))
1708                 {
1709                         val = stof(cmd);
1710                         continue;
1711                 }
1712                 switch(cmd)
1713                 {
1714                         case "no":
1715                                 op = OP_MAX;
1716                                 val = 0;
1717                                 continue;
1718                         case "max":
1719                                 op = OP_MAX;
1720                                 continue;
1721                         case "min":
1722                                 op = OP_MIN;
1723                                 continue;
1724                         case "plus":
1725                                 op = OP_PLUS;
1726                                 continue;
1727                         case "minus":
1728                                 op = OP_MINUS;
1729                                 continue;
1730                         case "ALL":
1731                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1732                                 got += GiveValue(e, strength_finished, op, val);
1733                                 got += GiveValue(e, invincible_finished, op, val);
1734                                 got += GiveValue(e, superweapons_finished, op, val);
1735                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1736                         case "all":
1737                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1738                                 got += GiveValue(e, health, op, val);
1739                                 got += GiveValue(e, armorvalue, op, val);
1740                         case "allweapons":
1741                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1742                                 {
1743                                         wi = get_weaponinfo(j);
1744                                         if(wi.weapon)
1745                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1746                                                         got += GiveWeapon(e, j, op, val);
1747                                 }
1748                         case "allammo":
1749                                 got += GiveValue(e, ammo_cells, op, val);
1750                                 got += GiveValue(e, ammo_plasma, op, val);
1751                                 got += GiveValue(e, ammo_shells, op, val);
1752                                 got += GiveValue(e, ammo_nails, op, val);
1753                                 got += GiveValue(e, ammo_rockets, op, val);
1754                                 got += GiveValue(e, ammo_fuel, op, val);
1755                                 break;
1756                         case "unlimited_ammo":
1757                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1758                                 break;
1759                         case "unlimited_weapon_ammo":
1760                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1761                                 break;
1762                         case "unlimited_superweapons":
1763                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1764                                 break;
1765                         case "jetpack":
1766                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1767                                 break;
1768                         case "fuel_regen":
1769                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1770                                 break;
1771                         case "strength":
1772                                 got += GiveValue(e, strength_finished, op, val);
1773                                 break;
1774                         case "invincible":
1775                                 got += GiveValue(e, invincible_finished, op, val);
1776                                 break;
1777                         case "superweapons":
1778                                 got += GiveValue(e, superweapons_finished, op, val);
1779                                 break;
1780                         case "cells":
1781                                 got += GiveValue(e, ammo_cells, op, val);
1782                                 break;
1783                         case "plasma":
1784                                 got += GiveValue(e, ammo_plasma, op, val);
1785                                 break;
1786                         case "shells":
1787                                 got += GiveValue(e, ammo_shells, op, val);
1788                                 break;
1789                         case "nails":
1790                         case "bullets":
1791                                 got += GiveValue(e, ammo_nails, op, val);
1792                                 break;
1793                         case "rockets":
1794                                 got += GiveValue(e, ammo_rockets, op, val);
1795                                 break;
1796                         case "health":
1797                                 got += GiveValue(e, health, op, val);
1798                                 break;
1799                         case "armor":
1800                                 got += GiveValue(e, armorvalue, op, val);
1801                                 break;
1802                         case "fuel":
1803                                 got += GiveValue(e, ammo_fuel, op, val);
1804                                 break;
1805                         default:
1806                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1807                                 {
1808                                         wi = get_weaponinfo(j);
1809                                         if(cmd == wi.netname)
1810                                         {
1811                                                 got += GiveWeapon(e, j, op, val);
1812                                                 break;
1813                                         }
1814                                 }
1815                                 if(j > WEP_LAST)
1816                                         LOG_INFO("give: invalid item ", cmd, "\n");
1817                                 break;
1818                 }
1819                 val = 999;
1820                 op = OP_SET;
1821         }
1822
1823         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND(ITEMPICKUP), string_null);
1824         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND(POWERUP), SND(POWEROFF));
1825         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND(POWERUP), SND(POWEROFF));
1826         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND(ITEMPICKUP), string_null);
1827         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1828         {
1829                 wi = get_weaponinfo(j);
1830                 if(wi.weapon)
1831                 {
1832                         POSTGIVE_WEAPON(e, j, SND(WEAPONPICKUP), string_null);
1833                         if (!(save_weapons & WepSet_FromWeapon(j)))
1834                                 if(e.weapons & WepSet_FromWeapon(j)) {
1835                                         Weapon w = get_weaponinfo(wi.weapon);
1836                                         w.wr_init(w);
1837                                 }
1838                 }
1839         }
1840         POSTGIVE_VALUE(e, strength_finished, 1, SND(POWERUP), SND(POWEROFF));
1841         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", SND(POWEROFF));
1842         POSTGIVE_VALUE(e, ammo_nails, 0, SND(ITEMPICKUP), string_null);
1843         POSTGIVE_VALUE(e, ammo_cells, 0, SND(ITEMPICKUP), string_null);
1844         POSTGIVE_VALUE(e, ammo_plasma, 0, SND(ITEMPICKUP), string_null);
1845         POSTGIVE_VALUE(e, ammo_shells, 0, SND(ITEMPICKUP), string_null);
1846         POSTGIVE_VALUE(e, ammo_rockets, 0, SND(ITEMPICKUP), string_null);
1847         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND(ITEMPICKUP), string_null);
1848         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND(ARMOR25), string_null);
1849         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND(MEGAHEALTH), string_null);
1850
1851         if(e.superweapons_finished <= 0)
1852                 if(self.weapons & WEPSET_SUPERWEAPONS)
1853                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1854
1855         if(e.strength_finished <= 0)
1856                 e.strength_finished = 0;
1857         else
1858                 e.strength_finished += time;
1859         if(e.invincible_finished <= 0)
1860                 e.invincible_finished = 0;
1861         else
1862                 e.invincible_finished += time;
1863         if(e.superweapons_finished <= 0)
1864                 e.superweapons_finished = 0;
1865         else
1866                 e.superweapons_finished += time;
1867
1868         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
1869                 _switchweapon = true;
1870         if(_switchweapon)
1871                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1872
1873         return got;
1874 }
1875 #endif