qcsrc/server/vehicles/racer.qc

   1 #define RACER_MIN '-120 -120 -40'
   2 #define RACER_MAX '120 120 40'
   3 #define RACER_ENGINE "sound/vehicles/racer.wav"
   4
   5 #ifdef SVQC
   6 void racer_exit(float eject);
   7 void racer_enter();
   8
   9 // Auto cvars
  10 float autocvar_g_vehicle_racer_speed_afterburn;
  11 float autocvar_g_vehicle_racer_afterburn_cost;
  12
  13 float autocvar_g_vehicle_racer_anglestabilizer;
  14 float autocvar_g_vehicle_racer_downforce;
  15
  16 float autocvar_g_vehicle_racer_speed_forward;
  17 float autocvar_g_vehicle_racer_speed_strafe;
  18 float autocvar_g_vehicle_racer_springlength;
  19 float autocvar_g_vehicle_racer_upforcedamper;
  20 float autocvar_g_vehicle_racer_friction;
  21
  22 float autocvar_g_vehicle_racer_hovertype;
  23 float autocvar_g_vehicle_racer_hoverpower;
  24
  25 float autocvar_g_vehicle_racer_turnroll;
  26 float autocvar_g_vehicle_racer_turnspeed;
  27 float autocvar_g_vehicle_racer_pitchspeed;
  28
  29 float autocvar_g_vehicle_racer_energy;
  30 float autocvar_g_vehicle_racer_energy_regen;
  31 float autocvar_g_vehicle_racer_energy_regen_pause;
  32
  33 float autocvar_g_vehicle_racer_health;
  34 float autocvar_g_vehicle_racer_health_regen;
  35 float autocvar_g_vehicle_racer_health_regen_pause;
  36
  37 float autocvar_g_vehicle_racer_shield;
  38 float autocvar_g_vehicle_racer_shield_regen;
  39 float autocvar_g_vehicle_racer_shield_regen_pause;
  40
  41 float autocvar_g_vehicle_racer_cannon_cost;
  42 float autocvar_g_vehicle_racer_cannon_damage;
  43 float autocvar_g_vehicle_racer_cannon_radius;
  44 float autocvar_g_vehicle_racer_cannon_refire;
  45 float autocvar_g_vehicle_racer_cannon_speed;
  46 float autocvar_g_vehicle_racer_cannon_spread;
  47 float autocvar_g_vehicle_racer_cannon_force;
  48
  49 float autocvar_g_vehicle_racer_rocket_accel;
  50 float autocvar_g_vehicle_racer_rocket_damage;
  51 float autocvar_g_vehicle_racer_rocket_radius;
  52 float autocvar_g_vehicle_racer_rocket_force;
  53 float autocvar_g_vehicle_racer_rocket_refire;
  54 float autocvar_g_vehicle_racer_rocket_speed;
  55 float autocvar_g_vehicle_racer_rocket_turnrate;
  56
  57 float autocvar_g_vehicle_racer_rocket_locktarget;
  58 float autocvar_g_vehicle_racer_rocket_locking_time;
  59 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  60 float autocvar_g_vehicle_racer_rocket_locked_time;
  61 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  62
  63 float autocvar_g_vehicle_racer_respawntime;
  64
  65 float autocvar_g_vehicle_racer_blowup_radius;
  66 float autocvar_g_vehicle_racer_blowup_coredamage;
  67 float autocvar_g_vehicle_racer_blowup_edgedamage;
  68 float autocvar_g_vehicle_racer_blowup_forceintensity;
  69
  70 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
  71
  72 void racer_align4point()
  73 {
  74     vector push_vector, v_add;
  75     float fl_push, fr_push, bl_push, br_push;
  76
  77
  78     push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  79     fr_push      = force_fromtag_normpower;
  80     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  81
  82     push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  83     fl_push      = force_fromtag_normpower;
  84     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  85
  86     push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  87     br_push      = force_fromtag_normpower;
  88     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  89
  90     push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  91     bl_push      = force_fromtag_normpower;
  92     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  93
  94     self.velocity += (push_vector * frametime);
  95
  96     // Anti ocilation
  97     if(self.velocity_z  > 0)
  98         self.velocity_z *= 1 - (autocvar_g_vehicle_racer_upforcedamper * frametime);
  99
 100     self.velocity   += v_add;
 101     //self.velocity_z -= autocvar_sv_gravity * frametime;
 102
 103     push_vector_x =  (fl_push - bl_push);
 104     push_vector_x += (fr_push - br_push);
 105     push_vector_x *= 360;
 106
 107     push_vector_z = (fr_push - fl_push);
 108     push_vector_z += (br_push - bl_push);
 109     push_vector_z *= 360;
 110
 111     // Apply angle diffrance
 112     self.angles_z += push_vector_z * frametime;
 113     self.angles_x += push_vector_x * frametime;
 114
 115     // Apply stabilizer
 116     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 117     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 118 }
 119
 120 void racer_fire_cannon(string tagname)
 121 {
 122     vector v;
 123     entity bolt;
 124
 125     v = gettaginfo(self, gettagindex(self, tagname));
 126     bolt = vehicles_projectile("wakizashi_gun_muzzleflash", "weapons/lasergun_fire.wav",
 127                            v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 128                            autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 129                            DEATH_WAKIGUN, PROJECTILE_WAKICANNON, 0, TRUE, TRUE);
 130
 131         // Fix z-aim (for chase mode)
 132     v = normalize(trace_endpos - bolt.origin);
 133     v_forward_z = v_z * 0.5;
 134     bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 135 }
 136
 137 void racer_rocket_groundhugger()
 138 {
 139     vector olddir, newdir;
 140     float oldvel, newvel;
 141
 142     self.nextthink  = time;
 143
 144     if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 145     {
 146         self.use();
 147         return;
 148     }
 149
 150     if not (self.realowner.vehicle)
 151     {
 152         UpdateCSQCProjectile(self);
 153         return;
 154     }
 155
 156     olddir = normalize(self.velocity);
 157     oldvel = vlen(self.velocity);
 158     newvel = oldvel + self.lip;
 159
 160     tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 161     if(trace_fraction <= 0.5)
 162     {
 163         // Hitting somethign soon, just speed ahead
 164         self.velocity = olddir * newvel;
 165         UpdateCSQCProjectile(self);
 166         return;
 167     }
 168
 169     traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 170     if(trace_fraction != 1.0)
 171     {
 172         newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 173         self.velocity = normalize(olddir + newdir) * newvel;
 174     }
 175     else
 176     {
 177         self.velocity = olddir * newvel;
 178         self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 179     }
 180
 181     UpdateCSQCProjectile(self);
 182     return;
 183 }
 184
 185 void racer_rocket_tracker()
 186 {
 187     vector olddir, newdir;
 188     float oldvel, newvel;
 189
 190     self.nextthink  = time;
 191
 192     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 193     {
 194         self.use();
 195         return;
 196     }
 197
 198     if not (self.realowner.vehicle)
 199     {
 200         UpdateCSQCProjectile(self);
 201         return;
 202     }
 203
 204     olddir = normalize(self.velocity);
 205     oldvel = vlen(self.velocity);
 206     newvel = oldvel + self.lip;
 207     makevectors(vectoangles(olddir));
 208
 209     traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 210     newdir = normalize(self.enemy.origin - self.origin);
 211
 212     if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 213     {
 214         //bprint("Target lost!\n");
 215         //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 216         self.think = racer_rocket_groundhugger;
 217         return;
 218     }
 219
 220     if(trace_fraction != 1.0)
 221         newdir_z += 16 * sys_frametime;
 222
 223     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 224     self.velocity_z -= 800 * sys_frametime;
 225
 226     UpdateCSQCProjectile(self);
 227     return;
 228 }
 229
 230 void racer_fire_rocket(string tagname, entity trg)
 231 {
 232     vector v;
 233     entity rocket;
 234
 235     v = gettaginfo(self, gettagindex(self, tagname));
 236     rocket = vehicles_projectile("wakizashi_rocket_launch", "weapons/rocket_fire.wav",
 237                            v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 238                            autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 239                            DEATH_WAKIROCKET, PROJECTILE_WAKIROCKET, 20, FALSE, FALSE);
 240
 241     rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 242     rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
 243     rocket.nextthink        = time;
 244     rocket.enemy            = trg;
 245     rocket.cnt              = time + 15;
 246
 247     if(trg)
 248         rocket.think            = racer_rocket_tracker;
 249     else
 250         rocket.think            = racer_rocket_groundhugger;
 251 }
 252
 253 float racer_frame()
 254 {
 255     entity player, racer;
 256     vector df;
 257     float ftmp;
 258
 259     player          = self;
 260     racer           = self.vehicle;
 261
 262     player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 263
 264     self = racer;
 265
 266     if(racer.deadflag != DEAD_NO)
 267     {
 268         self = player;
 269         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 270         return 1;
 271     }
 272
 273     racer_align4point();
 274
 275     crosshair_trace(player);
 276
 277     racer.angles_x *= -1;
 278
 279     // Yaw
 280     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 281     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 282     racer.angles_y = anglemods(racer.angles_y + ftmp);
 283
 284     // Roll
 285     racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * frametime;
 286
 287     // Pitch
 288     ftmp = autocvar_g_vehicle_racer_pitchspeed  * frametime;
 289     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 290     racer.angles_x = bound(-30, anglemods(racer.angles_x + ftmp), 30);
 291
 292     makevectors(racer.angles);
 293     racer.angles_x *= -1;
 294
 295
 296     ftmp = racer.velocity_z;
 297     df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 298     racer.velocity_z = ftmp;
 299
 300     if(player.movement_x != 0)
 301     {
 302         if(player.movement_x > 0)
 303             df += v_forward  * autocvar_g_vehicle_racer_speed_forward;
 304         else if(player.movement_x < 0)
 305             df -= v_forward  * autocvar_g_vehicle_racer_speed_forward;
 306     }
 307
 308     if(player.movement_y != 0)
 309     {
 310         if(player.movement_y < 0)
 311             df -= v_right * autocvar_g_vehicle_racer_speed_strafe;
 312         else if(player.movement_y > 0)
 313             df += v_right * autocvar_g_vehicle_racer_speed_strafe;
 314     }
 315
 316     if(vlen(player.movement) != 0)
 317     {
 318         if(self.sound_nexttime < time || self.sounds != 1)
 319         {
 320             self.sounds = 1;
 321             self.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 322             sound (self, CHAN_TRIGGER, "vehicles/racer_move.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 323         }
 324     }
 325     else
 326     {
 327         if(self.sound_nexttime < time || self.sounds != 0)
 328         {
 329             self.sounds = 0;
 330             self.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 331             sound (self, CHAN_TRIGGER, "vehicles/racer_idle.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 332         }
 333     }
 334
 335     // Afterburn
 336     if (player.BUTTON_JUMP && racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
 337     {
 338         racer.wait = time;
 339         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
 340         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 341
 342         if(self.strength_finished < time)
 343         {
 344             //self.sounds = 2;
 345             self.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 346             sound (self, CHAN_PAIN, "vehicles/racer_boost.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 347         }
 348     }
 349     else
 350     {
 351         self.strength_finished = 0;
 352         sound (self, CHAN_PAIN, "misc/null.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 353     }
 354
 355
 356     racer.velocity  += df * frametime;
 357
 358     df = (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce * v_up) * frametime;
 359     racer.velocity  = racer.velocity - df;
 360     player.movement = racer.velocity;
 361
 362     if(player.BUTTON_ATCK)
 363     if(time > racer.attack_finished_single)
 364     if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 365     {
 366         racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 367         racer.wait = time;
 368
 369         crosshair_trace(player);
 370         if(racer.cnt)
 371         {
 372             racer_fire_cannon("tag_fire1");
 373             racer.cnt = 0;
 374         }
 375         else
 376         {
 377             racer_fire_cannon("tag_fire2");
 378             racer.cnt = 1;
 379         }
 380         racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 381         //self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 382     }
 383
 384     if(autocvar_g_vehicle_racer_rocket_locktarget)
 385     {
 386         vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 387                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 388                          autocvar_g_vehicle_racer_rocket_locked_time);
 389
 390         if(self.lock_target)
 391         {
 392             if(racer.lock_strength == 1)
 393                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 394             else if(self.lock_strength > 0.5)
 395                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 396             else if(self.lock_strength < 0.5)
 397                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 398         }
 399     }
 400
 401     if(time > racer.delay)
 402     if(player.BUTTON_ATCK2)
 403     {
 404         self.misc_bulletcounter += 1;
 405         racer.delay = time + 0.3;
 406         if(self.misc_bulletcounter == 1)
 407             racer_fire_rocket("tag_rocket_r", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 408         else if(self.misc_bulletcounter == 2)
 409         {
 410             racer_fire_rocket("tag_rocket_l", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 411             self.lock_strength  = 0;
 412             self.lock_target    = world;
 413             self.misc_bulletcounter = 0;
 414
 415             racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 416             racer.lip = time;
 417         }
 418     }
 419     player.vehicle_reload1 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 420
 421     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 422         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime);
 423
 424     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 425         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime);
 426
 427     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 428         vehicles_regen(wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime);
 429
 430
 431     VEHICLE_UPDATE_PLAYER(health, racer);
 432     VEHICLE_UPDATE_PLAYER(energy, racer);
 433
 434     if(self.vehicle_flags & VHF_HASSHIELD)
 435         VEHICLE_UPDATE_PLAYER(shield, racer);
 436
 437
 438     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 439     setorigin(player,racer.origin + '0 0 32');
 440     player.velocity = racer.velocity;
 441
 442     self = player;
 443     return 1;
 444 }
 445
 446 void racer_think()
 447 {
 448     /*
 449     float a, b, c;a = autocvar_g_vehicle_racer_anglestabilizer;
 450     b = autocvar_g_vehicle_racer_springlength;
 451     c = autocvar_g_vehicle_racer_hoverpower;
 452
 453     autocvar_g_vehicle_racer_anglestabilizer = 36;
 454     autocvar_g_vehicle_racer_springlength = 96;
 455     autocvar_g_vehicle_racer_hoverpower = 300;
 456     */
 457
 458     racer_align4point(); //time - self.nextthink);
 459
 460     /*
 461     //if(self.velocity_z > 0)
 462     //    self.velocity_z *= 0.95;
 463
 464     autocvar_g_vehicle_racer_anglestabilizer = a;
 465     autocvar_g_vehicle_racer_springlength = b;
 466     autocvar_g_vehicle_racer_hoverpower = c;
 467     */
 468
 469     self.velocity_x *= 0.9;
 470     self.velocity_y *= 0.9;
 471     self.velocity_z *= 0.8;
 472     self.velocity_z += sin(time * 2) * 16;
 473     self.nextthink = time; // + 0.05;
 474 }
 475
 476 void racer_enter()
 477 {
 478     self.movetype = MOVETYPE_BOUNCE;
 479     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health);
 480     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield);
 481
 482     if(self.owner.flagcarried)
 483        setorigin(self.owner.flagcarried, '-190 0 96');
 484 }
 485
 486 void racer_exit(float eject)
 487 {
 488     vector spot;
 489
 490     self.think      = racer_think;
 491     self.nextthink  = time;
 492     self.movetype   = MOVETYPE_TOSS;
 493
 494     if not (self.owner)
 495         return;
 496
 497         makevectors(self.angles);
 498         if(eject)
 499         {
 500             spot = self.origin + v_forward * 100 + '0 0 64';
 501             spot = vehicles_findgoodexit(spot);
 502             setorigin(self.owner , spot);
 503             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 504         }
 505         else
 506         {
 507             spot = self.origin - v_forward * 200 + '0 0 64';
 508             spot = vehicles_findgoodexit(spot);
 509             setorigin(self.owner , spot);
 510         }
 511
 512     self.owner = world;
 513 }
 514
 515 void racer_spawn()
 516 {
 517     self.think          = racer_think;
 518     self.nextthink      = time;
 519     self.vehicle_health = autocvar_g_vehicle_racer_health;
 520     self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 521
 522     self.movetype       = MOVETYPE_TOSS;
 523     self.solid          = SOLID_SLIDEBOX;
 524     self.delay          = time;
 525     self.scale          = 0.5;
 526
 527     setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
 528 }
 529
 530
 531 void racer_blowup()
 532 {
 533     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 534     pointparticles(particleeffectnum("explosion_big"), self.origin, '0 0 0', 1);
 535
 536     self.deadflag    = DEAD_DEAD;
 537     self.vehicle_exit(VHEF_NORMAL);
 538
 539     RadiusDamage (self, self, autocvar_g_vehicle_racer_blowup_coredamage,
 540                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 541                                         autocvar_g_vehicle_racer_blowup_radius, world,
 542                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 543                                         DEATH_WAKIBLOWUP, world);
 544
 545     self.alpha = -1;
 546     self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 547     self.think      = racer_spawn;
 548     self.movetype   = MOVETYPE_NONE;
 549     self.effects    = EF_NODRAW;
 550
 551     self.colormod  = '0 0 0';
 552     self.avelocity = '0 0 0';
 553     self.velocity  = '0 0 0';
 554
 555     setorigin(self, self.pos1);
 556         self.think     = racer_spawn;
 557         self.nextthink = time + autocvar_g_vehicle_racer_respawntime;
 558 }
 559
 560 void racer_deadtouch()
 561 {
 562     dprint("Boink!\n");
 563     self.avelocity_x *= 0.7;
 564     self.cnt -= 1;
 565     if(self.cnt <= 0)
 566         racer_blowup();
 567 }
 568
 569 void racer_die()
 570 {
 571     self.health       = 0;
 572     self.event_damage = SUB_Null;
 573     self.iscreature   = FALSE;
 574     self.solid        = SOLID_CORPSE;
 575     self.takedamage   = DAMAGE_NO;
 576     self.deadflag     = DEAD_DYING;
 577     self.movetype     = MOVETYPE_BOUNCE;
 578     self.wait         = time;
 579     self.cnt          = 1 + random() * 2;
 580     self.touch        = racer_deadtouch;
 581
 582     pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 583
 584     if(random() < 0.5)
 585         self.avelocity_z  = 32;
 586     else
 587         self.avelocity_z  = -32;
 588
 589     self.avelocity_x = -vlen(self.velocity) * 0.2;
 590     self.velocity   += '0 0 700';
 591     self.colormod    = '-0.5 -0.5 -0.5';
 592
 593         self.think     = racer_blowup;
 594         self.nextthink = 2 + time + random() * 3;
 595 }
 596
 597 void racer_dinit()
 598 {
 599     if not (vehicle_initialize(
 600              "Wakizashi",
 601              "models/vehicles/wakizashi.dpm",
 602              "",
 603              "models/vehicles/wakizashi_cockpit.dpm",
 604              "", "", "tag_viewport",
 605              HUD_WAKIZASHI,
 606              0.5 * RACER_MIN, 0.5 * RACER_MAX,
 607              FALSE,
 608              racer_spawn, autocvar_g_vehicle_racer_respawntime,
 609              racer_frame,
 610              racer_enter, racer_exit,
 611              racer_die,   racer_think,
 612              TRUE))
 613     {
 614         remove(self);
 615         return;
 616     }
 617
 618     if(autocvar_g_vehicle_racer_hovertype != 0)
 619         racer_force_from_tag = vehicles_force_fromtag_maglev;
 620     else
 621         racer_force_from_tag = vehicles_force_fromtag_hover;
 622
 623     // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 624     self.scale = 0.5;
 625     setattachment(self.vehicle_hudmodel, self, "");
 626     setattachment(self.vehicle_viewport, self, "tag_viewport");
 627
 628     self.mass               = 900;
 629 }
 630
 631 void spawnfunc_vehicle_racer()
 632 {
 633
 634     precache_sound ("weapons/laserimpact.wav");
 635     precache_sound ("weapons/lasergun_fire.wav");
 636     precache_sound ("weapons/rocket_fire.wav");
 637     precache_sound ("weapons/rocket_impact.wav");
 638
 639     precache_sound ("vehicles/racer_idle.wav");
 640     precache_sound ("vehicles/racer_move.wav");
 641     precache_sound ("vehicles/racer_boost.wav");
 642
 643     precache_model ("models/vhshield.md3");
 644     precache_model ("models/vehicles/wakizashi.dpm");
 645     precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 646
 647     vehicles_configcheck("vehicle_racer.cfg", autocvar_g_vehicle_racer_health);
 648     if(autocvar_g_vehicle_racer_energy)
 649         if(autocvar_g_vehicle_racer_energy_regen)
 650             self.vehicle_flags |= VHF_ENERGYREGEN;
 651
 652     if(autocvar_g_vehicle_racer_shield)
 653         self.vehicle_flags |= VHF_HASSHIELD;
 654
 655     if(autocvar_g_vehicle_racer_shield_regen)
 656         self.vehicle_flags |= VHF_SHIELDREGEN;
 657
 658     if(autocvar_g_vehicle_racer_health_regen)
 659         self.vehicle_flags |= VHF_HEALTHREGEN;
 660
 661     self.think = racer_dinit;
 662     self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_racer_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 663 }
 664 #endif // SVQC