qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teamplay)
  16                 return 0;
  17         if(autocvar_g_campaign)
  18                 return 0;
  19         if(autocvar_bot_vs_human && (c3==-1 && c4==-1))
  20                 return 0;
  21         if(!autocvar_g_balance_teams_force)
  22                 return -1;
  23         return 1;
  24 }
  25
  26 void TeamchangeFrags(entity e)
  27 {
  28         PlayerScore_Clear(e);
  29 }
  30
  31 vector TeamColor(float teem)
  32 {
  33         switch(teem)
  34         {
  35                 case COLOR_TEAM1:
  36                         return '1 0.0625 0.0625';
  37                 case COLOR_TEAM2:
  38                         return '0.0625 0.0625 1';
  39                 case COLOR_TEAM3:
  40                         return '1 1 0.0625';
  41                 case COLOR_TEAM4:
  42                         return '1 0.0625 1';
  43                 default:
  44                         return '1 1 1';
  45         }
  46 }
  47
  48 string TeamName(float t)
  49 {
  50         return strcat(Team_ColorName(t), " Team");
  51 }
  52 string ColoredTeamName(float t)
  53 {
  54         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  55 }
  56 string TeamNoName(float t)
  57 {
  58         // fixme: Search for team entities and get their .netname's!
  59         if(t == 1)
  60                 return "Red Team";
  61         if(t == 2)
  62                 return "Blue Team";
  63         if(t == 3)
  64                 return "Yellow Team";
  65         if(t == 4)
  66                 return "Pink Team";
  67         return "Neutral Team";
  68 }
  69
  70 void dom_init();
  71 void ctf_init();
  72 void runematch_init();
  73 void tdm_init();
  74 void entcs_init();
  75
  76 void LogTeamchange(float player_id, float team_number, float type)
  77 {
  78         if(!autocvar_sv_eventlog)
  79                 return;
  80
  81         if(player_id < 1)
  82                 return;
  83
  84         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  85 }
  86
  87 void default_delayedinit()
  88 {
  89         if(!scores_initialized)
  90                 ScoreRules_generic();
  91 }
  92
  93 void ActivateTeamplay()
  94 {
  95         serverflags |= SERVERFLAG_TEAMPLAY;
  96         teamplay = 1;
  97 }
  98
  99 void InitGameplayMode()
 100 {
 101         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 102
 103         qualifying_override = -1;
 104
 105         VoteReset();
 106
 107         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 108         get_mi_min_max(1);
 109         world.mins = mi_min;
 110         world.maxs = mi_max;
 111
 112         MapInfo_LoadMapSettings(mapname);
 113         teamplay = 0;
 114         serverflags &~= SERVERFLAG_TEAMPLAY;
 115
 116         if not(cvar_value_issafe(world.fog))
 117         {
 118                 print("The current map contains a potentially harmful fog setting, ignored\n");
 119                 world.fog = string_null;
 120         }
 121         if(MapInfo_Map_fog != "")
 122                 if(MapInfo_Map_fog == "none")
 123                         world.fog = string_null;
 124                 else
 125                         world.fog = strzone(MapInfo_Map_fog);
 126         clientstuff = strzone(MapInfo_Map_clientstuff);
 127
 128         MapInfo_ClearTemps();
 129
 130         // set both here, gamemode can override it later
 131         timelimit_override = autocvar_timelimit_override;
 132         fraglimit_override = autocvar_fraglimit_override;
 133         leadlimit_override = autocvar_leadlimit_override;
 134         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 135
 136         if(g_dm)
 137         {
 138         }
 139
 140         if(g_tdm)
 141         {
 142                 ActivateTeamplay();
 143                 tdm_init();
 144                 if(autocvar_g_tdm_team_spawns)
 145                         have_team_spawns = -1; // request team spawns
 146         }
 147
 148         if(g_domination)
 149         {
 150                 ActivateTeamplay();
 151                 fraglimit_override = autocvar_g_domination_point_limit;
 152                 leadlimit_override = autocvar_g_domination_point_leadlimit;
 153                 dom_init();
 154                 have_team_spawns = -1; // request team spawns
 155         }
 156
 157         if(g_ctf)
 158         {
 159                 ActivateTeamplay();
 160                 g_ctf_ignore_frags = autocvar_g_ctf_ignore_frags;
 161                 fraglimit_override = autocvar_capturelimit_override;
 162                 leadlimit_override = autocvar_captureleadlimit_override;
 163                 ctf_init();
 164                 have_team_spawns = -1; // request team spawns
 165         }
 166
 167         if(g_runematch)
 168         {
 169                 // ActivateTeamplay();
 170                 fraglimit_override = autocvar_g_runematch_point_limit;
 171                 leadlimit_override = autocvar_g_runematch_point_leadlimit;
 172                 runematch_init();
 173         }
 174
 175         if(g_lms)
 176         {
 177                 fraglimit_override = autocvar_g_lms_lives_override;
 178                 leadlimit_override = 0; // not supported by LMS
 179                 if(fraglimit_override == 0)
 180                         fraglimit_override = -1;
 181                 lms_lowest_lives = 9999;
 182                 lms_next_place = 0;
 183                 ScoreRules_lms();
 184         }
 185
 186         if(g_arena)
 187         {
 188                 fraglimit_override = autocvar_g_arena_point_limit;
 189                 leadlimit_override = autocvar_g_arena_point_leadlimit;
 190                 maxspawned = autocvar_g_arena_maxspawned;
 191                 if(maxspawned < 2)
 192                         maxspawned = 2;
 193                 arena_roundbased = autocvar_g_arena_roundbased;
 194         }
 195
 196         if(g_ca)
 197         {
 198                 ActivateTeamplay();
 199                 fraglimit_override = autocvar_g_ca_point_limit;
 200                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 201                 precache_sound("ctf/red_capture.wav");
 202                 precache_sound("ctf/blue_capture.wav");
 203         }
 204         if(g_keyhunt)
 205         {
 206                 ActivateTeamplay();
 207                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 208                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 209                 MUTATOR_ADD(gamemode_keyhunt);
 210         }
 211
 212         if(g_freezetag)
 213         {
 214                 ActivateTeamplay();
 215                 fraglimit_override = autocvar_g_freezetag_point_limit;
 216                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 217                 MUTATOR_ADD(gamemode_freezetag);
 218         }
 219
 220         if(g_assault)
 221         {
 222                 ActivateTeamplay();
 223                 ScoreRules_assault();
 224                 have_team_spawns = -1; // request team spawns
 225         }
 226
 227         if(g_onslaught)
 228         {
 229                 ActivateTeamplay();
 230                 have_team_spawns = -1; // request team spawns
 231         }
 232
 233         if(g_race)
 234         {
 235
 236                 if(autocvar_g_race_teams)
 237                 {
 238                         ActivateTeamplay();
 239                         race_teams = bound(2, autocvar_g_race_teams, 4);
 240                         have_team_spawns = -1; // request team spawns
 241                 }
 242                 else
 243                         race_teams = 0;
 244
 245                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 246                 fraglimit_override = autocvar_g_race_laps_limit;
 247                 leadlimit_override = 0; // currently not supported by race
 248         }
 249
 250         if(g_cts)
 251         {
 252                 g_race_qualifying = 1;
 253                 fraglimit_override = 0;
 254                 leadlimit_override = 0;
 255         }
 256
 257         if(g_nexball)
 258         {
 259         fraglimit_override = autocvar_g_nexball_goallimit;
 260         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 261         ActivateTeamplay();
 262         have_team_spawns = -1; // request team spawns
 263             MUTATOR_ADD(gamemode_nexball);
 264         }
 265
 266         if(g_keepaway)
 267         {
 268                 MUTATOR_ADD(gamemode_keepaway);
 269         }
 270
 271         if(teamplay)
 272                 entcs_init();
 273
 274         cache_mutatormsg = strzone("");
 275         cache_lastmutatormsg = strzone("");
 276
 277         // enforce the server's universal frag/time limits
 278         if(!autocvar_g_campaign)
 279         {
 280                 if(fraglimit_override >= 0)
 281                         cvar_set("fraglimit", ftos(fraglimit_override));
 282                 if(timelimit_override >= 0)
 283                         cvar_set("timelimit", ftos(timelimit_override));
 284                 if(leadlimit_override >= 0)
 285                         cvar_set("leadlimit", ftos(leadlimit_override));
 286                 if(qualifying_override >= 0)
 287                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 288         }
 289
 290         if(g_race)
 291         {
 292                 // we need to find out the correct value for g_race_qualifying
 293                 if(autocvar_g_campaign)
 294                 {
 295                         g_race_qualifying = 1;
 296                 }
 297                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 298                 {
 299                         g_race_qualifying = 2;
 300                         race_fraglimit = autocvar_fraglimit;
 301                         race_leadlimit = autocvar_leadlimit;
 302                         race_timelimit = autocvar_timelimit;
 303                         cvar_set("fraglimit", "0");
 304                         cvar_set("leadlimit", "0");
 305                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 306                 }
 307                 else
 308                         g_race_qualifying = 0;
 309         }
 310
 311         if(g_race || g_cts)
 312         {
 313                 if(g_race_qualifying)
 314                         independent_players = 1;
 315
 316                 ScoreRules_race();
 317         }
 318
 319         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 320 }
 321
 322 string GetClientVersionMessage() {
 323         string versionmsg;
 324         if (self.version_mismatch) {
 325                 if(self.version < autocvar_gameversion) {
 326                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 327                 } else {
 328                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 329                 }
 330         } else {
 331                 versionmsg = "^2client version and server version are compatible.^8";
 332         }
 333         return versionmsg;
 334 }
 335
 336 string getwelcomemessage(void)
 337 {
 338         string s, modifications, motd;
 339
 340         ret_string = "";
 341         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 342         modifications = ret_string;
 343
 344         if(g_minstagib)
 345                 modifications = strcat(modifications, ", MinstaGib");
 346         if(g_weaponarena)
 347         {
 348                 if(g_weaponarena_random)
 349                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 350                 else
 351                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 352         }
 353         if(autocvar_g_start_weapon_laser == 0)
 354                 modifications = strcat(modifications, ", No start weapons");
 355         if(autocvar_sv_gravity < 800)
 356                 modifications = strcat(modifications, ", Low gravity");
 357         if(g_cloaked && !g_cts)
 358                 modifications = strcat(modifications, ", Cloaked");
 359         if(g_grappling_hook)
 360                 modifications = strcat(modifications, ", Hook");
 361         if(g_midair)
 362                 modifications = strcat(modifications, ", Midair");
 363         if(g_pinata)
 364                 modifications = strcat(modifications, ", Piñata");
 365         if(g_weapon_stay && !g_cts)
 366                 modifications = strcat(modifications, ", Weapons stay");
 367         if(g_bloodloss > 0)
 368                 modifications = strcat(modifications, ", Blood loss");
 369         if(g_jetpack)
 370                 modifications = strcat(modifications, ", Jet pack");
 371         if(autocvar_g_powerups == 0)
 372                 modifications = strcat(modifications, ", No powerups");
 373         if(autocvar_g_powerups > 0)
 374                 modifications = strcat(modifications, ", Powerups");
 375         modifications = substring(modifications, 2, strlen(modifications) - 2);
 376
 377         string versionmessage;
 378         versionmessage = GetClientVersionMessage();
 379
 380         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 381         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 382
 383         if(modifications != "")
 384                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 385
 386         if (g_grappling_hook)
 387                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 388
 389         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 390         {
 391                 if(cache_lastmutatormsg)
 392                         strunzone(cache_lastmutatormsg);
 393                 if(cache_mutatormsg)
 394                         strunzone(cache_mutatormsg);
 395                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 396                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 397         }
 398
 399         if (cache_mutatormsg != "") {
 400                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 401         }
 402
 403         motd = autocvar_sv_motd;
 404         if (motd != "") {
 405                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 406         }
 407         return s;
 408 }
 409
 410 void SetPlayerColors(entity pl, float _color)
 411 {
 412         /*string s;
 413         s = ftos(cl);
 414         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 415         pl.team = cl + 1;
 416         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 417         pl.clientcolors = 16*cl + cl;*/
 418
 419         float pants, shirt;
 420         pants = _color & 0x0F;
 421         shirt = _color & 0xF0;
 422
 423
 424         if(teamplay) {
 425                 setcolor(pl, 16*pants + pants);
 426         } else {
 427                 setcolor(pl, shirt + pants);
 428         }
 429 }
 430
 431 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 432 {
 433         float _color;
 434
 435         if(t == 4)
 436                 _color = COLOR_TEAM4 - 1;
 437         else if(t == 3)
 438                 _color = COLOR_TEAM3 - 1;
 439         else if(t == 2)
 440                 _color = COLOR_TEAM2 - 1;
 441         else
 442                 _color = COLOR_TEAM1 - 1;
 443
 444         SetPlayerColors(pl,_color);
 445
 446         if(t != s) {
 447                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 448
 449                 if(!noprint)
 450                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 451         }
 452
 453 }
 454
 455 // set c1...c4 to show what teams are allowed
 456 void CheckAllowedTeams (entity for_whom)
 457 {
 458         float dm;
 459         entity head;
 460         string teament_name;
 461
 462         c1 = c2 = c3 = c4 = -1;
 463         cb1 = cb2 = cb3 = cb4 = 0;
 464
 465         teament_name = string_null;
 466         if(g_onslaught)
 467         {
 468                 // onslaught is special
 469                 head = findchain(classname, "onslaught_generator");
 470                 while (head)
 471                 {
 472                         if (head.team == COLOR_TEAM1) c1 = 0;
 473                         if (head.team == COLOR_TEAM2) c2 = 0;
 474                         if (head.team == COLOR_TEAM3) c3 = 0;
 475                         if (head.team == COLOR_TEAM4) c4 = 0;
 476                         head = head.chain;
 477                 }
 478         }
 479         else if(g_domination)
 480                 teament_name = "dom_team";
 481         else if(g_ctf)
 482                 teament_name = "ctf_team";
 483         else if(g_tdm)
 484                 teament_name = "tdm_team";
 485         else if(g_nexball)
 486                 teament_name = "nexball_team";
 487         else if(g_assault)
 488                 c1 = c2 = 0; // Assault always has 2 teams
 489         else
 490         {
 491                 // cover anything else by treating it like tdm with no teams spawned
 492                 if(g_race)
 493                         dm = race_teams;
 494                 else
 495                         dm = 2;
 496
 497                 ret_float = dm;
 498                 MUTATOR_CALLHOOK(GetTeamCount);
 499                 dm = ret_float;
 500
 501                 if(dm >= 4)
 502                         c1 = c2 = c3 = c4 = 0;
 503                 else if(dm >= 3)
 504                         c1 = c2 = c3 = 0;
 505                 else
 506                         c1 = c2 = 0;
 507         }
 508
 509         // find out what teams are allowed if necessary
 510         if(teament_name)
 511         {
 512                 head = find(world, classname, teament_name);
 513                 while(head)
 514                 {
 515                         if(!(g_domination && head.netname == ""))
 516                         {
 517                                 if(head.team == COLOR_TEAM1)
 518                                         c1 = 0;
 519                                 else if(head.team == COLOR_TEAM2)
 520                                         c2 = 0;
 521                                 else if(head.team == COLOR_TEAM3)
 522                                         c3 = 0;
 523                                 else if(head.team == COLOR_TEAM4)
 524                                         c4 = 0;
 525                         }
 526                         head = find(head, classname, teament_name);
 527                 }
 528         }
 529
 530         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 531         if(c3==-1 && c4==-1)
 532         if(autocvar_bot_vs_human && for_whom)
 533         {
 534                 if(autocvar_bot_vs_human > 0)
 535                 {
 536                         // bots are all blue
 537                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 538                                 c1 = c3 = c4 = -1;
 539                         else
 540                                 c2 = -1;
 541                 }
 542                 else
 543                 {
 544                         // bots are all red
 545                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 546                                 c2 = c3 = c4 = -1;
 547                         else
 548                                 c1 = -1;
 549                 }
 550         }
 551
 552         // if player has a forced team, ONLY allow that one
 553         if(self.team_forced == COLOR_TEAM1 && c1 >= 0)
 554                 c2 = c3 = c4 = -1;
 555         else if(self.team_forced == COLOR_TEAM2 && c2 >= 0)
 556                 c1 = c3 = c4 = -1;
 557         else if(self.team_forced == COLOR_TEAM3 && c3 >= 0)
 558                 c1 = c2 = c4 = -1;
 559         else if(self.team_forced == COLOR_TEAM4 && c4 >= 0)
 560                 c1 = c2 = c3 = -1;
 561 }
 562
 563 float PlayerValue(entity p)
 564 {
 565         if(IsTeamBalanceForced() == 1)
 566                 return 1;
 567         return 1;
 568         // FIXME: it always returns 1...
 569 }
 570
 571 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 572 // teams that are allowed will now have their player counts stored in c1...c4
 573 void GetTeamCounts(entity ignore)
 574 {
 575         entity head;
 576         float value, bvalue;
 577         // now count how many players are on each team already
 578
 579         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 580         // also remember the lowest-scoring player
 581
 582         FOR_EACH_CLIENT(head)
 583         {
 584                 float t;
 585                 if(head.classname == "player")
 586                         t = head.team;
 587                 else if(head.team_forced > 0)
 588                         t = head.team_forced; // reserve the spot
 589                 else
 590                         continue;
 591                 if(head != ignore)// && head.netname != "")
 592                 {
 593                         value = PlayerValue(head);
 594                         if(clienttype(head) == CLIENTTYPE_BOT)
 595                                 bvalue = value;
 596                         else
 597                                 bvalue = 0;
 598                         if(t == COLOR_TEAM1)
 599                         {
 600                                 if(c1 >= 0)
 601                                 {
 602                                         c1 = c1 + value;
 603                                         cb1 = cb1 + bvalue;
 604                                 }
 605                         }
 606                         if(t == COLOR_TEAM2)
 607                         {
 608                                 if(c2 >= 0)
 609                                 {
 610                                         c2 = c2 + value;
 611                                         cb2 = cb2 + bvalue;
 612                                 }
 613                         }
 614                         if(t == COLOR_TEAM3)
 615                         {
 616                                 if(c3 >= 0)
 617                                 {
 618                                         c3 = c3 + value;
 619                                         cb3 = cb3 + bvalue;
 620                                 }
 621                         }
 622                         if(t == COLOR_TEAM4)
 623                         {
 624                                 if(c4 >= 0)
 625                                 {
 626                                         c4 = c4 + value;
 627                                         cb4 = cb4 + bvalue;
 628                                 }
 629                         }
 630                 }
 631         }
 632
 633         // if the player who has a forced team has not joined yet, reserve the spot
 634         if(autocvar_g_campaign)
 635         {
 636                 switch(autocvar_g_campaign_forceteam)
 637                 {
 638                         case 1: if(c1 == cb1) ++c1; break;
 639                         case 2: if(c2 == cb2) ++c2; break;
 640                         case 3: if(c3 == cb3) ++c3; break;
 641                         case 4: if(c4 == cb4) ++c4; break;
 642                 }
 643         }
 644 }
 645
 646 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 647 {
 648         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 649         float f;
 650         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 651
 652         switch(ta)
 653         {
 654                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 655                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 656                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 657                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 658         }
 659         switch(tb)
 660         {
 661                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 662                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 663                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 664                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 665         }
 666
 667         // invalid
 668         if(ca < 0 || cb < 0)
 669                 return FALSE;
 670
 671         // equal
 672         if(ta == tb)
 673                 return TRUE;
 674
 675         if(clienttype(e) == CLIENTTYPE_REAL)
 676         {
 677                 if(bots_would_leave)
 678                 {
 679                         ca -= cba * 0.999;
 680                         cb -= cbb * 0.999;
 681                 }
 682         }
 683
 684         // first, normalize
 685         f = max(ca, cb, 1);
 686         ca /= f;
 687         cb /= f;
 688         f = max(sa, sb, 1);
 689         sa /= f;
 690         sb /= f;
 691
 692         // the more we're at the end of the match, the more take scores into account
 693         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 694         ca += (sa - ca) * f;
 695         cb += (sb - cb) * f;
 696
 697         return ca <= cb;
 698 }
 699
 700 // returns # of smallest team (1, 2, 3, 4)
 701 // NOTE: Assumes CheckAllowedTeams has already been called!
 702 float FindSmallestTeam(entity pl, float ignore_pl)
 703 {
 704         float totalteams, t;
 705         totalteams = 0;
 706
 707         // find out what teams are available
 708         //CheckAllowedTeams();
 709
 710         // make sure there are at least 2 teams to join
 711         if(c1 >= 0)
 712                 totalteams = totalteams + 1;
 713         if(c2 >= 0)
 714                 totalteams = totalteams + 1;
 715         if(c3 >= 0)
 716                 totalteams = totalteams + 1;
 717         if(c4 >= 0)
 718                 totalteams = totalteams + 1;
 719
 720         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 721                 totalteams += 1;
 722
 723         if(totalteams <= 1)
 724         {
 725                 if(autocvar_g_campaign && pl && clienttype(pl) == CLIENTTYPE_REAL)
 726                         return 1; // special case for campaign and player joining
 727                 else if(g_domination)
 728                         error("Too few teams available for domination\n");
 729                 else if(g_ctf)
 730                         error("Too few teams available for ctf\n");
 731                 else if(g_keyhunt)
 732                         error("Too few teams available for key hunt\n");
 733                 else if(g_freezetag)
 734                         error("Too few teams available for freeze tag\n");
 735                 else
 736                         error("Too few teams available for team deathmatch\n");
 737         }
 738
 739         // count how many players are in each team
 740         if(ignore_pl)
 741                 GetTeamCounts(pl);
 742         else
 743                 GetTeamCounts(world);
 744
 745         RandomSelection_Init();
 746
 747         t = 1;
 748         if(TeamSmallerEqThanTeam(2, t, pl))
 749                 t = 2;
 750         if(TeamSmallerEqThanTeam(3, t, pl))
 751                 t = 3;
 752         if(TeamSmallerEqThanTeam(4, t, pl))
 753                 t = 4;
 754
 755         // now t is the minimum, or A minimum!
 756         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 757                 RandomSelection_Add(world, 1, string_null, 1, 1);
 758         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 759                 RandomSelection_Add(world, 2, string_null, 1, 1);
 760         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 761                 RandomSelection_Add(world, 3, string_null, 1, 1);
 762         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 763                 RandomSelection_Add(world, 4, string_null, 1, 1);
 764
 765         return RandomSelection_chosen_float;
 766 }
 767
 768 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 769 {
 770         float smallest, selectedteam;
 771
 772         // don't join a team if we're not playing a team game
 773         if(!teamplay)
 774                 return 0;
 775
 776         // find out what teams are available
 777         CheckAllowedTeams(pl);
 778
 779         // if we don't care what team he ends up on, put him on whatever team he entered as.
 780         // if he's not on a valid team, then let other code put him on the smallest team
 781         if(!forcebestteam)
 782         {
 783                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 784                         selectedteam = pl.team;
 785                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 786                         selectedteam = pl.team;
 787                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 788                         selectedteam = pl.team;
 789                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 790                         selectedteam = pl.team;
 791                 else
 792                         selectedteam = -1;
 793
 794                 if(selectedteam > 0)
 795                 {
 796                         if(!only_return_best)
 797                         {
 798                                 SetPlayerColors(pl, selectedteam - 1);
 799
 800                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 801                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 802                                 LogTeamchange(pl.playerid, pl.team, 99);
 803                         }
 804                         return selectedteam;
 805                 }
 806                 // otherwise end up on the smallest team (handled below)
 807         }
 808
 809         smallest = FindSmallestTeam(pl, TRUE);
 810
 811         if(!only_return_best && !pl.bot_forced_team)
 812         {
 813                 TeamchangeFrags(self);
 814                 if(smallest == 1)
 815                 {
 816                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 817                 }
 818                 else if(smallest == 2)
 819                 {
 820                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 821                 }
 822                 else if(smallest == 3)
 823                 {
 824                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 825                 }
 826                 else if(smallest == 4)
 827                 {
 828                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 829                 }
 830                 else
 831                 {
 832                         error("smallest team: invalid team\n");
 833                 }
 834
 835                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 836
 837                 if(pl.deadflag == DEAD_NO)
 838                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 839         }
 840
 841         return smallest;
 842 }
 843
 844 //void() ctf_playerchanged;
 845 void SV_ChangeTeam(float _color)
 846 {
 847         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 848
 849         // in normal deathmatch we can just apply the color and we're done
 850         if(!teamplay) {
 851                 SetPlayerColors(self, _color);
 852                 return;
 853         }
 854
 855         scolor = self.clientcolors & 0x0F;
 856         dcolor = _color & 0x0F;
 857
 858         if(scolor == COLOR_TEAM1 - 1)
 859                 steam = 1;
 860         else if(scolor == COLOR_TEAM2 - 1)
 861                 steam = 2;
 862         else if(scolor == COLOR_TEAM3 - 1)
 863                 steam = 3;
 864         else // if(scolor == COLOR_TEAM4 - 1)
 865                 steam = 4;
 866         if(dcolor == COLOR_TEAM1 - 1)
 867                 dteam = 1;
 868         else if(dcolor == COLOR_TEAM2 - 1)
 869                 dteam = 2;
 870         else if(dcolor == COLOR_TEAM3 - 1)
 871                 dteam = 3;
 872         else // if(dcolor == COLOR_TEAM4 - 1)
 873                 dteam = 4;
 874
 875         CheckAllowedTeams(self);
 876
 877         if(dteam == 1 && c1 < 0) dteam = 4;
 878         if(dteam == 4 && c4 < 0) dteam = 3;
 879         if(dteam == 3 && c3 < 0) dteam = 2;
 880         if(dteam == 2 && c2 < 0) dteam = 1;
 881
 882         // not changing teams
 883         if(scolor == dcolor)
 884         {
 885                 //bprint("same team change\n");
 886                 SetPlayerTeam(self, dteam, steam, TRUE);
 887                 return;
 888         }
 889
 890         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 891                 sprint(self, "Team changes not allowed\n");
 892                 return; // changing teams is not allowed
 893         }
 894
 895         if(autocvar_g_balance_teams_prevent_imbalance)
 896         {
 897                 GetTeamCounts(self);
 898                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 899                 {
 900                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 901                         return;
 902                 }
 903         }
 904
 905 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 906
 907         if(self.classname == "player" && steam != dteam)
 908         {
 909                 // reduce frags during a team change
 910                 TeamchangeFrags(self);
 911         }
 912
 913         SetPlayerTeam(self, dteam, steam, FALSE);
 914
 915         if(self.classname == "player" && steam != dteam)
 916         {
 917                 // kill player when changing teams
 918                 if(self.deadflag == DEAD_NO)
 919                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 920         }
 921         //ctf_playerchanged();
 922 }
 923
 924 void ShufflePlayerOutOfTeam (float source_team)
 925 {
 926         float smallestteam, smallestteam_count, steam;
 927         float lowest_bot_score, lowest_player_score;
 928         entity head, lowest_bot, lowest_player, selected;
 929
 930         smallestteam = 0;
 931         smallestteam_count = 999999999;
 932
 933         if(c1 >= 0 && c1 < smallestteam_count)
 934         {
 935                 smallestteam = 1;
 936                 smallestteam_count = c1;
 937         }
 938         if(c2 >= 0 && c2 < smallestteam_count)
 939         {
 940                 smallestteam = 2;
 941                 smallestteam_count = c2;
 942         }
 943         if(c3 >= 0 && c3 < smallestteam_count)
 944         {
 945                 smallestteam = 3;
 946                 smallestteam_count = c3;
 947         }
 948         if(c4 >= 0 && c4 < smallestteam_count)
 949         {
 950                 smallestteam = 4;
 951                 smallestteam_count = c4;
 952         }
 953
 954         if(!smallestteam)
 955         {
 956                 bprint("warning: no smallest team\n");
 957                 return;
 958         }
 959
 960         if(source_team == 1)
 961                 steam = COLOR_TEAM1;
 962         else if(source_team == 2)
 963                 steam = COLOR_TEAM2;
 964         else if(source_team == 3)
 965                 steam = COLOR_TEAM3;
 966         else // if(source_team == 4)
 967                 steam = COLOR_TEAM4;
 968
 969         lowest_bot = world;
 970         lowest_bot_score = 999999999;
 971         lowest_player = world;
 972         lowest_player_score = 999999999;
 973
 974         // find the lowest-scoring player & bot of that team
 975         FOR_EACH_PLAYER(head)
 976         {
 977                 if(head.team == steam)
 978                 {
 979                         if(head.isbot)
 980                         {
 981                                 if(head.totalfrags < lowest_bot_score)
 982                                 {
 983                                         lowest_bot = head;
 984                                         lowest_bot_score = head.totalfrags;
 985                                 }
 986                         }
 987                         else
 988                         {
 989                                 if(head.totalfrags < lowest_player_score)
 990                                 {
 991                                         lowest_player = head;
 992                                         lowest_player_score = head.totalfrags;
 993                                 }
 994                         }
 995                 }
 996         }
 997
 998         // prefers to move a bot...
 999         if(lowest_bot != world)
1000                 selected = lowest_bot;
1001         // but it will move a player if it has to
1002         else
1003                 selected = lowest_player;
1004         // don't do anything if it couldn't find anyone
1005         if(!selected)
1006         {
1007                 bprint("warning: couldn't find a player to move from team\n");
1008                 return;
1009         }
1010
1011         // smallest team gains a member
1012         if(smallestteam == 1)
1013         {
1014                 c1 = c1 + 1;
1015         }
1016         else if(smallestteam == 2)
1017         {
1018                 c2 = c2 + 1;
1019         }
1020         else if(smallestteam == 3)
1021         {
1022                 c3 = c3 + 1;
1023         }
1024         else if(smallestteam == 4)
1025         {
1026                 c4 = c4 + 1;
1027         }
1028         else
1029         {
1030                 bprint("warning: destination team invalid\n");
1031                 return;
1032         }
1033         // source team loses a member
1034         if(source_team == 1)
1035         {
1036                 c1 = c1 + 1;
1037         }
1038         else if(source_team == 2)
1039         {
1040                 c2 = c2 + 2;
1041         }
1042         else if(source_team == 3)
1043         {
1044                 c3 = c3 + 3;
1045         }
1046         else if(source_team == 4)
1047         {
1048                 c4 = c4 + 4;
1049         }
1050         else
1051         {
1052                 bprint("warning: source team invalid\n");
1053                 return;
1054         }
1055
1056         // move the player to the new team
1057         TeamchangeFrags(selected);
1058         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1059
1060         if(selected.deadflag == DEAD_NO)
1061                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1062         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1063 }
1064
1065 void CauseRebalance(float source_team, float howmany_toomany)
1066 {
1067         if(IsTeamBalanceForced() == 1)
1068         {
1069                 bprint("Rebalancing Teams\n");
1070                 ShufflePlayerOutOfTeam(source_team);
1071         }
1072 }
1073
1074 // part of g_balance_teams_force
1075 // occasionally perform an audit of the teams to make
1076 // sure they're more or less balanced in player count.
1077 void AuditTeams()
1078 {
1079         float numplayers, numteams, smallest, toomany;
1080         float balance;
1081         balance = IsTeamBalanceForced();
1082         if(balance == 0)
1083                 return;
1084
1085         if(audit_teams_time > time)
1086                 return;
1087
1088         audit_teams_time = time + 4 + random();
1089
1090 //      bprint("Auditing teams\n");
1091
1092         CheckAllowedTeams(world);
1093         GetTeamCounts(world);
1094
1095
1096         numteams = numplayers = smallest = 0;
1097         if(c1 >= 0)
1098         {
1099                 numteams = numteams + 1;
1100                 numplayers = numplayers + c1;
1101                 smallest = c1;
1102         }
1103         if(c2 >= 0)
1104         {
1105                 numteams = numteams + 1;
1106                 numplayers = numplayers + c2;
1107                 if(c2 < smallest)
1108                         smallest = c2;
1109         }
1110         if(c3 >= 0)
1111         {
1112                 numteams = numteams + 1;
1113                 numplayers = numplayers + c3;
1114                 if(c3 < smallest)
1115                         smallest = c3;
1116         }
1117         if(c4 >= 0)
1118         {
1119                 numteams = numteams + 1;
1120                 numplayers = numplayers + c4;
1121                 if(c4 < smallest)
1122                         smallest = c4;
1123         }
1124
1125         if(numplayers <= 0)
1126                 return; // no players to move around
1127         if(numteams < 2)
1128                 return; // don't bother shuffling if for some reason there aren't any teams
1129
1130         toomany = smallest + 1;
1131
1132         if(c1 && c1 > toomany)
1133                 CauseRebalance(1, c1 - toomany);
1134         if(c2 && c2 > toomany)
1135                 CauseRebalance(2, c2 - toomany);
1136         if(c3 && c3 > toomany)
1137                 CauseRebalance(3, c3 - toomany);
1138         if(c4 && c4 > toomany)
1139                 CauseRebalance(4, c4 - toomany);
1140
1141         // if teams are still unbalanced, balance them further in the next audit,
1142         // which will happen sooner (keep doing rapid audits until things are in order)
1143         audit_teams_time = time + 0.7 + random()*0.3;
1144 }
1145
1146 // code from here on is just to support maps that don't have team entities
1147 void tdm_spawnteam (string teamname, float teamcolor)
1148 {
1149         entity e;
1150         e = spawn();
1151         e.classname = "tdm_team";
1152         e.netname = teamname;
1153         e.cnt = teamcolor;
1154         e.team = e.cnt + 1;
1155 }
1156
1157 // spawn some default teams if the map is not set up for tdm
1158 void tdm_spawnteams()
1159 {
1160         float numteams;
1161
1162         numteams = autocvar_g_tdm_teams_override;
1163         if(numteams < 2)
1164                 numteams = autocvar_g_tdm_teams;
1165         numteams = bound(2, numteams, 4);
1166
1167         tdm_spawnteam("Red", COLOR_TEAM1-1);
1168         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1169         if(numteams >= 3)
1170                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1171         if(numteams >= 4)
1172                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1173 }
1174
1175 void tdm_delayedinit()
1176 {
1177         // if no teams are found, spawn defaults
1178         if (find(world, classname, "tdm_team") == world)
1179                 tdm_spawnteams();
1180 }
1181
1182 void tdm_init()
1183 {
1184         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1185 }