qcsrc/server/vehicles/racer.qc

   1 #define RACER_MIN '-120 -120 -40'
   2 #define RACER_MAX '120 120 40'
   3 #define RACER_TICRATE 0.05
   4
   5 void racer_exit(float eject);
   6 void racer_enter();
   7
   8 // Auto cvars
   9 float autocvar_g_vehicle_racer_speed_afterburn;
  10 float autocvar_g_vehicle_racer_afterburn_cost;
  11
  12 float autocvar_g_vehicle_racer_anglestabilizer;
  13 float autocvar_g_vehicle_racer_downforce;
  14
  15 float autocvar_g_vehicle_racer_speed_forward;
  16 float autocvar_g_vehicle_racer_speed_strafe;
  17 float autocvar_g_vehicle_racer_springlength;
  18 float autocvar_g_vehicle_racer_upforcedamper;
  19
  20 float autocvar_g_vehicle_racer_hovertype;
  21 float autocvar_g_vehicle_racer_hoverpower;
  22
  23 float autocvar_g_vehicle_racer_turnroll;
  24 float autocvar_g_vehicle_racer_turnspeed;
  25 float autocvar_g_vehicle_racer_pitchspeed;
  26
  27 float autocvar_g_vehicle_racer_energy;
  28 float autocvar_g_vehicle_racer_energy_regen;
  29 float autocvar_g_vehicle_racer_energy_regen_pause;
  30
  31 float autocvar_g_vehicle_racer_health;
  32 float autocvar_g_vehicle_racer_health_regen;
  33 float autocvar_g_vehicle_racer_health_regen_pause;
  34
  35 float autocvar_g_vehicle_racer_shield;
  36 float autocvar_g_vehicle_racer_shield_regen;
  37 float autocvar_g_vehicle_racer_shield_regen_pause;
  38
  39 float autocvar_g_vehicle_racer_laser_cost;
  40 float autocvar_g_vehicle_racer_laser_damage;
  41 float autocvar_g_vehicle_racer_laser_radius;
  42 float autocvar_g_vehicle_racer_laser_refire;
  43 float autocvar_g_vehicle_racer_laser_speed;
  44
  45 float autocvar_g_vehicle_racer_rocket_accel;
  46 float autocvar_g_vehicle_racer_rocket_damage;
  47 float autocvar_g_vehicle_racer_rocket_radius;
  48 float autocvar_g_vehicle_racer_rocket_refire;
  49 float autocvar_g_vehicle_racer_rocket_speed;
  50 float autocvar_g_vehicle_racer_rocket_turnrate;
  51
  52 float autocvar_g_vehicle_racer_rocket_locktarget;
  53 float autocvar_g_vehicle_racer_rocket_locking_time;
  54 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  55 float autocvar_g_vehicle_racer_rocket_locked_time;
  56 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  57
  58 float autocvar_g_vehicle_racer_respawntime;
  59 float autocvar_g_vehicle_racer_collision_multiplier;
  60
  61 float autocvar_g_vehicle_racer_blowup_radius;
  62 float autocvar_g_vehicle_racer_blowup_coredamage;
  63 float autocvar_g_vehicle_racer_blowup_edgedamage;
  64 float autocvar_g_vehicle_racer_blowup_forceintensity;
  65
  66 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
  67
  68 void racer_align4point()
  69 {
  70     vector push_vector, v_add;
  71     float fl_push, fr_push, bl_push, br_push;
  72
  73
  74     push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  75     fr_push      = force_fromtag_normpower;
  76     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  77
  78     push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  79     fl_push      = force_fromtag_normpower;
  80     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  81
  82     push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  83     br_push      = force_fromtag_normpower;
  84     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  85
  86     push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  87     bl_push      = force_fromtag_normpower;
  88     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  89
  90     self.velocity += (push_vector * frametime);
  91
  92     // Anti ocilation
  93     if(self.velocity_z  > 0)
  94         self.velocity_z *= 1 - (autocvar_g_vehicle_racer_upforcedamper * frametime);
  95
  96     self.velocity   += v_add;
  97     self.velocity_z -= autocvar_sv_gravity * frametime;
  98
  99     push_vector_x =  (fl_push - bl_push);
 100     push_vector_x += (fr_push - br_push);
 101     push_vector_x *= 360;
 102
 103     push_vector_z = (fr_push - fl_push);
 104     push_vector_z += (br_push - bl_push);
 105     push_vector_z *= 360;
 106
 107     // Apply angle diffrance
 108     self.angles_z += push_vector_z * frametime;
 109     self.angles_x += push_vector_x * frametime;
 110
 111     // Apply stabilizer
 112     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 113     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 114 }
 115
 116 void racer_rocket_explode()
 117 {
 118         PROJECTILE_TOUCH;
 119     if(other.owner == self.owner)
 120         return;
 121
 122         self.event_damage = SUB_Null;
 123
 124     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 125     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 126     RadiusDamage (self, self.realowner ,autocvar_g_vehicle_racer_rocket_damage, 0, autocvar_g_vehicle_racer_rocket_radius, world, 150, DEATH_WAKIROCKET, world);
 127
 128     remove (self);
 129 }
 130
 131 void racer_bolt_explode()
 132 {
 133         PROJECTILE_TOUCH;
 134     pointparticles(particleeffectnum("wakizashi_gun_impact"), findbetterlocation (self.origin, 8), trace_plane_normal * 1000, 1);
 135     RadiusDamage (self, self.realowner, autocvar_g_vehicle_racer_laser_damage, 0, autocvar_g_vehicle_racer_laser_radius, world, 150, DEATH_WAKIGUN, world);
 136     sound (self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 137     remove (self);
 138 }
 139
 140 void racer_fire_cannon(string tagname)
 141 {
 142     entity bolt;
 143     vector v;
 144
 145     bolt = spawn();
 146     sound (self, CHAN_WEAPON, "weapons/lasergun_fire.wav", VOL_BASE, ATTN_NORM);
 147
 148     setorigin(bolt, gettaginfo(self, gettagindex(self, tagname)));
 149     PROJECTILE_MAKETRIGGER(bolt);
 150
 151     bolt.movetype        = MOVETYPE_FLYMISSILE;
 152     bolt.flags           = FL_PROJECTILE | FL_NOTARGET;
 153     bolt.owner           = self;
 154     bolt.realowner       = self.owner;
 155     bolt.touch           = racer_bolt_explode;
 156     bolt.think           = racer_bolt_explode;
 157     bolt.nextthink       = time + 9;
 158
 159     bolt.bot_dodge       = TRUE;
 160     bolt.bot_dodgerating = autocvar_g_vehicle_racer_laser_damage;
 161
 162         // Fix z-aim (for chase mode)
 163     v = normalize(trace_endpos - bolt.origin);
 164     v_forward_z = v_z * 0.5;
 165
 166     bolt.velocity = v_forward * autocvar_g_vehicle_racer_laser_speed;
 167
 168     pointparticles(particleeffectnum("wakizashi_gun_muzzleflash"), bolt.origin, bolt.velocity, 1);
 169
 170     CSQCProjectile(bolt, TRUE, PROJECTILE_WAKICANNON, TRUE);
 171 }
 172
 173 void racer_rocket_groundhugger()
 174 {
 175     vector olddir, newdir;
 176     float oldvel, newvel;
 177
 178     self.nextthink  = time;
 179
 180     if ((self.owner.deadflag != DEAD_NO) || (self.cnt < time))
 181     {
 182         racer_rocket_explode();
 183         return;
 184     }
 185
 186     if not (self.realowner.vehicle)
 187     {
 188         UpdateCSQCProjectile(self);
 189         return;
 190     }
 191
 192     olddir = normalize(self.velocity);
 193     oldvel = vlen(self.velocity);
 194     newvel = oldvel + self.lip;
 195
 196     tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 197     if(trace_fraction <= 0.5)
 198     {
 199         // Hitting somethign soon, just speed ahead
 200         self.velocity = olddir * newvel;
 201         UpdateCSQCProjectile(self);
 202         return;
 203     }
 204
 205     traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 206     if(trace_fraction != 1.0)
 207     {
 208         newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 209         self.velocity = normalize(olddir + newdir) * newvel;
 210     }
 211     else
 212     {
 213         self.velocity = olddir * newvel;
 214         self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 215     }
 216
 217     UpdateCSQCProjectile(self);
 218     return;
 219 }
 220
 221 void racer_rocket_tracker()
 222 {
 223     vector olddir, newdir;
 224     float oldvel, newvel;
 225
 226     self.nextthink  = time;
 227
 228     if ((self.owner.deadflag != DEAD_NO) || (self.cnt < time))
 229     {
 230         racer_rocket_explode();
 231         return;
 232     }
 233
 234     if not (self.realowner.vehicle)
 235     {
 236         UpdateCSQCProjectile(self);
 237         return;
 238     }
 239
 240     olddir = normalize(self.velocity);
 241     oldvel = vlen(self.velocity);
 242     newvel = oldvel + self.lip;
 243     makevectors(vectoangles(olddir));
 244
 245     traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 246     newdir = normalize(self.enemy.origin - self.origin);
 247
 248     if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 249     {
 250         //bprint("Target lost!\n");
 251         //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 252         self.think = racer_rocket_groundhugger;
 253         return;
 254     }
 255
 256     if(trace_fraction != 1.0)
 257         newdir_z += 16 * sys_frametime;
 258
 259     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 260     self.velocity_z -= 800 * sys_frametime;
 261
 262     UpdateCSQCProjectile(self);
 263     return;
 264 }
 265
 266 void racer_fire_rocket(string tagname, entity trg)
 267 {
 268     entity rocket;
 269
 270     sound (self, CHAN_WEAPON, "weapons/rocket_fire.wav", VOL_BASE, ATTN_NORM);
 271
 272     rocket = spawn();
 273     setsize (rocket, '-1 -1 -1', '1 1 1');
 274     setorigin(rocket, gettaginfo(self, gettagindex(self, tagname)));
 275
 276     rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 277     rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
 278     rocket.solid            = SOLID_BBOX;
 279     rocket.movetype         = MOVETYPE_FLYMISSILE;
 280     rocket.flags            = FL_PROJECTILE;
 281     rocket.owner            = self;
 282     rocket.realowner        = self.owner;
 283     rocket.touch            = racer_rocket_explode;
 284     rocket.bot_dodge        = TRUE;
 285     rocket.bot_dodgerating  = autocvar_g_vehicle_racer_rocket_damage;
 286     rocket.cnt              = time + 9;
 287     rocket.velocity         = v_forward * autocvar_g_vehicle_racer_rocket_speed;
 288
 289     if(trg)
 290         rocket.think            = racer_rocket_tracker;
 291     else
 292         rocket.think            = racer_rocket_groundhugger;
 293
 294     rocket.nextthink        = time;
 295     rocket.enemy            = trg;
 296
 297     CSQCProjectile(rocket, TRUE, PROJECTILE_WAKIROCKET, TRUE);
 298 }
 299
 300 float racer_frame()
 301 {
 302     entity player, racer;
 303     vector df;
 304     float ftmp;
 305
 306     player          = self;
 307     racer           = self.vehicle;
 308
 309     player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 310
 311     self = racer;
 312
 313     if(player.BUTTON_USE)
 314     {
 315         vehicles_exit(VHEF_NORMAL);
 316         self = player;
 317         return 0;
 318     }
 319
 320     if(racer.deadflag != DEAD_NO)
 321     {
 322         self = player;
 323         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 324         return 1;
 325     }
 326
 327     racer_align4point();
 328
 329     crosshair_trace(player);
 330
 331 #if VEHICLES_VIEWROTATE_CROSSHAIR
 332     float ftmp2;
 333     racer.angles_x *= -1;
 334     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 335     if(df_x > 180)  df_x -= 360;
 336     if(df_x < -180) df_x += 360;
 337     if(df_y > 180)  df_y -= 360;
 338     if(df_y < -180) df_y += 360;
 339
 340     // Yaw
 341     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 342     ftmp2 = ftmp * -1;
 343
 344     ftmp = bound(ftmp2, shortangle_f(df_y - racer.angles_y, racer.angles_y), ftmp);
 345     ftmp2 = anglemods(racer.angles_y + ftmp);
 346
 347     // Roll
 348     ftmp = bound(-45, shortangle_f(df_z + ((racer.angles_y - ftmp2) * autocvar_g_vehicle_racer_turnroll), racer.angles_z), 45);
 349     ftmp = anglemods(racer.angles_z + ftmp) * frametime;
 350     racer.angles_z = bound(-65, racer.angles_z + ftmp, 65);
 351
 352     // Turn
 353     racer.angles_y = ftmp2;
 354
 355     // Pitch
 356     ftmp = autocvar_g_vehicle_racer_pitchspeed * frametime;
 357     ftmp2 = ftmp * -1;
 358
 359     ftmp = bound(ftmp2, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 360     racer.angles_x = anglemods(racer.angles_x + ftmp);
 361
 362     makevectors(racer.angles);
 363     racer.angles_x *= -1;
 364 #else
 365     racer.angles_x *= -1;
 366
 367     // Yaw
 368     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 369     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 370     racer.angles_y = anglemods(racer.angles_y + ftmp);
 371
 372     // Roll
 373     racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * frametime;
 374
 375     // Pitch
 376     ftmp = autocvar_g_vehicle_racer_pitchspeed  * frametime;
 377     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 378     racer.angles_x = bound(-30, anglemods(racer.angles_x + ftmp), 30);
 379
 380     makevectors(racer.angles);
 381     racer.angles_x *= -1;
 382 #endif
 383
 384     df = racer.velocity * -0.5;
 385
 386     if(player.movement_x != 0)
 387     {
 388         if(player.movement_x > 0)
 389             df += v_forward  * autocvar_g_vehicle_racer_speed_forward;
 390         else if(player.movement_x < 0)
 391             df -= v_forward  * autocvar_g_vehicle_racer_speed_forward;
 392     }
 393
 394     if(player.movement_y != 0)
 395     {
 396         if(player.movement_y < 0)
 397             df -= v_right * autocvar_g_vehicle_racer_speed_strafe;
 398         else if(player.movement_y > 0)
 399             df += v_right * autocvar_g_vehicle_racer_speed_strafe;
 400     }
 401
 402     // Afterburn
 403     if (player.BUTTON_JUMP)
 404     if(racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
 405     {
 406         racer.wait = time;
 407         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
 408         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 409         self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 410     }
 411
 412     racer.velocity  += df * frametime;
 413
 414     df = (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce * v_up) * frametime;
 415     racer.velocity  = racer.velocity - df;
 416     player.movement = racer.velocity;
 417
 418     if(player.BUTTON_ATCK)
 419     if(time > racer.attack_finished_single)
 420     if(racer.vehicle_energy >= autocvar_g_vehicle_racer_laser_cost)
 421     {
 422         racer.vehicle_energy -= autocvar_g_vehicle_racer_laser_cost;
 423         racer.wait = time;
 424
 425         crosshair_trace(player);
 426         if(racer.cnt)
 427         {
 428             racer_fire_cannon("tag_fire1");
 429             racer.cnt = 0;
 430         }
 431         else
 432         {
 433             racer_fire_cannon("tag_fire2");
 434             racer.cnt = 1;
 435         }
 436         racer.attack_finished_single = time + autocvar_g_vehicle_racer_laser_refire;
 437         self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 438     }
 439
 440     if(autocvar_g_vehicle_racer_rocket_locktarget)
 441     {
 442         vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 443                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 444                          autocvar_g_vehicle_racer_rocket_locked_time);
 445
 446         if(self.lock_target)
 447         {
 448             if(racer.lock_strength == 1)
 449                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 450             else if(self.lock_strength > 0.5)
 451                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 452             else if(self.lock_strength < 0.5)
 453                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 454         }
 455     }
 456
 457     if(time > racer.delay)
 458     if(player.BUTTON_ATCK2)
 459     {
 460         self.misc_bulletcounter += 1;
 461         racer.delay = time + 0.2;
 462         if(self.misc_bulletcounter == 1)
 463             racer_fire_rocket("tag_rocket_r", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 464         else if(self.misc_bulletcounter == 2)
 465         {
 466             racer_fire_rocket("tag_rocket_l", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 467             self.lock_strength  = 0;
 468             self.lock_target    = world;
 469             self.misc_bulletcounter = 0;
 470
 471             racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 472             racer.lip = time;
 473         }
 474     }
 475     player.vehicle_reload1 = (time - racer.lip) / (racer.delay - racer.lip);
 476
 477     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 478         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime);
 479
 480     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 481         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime);
 482
 483     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 484         vehicles_regen(wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime);
 485
 486
 487     VEHICLE_UPDATE_PLAYER(health, racer);
 488
 489     if(self.vehicle_flags & VHF_HASSHIELD)
 490         VEHICLE_UPDATE_PLAYER(shield, racer);
 491
 492
 493     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 494     setorigin(player,racer.origin + '0 0 32');
 495     player.velocity = racer.velocity;
 496
 497     self = player;
 498     return 1;
 499 }
 500
 501 void racer_think()
 502 {
 503     float a, b, c;
 504
 505     a = autocvar_g_vehicle_racer_anglestabilizer;
 506     b = autocvar_g_vehicle_racer_springlength;
 507     c = autocvar_g_vehicle_racer_hoverpower;
 508
 509     autocvar_g_vehicle_racer_anglestabilizer = 36;
 510     autocvar_g_vehicle_racer_springlength = 96;
 511     autocvar_g_vehicle_racer_hoverpower = 300;
 512
 513     racer_align4point(); //time - self.nextthink);
 514
 515     //if(self.velocity_z > 0)
 516     //    self.velocity_z *= 0.95;
 517
 518     autocvar_g_vehicle_racer_anglestabilizer = a;
 519     autocvar_g_vehicle_racer_springlength = b;
 520     autocvar_g_vehicle_racer_hoverpower = c;
 521
 522     self.velocity_x *= 0.95;
 523     self.velocity_y *= 0.95;
 524
 525     self.nextthink = time + 0.05;
 526 }
 527
 528 void racer_enter()
 529 {
 530     self.movetype = MOVETYPE_BOUNCE; //MISSILE;
 531     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health);
 532     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield);
 533 }
 534
 535 void racer_exit(float eject)
 536 {
 537     self.think      = racer_think;
 538     self.nextthink  = time;
 539     self.movetype   = MOVETYPE_BOUNCEMISSILE;
 540
 541     if not (self.owner)
 542         return;
 543
 544         makevectors(self.angles);
 545         if(eject)
 546         {
 547             setorigin(self.owner, self.origin + v_forward * 100 + v_up * 32);
 548             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 549         }
 550         else
 551         {
 552             setorigin(self.owner, self.origin - v_forward * 100 + v_up * 32);
 553             self.owner.velocity = v_forward * -150;
 554         }
 555     self.owner = world;
 556 }
 557
 558 void racer_spawn()
 559 {
 560     self.think          = racer_think;
 561     self.nextthink      = time;
 562     self.vehicle_health = autocvar_g_vehicle_racer_health;
 563     self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 564
 565     self.movetype       = MOVETYPE_TOSS;
 566     self.solid          = SOLID_SLIDEBOX;
 567     self.delay          = time;
 568     self.scale          = 0.5;
 569
 570     setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
 571 }
 572
 573
 574 void racer_blowup()
 575 {
 576
 577     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 578     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 579
 580     self.deadflag    = DEAD_DEAD;
 581     self.vehicle_exit(VHEF_NORMAL);
 582
 583     RadiusDamage (self, self, autocvar_g_vehicle_racer_blowup_coredamage,
 584                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 585                                         autocvar_g_vehicle_racer_blowup_radius, world,
 586                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 587                                         DEATH_WAKIBLOWUP, world);
 588
 589     self.alpha = -1;
 590     self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 591     self.think      = racer_spawn;
 592     self.movetype   = MOVETYPE_NONE;
 593     self.effects    = EF_NODRAW;
 594
 595     self.colormod  = '0 0 0';
 596     self.avelocity = '0 0 0';
 597     self.velocity  = '0 0 0';
 598
 599     setorigin(self, self.pos1);
 600         self.think     = racer_spawn;
 601         self.nextthink = time + autocvar_g_vehicle_racer_respawntime;
 602 }
 603
 604 void racer_deadtouch()
 605 {
 606     self.avelocity_x *= 0.7;
 607     self.cnt -= 1;
 608     if(self.cnt <= 0)
 609         racer_blowup();
 610 }
 611
 612 void racer_die()
 613 {
 614     self.health       = 0;
 615     self.event_damage = SUB_Null;
 616     self.iscreature   = FALSE;
 617     self.solid        = SOLID_CORPSE;
 618     self.takedamage   = DAMAGE_NO;
 619     self.deadflag     = DEAD_DYING;
 620     self.movetype     = MOVETYPE_BOUNCE;
 621     self.wait         = time;
 622     self.cnt          = 1 + random() * 3;
 623     self.touch        = racer_deadtouch;
 624
 625     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 626
 627     if(random() < 0.5)
 628         self.avelocity_z  = 16;
 629     else
 630         self.avelocity_z  = -16;
 631
 632     self.avelocity_x = -vlen(self.velocity) * 0.2;
 633     self.velocity     += '0 0 700';
 634     self.colormod = '-0.5 -0.5 -0.5';
 635
 636         self.think     = racer_blowup;
 637         self.nextthink = 2 + time + random() * 3;
 638 }
 639
 640 void racer_dinit()
 641 {
 642     if not (vehicle_initialize(
 643              "Wakizashi",
 644              "models/vehicles/wakizashi.dpm",
 645              "",
 646              "models/vehicles/wakizashi_cockpit.dpm",
 647              "", "", "tag_viewport",
 648              HUD_WAKIZASHI,
 649              0.5 * RACER_MIN, 0.5 * RACER_MAX,
 650              FALSE,
 651              racer_spawn, autocvar_g_vehicle_racer_respawntime,
 652              racer_frame,
 653              racer_enter, racer_exit,
 654              racer_die,   racer_think))
 655     {
 656         remove(self);
 657         return;
 658     }
 659
 660     if(autocvar_g_vehicle_racer_hovertype != 0)
 661         racer_force_from_tag = vehicles_force_fromtag_maglev;
 662     else
 663         racer_force_from_tag = vehicles_force_fromtag_hover;
 664
 665     // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 666     self.scale = 0.5;
 667     setattachment(self.vehicle_hudmodel, self, "");
 668     setattachment(self.vehicle_viewport, self, "tag_viewport");
 669
 670     self.mass               = 900;
 671 }
 672
 673 void spawnfunc_vehicle_racer()
 674 {
 675
 676     precache_sound ("weapons/laserimpact.wav");
 677     precache_sound ("weapons/lasergun_fire.wav");
 678     precache_sound ("weapons/rocket_fire.wav");
 679     precache_sound ("weapons/rocket_impact.wav");
 680
 681     precache_model ("models/vhshield.md3");
 682     precache_model ("models/vehicles/wakizashi.dpm");
 683     precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 684
 685
 686     vehicles_configcheck("vehicle_racer.cfg", autocvar_g_vehicle_racer_health);
 687     if(autocvar_g_vehicle_racer_energy)
 688         if(autocvar_g_vehicle_racer_energy_regen)
 689             self.vehicle_flags |= VHF_ENERGYREGEN;
 690
 691     if(autocvar_g_vehicle_racer_shield)
 692         self.vehicle_flags |= VHF_HASSHIELD;
 693
 694     if(autocvar_g_vehicle_racer_shield_regen)
 695         self.vehicle_flags |= VHF_SHIELDREGEN;
 696
 697     if(autocvar_g_vehicle_racer_health_regen)
 698         self.vehicle_flags |= VHF_HEALTHREGEN;
 699
 700     self.think = racer_dinit;
 701     self.nextthink = time + 1;
 702 }