qcsrc/server/vehicles/racer.qc

   1 #define RACER_MIN '-120 -120 -40'
   2 #define RACER_MAX '120 120 40'
   3
   4 #ifdef SVQC
   5 void racer_exit(float eject);
   6 void racer_enter();
   7
   8 // Auto cvars
   9 float autocvar_g_vehicle_racer_speed_afterburn;
  10 float autocvar_g_vehicle_racer_afterburn_cost;
  11
  12 float autocvar_g_vehicle_racer_anglestabilizer;
  13 float autocvar_g_vehicle_racer_downforce;
  14
  15 float autocvar_g_vehicle_racer_speed_forward;
  16 float autocvar_g_vehicle_racer_speed_strafe;
  17 float autocvar_g_vehicle_racer_springlength;
  18 float autocvar_g_vehicle_racer_upforcedamper;
  19 float autocvar_g_vehicle_racer_friction;
  20
  21 float autocvar_g_vehicle_racer_hovertype;
  22 float autocvar_g_vehicle_racer_hoverpower;
  23
  24 float autocvar_g_vehicle_racer_turnroll;
  25 float autocvar_g_vehicle_racer_turnspeed;
  26 float autocvar_g_vehicle_racer_pitchspeed;
  27
  28 float autocvar_g_vehicle_racer_energy;
  29 float autocvar_g_vehicle_racer_energy_regen;
  30 float autocvar_g_vehicle_racer_energy_regen_pause;
  31
  32 float autocvar_g_vehicle_racer_health;
  33 float autocvar_g_vehicle_racer_health_regen;
  34 float autocvar_g_vehicle_racer_health_regen_pause;
  35
  36 float autocvar_g_vehicle_racer_shield;
  37 float autocvar_g_vehicle_racer_shield_regen;
  38 float autocvar_g_vehicle_racer_shield_regen_pause;
  39
  40 float autocvar_g_vehicle_racer_cannon_cost;
  41 float autocvar_g_vehicle_racer_cannon_damage;
  42 float autocvar_g_vehicle_racer_cannon_radius;
  43 float autocvar_g_vehicle_racer_cannon_refire;
  44 float autocvar_g_vehicle_racer_cannon_speed;
  45 float autocvar_g_vehicle_racer_cannon_spread;
  46 float autocvar_g_vehicle_racer_cannon_force;
  47
  48 float autocvar_g_vehicle_racer_rocket_accel;
  49 float autocvar_g_vehicle_racer_rocket_damage;
  50 float autocvar_g_vehicle_racer_rocket_radius;
  51 float autocvar_g_vehicle_racer_rocket_force;
  52 float autocvar_g_vehicle_racer_rocket_refire;
  53 float autocvar_g_vehicle_racer_rocket_speed;
  54 float autocvar_g_vehicle_racer_rocket_turnrate;
  55
  56 float autocvar_g_vehicle_racer_rocket_locktarget;
  57 float autocvar_g_vehicle_racer_rocket_locking_time;
  58 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  59 float autocvar_g_vehicle_racer_rocket_locked_time;
  60 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  61
  62 float autocvar_g_vehicle_racer_respawntime;
  63
  64 float autocvar_g_vehicle_racer_blowup_radius;
  65 float autocvar_g_vehicle_racer_blowup_coredamage;
  66 float autocvar_g_vehicle_racer_blowup_edgedamage;
  67 float autocvar_g_vehicle_racer_blowup_forceintensity;
  68
  69 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
  70
  71 void racer_align4point()
  72 {
  73     vector push_vector, v_add;
  74     float fl_push, fr_push, bl_push, br_push;
  75
  76
  77     push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  78     fr_push      = force_fromtag_normpower;
  79     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  80
  81     push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  82     fl_push      = force_fromtag_normpower;
  83     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  84
  85     push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  86     br_push      = force_fromtag_normpower;
  87     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  88
  89     push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  90     bl_push      = force_fromtag_normpower;
  91     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  92
  93     self.velocity += (push_vector * frametime);
  94
  95     // Anti ocilation
  96     if(self.velocity_z  > 0)
  97         self.velocity_z *= 1 - (autocvar_g_vehicle_racer_upforcedamper * frametime);
  98
  99     self.velocity   += v_add;
 100     //self.velocity_z -= autocvar_sv_gravity * frametime;
 101
 102     push_vector_x =  (fl_push - bl_push);
 103     push_vector_x += (fr_push - br_push);
 104     push_vector_x *= 360;
 105
 106     push_vector_z = (fr_push - fl_push);
 107     push_vector_z += (br_push - bl_push);
 108     push_vector_z *= 360;
 109
 110     // Apply angle diffrance
 111     self.angles_z += push_vector_z * frametime;
 112     self.angles_x += push_vector_x * frametime;
 113
 114     // Apply stabilizer
 115     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 116     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 117 }
 118
 119 void racer_fire_cannon(string tagname)
 120 {
 121     vector v;
 122     entity bolt;
 123
 124     v = gettaginfo(self, gettagindex(self, tagname));
 125     bolt = vehicles_projectile("wakizashi_gun_muzzleflash", "weapons/lasergun_fire.wav",
 126                            v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 127                            autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 128                            DEATH_WAKIGUN, PROJECTILE_WAKICANNON, 0, TRUE, TRUE);
 129
 130         // Fix z-aim (for chase mode)
 131     v = normalize(trace_endpos - bolt.origin);
 132     v_forward_z = v_z * 0.5;
 133     bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 134 }
 135
 136 void racer_rocket_groundhugger()
 137 {
 138     vector olddir, newdir;
 139     float oldvel, newvel;
 140
 141     self.nextthink  = time;
 142
 143     if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 144     {
 145         self.use();
 146         return;
 147     }
 148
 149     if not (self.realowner.vehicle)
 150     {
 151         UpdateCSQCProjectile(self);
 152         return;
 153     }
 154
 155     olddir = normalize(self.velocity);
 156     oldvel = vlen(self.velocity);
 157     newvel = oldvel + self.lip;
 158
 159     tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 160     if(trace_fraction <= 0.5)
 161     {
 162         // Hitting somethign soon, just speed ahead
 163         self.velocity = olddir * newvel;
 164         UpdateCSQCProjectile(self);
 165         return;
 166     }
 167
 168     traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 169     if(trace_fraction != 1.0)
 170     {
 171         newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 172         self.velocity = normalize(olddir + newdir) * newvel;
 173     }
 174     else
 175     {
 176         self.velocity = olddir * newvel;
 177         self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 178     }
 179
 180     UpdateCSQCProjectile(self);
 181     return;
 182 }
 183
 184 void racer_rocket_tracker()
 185 {
 186     vector olddir, newdir;
 187     float oldvel, newvel;
 188
 189     self.nextthink  = time;
 190
 191     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 192     {
 193         self.use();
 194         return;
 195     }
 196
 197     if not (self.realowner.vehicle)
 198     {
 199         UpdateCSQCProjectile(self);
 200         return;
 201     }
 202
 203     olddir = normalize(self.velocity);
 204     oldvel = vlen(self.velocity);
 205     newvel = oldvel + self.lip;
 206     makevectors(vectoangles(olddir));
 207
 208     traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 209     newdir = normalize(self.enemy.origin - self.origin);
 210
 211     if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 212     {
 213         //bprint("Target lost!\n");
 214         //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 215         self.think = racer_rocket_groundhugger;
 216         return;
 217     }
 218
 219     if(trace_fraction != 1.0)
 220         newdir_z += 16 * sys_frametime;
 221
 222     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 223     self.velocity_z -= 800 * sys_frametime;
 224
 225     UpdateCSQCProjectile(self);
 226     return;
 227 }
 228
 229 void racer_fire_rocket(string tagname, entity trg)
 230 {
 231     vector v;
 232     entity rocket;
 233
 234     v = gettaginfo(self, gettagindex(self, tagname));
 235     rocket = vehicles_projectile("wakizashi_rocket_launch", "weapons/rocket_fire.wav",
 236                            v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 237                            autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 238                            DEATH_WAKIROCKET, PROJECTILE_WAKIROCKET, 20, FALSE, FALSE);
 239
 240     rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 241     rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
 242     rocket.nextthink        = time;
 243     rocket.enemy            = trg;
 244     rocket.cnt              = time + 15;
 245
 246     if(trg)
 247         rocket.think            = racer_rocket_tracker;
 248     else
 249         rocket.think            = racer_rocket_groundhugger;
 250 }
 251
 252 float racer_frame()
 253 {
 254     entity player, racer;
 255     vector df;
 256     float ftmp;
 257
 258     player          = self;
 259     racer           = self.vehicle;
 260
 261     player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 262
 263     self = racer;
 264
 265     if(player.BUTTON_USE)
 266     {
 267         vehicles_exit(VHEF_NORMAL);
 268         self = player;
 269         return 0;
 270     }
 271
 272     if(racer.deadflag != DEAD_NO)
 273     {
 274         self = player;
 275         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 276         return 1;
 277     }
 278
 279     racer_align4point();
 280
 281     crosshair_trace(player);
 282
 283 #if VEHICLES_VIEWROTATE_CROSSHAIR
 284     float ftmp2;
 285     racer.angles_x *= -1;
 286     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 287     if(df_x > 180)  df_x -= 360;
 288     if(df_x < -180) df_x += 360;
 289     if(df_y > 180)  df_y -= 360;
 290     if(df_y < -180) df_y += 360;
 291
 292     // Yaw
 293     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 294     ftmp2 = ftmp * -1;
 295
 296     ftmp = bound(ftmp2, shortangle_f(df_y - racer.angles_y, racer.angles_y), ftmp);
 297     ftmp2 = anglemods(racer.angles_y + ftmp);
 298
 299     // Roll
 300     ftmp = bound(-45, shortangle_f(df_z + ((racer.angles_y - ftmp2) * autocvar_g_vehicle_racer_turnroll), racer.angles_z), 45);
 301     ftmp = anglemods(racer.angles_z + ftmp) * frametime;
 302     racer.angles_z = bound(-65, racer.angles_z + ftmp, 65);
 303
 304     // Turn
 305     racer.angles_y = ftmp2;
 306
 307     // Pitch
 308     ftmp = autocvar_g_vehicle_racer_pitchspeed * frametime;
 309     ftmp2 = ftmp * -1;
 310
 311     ftmp = bound(ftmp2, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 312     racer.angles_x = anglemods(racer.angles_x + ftmp);
 313
 314     makevectors(racer.angles);
 315     racer.angles_x *= -1;
 316 #else
 317     racer.angles_x *= -1;
 318
 319     // Yaw
 320     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 321     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 322     racer.angles_y = anglemods(racer.angles_y + ftmp);
 323
 324     // Roll
 325     racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * frametime;
 326
 327     // Pitch
 328     ftmp = autocvar_g_vehicle_racer_pitchspeed  * frametime;
 329     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 330     racer.angles_x = bound(-30, anglemods(racer.angles_x + ftmp), 30);
 331
 332     makevectors(racer.angles);
 333     racer.angles_x *= -1;
 334 #endif
 335
 336     ftmp = racer.velocity_z;
 337     df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 338     racer.velocity_z = ftmp;
 339
 340     if(player.movement_x != 0)
 341     {
 342         if(player.movement_x > 0)
 343             df += v_forward  * autocvar_g_vehicle_racer_speed_forward;
 344         else if(player.movement_x < 0)
 345             df -= v_forward  * autocvar_g_vehicle_racer_speed_forward;
 346     }
 347
 348     if(player.movement_y != 0)
 349     {
 350         if(player.movement_y < 0)
 351             df -= v_right * autocvar_g_vehicle_racer_speed_strafe;
 352         else if(player.movement_y > 0)
 353             df += v_right * autocvar_g_vehicle_racer_speed_strafe;
 354     }
 355
 356     // Afterburn
 357     if (player.BUTTON_JUMP)
 358     if(racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
 359     {
 360         racer.wait = time;
 361         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
 362         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 363         //self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 364     }
 365
 366     racer.velocity  += df * frametime;
 367
 368     df = (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce * v_up) * frametime;
 369     racer.velocity  = racer.velocity - df;
 370     player.movement = racer.velocity;
 371
 372     if(player.BUTTON_ATCK)
 373     if(time > racer.attack_finished_single)
 374     if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 375     {
 376         racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 377         racer.wait = time;
 378
 379         crosshair_trace(player);
 380         if(racer.cnt)
 381         {
 382             racer_fire_cannon("tag_fire1");
 383             racer.cnt = 0;
 384         }
 385         else
 386         {
 387             racer_fire_cannon("tag_fire2");
 388             racer.cnt = 1;
 389         }
 390         racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 391         //self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 392     }
 393
 394     if(autocvar_g_vehicle_racer_rocket_locktarget)
 395     {
 396         vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 397                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 398                          autocvar_g_vehicle_racer_rocket_locked_time);
 399
 400         if(self.lock_target)
 401         {
 402             if(racer.lock_strength == 1)
 403                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 404             else if(self.lock_strength > 0.5)
 405                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 406             else if(self.lock_strength < 0.5)
 407                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 408         }
 409     }
 410
 411     if(time > racer.delay)
 412     if(player.BUTTON_ATCK2)
 413     {
 414         self.misc_bulletcounter += 1;
 415         racer.delay = time + 0.2;
 416         if(self.misc_bulletcounter == 1)
 417             racer_fire_rocket("tag_rocket_r", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 418         else if(self.misc_bulletcounter == 2)
 419         {
 420             racer_fire_rocket("tag_rocket_l", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 421             self.lock_strength  = 0;
 422             self.lock_target    = world;
 423             self.misc_bulletcounter = 0;
 424
 425             racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 426             racer.lip = time;
 427         }
 428     }
 429     player.vehicle_reload1 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 430
 431     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 432         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime);
 433
 434     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 435         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime);
 436
 437     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 438         vehicles_regen(wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime);
 439
 440
 441     VEHICLE_UPDATE_PLAYER(health, racer);
 442     VEHICLE_UPDATE_PLAYER(energy, racer);
 443
 444     if(self.vehicle_flags & VHF_HASSHIELD)
 445         VEHICLE_UPDATE_PLAYER(shield, racer);
 446
 447
 448     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 449     setorigin(player,racer.origin + '0 0 32');
 450     player.velocity = racer.velocity;
 451
 452     self = player;
 453     return 1;
 454 }
 455
 456 void racer_think()
 457 {
 458     /*
 459     float a, b, c;a = autocvar_g_vehicle_racer_anglestabilizer;
 460     b = autocvar_g_vehicle_racer_springlength;
 461     c = autocvar_g_vehicle_racer_hoverpower;
 462
 463     autocvar_g_vehicle_racer_anglestabilizer = 36;
 464     autocvar_g_vehicle_racer_springlength = 96;
 465     autocvar_g_vehicle_racer_hoverpower = 300;
 466     */
 467
 468     racer_align4point(); //time - self.nextthink);
 469
 470     /*
 471     //if(self.velocity_z > 0)
 472     //    self.velocity_z *= 0.95;
 473
 474     autocvar_g_vehicle_racer_anglestabilizer = a;
 475     autocvar_g_vehicle_racer_springlength = b;
 476     autocvar_g_vehicle_racer_hoverpower = c;
 477     */
 478
 479     self.velocity_x *= 0.9;
 480     self.velocity_y *= 0.9;
 481     self.velocity_z *= 0.8;
 482     self.velocity_z += sin(time * 2) * 16;
 483     self.nextthink = time + 0.05;
 484 }
 485
 486 void racer_enter()
 487 {
 488     self.movetype = MOVETYPE_BOUNCE;
 489     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health);
 490     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield);
 491 }
 492
 493 void racer_exit(float eject)
 494 {
 495     self.think      = racer_think;
 496     self.nextthink  = time;
 497     self.movetype   = MOVETYPE_TOSS;
 498
 499     if not (self.owner)
 500         return;
 501
 502         makevectors(self.angles);
 503         if(eject)
 504         {
 505             setorigin(self.owner, self.origin + v_forward * 100 + v_up * 32);
 506             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 507         }
 508         else
 509         {
 510             setorigin(self.owner, self.origin - v_forward * 100 + v_up * 32);
 511             self.owner.velocity = v_forward * -150;
 512         }
 513     self.owner = world;
 514 }
 515
 516 void racer_spawn()
 517 {
 518     self.think          = racer_think;
 519     self.nextthink      = time;
 520     self.vehicle_health = autocvar_g_vehicle_racer_health;
 521     self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 522
 523     self.movetype       = MOVETYPE_TOSS;
 524     self.solid          = SOLID_SLIDEBOX;
 525     self.delay          = time;
 526     self.scale          = 0.5;
 527
 528     setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
 529 }
 530
 531
 532 void racer_blowup()
 533 {
 534     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 535     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 536
 537     self.deadflag    = DEAD_DEAD;
 538     self.vehicle_exit(VHEF_NORMAL);
 539
 540     RadiusDamage (self, self, autocvar_g_vehicle_racer_blowup_coredamage,
 541                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 542                                         autocvar_g_vehicle_racer_blowup_radius, world,
 543                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 544                                         DEATH_WAKIBLOWUP, world);
 545
 546     self.alpha = -1;
 547     self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 548     self.think      = racer_spawn;
 549     self.movetype   = MOVETYPE_NONE;
 550     self.effects    = EF_NODRAW;
 551
 552     self.colormod  = '0 0 0';
 553     self.avelocity = '0 0 0';
 554     self.velocity  = '0 0 0';
 555
 556     setorigin(self, self.pos1);
 557         self.think     = racer_spawn;
 558         self.nextthink = time + autocvar_g_vehicle_racer_respawntime;
 559 }
 560
 561 void racer_deadtouch()
 562 {
 563     self.avelocity_x *= 0.7;
 564     self.cnt -= 1;
 565     if(self.cnt <= 0)
 566         racer_blowup();
 567 }
 568
 569 void racer_die()
 570 {
 571     self.health       = 0;
 572     self.event_damage = SUB_Null;
 573     self.iscreature   = FALSE;
 574     self.solid        = SOLID_CORPSE;
 575     self.takedamage   = DAMAGE_NO;
 576     self.deadflag     = DEAD_DYING;
 577     self.movetype     = MOVETYPE_BOUNCE;
 578     self.wait         = time;
 579     self.cnt          = 1 + random() * 3;
 580     self.touch        = racer_deadtouch;
 581
 582     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 583
 584     if(random() < 0.5)
 585         self.avelocity_z  = 16;
 586     else
 587         self.avelocity_z  = -16;
 588
 589     self.avelocity_x = -vlen(self.velocity) * 0.2;
 590     self.velocity   += '0 0 700';
 591     self.colormod    = '-0.5 -0.5 -0.5';
 592
 593         self.think     = racer_blowup;
 594         self.nextthink = 2 + time + random() * 3;
 595 }
 596
 597 #ifdef VEHICLES_CSQC
 598 void racer_send_exta(entity to)
 599 {
 600
 601 }
 602 #endif
 603
 604 void racer_dinit()
 605 {
 606     if not (vehicle_initialize(
 607              "Wakizashi",
 608              "models/vehicles/wakizashi.dpm",
 609              "",
 610              "models/vehicles/wakizashi_cockpit.dpm",
 611              "", "", "tag_viewport",
 612              HUD_WAKIZASHI,
 613              0.5 * RACER_MIN, 0.5 * RACER_MAX,
 614              FALSE,
 615              racer_spawn, autocvar_g_vehicle_racer_respawntime,
 616              racer_frame,
 617              racer_enter, racer_exit,
 618              racer_die,   racer_think,
 619              FALSE))
 620     {
 621         remove(self);
 622         return;
 623     }
 624
 625     if(autocvar_g_vehicle_racer_hovertype != 0)
 626         racer_force_from_tag = vehicles_force_fromtag_maglev;
 627     else
 628         racer_force_from_tag = vehicles_force_fromtag_hover;
 629
 630     // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 631     self.scale = 0.5;
 632     setattachment(self.vehicle_hudmodel, self, "");
 633     setattachment(self.vehicle_viewport, self, "tag_viewport");
 634
 635     self.mass               = 900;
 636 }
 637
 638 void spawnfunc_vehicle_racer()
 639 {
 640
 641     precache_sound ("weapons/laserimpact.wav");
 642     precache_sound ("weapons/lasergun_fire.wav");
 643     precache_sound ("weapons/rocket_fire.wav");
 644     precache_sound ("weapons/rocket_impact.wav");
 645
 646     precache_model ("models/vhshield.md3");
 647     precache_model ("models/vehicles/wakizashi.dpm");
 648     precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 649
 650     vehicles_configcheck("vehicle_racer.cfg", autocvar_g_vehicle_racer_health);
 651     if(autocvar_g_vehicle_racer_energy)
 652         if(autocvar_g_vehicle_racer_energy_regen)
 653             self.vehicle_flags |= VHF_ENERGYREGEN;
 654
 655     if(autocvar_g_vehicle_racer_shield)
 656         self.vehicle_flags |= VHF_HASSHIELD;
 657
 658     if(autocvar_g_vehicle_racer_shield_regen)
 659         self.vehicle_flags |= VHF_SHIELDREGEN;
 660
 661     if(autocvar_g_vehicle_racer_health_regen)
 662         self.vehicle_flags |= VHF_HEALTHREGEN;
 663
 664     self.think = racer_dinit;
 665     self.nextthink = time + 1;
 666 }
 667
 668 #endif // SVQC
 669
 670 #ifdef CSQC
 671 void racer_draw()
 672 {
 673
 674 }
 675
 676 void racer_draw2d()
 677 {
 678
 679 }
 680
 681 void racer_read_extra()
 682 {
 683
 684 }
 685
 686 void vehicle_racer_assemble()
 687 {
 688
 689 }
 690 #endif //CSQC