qcsrc/server/vehicles/racer.qc

   1 #define RACER_MIN '-120 -120 -40'
   2 #define RACER_MAX '120 120 40'
   3 #define RACER_ENGINE "sound/vehicles/racer.wav"
   4
   5 #ifdef SVQC
   6 void racer_exit(float eject);
   7 void racer_enter();
   8
   9 // Auto cvars
  10 float autocvar_g_vehicle_racer_speed_afterburn;
  11 float autocvar_g_vehicle_racer_afterburn_cost;
  12
  13 float autocvar_g_vehicle_racer_anglestabilizer;
  14 float autocvar_g_vehicle_racer_downforce;
  15
  16 float autocvar_g_vehicle_racer_speed_forward;
  17 float autocvar_g_vehicle_racer_speed_strafe;
  18 float autocvar_g_vehicle_racer_springlength;
  19 float autocvar_g_vehicle_racer_upforcedamper;
  20 float autocvar_g_vehicle_racer_friction;
  21
  22 float autocvar_g_vehicle_racer_hovertype;
  23 float autocvar_g_vehicle_racer_hoverpower;
  24
  25 float autocvar_g_vehicle_racer_turnroll;
  26 float autocvar_g_vehicle_racer_turnspeed;
  27 float autocvar_g_vehicle_racer_pitchspeed;
  28
  29 float autocvar_g_vehicle_racer_energy;
  30 float autocvar_g_vehicle_racer_energy_regen;
  31 float autocvar_g_vehicle_racer_energy_regen_pause;
  32
  33 float autocvar_g_vehicle_racer_health;
  34 float autocvar_g_vehicle_racer_health_regen;
  35 float autocvar_g_vehicle_racer_health_regen_pause;
  36
  37 float autocvar_g_vehicle_racer_shield;
  38 float autocvar_g_vehicle_racer_shield_regen;
  39 float autocvar_g_vehicle_racer_shield_regen_pause;
  40
  41 float autocvar_g_vehicle_racer_cannon_cost;
  42 float autocvar_g_vehicle_racer_cannon_damage;
  43 float autocvar_g_vehicle_racer_cannon_radius;
  44 float autocvar_g_vehicle_racer_cannon_refire;
  45 float autocvar_g_vehicle_racer_cannon_speed;
  46 float autocvar_g_vehicle_racer_cannon_spread;
  47 float autocvar_g_vehicle_racer_cannon_force;
  48
  49 float autocvar_g_vehicle_racer_rocket_accel;
  50 float autocvar_g_vehicle_racer_rocket_damage;
  51 float autocvar_g_vehicle_racer_rocket_radius;
  52 float autocvar_g_vehicle_racer_rocket_force;
  53 float autocvar_g_vehicle_racer_rocket_refire;
  54 float autocvar_g_vehicle_racer_rocket_speed;
  55 float autocvar_g_vehicle_racer_rocket_turnrate;
  56
  57 float autocvar_g_vehicle_racer_rocket_locktarget;
  58 float autocvar_g_vehicle_racer_rocket_locking_time;
  59 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  60 float autocvar_g_vehicle_racer_rocket_locked_time;
  61 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  62
  63 float autocvar_g_vehicle_racer_respawntime;
  64
  65 float autocvar_g_vehicle_racer_blowup_radius;
  66 float autocvar_g_vehicle_racer_blowup_coredamage;
  67 float autocvar_g_vehicle_racer_blowup_edgedamage;
  68 float autocvar_g_vehicle_racer_blowup_forceintensity;
  69
  70 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
  71
  72 void racer_align4point()
  73 {
  74     vector push_vector, v_add;
  75     float fl_push, fr_push, bl_push, br_push;
  76
  77
  78     push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  79     fr_push      = force_fromtag_normpower;
  80     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  81
  82     push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  83     fl_push      = force_fromtag_normpower;
  84     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  85
  86     push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  87     br_push      = force_fromtag_normpower;
  88     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  89
  90     push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  91     bl_push      = force_fromtag_normpower;
  92     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  93
  94     self.velocity += (push_vector * frametime);
  95
  96     // Anti ocilation
  97     if(self.velocity_z  > 0)
  98         self.velocity_z *= 1 - (autocvar_g_vehicle_racer_upforcedamper * frametime);
  99
 100     self.velocity   += v_add;
 101     //self.velocity_z -= autocvar_sv_gravity * frametime;
 102
 103     push_vector_x =  (fl_push - bl_push);
 104     push_vector_x += (fr_push - br_push);
 105     push_vector_x *= 360;
 106
 107     push_vector_z = (fr_push - fl_push);
 108     push_vector_z += (br_push - bl_push);
 109     push_vector_z *= 360;
 110
 111     // Apply angle diffrance
 112     self.angles_z += push_vector_z * frametime;
 113     self.angles_x += push_vector_x * frametime;
 114
 115     // Apply stabilizer
 116     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 117     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 118 }
 119
 120 void racer_fire_cannon(string tagname)
 121 {
 122     vector v;
 123     entity bolt;
 124
 125     v = gettaginfo(self, gettagindex(self, tagname));
 126     bolt = vehicles_projectile("wakizashi_gun_muzzleflash", "weapons/lasergun_fire.wav",
 127                            v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 128                            autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 129                            DEATH_WAKIGUN, PROJECTILE_WAKICANNON, 0, TRUE, TRUE);
 130
 131         // Fix z-aim (for chase mode)
 132     v = normalize(trace_endpos - bolt.origin);
 133     v_forward_z = v_z * 0.5;
 134     bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 135 }
 136
 137 void racer_rocket_groundhugger()
 138 {
 139     vector olddir, newdir;
 140     float oldvel, newvel;
 141
 142     self.nextthink  = time;
 143
 144     if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 145     {
 146         self.use();
 147         return;
 148     }
 149
 150     if not (self.realowner.vehicle)
 151     {
 152         UpdateCSQCProjectile(self);
 153         return;
 154     }
 155
 156     olddir = normalize(self.velocity);
 157     oldvel = vlen(self.velocity);
 158     newvel = oldvel + self.lip;
 159
 160     tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 161     if(trace_fraction <= 0.5)
 162     {
 163         // Hitting somethign soon, just speed ahead
 164         self.velocity = olddir * newvel;
 165         UpdateCSQCProjectile(self);
 166         return;
 167     }
 168
 169     traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 170     if(trace_fraction != 1.0)
 171     {
 172         newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 173         self.velocity = normalize(olddir + newdir) * newvel;
 174     }
 175     else
 176     {
 177         self.velocity = olddir * newvel;
 178         self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 179     }
 180
 181     UpdateCSQCProjectile(self);
 182     return;
 183 }
 184
 185 void racer_rocket_tracker()
 186 {
 187     vector olddir, newdir;
 188     float oldvel, newvel;
 189
 190     self.nextthink  = time;
 191
 192     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 193     {
 194         self.use();
 195         return;
 196     }
 197
 198     if not (self.realowner.vehicle)
 199     {
 200         UpdateCSQCProjectile(self);
 201         return;
 202     }
 203
 204     olddir = normalize(self.velocity);
 205     oldvel = vlen(self.velocity);
 206     newvel = oldvel + self.lip;
 207     makevectors(vectoangles(olddir));
 208
 209     traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 210     newdir = normalize(self.enemy.origin - self.origin);
 211
 212     if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 213     {
 214         //bprint("Target lost!\n");
 215         //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 216         self.think = racer_rocket_groundhugger;
 217         return;
 218     }
 219
 220     if(trace_fraction != 1.0)
 221         newdir_z += 16 * sys_frametime;
 222
 223     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 224     self.velocity_z -= 800 * sys_frametime;
 225
 226     UpdateCSQCProjectile(self);
 227     return;
 228 }
 229
 230 void racer_fire_rocket(string tagname, entity trg)
 231 {
 232     vector v;
 233     entity rocket;
 234
 235     v = gettaginfo(self, gettagindex(self, tagname));
 236     rocket = vehicles_projectile("wakizashi_rocket_launch", "weapons/rocket_fire.wav",
 237                            v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 238                            autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 239                            DEATH_WAKIROCKET, PROJECTILE_WAKIROCKET, 20, FALSE, FALSE);
 240
 241     rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 242     rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
 243     rocket.nextthink        = time;
 244     rocket.enemy            = trg;
 245     rocket.cnt              = time + 15;
 246
 247     if(trg)
 248         rocket.think            = racer_rocket_tracker;
 249     else
 250         rocket.think            = racer_rocket_groundhugger;
 251 }
 252
 253 float racer_frame()
 254 {
 255     entity player, racer;
 256     vector df;
 257     float ftmp;
 258
 259     player  = self;
 260     racer   = self.vehicle;
 261     self    = racer;
 262
 263     player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 264
 265     vehicles_painframe();
 266
 267     if(racer.deadflag != DEAD_NO)
 268     {
 269         self = player;
 270         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 271         return 1;
 272     }
 273
 274     racer_align4point();
 275
 276     crosshair_trace(player);
 277
 278     racer.angles_x *= -1;
 279
 280     // Yaw
 281     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 282     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 283     racer.angles_y = anglemods(racer.angles_y + ftmp);
 284
 285     // Roll
 286     racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * frametime;
 287
 288     // Pitch
 289     ftmp = autocvar_g_vehicle_racer_pitchspeed  * frametime;
 290     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 291     racer.angles_x = bound(-30, anglemods(racer.angles_x + ftmp), 30);
 292
 293     makevectors(racer.angles);
 294     racer.angles_x *= -1;
 295
 296
 297     ftmp = racer.velocity_z;
 298     df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 299     racer.velocity_z = ftmp;
 300
 301     if(player.movement_x != 0)
 302     {
 303         if(player.movement_x > 0)
 304             df += v_forward  * autocvar_g_vehicle_racer_speed_forward;
 305         else if(player.movement_x < 0)
 306             df -= v_forward  * autocvar_g_vehicle_racer_speed_forward;
 307     }
 308
 309     if(player.movement_y != 0)
 310     {
 311         if(player.movement_y < 0)
 312             df -= v_right * autocvar_g_vehicle_racer_speed_strafe;
 313         else if(player.movement_y > 0)
 314             df += v_right * autocvar_g_vehicle_racer_speed_strafe;
 315     }
 316
 317     if(vlen(player.movement) != 0)
 318     {
 319         if(self.sound_nexttime < time || self.sounds != 1)
 320         {
 321             self.sounds = 1;
 322             self.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 323             sound (self, CHAN_TRIGGER, "vehicles/racer_move.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 324         }
 325     }
 326     else
 327     {
 328         if(self.sound_nexttime < time || self.sounds != 0)
 329         {
 330             self.sounds = 0;
 331             self.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 332             sound (self, CHAN_TRIGGER, "vehicles/racer_idle.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 333         }
 334     }
 335
 336     // Afterburn
 337     if (player.BUTTON_JUMP && racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
 338     {
 339         if(time - racer.wait > 0.2)
 340             pointparticles(particleeffectnum("wakizashi_booster_smoke"), self.origin, '0 0 0', 1);
 341
 342         racer.wait = time;
 343         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
 344         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 345
 346         if(self.invincible_finished < time)
 347         {
 348             traceline(self.origin, self.origin - '0 0 256', MOVE_NORMAL, self);
 349             if(trace_fraction != 1.0)
 350                 pointparticles(particleeffectnum("smoke_small"), trace_endpos, '0 0 0', 1);
 351
 352             self.invincible_finished = time + 0.1 + (random() * 0.1);
 353         }
 354
 355         if(self.strength_finished < time)
 356         {
 357             //self.sounds = 2;
 358             self.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 359             sound (self, CHAN_PAIN, "vehicles/racer_boost.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 360         }
 361     }
 362     else
 363     {
 364         self.strength_finished = 0;
 365         sound (self, CHAN_PAIN, "misc/null.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 366     }
 367
 368
 369     racer.velocity  += df * frametime;
 370
 371     df = (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce * v_up) * frametime;
 372     racer.velocity  = racer.velocity - df;
 373     player.movement = racer.velocity;
 374
 375     if(player.BUTTON_ATCK)
 376     if(time > racer.attack_finished_single)
 377     if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 378     {
 379         racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 380         racer.wait = time;
 381
 382         crosshair_trace(player);
 383         if(racer.cnt)
 384         {
 385             racer_fire_cannon("tag_fire1");
 386             racer.cnt = 0;
 387         }
 388         else
 389         {
 390             racer_fire_cannon("tag_fire2");
 391             racer.cnt = 1;
 392         }
 393         racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 394         //self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 395     }
 396
 397     if(autocvar_g_vehicle_racer_rocket_locktarget)
 398     {
 399         vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 400                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 401                          autocvar_g_vehicle_racer_rocket_locked_time);
 402
 403         if(self.lock_target)
 404         {
 405             if(racer.lock_strength == 1)
 406                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 407             else if(self.lock_strength > 0.5)
 408                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 409             else if(self.lock_strength < 0.5)
 410                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 411         }
 412     }
 413
 414     if(time > racer.delay)
 415     if(player.BUTTON_ATCK2)
 416     {
 417         self.misc_bulletcounter += 1;
 418         racer.delay = time + 0.3;
 419         if(self.misc_bulletcounter == 1)
 420             racer_fire_rocket("tag_rocket_r", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 421         else if(self.misc_bulletcounter == 2)
 422         {
 423             racer_fire_rocket("tag_rocket_l", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 424             self.lock_strength  = 0;
 425             self.lock_target    = world;
 426             self.misc_bulletcounter = 0;
 427
 428             racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 429             racer.lip = time;
 430         }
 431     }
 432     player.vehicle_reload1 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 433
 434     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 435         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime);
 436
 437     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 438         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime);
 439
 440     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 441         vehicles_regen(wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime);
 442
 443
 444     VEHICLE_UPDATE_PLAYER(health, racer);
 445     VEHICLE_UPDATE_PLAYER(energy, racer);
 446
 447     if(self.vehicle_flags & VHF_HASSHIELD)
 448         VEHICLE_UPDATE_PLAYER(shield, racer);
 449
 450
 451     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 452     setorigin(player,racer.origin + '0 0 32');
 453     player.velocity = racer.velocity;
 454
 455     self = player;
 456     return 1;
 457 }
 458
 459 void racer_think()
 460 {
 461     /*
 462     float a, b, c;a = autocvar_g_vehicle_racer_anglestabilizer;
 463     b = autocvar_g_vehicle_racer_springlength;
 464     c = autocvar_g_vehicle_racer_hoverpower;
 465
 466     autocvar_g_vehicle_racer_anglestabilizer = 36;
 467     autocvar_g_vehicle_racer_springlength = 96;
 468     autocvar_g_vehicle_racer_hoverpower = 300;
 469     */
 470
 471     racer_align4point(); //time - self.nextthink);
 472
 473     /*
 474     //if(self.velocity_z > 0)
 475     //    self.velocity_z *= 0.95;
 476
 477     autocvar_g_vehicle_racer_anglestabilizer = a;
 478     autocvar_g_vehicle_racer_springlength = b;
 479     autocvar_g_vehicle_racer_hoverpower = c;
 480     */
 481
 482     self.velocity_x *= 0.9;
 483     self.velocity_y *= 0.9;
 484     self.velocity_z *= 0.8;
 485     self.velocity_z += sin(time * 2) * 16;
 486     self.nextthink = time; // + 0.05;
 487 }
 488
 489 void racer_enter()
 490 {
 491     self.movetype = MOVETYPE_BOUNCE;
 492     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health);
 493     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield);
 494
 495     if(self.owner.flagcarried)
 496        setorigin(self.owner.flagcarried, '-190 0 96');
 497 }
 498
 499 void racer_exit(float eject)
 500 {
 501     vector spot;
 502
 503     self.think      = racer_think;
 504     self.nextthink  = time;
 505     self.movetype   = MOVETYPE_TOSS;
 506     sound (self, CHAN_PAIN, "misc/null.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 507
 508     if not (self.owner)
 509         return;
 510
 511         makevectors(self.angles);
 512         if(eject)
 513         {
 514             spot = self.origin + v_forward * 100 + '0 0 64';
 515             spot = vehicles_findgoodexit(spot);
 516             setorigin(self.owner , spot);
 517             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 518         }
 519         else
 520         {
 521             spot = self.origin - v_forward * 200 + '0 0 64';
 522             spot = vehicles_findgoodexit(spot);
 523             setorigin(self.owner , spot);
 524         }
 525
 526     self.owner = world;
 527 }
 528
 529 void racer_spawn()
 530 {
 531     self.think          = racer_think;
 532     self.nextthink      = time;
 533     self.vehicle_health = autocvar_g_vehicle_racer_health;
 534     self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 535
 536     self.movetype       = MOVETYPE_TOSS;
 537     self.solid          = SOLID_SLIDEBOX;
 538     self.delay          = time;
 539     self.scale          = 0.5;
 540
 541     setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
 542 }
 543
 544
 545 void racer_blowup()
 546 {
 547     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 548     pointparticles(particleeffectnum("explosion_big"), self.origin, '0 0 0', 1);
 549
 550     self.deadflag    = DEAD_DEAD;
 551     self.vehicle_exit(VHEF_NORMAL);
 552
 553     RadiusDamage (self, self, autocvar_g_vehicle_racer_blowup_coredamage,
 554                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 555                                         autocvar_g_vehicle_racer_blowup_radius, world,
 556                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 557                                         DEATH_WAKIBLOWUP, world);
 558
 559     self.alpha = -1;
 560     self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 561     self.think      = racer_spawn;
 562     self.movetype   = MOVETYPE_NONE;
 563     self.effects    = EF_NODRAW;
 564
 565     self.colormod  = '0 0 0';
 566     self.avelocity = '0 0 0';
 567     self.velocity  = '0 0 0';
 568
 569     setorigin(self, self.pos1);
 570         self.think     = racer_spawn;
 571         self.nextthink = time + autocvar_g_vehicle_racer_respawntime;
 572 }
 573
 574 void racer_deadtouch()
 575 {
 576     dprint("Boink!\n");
 577     self.avelocity_x *= 0.7;
 578     self.cnt -= 1;
 579     if(self.cnt <= 0)
 580         racer_blowup();
 581 }
 582
 583 void racer_die()
 584 {
 585     self.health       = 0;
 586     self.event_damage = SUB_Null;
 587     self.iscreature   = FALSE;
 588     self.solid        = SOLID_CORPSE;
 589     self.takedamage   = DAMAGE_NO;
 590     self.deadflag     = DEAD_DYING;
 591     self.movetype     = MOVETYPE_BOUNCE;
 592     self.wait         = time;
 593     self.cnt          = 1 + random() * 2;
 594     self.touch        = racer_deadtouch;
 595
 596     pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 597
 598     if(random() < 0.5)
 599         self.avelocity_z  = 32;
 600     else
 601         self.avelocity_z  = -32;
 602
 603     self.avelocity_x = -vlen(self.velocity) * 0.2;
 604     self.velocity   += '0 0 700';
 605     self.colormod    = '-0.5 -0.5 -0.5';
 606
 607         self.think     = racer_blowup;
 608         self.nextthink = 2 + time + random() * 3;
 609 }
 610
 611 void racer_dinit()
 612 {
 613     if not (vehicle_initialize(
 614              "Wakizashi",
 615              "models/vehicles/wakizashi.dpm",
 616              "",
 617              "models/vehicles/wakizashi_cockpit.dpm",
 618              "", "", "tag_viewport",
 619              HUD_WAKIZASHI,
 620              0.5 * RACER_MIN, 0.5 * RACER_MAX,
 621              FALSE,
 622              racer_spawn, autocvar_g_vehicle_racer_respawntime,
 623              racer_frame,
 624              racer_enter, racer_exit,
 625              racer_die,   racer_think,
 626              TRUE))
 627     {
 628         remove(self);
 629         return;
 630     }
 631
 632     if(autocvar_g_vehicle_racer_hovertype != 0)
 633         racer_force_from_tag = vehicles_force_fromtag_maglev;
 634     else
 635         racer_force_from_tag = vehicles_force_fromtag_hover;
 636
 637     // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 638     self.scale = 0.5;
 639     setattachment(self.vehicle_hudmodel, self, "");
 640     setattachment(self.vehicle_viewport, self, "tag_viewport");
 641
 642     self.mass               = 900;
 643 }
 644
 645 void spawnfunc_vehicle_racer()
 646 {
 647     self.vehicle_flags |= VHF_DMGSHAKE;
 648     self.vehicle_flags |= VHF_DMGROLL;
 649
 650     precache_sound ("weapons/laserimpact.wav");
 651     precache_sound ("weapons/lasergun_fire.wav");
 652     precache_sound ("weapons/rocket_fire.wav");
 653     precache_sound ("weapons/rocket_impact.wav");
 654
 655     precache_sound ("vehicles/racer_idle.wav");
 656     precache_sound ("vehicles/racer_move.wav");
 657     precache_sound ("vehicles/racer_boost.wav");
 658
 659     precache_model ("models/vhshield.md3");
 660     precache_model ("models/vehicles/wakizashi.dpm");
 661     precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 662
 663     vehicles_configcheck("vehicle_racer.cfg", autocvar_g_vehicle_racer_health);
 664     if(autocvar_g_vehicle_racer_energy)
 665         if(autocvar_g_vehicle_racer_energy_regen)
 666             self.vehicle_flags |= VHF_ENERGYREGEN;
 667
 668     if(autocvar_g_vehicle_racer_shield)
 669         self.vehicle_flags |= VHF_HASSHIELD;
 670
 671     if(autocvar_g_vehicle_racer_shield_regen)
 672         self.vehicle_flags |= VHF_SHIELDREGEN;
 673
 674     if(autocvar_g_vehicle_racer_health_regen)
 675         self.vehicle_flags |= VHF_HEALTHREGEN;
 676
 677     self.think = racer_dinit;
 678     self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_racer_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 679 }
 680 #endif // SVQC