qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 //float audit_teams_time;
  10
  11 void TeamchangeFrags(entity e)
  12 {
  13         PlayerScore_Clear(e);
  14 }
  15
  16 vector TeamColor(float teem)
  17 {
  18         switch(teem)
  19         {
  20                 case COLOR_TEAM1:
  21                         return '1 0.0625 0.0625';
  22                 case COLOR_TEAM2:
  23                         return '0.0625 0.0625 1';
  24                 case COLOR_TEAM3:
  25                         return '1 1 0.0625';
  26                 case COLOR_TEAM4:
  27                         return '1 0.0625 1';
  28                 default:
  29                         return '1 1 1';
  30         }
  31 }
  32
  33 string TeamName(float t)
  34 {
  35         return strcat(Team_ColorName(t), " Team");
  36 }
  37 string ColoredTeamName(float t)
  38 {
  39         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  40 }
  41 string TeamNoName(float t)
  42 {
  43         // fixme: Search for team entities and get their .netname's!
  44         if(t == 1)
  45                 return "Red Team";
  46         if(t == 2)
  47                 return "Blue Team";
  48         if(t == 3)
  49                 return "Yellow Team";
  50         if(t == 4)
  51                 return "Pink Team";
  52         return "Neutral Team";
  53 }
  54
  55 void dom_init();
  56 void runematch_init();
  57 void tdm_init();
  58 void entcs_init();
  59
  60 void LogTeamchange(float player_id, float team_number, float type)
  61 {
  62         if(!autocvar_sv_eventlog)
  63                 return;
  64
  65         if(player_id < 1)
  66                 return;
  67
  68         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  69 }
  70
  71 void default_delayedinit()
  72 {
  73         if(!scores_initialized)
  74                 ScoreRules_generic();
  75 }
  76
  77 void ActivateTeamplay()
  78 {
  79         serverflags |= SERVERFLAG_TEAMPLAY;
  80         teamplay = 1;
  81 }
  82
  83 void InitGameplayMode()
  84 {
  85         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  86
  87         qualifying_override = -1;
  88
  89         VoteReset();
  90
  91         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  92         get_mi_min_max(1);
  93         world.mins = mi_min;
  94         world.maxs = mi_max;
  95
  96         MapInfo_LoadMapSettings(mapname);
  97         teamplay = 0;
  98         serverflags &~= SERVERFLAG_TEAMPLAY;
  99
 100         if not(cvar_value_issafe(world.fog))
 101         {
 102                 print("The current map contains a potentially harmful fog setting, ignored\n");
 103                 world.fog = string_null;
 104         }
 105         if(MapInfo_Map_fog != "")
 106                 if(MapInfo_Map_fog == "none")
 107                         world.fog = string_null;
 108                 else
 109                         world.fog = strzone(MapInfo_Map_fog);
 110         clientstuff = strzone(MapInfo_Map_clientstuff);
 111
 112         MapInfo_ClearTemps();
 113
 114         // set both here, gamemode can override it later
 115         timelimit_override = autocvar_timelimit_override;
 116         fraglimit_override = autocvar_fraglimit_override;
 117         leadlimit_override = autocvar_leadlimit_override;
 118         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 119
 120         if(g_dm)
 121         {
 122         }
 123
 124         if(g_tdm)
 125         {
 126                 ActivateTeamplay();
 127                 tdm_init();
 128                 if(autocvar_g_tdm_team_spawns)
 129                         have_team_spawns = -1; // request team spawns
 130         }
 131
 132         if(g_domination)
 133         {
 134                 ActivateTeamplay();
 135                 fraglimit_override = autocvar_g_domination_point_limit;
 136                 leadlimit_override = autocvar_g_domination_point_leadlimit;
 137                 dom_init();
 138                 have_team_spawns = -1; // request team spawns
 139         }
 140
 141         if(g_ctf)
 142         {
 143                 ActivateTeamplay();
 144                 fraglimit_override = autocvar_capturelimit_override;
 145                 leadlimit_override = autocvar_captureleadlimit_override;
 146                 MUTATOR_ADD(gamemode_ctf);
 147                 have_team_spawns = -1; // request team spawns
 148         }
 149
 150         if(g_td)
 151         {
 152                 fraglimit_override = 0; // no limits in TD - it's a survival mode
 153                 leadlimit_override = 0;
 154                 MUTATOR_ADD(gamemode_td);
 155         }
 156
 157         if(g_runematch)
 158         {
 159                 // ActivateTeamplay();
 160                 fraglimit_override = autocvar_g_runematch_point_limit;
 161                 leadlimit_override = autocvar_g_runematch_point_leadlimit;
 162                 runematch_init();
 163         }
 164
 165         if(g_lms)
 166         {
 167                 fraglimit_override = autocvar_g_lms_lives_override;
 168                 leadlimit_override = 0; // not supported by LMS
 169                 if(fraglimit_override == 0)
 170                         fraglimit_override = -1;
 171                 lms_lowest_lives = 9999;
 172                 lms_next_place = 0;
 173                 ScoreRules_lms();
 174         }
 175
 176         if(g_arena)
 177         {
 178                 fraglimit_override = autocvar_g_arena_point_limit;
 179                 leadlimit_override = autocvar_g_arena_point_leadlimit;
 180                 maxspawned = autocvar_g_arena_maxspawned;
 181                 if(maxspawned < 2)
 182                         maxspawned = 2;
 183                 arena_roundbased = autocvar_g_arena_roundbased;
 184         }
 185
 186         if(g_ca)
 187         {
 188                 ActivateTeamplay();
 189                 fraglimit_override = autocvar_g_ca_point_limit;
 190                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 191                 precache_sound("ctf/red_capture.wav");
 192                 precache_sound("ctf/blue_capture.wav");
 193         }
 194         if(g_keyhunt)
 195         {
 196                 ActivateTeamplay();
 197                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 198                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 199                 MUTATOR_ADD(gamemode_keyhunt);
 200         }
 201
 202         if(g_freezetag)
 203         {
 204                 ActivateTeamplay();
 205                 fraglimit_override = autocvar_g_freezetag_point_limit;
 206                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 207                 MUTATOR_ADD(gamemode_freezetag);
 208         }
 209
 210         if(g_assault)
 211         {
 212                 ActivateTeamplay();
 213                 ScoreRules_assault();
 214                 have_team_spawns = -1; // request team spawns
 215         }
 216
 217         if(g_onslaught)
 218         {
 219                 ActivateTeamplay();
 220                 have_team_spawns = -1; // request team spawns
 221                 MUTATOR_ADD(gamemode_onslaught);
 222         }
 223
 224         if(g_race)
 225         {
 226
 227                 if(autocvar_g_race_teams)
 228                 {
 229                         ActivateTeamplay();
 230                         race_teams = bound(2, autocvar_g_race_teams, 4);
 231                         have_team_spawns = -1; // request team spawns
 232                 }
 233                 else
 234                         race_teams = 0;
 235
 236                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 237                 fraglimit_override = autocvar_g_race_laps_limit;
 238                 leadlimit_override = 0; // currently not supported by race
 239         }
 240
 241         if(g_cts)
 242         {
 243                 g_race_qualifying = 1;
 244                 fraglimit_override = 0;
 245                 leadlimit_override = 0;
 246         }
 247
 248         if(g_nexball)
 249         {
 250         fraglimit_override = autocvar_g_nexball_goallimit;
 251         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 252         ActivateTeamplay();
 253         have_team_spawns = -1; // request team spawns
 254             MUTATOR_ADD(gamemode_nexball);
 255         }
 256
 257         if(g_keepaway)
 258         {
 259                 MUTATOR_ADD(gamemode_keepaway);
 260         }
 261
 262         if(teamplay)
 263                 entcs_init();
 264
 265         cache_mutatormsg = strzone("");
 266         cache_lastmutatormsg = strzone("");
 267
 268         // enforce the server's universal frag/time limits
 269         if(!autocvar_g_campaign)
 270         {
 271                 if(fraglimit_override >= 0)
 272                         cvar_set("fraglimit", ftos(fraglimit_override));
 273                 if(timelimit_override >= 0)
 274                         cvar_set("timelimit", ftos(timelimit_override));
 275                 if(leadlimit_override >= 0)
 276                         cvar_set("leadlimit", ftos(leadlimit_override));
 277                 if(qualifying_override >= 0)
 278                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 279         }
 280
 281         if(g_race)
 282         {
 283                 // we need to find out the correct value for g_race_qualifying
 284                 if(autocvar_g_campaign)
 285                 {
 286                         g_race_qualifying = 1;
 287                 }
 288                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 289                 {
 290                         g_race_qualifying = 2;
 291                         race_fraglimit = autocvar_fraglimit;
 292                         race_leadlimit = autocvar_leadlimit;
 293                         race_timelimit = autocvar_timelimit;
 294                         cvar_set("fraglimit", "0");
 295                         cvar_set("leadlimit", "0");
 296                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 297                 }
 298                 else
 299                         g_race_qualifying = 0;
 300         }
 301
 302         if(g_race || g_cts)
 303         {
 304                 if(g_race_qualifying)
 305                         independent_players = 1;
 306
 307                 ScoreRules_race();
 308         }
 309
 310         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 311 }
 312
 313 string GetClientVersionMessage() {
 314         string versionmsg;
 315         if (self.version_mismatch) {
 316                 if(self.version < autocvar_gameversion) {
 317                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 318                 } else {
 319                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 320                 }
 321         } else {
 322                 versionmsg = "^2client version and server version are compatible.^8";
 323         }
 324         return versionmsg;
 325 }
 326
 327 string getwelcomemessage(void)
 328 {
 329         string s, modifications, motd;
 330
 331         ret_string = "";
 332         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 333         modifications = ret_string;
 334
 335         if(g_minstagib)
 336                 modifications = strcat(modifications, ", MinstaGib");
 337         if(g_weaponarena)
 338         {
 339                 if(g_weaponarena_random)
 340                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 341                 else
 342                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 343         }
 344         if(autocvar_g_start_weapon_laser == 0)
 345                 modifications = strcat(modifications, ", No start weapons");
 346         if(autocvar_sv_gravity < 800)
 347                 modifications = strcat(modifications, ", Low gravity");
 348         if(g_cloaked && !g_cts)
 349                 modifications = strcat(modifications, ", Cloaked");
 350         if(g_grappling_hook)
 351                 modifications = strcat(modifications, ", Hook");
 352         if(g_midair)
 353                 modifications = strcat(modifications, ", Midair");
 354         if(g_pinata)
 355                 modifications = strcat(modifications, ", Piñata");
 356         if(g_weapon_stay && !g_cts)
 357                 modifications = strcat(modifications, ", Weapons stay");
 358         if(g_bloodloss > 0)
 359                 modifications = strcat(modifications, ", Blood loss");
 360         if(g_jetpack)
 361                 modifications = strcat(modifications, ", Jet pack");
 362         if(autocvar_g_powerups == 0)
 363                 modifications = strcat(modifications, ", No powerups");
 364         if(autocvar_g_powerups > 0)
 365                 modifications = strcat(modifications, ", Powerups");
 366         modifications = substring(modifications, 2, strlen(modifications) - 2);
 367
 368         string versionmessage;
 369         versionmessage = GetClientVersionMessage();
 370
 371         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 372         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 373
 374         if(modifications != "")
 375                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 376
 377         if (g_grappling_hook)
 378                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 379
 380         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 381         {
 382                 if(cache_lastmutatormsg)
 383                         strunzone(cache_lastmutatormsg);
 384                 if(cache_mutatormsg)
 385                         strunzone(cache_mutatormsg);
 386                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 387                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 388         }
 389
 390         if (cache_mutatormsg != "") {
 391                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 392         }
 393
 394         motd = autocvar_sv_motd;
 395         if (motd != "") {
 396                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 397         }
 398         return s;
 399 }
 400
 401 void SetPlayerColors(entity pl, float _color)
 402 {
 403         /*string s;
 404         s = ftos(cl);
 405         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 406         pl.team = cl + 1;
 407         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 408         pl.clientcolors = 16*cl + cl;*/
 409
 410         float pants, shirt;
 411         pants = _color & 0x0F;
 412         shirt = _color & 0xF0;
 413
 414
 415         if(teamplay) {
 416                 setcolor(pl, 16*pants + pants);
 417         } else {
 418                 setcolor(pl, shirt + pants);
 419         }
 420 }
 421
 422 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 423 {
 424         float _color;
 425
 426         if(t == 4)
 427                 _color = COLOR_TEAM4 - 1;
 428         else if(t == 3)
 429                 _color = COLOR_TEAM3 - 1;
 430         else if(t == 2)
 431                 _color = COLOR_TEAM2 - 1;
 432         else
 433                 _color = COLOR_TEAM1 - 1;
 434
 435         SetPlayerColors(pl,_color);
 436
 437         if(t != s) {
 438                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 439
 440                 if(!noprint)
 441                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 442         }
 443
 444 }
 445
 446 // set c1...c4 to show what teams are allowed
 447 void CheckAllowedTeams (entity for_whom)
 448 {
 449         float dm;
 450         entity head;
 451         string teament_name;
 452
 453         c1 = c2 = c3 = c4 = -1;
 454         cb1 = cb2 = cb3 = cb4 = 0;
 455
 456         teament_name = string_null;
 457         if(g_onslaught)
 458         {
 459                 // onslaught is special
 460                 head = findchain(classname, "onslaught_generator");
 461                 while (head)
 462                 {
 463                         if (head.team == COLOR_TEAM1) c1 = 0;
 464                         if (head.team == COLOR_TEAM2) c2 = 0;
 465                         if (head.team == COLOR_TEAM3) c3 = 0;
 466                         if (head.team == COLOR_TEAM4) c4 = 0;
 467                         head = head.chain;
 468                 }
 469         }
 470         else if(g_domination)
 471                 teament_name = "dom_team";
 472         else if(g_ctf)
 473                 teament_name = "ctf_team";
 474         else if(g_tdm)
 475                 teament_name = "tdm_team";
 476         else if(g_nexball)
 477                 teament_name = "nexball_team";
 478         else if(g_assault)
 479                 c1 = c2 = 0; // Assault always has 2 teams
 480         else
 481         {
 482                 // cover anything else by treating it like tdm with no teams spawned
 483                 if(g_race)
 484                         dm = race_teams;
 485                 else
 486                         dm = 2;
 487
 488                 ret_float = dm;
 489                 MUTATOR_CALLHOOK(GetTeamCount);
 490                 dm = ret_float;
 491
 492                 if(dm >= 4)
 493                         c1 = c2 = c3 = c4 = 0;
 494                 else if(dm >= 3)
 495                         c1 = c2 = c3 = 0;
 496                 else
 497                         c1 = c2 = 0;
 498         }
 499
 500         // find out what teams are allowed if necessary
 501         if(teament_name)
 502         {
 503                 head = find(world, classname, teament_name);
 504                 while(head)
 505                 {
 506                         if(!(g_domination && head.netname == ""))
 507                         {
 508                                 if(head.team == COLOR_TEAM1)
 509                                         c1 = 0;
 510                                 else if(head.team == COLOR_TEAM2)
 511                                         c2 = 0;
 512                                 else if(head.team == COLOR_TEAM3)
 513                                         c3 = 0;
 514                                 else if(head.team == COLOR_TEAM4)
 515                                         c4 = 0;
 516                         }
 517                         head = find(head, classname, teament_name);
 518                 }
 519         }
 520
 521         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 522         if(c3==-1 && c4==-1)
 523         if(autocvar_bot_vs_human && for_whom)
 524         {
 525                 if(autocvar_bot_vs_human > 0)
 526                 {
 527                         // bots are all blue
 528                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 529                                 c1 = c3 = c4 = -1;
 530                         else
 531                                 c2 = -1;
 532                 }
 533                 else
 534                 {
 535                         // bots are all red
 536                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 537                                 c2 = c3 = c4 = -1;
 538                         else
 539                                 c1 = -1;
 540                 }
 541         }
 542
 543         // if player has a forced team, ONLY allow that one
 544         if(self.team_forced == COLOR_TEAM1 && c1 >= 0)
 545                 c2 = c3 = c4 = -1;
 546         else if(self.team_forced == COLOR_TEAM2 && c2 >= 0)
 547                 c1 = c3 = c4 = -1;
 548         else if(self.team_forced == COLOR_TEAM3 && c3 >= 0)
 549                 c1 = c2 = c4 = -1;
 550         else if(self.team_forced == COLOR_TEAM4 && c4 >= 0)
 551                 c1 = c2 = c3 = -1;
 552 }
 553
 554 float PlayerValue(entity p)
 555 {
 556         return 1;
 557         // FIXME: it always returns 1...
 558 }
 559
 560 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 561 // teams that are allowed will now have their player counts stored in c1...c4
 562 void GetTeamCounts(entity ignore)
 563 {
 564         entity head;
 565         float value, bvalue;
 566         // now count how many players are on each team already
 567
 568         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 569         // also remember the lowest-scoring player
 570
 571         FOR_EACH_CLIENT(head)
 572         {
 573                 float t;
 574                 if(head.classname == "player")
 575                         t = head.team;
 576                 else if(head.team_forced > 0)
 577                         t = head.team_forced; // reserve the spot
 578                 else
 579                         continue;
 580                 if(head != ignore)// && head.netname != "")
 581                 {
 582                         value = PlayerValue(head);
 583                         if(clienttype(head) == CLIENTTYPE_BOT)
 584                                 bvalue = value;
 585                         else
 586                                 bvalue = 0;
 587                         if(t == COLOR_TEAM1)
 588                         {
 589                                 if(c1 >= 0)
 590                                 {
 591                                         c1 = c1 + value;
 592                                         cb1 = cb1 + bvalue;
 593                                 }
 594                         }
 595                         if(t == COLOR_TEAM2)
 596                         {
 597                                 if(c2 >= 0)
 598                                 {
 599                                         c2 = c2 + value;
 600                                         cb2 = cb2 + bvalue;
 601                                 }
 602                         }
 603                         if(t == COLOR_TEAM3)
 604                         {
 605                                 if(c3 >= 0)
 606                                 {
 607                                         c3 = c3 + value;
 608                                         cb3 = cb3 + bvalue;
 609                                 }
 610                         }
 611                         if(t == COLOR_TEAM4)
 612                         {
 613                                 if(c4 >= 0)
 614                                 {
 615                                         c4 = c4 + value;
 616                                         cb4 = cb4 + bvalue;
 617                                 }
 618                         }
 619                 }
 620         }
 621
 622         // if the player who has a forced team has not joined yet, reserve the spot
 623         if(autocvar_g_campaign)
 624         {
 625                 switch(autocvar_g_campaign_forceteam)
 626                 {
 627                         case 1: if(c1 == cb1) ++c1; break;
 628                         case 2: if(c2 == cb2) ++c2; break;
 629                         case 3: if(c3 == cb3) ++c3; break;
 630                         case 4: if(c4 == cb4) ++c4; break;
 631                 }
 632         }
 633 }
 634
 635 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 636 {
 637         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 638         float f;
 639         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 640
 641         switch(ta)
 642         {
 643                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 644                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 645                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 646                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 647         }
 648         switch(tb)
 649         {
 650                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 651                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 652                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 653                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 654         }
 655
 656         // invalid
 657         if(ca < 0 || cb < 0)
 658                 return FALSE;
 659
 660         // equal
 661         if(ta == tb)
 662                 return TRUE;
 663
 664         if(clienttype(e) == CLIENTTYPE_REAL)
 665         {
 666                 if(bots_would_leave)
 667                 {
 668                         ca -= cba * 0.999;
 669                         cb -= cbb * 0.999;
 670                 }
 671         }
 672
 673         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 674         if(ca < 1)
 675                 if(cb >= 1)
 676                         return TRUE;
 677         if(ca >= 1)
 678                 if(cb < 1)
 679                         return FALSE;
 680
 681         // first, normalize
 682         f = max(ca, cb, 1);
 683         ca /= f;
 684         cb /= f;
 685         f = max(sa, sb, 1);
 686         sa /= f;
 687         sb /= f;
 688
 689         // the more we're at the end of the match, the more take scores into account
 690         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 691         ca += (sa - ca) * f;
 692         cb += (sb - cb) * f;
 693
 694         return ca <= cb;
 695 }
 696
 697 // returns # of smallest team (1, 2, 3, 4)
 698 // NOTE: Assumes CheckAllowedTeams has already been called!
 699 float FindSmallestTeam(entity pl, float ignore_pl)
 700 {
 701         float totalteams, t;
 702         totalteams = 0;
 703
 704         // find out what teams are available
 705         //CheckAllowedTeams();
 706
 707         // make sure there are at least 2 teams to join
 708         if(c1 >= 0)
 709                 totalteams = totalteams + 1;
 710         if(c2 >= 0)
 711                 totalteams = totalteams + 1;
 712         if(c3 >= 0)
 713                 totalteams = totalteams + 1;
 714         if(c4 >= 0)
 715                 totalteams = totalteams + 1;
 716
 717         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 718                 totalteams += 1;
 719
 720         if(totalteams <= 1)
 721         {
 722                 if(autocvar_g_campaign && pl && clienttype(pl) == CLIENTTYPE_REAL)
 723                         return 1; // special case for campaign and player joining
 724                 else if(g_domination)
 725                         error("Too few teams available for domination\n");
 726                 else if(g_ctf)
 727                         error("Too few teams available for ctf\n");
 728                 else if(g_keyhunt)
 729                         error("Too few teams available for key hunt\n");
 730                 else if(g_freezetag)
 731                         error("Too few teams available for freeze tag\n");
 732                 else
 733                         error("Too few teams available for team deathmatch\n");
 734         }
 735
 736         // count how many players are in each team
 737         if(ignore_pl)
 738                 GetTeamCounts(pl);
 739         else
 740                 GetTeamCounts(world);
 741
 742         RandomSelection_Init();
 743
 744         t = 1;
 745         if(TeamSmallerEqThanTeam(2, t, pl))
 746                 t = 2;
 747         if(TeamSmallerEqThanTeam(3, t, pl))
 748                 t = 3;
 749         if(TeamSmallerEqThanTeam(4, t, pl))
 750                 t = 4;
 751
 752         // now t is the minimum, or A minimum!
 753         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 754                 RandomSelection_Add(world, 1, string_null, 1, 1);
 755         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 756                 RandomSelection_Add(world, 2, string_null, 1, 1);
 757         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 758                 RandomSelection_Add(world, 3, string_null, 1, 1);
 759         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 760                 RandomSelection_Add(world, 4, string_null, 1, 1);
 761
 762         return RandomSelection_chosen_float;
 763 }
 764
 765 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 766 {
 767         float smallest, selectedteam;
 768
 769         // don't join a team if we're not playing a team game
 770         if(!teamplay)
 771                 return 0;
 772
 773         // find out what teams are available
 774         CheckAllowedTeams(pl);
 775
 776         // if we don't care what team he ends up on, put him on whatever team he entered as.
 777         // if he's not on a valid team, then let other code put him on the smallest team
 778         if(!forcebestteam)
 779         {
 780                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 781                         selectedteam = pl.team;
 782                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 783                         selectedteam = pl.team;
 784                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 785                         selectedteam = pl.team;
 786                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 787                         selectedteam = pl.team;
 788                 else
 789                         selectedteam = -1;
 790
 791                 if(selectedteam > 0)
 792                 {
 793                         if(!only_return_best)
 794                         {
 795                                 SetPlayerColors(pl, selectedteam - 1);
 796
 797                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 798                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 799                                 LogTeamchange(pl.playerid, pl.team, 99);
 800                         }
 801                         return selectedteam;
 802                 }
 803                 // otherwise end up on the smallest team (handled below)
 804         }
 805
 806         smallest = FindSmallestTeam(pl, TRUE);
 807
 808         if(!only_return_best && !pl.bot_forced_team)
 809         {
 810                 TeamchangeFrags(self);
 811                 if(smallest == 1)
 812                 {
 813                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 814                 }
 815                 else if(smallest == 2)
 816                 {
 817                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 818                 }
 819                 else if(smallest == 3)
 820                 {
 821                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 822                 }
 823                 else if(smallest == 4)
 824                 {
 825                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 826                 }
 827                 else
 828                 {
 829                         error("smallest team: invalid team\n");
 830                 }
 831
 832                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 833
 834                 if(pl.deadflag == DEAD_NO)
 835                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 836         }
 837
 838         return smallest;
 839 }
 840
 841 //void() ctf_playerchanged;
 842 void SV_ChangeTeam(float _color)
 843 {
 844         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 845
 846         // in normal deathmatch we can just apply the color and we're done
 847         if(!teamplay) {
 848                 SetPlayerColors(self, _color);
 849                 return;
 850         }
 851
 852         scolor = self.clientcolors & 0x0F;
 853         dcolor = _color & 0x0F;
 854
 855         if(scolor == COLOR_TEAM1 - 1)
 856                 steam = 1;
 857         else if(scolor == COLOR_TEAM2 - 1)
 858                 steam = 2;
 859         else if(scolor == COLOR_TEAM3 - 1)
 860                 steam = 3;
 861         else // if(scolor == COLOR_TEAM4 - 1)
 862                 steam = 4;
 863         if(dcolor == COLOR_TEAM1 - 1)
 864                 dteam = 1;
 865         else if(dcolor == COLOR_TEAM2 - 1)
 866                 dteam = 2;
 867         else if(dcolor == COLOR_TEAM3 - 1)
 868                 dteam = 3;
 869         else // if(dcolor == COLOR_TEAM4 - 1)
 870                 dteam = 4;
 871
 872         CheckAllowedTeams(self);
 873
 874         if(dteam == 1 && c1 < 0) dteam = 4;
 875         if(dteam == 4 && c4 < 0) dteam = 3;
 876         if(dteam == 3 && c3 < 0) dteam = 2;
 877         if(dteam == 2 && c2 < 0) dteam = 1;
 878
 879         // not changing teams
 880         if(scolor == dcolor)
 881         {
 882                 //bprint("same team change\n");
 883                 SetPlayerTeam(self, dteam, steam, TRUE);
 884                 return;
 885         }
 886
 887         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 888                 sprint(self, "Team changes not allowed\n");
 889                 return; // changing teams is not allowed
 890         }
 891
 892         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 893         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 894         {
 895                 GetTeamCounts(self);
 896                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 897                 {
 898                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 899                         return;
 900                 }
 901         }
 902
 903 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 904
 905         if(self.classname == "player" && steam != dteam)
 906         {
 907                 // reduce frags during a team change
 908                 TeamchangeFrags(self);
 909         }
 910
 911         SetPlayerTeam(self, dteam, steam, FALSE);
 912
 913         if(self.classname == "player" && steam != dteam)
 914         {
 915                 // kill player when changing teams
 916                 if(self.deadflag == DEAD_NO)
 917                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 918         }
 919 }
 920
 921 void ShufflePlayerOutOfTeam (float source_team)
 922 {
 923         float smallestteam, smallestteam_count, steam;
 924         float lowest_bot_score, lowest_player_score;
 925         entity head, lowest_bot, lowest_player, selected;
 926
 927         smallestteam = 0;
 928         smallestteam_count = 999999999;
 929
 930         if(c1 >= 0 && c1 < smallestteam_count)
 931         {
 932                 smallestteam = 1;
 933                 smallestteam_count = c1;
 934         }
 935         if(c2 >= 0 && c2 < smallestteam_count)
 936         {
 937                 smallestteam = 2;
 938                 smallestteam_count = c2;
 939         }
 940         if(c3 >= 0 && c3 < smallestteam_count)
 941         {
 942                 smallestteam = 3;
 943                 smallestteam_count = c3;
 944         }
 945         if(c4 >= 0 && c4 < smallestteam_count)
 946         {
 947                 smallestteam = 4;
 948                 smallestteam_count = c4;
 949         }
 950
 951         if(!smallestteam)
 952         {
 953                 bprint("warning: no smallest team\n");
 954                 return;
 955         }
 956
 957         if(source_team == 1)
 958                 steam = COLOR_TEAM1;
 959         else if(source_team == 2)
 960                 steam = COLOR_TEAM2;
 961         else if(source_team == 3)
 962                 steam = COLOR_TEAM3;
 963         else // if(source_team == 4)
 964                 steam = COLOR_TEAM4;
 965
 966         lowest_bot = world;
 967         lowest_bot_score = 999999999;
 968         lowest_player = world;
 969         lowest_player_score = 999999999;
 970
 971         // find the lowest-scoring player & bot of that team
 972         FOR_EACH_PLAYER(head)
 973         {
 974                 if(head.team == steam)
 975                 {
 976                         if(head.isbot)
 977                         {
 978                                 if(head.totalfrags < lowest_bot_score)
 979                                 {
 980                                         lowest_bot = head;
 981                                         lowest_bot_score = head.totalfrags;
 982                                 }
 983                         }
 984                         else
 985                         {
 986                                 if(head.totalfrags < lowest_player_score)
 987                                 {
 988                                         lowest_player = head;
 989                                         lowest_player_score = head.totalfrags;
 990                                 }
 991                         }
 992                 }
 993         }
 994
 995         // prefers to move a bot...
 996         if(lowest_bot != world)
 997                 selected = lowest_bot;
 998         // but it will move a player if it has to
 999         else
1000                 selected = lowest_player;
1001         // don't do anything if it couldn't find anyone
1002         if(!selected)
1003         {
1004                 bprint("warning: couldn't find a player to move from team\n");
1005                 return;
1006         }
1007
1008         // smallest team gains a member
1009         if(smallestteam == 1)
1010         {
1011                 c1 = c1 + 1;
1012         }
1013         else if(smallestteam == 2)
1014         {
1015                 c2 = c2 + 1;
1016         }
1017         else if(smallestteam == 3)
1018         {
1019                 c3 = c3 + 1;
1020         }
1021         else if(smallestteam == 4)
1022         {
1023                 c4 = c4 + 1;
1024         }
1025         else
1026         {
1027                 bprint("warning: destination team invalid\n");
1028                 return;
1029         }
1030         // source team loses a member
1031         if(source_team == 1)
1032         {
1033                 c1 = c1 + 1;
1034         }
1035         else if(source_team == 2)
1036         {
1037                 c2 = c2 + 2;
1038         }
1039         else if(source_team == 3)
1040         {
1041                 c3 = c3 + 3;
1042         }
1043         else if(source_team == 4)
1044         {
1045                 c4 = c4 + 4;
1046         }
1047         else
1048         {
1049                 bprint("warning: source team invalid\n");
1050                 return;
1051         }
1052
1053         // move the player to the new team
1054         TeamchangeFrags(selected);
1055         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1056
1057         if(selected.deadflag == DEAD_NO)
1058                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1059         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1060 }
1061
1062 // code from here on is just to support maps that don't have team entities
1063 void tdm_spawnteam (string teamname, float teamcolor)
1064 {
1065         entity e;
1066         e = spawn();
1067         e.classname = "tdm_team";
1068         e.netname = teamname;
1069         e.cnt = teamcolor;
1070         e.team = e.cnt + 1;
1071 }
1072
1073 // spawn some default teams if the map is not set up for tdm
1074 void tdm_spawnteams()
1075 {
1076         float numteams;
1077
1078         numteams = autocvar_g_tdm_teams_override;
1079         if(numteams < 2)
1080                 numteams = autocvar_g_tdm_teams;
1081         numteams = bound(2, numteams, 4);
1082
1083         tdm_spawnteam("Red", COLOR_TEAM1-1);
1084         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1085         if(numteams >= 3)
1086                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1087         if(numteams >= 4)
1088                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1089 }
1090
1091 void tdm_delayedinit()
1092 {
1093         // if no teams are found, spawn defaults
1094         if (find(world, classname, "tdm_team") == world)
1095                 tdm_spawnteams();
1096 }
1097
1098 void tdm_init()
1099 {
1100         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1101 }