qcsrc/server/vehicles/racer.qc

   1 #define RACER_MIN '-120 -120 -40'
   2 #define RACER_MAX '120 120 40'
   3 #define RACER_TICRATE 0.05
   4
   5 void racer_exit(float eject);
   6 void racer_enter();
   7
   8 // Auto cvars
   9 float autocvar_g_vehicle_racer_speed_afterburn;
  10 float autocvar_g_vehicle_racer_afterburn_cost;
  11
  12 float autocvar_g_vehicle_racer_anglestabilizer;
  13 float autocvar_g_vehicle_racer_downforce;
  14
  15 float autocvar_g_vehicle_racer_speed_forward;
  16 float autocvar_g_vehicle_racer_speed_strafe;
  17 float autocvar_g_vehicle_racer_springlength;
  18 float autocvar_g_vehicle_racer_upforcedamper;
  19
  20 float autocvar_g_vehicle_racer_hovertype;
  21 float autocvar_g_vehicle_racer_hoverpower;
  22
  23 float autocvar_g_vehicle_racer_turnroll;
  24 float autocvar_g_vehicle_racer_turnspeed;
  25 float autocvar_g_vehicle_racer_pitchspeed;
  26
  27 float autocvar_g_vehicle_racer_energy;
  28 float autocvar_g_vehicle_racer_energy_regen;
  29 float autocvar_g_vehicle_racer_energy_regen_pause;
  30
  31 float autocvar_g_vehicle_racer_health;
  32 float autocvar_g_vehicle_racer_health_regen;
  33 float autocvar_g_vehicle_racer_health_regen_pause;
  34
  35 float autocvar_g_vehicle_racer_shield;
  36 float autocvar_g_vehicle_racer_shield_regen;
  37 float autocvar_g_vehicle_racer_shield_regen_pause;
  38
  39 float autocvar_g_vehicle_racer_laser_cost;
  40 float autocvar_g_vehicle_racer_laser_damage;
  41 float autocvar_g_vehicle_racer_laser_radius;
  42 float autocvar_g_vehicle_racer_laser_refire;
  43 float autocvar_g_vehicle_racer_laser_speed;
  44
  45 float autocvar_g_vehicle_racer_rocket_accel;
  46 float autocvar_g_vehicle_racer_rocket_damage;
  47 float autocvar_g_vehicle_racer_rocket_radius;
  48 float autocvar_g_vehicle_racer_rocket_refire;
  49 float autocvar_g_vehicle_racer_rocket_speed;
  50 float autocvar_g_vehicle_racer_rocket_turnrate;
  51
  52 float autocvar_g_vehicle_racer_rocket_locktarget;
  53 float autocvar_g_vehicle_racer_rocket_locking_time;
  54 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  55 float autocvar_g_vehicle_racer_rocket_locked_time;
  56 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  57
  58 float autocvar_g_vehicle_racer_respawntime;
  59 float autocvar_g_vehicle_racer_collision_multiplier;
  60
  61 float autocvar_g_vehicle_racer_blowup_radius;
  62 float autocvar_g_vehicle_racer_blowup_coredamage;
  63 float autocvar_g_vehicle_racer_blowup_edgedamage;
  64 float autocvar_g_vehicle_racer_blowup_forceintensity;
  65
  66 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
  67
  68 void racer_align4point()
  69 {
  70     vector push_vector, v_add;
  71     float fl_push, fr_push, bl_push, br_push;
  72
  73
  74     push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  75     fr_push      = force_fromtag_normpower;
  76     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  77
  78     push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  79     fl_push      = force_fromtag_normpower;
  80     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  81
  82     push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  83     br_push      = force_fromtag_normpower;
  84     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  85
  86     push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  87     bl_push      = force_fromtag_normpower;
  88     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  89
  90     self.velocity += (push_vector * frametime);
  91
  92     // Anti ocilation
  93     if(self.velocity_z  > 0)
  94         self.velocity_z *= 1 - (autocvar_g_vehicle_racer_upforcedamper * frametime);
  95
  96     self.velocity   += v_add;
  97     self.velocity_z -= autocvar_sv_gravity * frametime;
  98
  99     push_vector_x =  (fl_push - bl_push);
 100     push_vector_x += (fr_push - br_push);
 101     push_vector_x *= 360;
 102
 103     push_vector_z = (fr_push - fl_push);
 104     push_vector_z += (br_push - bl_push);
 105     push_vector_z *= 360;
 106
 107     // Apply angle diffrance
 108     self.angles_z += push_vector_z * frametime;
 109     self.angles_x += push_vector_x * frametime;
 110
 111     // Apply stabilizer
 112     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 113     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 114 }
 115
 116 void racer_rocket_explode()
 117 {
 118         PROJECTILE_TOUCH;
 119     if(other.owner == self.owner)
 120         return;
 121
 122         self.event_damage = SUB_Null;
 123
 124     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 125     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 126     RadiusDamage (self, self.realowner ,autocvar_g_vehicle_racer_rocket_damage, 0, autocvar_g_vehicle_racer_rocket_radius, world, 150, DEATH_WAKIROCKET, world);
 127
 128     remove (self);
 129 }
 130
 131 void racer_bolt_explode()
 132 {
 133         PROJECTILE_TOUCH;
 134     pointparticles(particleeffectnum("wakizashi_gun_impact"), findbetterlocation (self.origin, 8), trace_plane_normal * 1000, 1);
 135     RadiusDamage (self, self.realowner, autocvar_g_vehicle_racer_laser_damage, 0, autocvar_g_vehicle_racer_laser_radius, world, 150, DEATH_WAKIGUN, world);
 136     sound (self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 137     remove (self);
 138 }
 139
 140 void racer_fire_cannon(string tagname)
 141 {
 142     entity bolt;
 143     vector v;
 144
 145     bolt = spawn();
 146     sound (self, CHAN_WEAPON, "weapons/lasergun_fire.wav", VOL_BASE, ATTN_NORM);
 147
 148     setorigin(bolt, gettaginfo(self, gettagindex(self, tagname)));
 149     PROJECTILE_MAKETRIGGER(bolt);
 150
 151     bolt.movetype        = MOVETYPE_FLYMISSILE;
 152     bolt.flags           = FL_PROJECTILE | FL_NOTARGET;
 153     bolt.owner           = self;
 154     bolt.realowner       = self.owner;
 155     bolt.touch           = racer_bolt_explode;
 156     bolt.think           = racer_bolt_explode;
 157     bolt.nextthink       = time + 9;
 158
 159     bolt.bot_dodge       = TRUE;
 160     bolt.bot_dodgerating = autocvar_g_vehicle_racer_laser_damage;
 161
 162         // Fix z-aim (for chase mode)
 163     v = normalize(trace_endpos - bolt.origin);
 164     v_forward_z = v_z * 0.5;
 165
 166     bolt.velocity = v_forward * autocvar_g_vehicle_racer_laser_speed;
 167
 168     pointparticles(particleeffectnum("wakizashi_gun_muzzleflash"), bolt.origin, bolt.velocity, 1);
 169
 170     CSQCProjectile(bolt, TRUE, PROJECTILE_WAKICANNON, TRUE);
 171 }
 172
 173 void racer_rocket_groundhugger()
 174 {
 175     vector olddir, newdir;
 176     float oldvel, newvel;
 177
 178     self.nextthink  = time;
 179
 180     if ((self.owner.deadflag != DEAD_NO) || (self.cnt < time))
 181     {
 182         racer_rocket_explode();
 183         return;
 184     }
 185
 186     if not (self.realowner.vehicle)
 187     {
 188         UpdateCSQCProjectile(self);
 189         return;
 190     }
 191
 192     olddir = normalize(self.velocity);
 193     oldvel = vlen(self.velocity);
 194     newvel = oldvel + self.lip;
 195
 196     tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 197     if(trace_fraction <= 0.5)
 198     {
 199         // Hitting somethign soon, just speed ahead
 200         self.velocity = olddir * newvel;
 201         UpdateCSQCProjectile(self);
 202         return;
 203     }
 204
 205     traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 206     if(trace_fraction != 1.0)
 207     {
 208         newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 209         self.velocity = normalize(olddir + newdir) * newvel;
 210     }
 211     else
 212     {
 213         self.velocity = olddir * newvel;
 214         self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 215     }
 216
 217     UpdateCSQCProjectile(self);
 218     return;
 219 }
 220
 221 void racer_rocket_tracker()
 222 {
 223     vector olddir, newdir;
 224     float oldvel, newvel;
 225
 226     self.nextthink  = time;
 227
 228     if ((self.owner.deadflag != DEAD_NO) || (self.cnt < time))
 229     {
 230         racer_rocket_explode();
 231         return;
 232     }
 233
 234     if not (self.realowner.vehicle)
 235     {
 236         UpdateCSQCProjectile(self);
 237         return;
 238     }
 239
 240     olddir = normalize(self.velocity);
 241     oldvel = vlen(self.velocity);
 242     newvel = oldvel + self.lip;
 243     makevectors(vectoangles(olddir));
 244
 245     traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 246     newdir = normalize(self.enemy.origin - self.origin);
 247
 248     if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 249     {
 250         //bprint("Target lost!\n");
 251         //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 252         self.think = racer_rocket_groundhugger;
 253         return;
 254     }
 255
 256     if(trace_fraction != 1.0)
 257         newdir_z += 16 * sys_frametime;
 258
 259     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 260     self.velocity_z -= 800 * sys_frametime;
 261
 262     UpdateCSQCProjectile(self);
 263     return;
 264 }
 265
 266 void racer_fire_rocket(string tagname, entity trg)
 267 {
 268     entity rocket;
 269
 270     sound (self, CHAN_WEAPON, "weapons/rocket_fire.wav", VOL_BASE, ATTN_NORM);
 271
 272     rocket = spawn();
 273     setsize (rocket, '-1 -1 -1', '1 1 1');
 274     setorigin(rocket, gettaginfo(self, gettagindex(self, tagname)));
 275
 276     rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 277     rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
 278     rocket.solid            = SOLID_BBOX;
 279     rocket.movetype         = MOVETYPE_FLYMISSILE;
 280     rocket.flags            = FL_PROJECTILE;
 281     rocket.owner            = self;
 282     rocket.realowner        = self.owner;
 283     rocket.touch            = racer_rocket_explode;
 284     rocket.bot_dodge        = TRUE;
 285     rocket.bot_dodgerating  = autocvar_g_vehicle_racer_rocket_damage;
 286     rocket.cnt              = time + 9;
 287     rocket.velocity         = v_forward * autocvar_g_vehicle_racer_rocket_speed;
 288
 289     if(trg)
 290         rocket.think            = racer_rocket_tracker;
 291     else
 292         rocket.think            = racer_rocket_groundhugger;
 293
 294     rocket.nextthink        = time;
 295     rocket.enemy            = trg;
 296
 297     CSQCProjectile(rocket, TRUE, PROJECTILE_WAKIROCKET, TRUE);
 298 }
 299
 300 .float fire1_waspressed;
 301 .float fire2_waspressed;
 302 float racer_frame()
 303 {
 304     entity player, racer;
 305     vector df;
 306     float ftmp, ftmp2;
 307
 308     player          = self;
 309     racer           = self.vehicle;
 310
 311     player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 312
 313     self = racer;
 314
 315     if(player.BUTTON_USE)
 316     {
 317         vehicles_exit(VHEF_NORMAL);
 318         self = player;
 319         return 0;
 320     }
 321
 322     if(racer.deadflag != DEAD_NO)
 323     {
 324         self = player;
 325         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 326         return 1;
 327     }
 328
 329     racer_align4point();
 330
 331     crosshair_trace(player);
 332
 333 #if VEHICLES_VIEWROTATE_CROSSHAIR
 334     // Move abt crosshir insted of v_angle. this allows custom chase camera.
 335     racer.angles_x *= -1;
 336     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 337     if(df_x > 180)  df_x -= 360;
 338     if(df_x < -180) df_x += 360;
 339     if(df_y > 180)  df_y -= 360;
 340     if(df_y < -180) df_y += 360;
 341
 342     // Yaw
 343     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 344     ftmp2 = ftmp * -1;
 345
 346     ftmp = bound(ftmp2, shortangle_f(df_y - racer.angles_y, racer.angles_y), ftmp);
 347     ftmp2 = anglemods(racer.angles_y + ftmp);
 348
 349     // Roll
 350     ftmp = bound(-45, shortangle_f(df_z + ((racer.angles_y - ftmp2) * autocvar_g_vehicle_racer_turnroll), racer.angles_z), 45);
 351     ftmp = anglemods(racer.angles_z + ftmp) * frametime;
 352     racer.angles_z = bound(-65, racer.angles_z + ftmp, 65);
 353
 354     // Turn
 355     racer.angles_y = ftmp2;
 356
 357     // Pitch
 358     ftmp = autocvar_g_vehicle_racer_pitchspeed * frametime;
 359     ftmp2 = ftmp * -1;
 360
 361     ftmp = bound(ftmp2, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 362     racer.angles_x = anglemods(racer.angles_x + ftmp);
 363
 364     makevectors(racer.angles);
 365     racer.angles_x *= -1;
 366 #else
 367     racer.angles_x *= -1;
 368
 369     // Yaw
 370     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 371     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 372     racer.angles_y = anglemods(racer.angles_y + ftmp);
 373
 374     // Roll
 375     racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * frametime;
 376
 377     // Pitch
 378     ftmp = autocvar_g_vehicle_racer_pitchspeed  * frametime;
 379     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 380     racer.angles_x = bound(-30, anglemods(racer.angles_x + ftmp), 30);
 381
 382     makevectors(racer.angles);
 383     racer.angles_x *= -1;
 384 #endif
 385
 386     df = racer.velocity * -0.5;
 387
 388     if(player.movement_x != 0)
 389     {
 390         if(player.movement_x > 0)
 391             df += v_forward  * autocvar_g_vehicle_racer_speed_forward;
 392         else if(player.movement_x < 0)
 393             df -= v_forward  * autocvar_g_vehicle_racer_speed_forward;
 394     }
 395
 396     if(player.movement_y != 0)
 397     {
 398         if(player.movement_y < 0)
 399             df -= v_right * autocvar_g_vehicle_racer_speed_strafe;
 400         else if(player.movement_y > 0)
 401             df += v_right * autocvar_g_vehicle_racer_speed_strafe;
 402     }
 403
 404     // limit _z to avoid flying on normal thrust
 405     //if(df_z > 0)
 406     //    df_z = min(df_z, 700);
 407
 408     // Afterburn
 409     if (player.BUTTON_JUMP)
 410     if(racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
 411     {
 412         racer.wait = time;
 413         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
 414         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 415         self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 416     }
 417
 418     racer.velocity  += df * frametime;
 419
 420     df = (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce * v_up) * frametime;
 421     racer.velocity  = racer.velocity - df;
 422     player.movement = racer.velocity;
 423
 424     if(player.BUTTON_ATCK)
 425     if(time > racer.attack_finished_single)
 426     if(racer.vehicle_energy >= autocvar_g_vehicle_racer_laser_cost)
 427     {
 428         racer.vehicle_energy -= autocvar_g_vehicle_racer_laser_cost;
 429         racer.wait = time;
 430
 431         crosshair_trace(player);
 432         if(racer.cnt)
 433         {
 434             racer_fire_cannon("tag_fire1");
 435             racer.cnt = 0;
 436         }
 437         else
 438         {
 439             racer_fire_cannon("tag_fire2");
 440             racer.cnt = 1;
 441         }
 442         racer.attack_finished_single = time + autocvar_g_vehicle_racer_laser_refire;
 443         self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 444     }
 445
 446     if(autocvar_g_vehicle_racer_rocket_locktarget)
 447     {
 448         vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 449                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 450                          autocvar_g_vehicle_racer_rocket_locked_time);
 451
 452         if(self.lock_target)
 453         {
 454             if(racer.lock_strength == 1)
 455                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 456             else if(self.lock_strength > 0.5)
 457                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 458             else if(self.lock_strength < 0.5)
 459                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 460         }
 461     }
 462
 463     if(time > racer.delay)
 464     if(player.BUTTON_ATCK2)
 465     {
 466         self.misc_bulletcounter += 1;
 467         racer.delay = time + 0.2;
 468         if(self.misc_bulletcounter == 1)
 469             racer_fire_rocket("tag_rocket_r", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 470         else if(self.misc_bulletcounter == 2)
 471         {
 472             racer_fire_rocket("tag_rocket_l", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 473             self.lock_strength  = 0;
 474             self.lock_target    = world;
 475             self.misc_bulletcounter = 0;
 476
 477             racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 478             racer.lip = time;
 479         }
 480     }
 481
 482     player.fire2_waspressed = player.BUTTON_ATCK2;
 483
 484     player.vehicle_reload1 = (time - racer.lip) / (racer.delay - racer.lip);
 485
 486     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 487         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime);
 488
 489     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 490         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime);
 491
 492     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 493         vehicles_regen(wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime);
 494
 495
 496     VEHICLE_UPDATE_PLAYER(health, racer);
 497
 498     if(self.vehicle_flags & VHF_HASSHIELD)
 499         VEHICLE_UPDATE_PLAYER(shield, racer);
 500
 501
 502     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 503     setorigin(player,racer.origin + '0 0 32');
 504     player.velocity = racer.velocity;
 505
 506     self = player;
 507     return 1;
 508 }
 509
 510 void racer_think()
 511 {
 512     float a, b, c;
 513
 514     a = autocvar_g_vehicle_racer_anglestabilizer;
 515     b = autocvar_g_vehicle_racer_springlength;
 516     c = autocvar_g_vehicle_racer_hoverpower;
 517
 518     autocvar_g_vehicle_racer_anglestabilizer = 36;
 519     autocvar_g_vehicle_racer_springlength = 96;
 520     autocvar_g_vehicle_racer_hoverpower = 300;
 521
 522     racer_align4point(); //time - self.nextthink);
 523
 524     //if(self.velocity_z > 0)
 525     //    self.velocity_z *= 0.95;
 526
 527     autocvar_g_vehicle_racer_anglestabilizer = a;
 528     autocvar_g_vehicle_racer_springlength = b;
 529     autocvar_g_vehicle_racer_hoverpower = c;
 530
 531     self.velocity_x *= 0.95;
 532     self.velocity_y *= 0.95;
 533
 534     self.nextthink = time + 0.05;
 535 }
 536
 537 void racer_enter()
 538 {
 539     self.movetype = MOVETYPE_BOUNCE; //MISSILE;
 540     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health);
 541     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield);
 542 }
 543
 544 void racer_exit(float eject)
 545 {
 546     self.think      = racer_think;
 547     self.nextthink  = time;
 548     self.movetype   = MOVETYPE_BOUNCEMISSILE;
 549
 550     if not (self.owner)
 551         return;
 552
 553         makevectors(self.angles);
 554         if(eject)
 555         {
 556             setorigin(self.owner, self.origin + v_forward * 100 + v_up * 32);
 557             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 558         }
 559         else
 560         {
 561             setorigin(self.owner, self.origin - v_forward * 100 + v_up * 32);
 562             self.owner.velocity = v_forward * -150;
 563         }
 564     self.owner = world;
 565 }
 566
 567 void racer_spawn()
 568 {
 569     self.think          = racer_think;
 570     self.nextthink      = time;
 571     self.vehicle_health = autocvar_g_vehicle_racer_health;
 572     self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 573
 574     self.movetype       = MOVETYPE_TOSS;
 575     self.solid          = SOLID_SLIDEBOX;
 576     self.delay          = time;
 577     self.scale          = 0.5;
 578
 579     setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
 580 }
 581
 582
 583 void racer_blowup()
 584 {
 585
 586     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 587     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 588
 589     self.deadflag    = DEAD_DEAD;
 590     self.vehicle_exit(VHEF_NORMAL);
 591
 592     RadiusDamage (self, self, autocvar_g_vehicle_racer_blowup_coredamage,
 593                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 594                                         autocvar_g_vehicle_racer_blowup_radius, world,
 595                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 596                                         DEATH_WAKIBLOWUP, world);
 597
 598     self.alpha = -1;
 599     self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 600     self.think      = racer_spawn;
 601     self.movetype   = MOVETYPE_NONE;
 602     self.effects    = EF_NODRAW;
 603
 604     self.colormod  = '0 0 0';
 605     self.avelocity = '0 0 0';
 606     self.velocity  = '0 0 0';
 607
 608     setorigin(self, self.pos1);
 609         self.think     = racer_spawn;
 610         self.nextthink = time + autocvar_g_vehicle_racer_respawntime;
 611 }
 612
 613 void racer_deadtouch()
 614 {
 615     self.avelocity_x *= 0.7;
 616     self.cnt -= 1;
 617     if(self.cnt <= 0)
 618         racer_blowup();
 619 }
 620
 621 void racer_die()
 622 {
 623     self.health       = 0;
 624     self.event_damage = SUB_Null;
 625     self.iscreature   = FALSE;
 626     self.solid        = SOLID_CORPSE;
 627     self.takedamage   = DAMAGE_NO;
 628     self.deadflag     = DEAD_DYING;
 629     self.movetype     = MOVETYPE_BOUNCE;
 630     self.wait         = time;
 631     self.cnt          = 1 + random() * 3;
 632     self.touch        = racer_deadtouch;
 633
 634     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 635
 636     if(random() < 0.5)
 637         self.avelocity_z  = 16;
 638     else
 639         self.avelocity_z  = -16;
 640
 641     self.avelocity_x = -vlen(self.velocity) * 0.2;
 642     self.velocity     += '0 0 700';
 643     self.colormod = '-0.5 -0.5 -0.5';
 644
 645         self.think     = racer_blowup;
 646         self.nextthink = 2 + time + random() * 3;
 647 }
 648
 649 void racer_dinit()
 650 {
 651     if not (vehicle_initialize(
 652              "Wakizashi",
 653              "models/vehicles/wakizashi.dpm",
 654              "",
 655              "models/vehicles/wakizashi_cockpit.dpm",
 656              "", "", "tag_viewport",
 657              HUD_WAKIZASHI,
 658              0.5 * RACER_MIN, 0.5 * RACER_MAX,
 659              FALSE,
 660              racer_spawn, autocvar_g_vehicle_racer_respawntime,
 661              racer_frame,
 662              racer_enter, racer_exit,
 663              racer_die,   racer_think))
 664     {
 665         remove(self);
 666         return;
 667     }
 668
 669     if(autocvar_g_vehicle_racer_hovertype != 0)
 670         racer_force_from_tag = vehicles_force_fromtag_maglev;
 671     else
 672         racer_force_from_tag = vehicles_force_fromtag_hover;
 673
 674     // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 675     self.scale = 0.5;
 676     setattachment(self.vehicle_hudmodel, self, "");
 677     setattachment(self.vehicle_viewport, self, "tag_viewport");
 678
 679     self.mass               = 900;
 680 }
 681
 682 void spawnfunc_vehicle_racer()
 683 {
 684
 685     precache_sound ("weapons/laserimpact.wav");
 686     precache_sound ("weapons/lasergun_fire.wav");
 687     precache_sound ("weapons/rocket_fire.wav");
 688     precache_sound ("weapons/rocket_impact.wav");
 689
 690     precache_model ("models/vhshield.md3");
 691     precache_model ("models/vehicles/wakizashi.dpm");
 692     precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 693
 694
 695     vehicles_configcheck("vehicle_racer.cfg", autocvar_g_vehicle_racer_health);
 696     if(autocvar_g_vehicle_racer_energy)
 697         if(autocvar_g_vehicle_racer_energy_regen)
 698             self.vehicle_flags |= VHF_ENERGYREGEN;
 699
 700     if(autocvar_g_vehicle_racer_shield)
 701         self.vehicle_flags |= VHF_HASSHIELD;
 702
 703     if(autocvar_g_vehicle_racer_shield_regen)
 704         self.vehicle_flags |= VHF_SHIELDREGEN;
 705
 706     if(autocvar_g_vehicle_racer_health_regen)
 707         self.vehicle_flags |= VHF_HEALTHREGEN;
 708
 709     self.think = racer_dinit;
 710     self.nextthink = time + 1;
 711 }