qcsrc/server/vehicles/raptor.qc

   1 #define RAPTOR_MIN '-80 -80 0'
   2 #define RAPTOR_MAX '80 80 70'
   3
   4 float autocvar_g_vehicle_raptor_respawntime;
   5
   6 float autocvar_g_vehicle_raptor_movestyle;
   7 float autocvar_g_vehicle_raptor_turnspeed;
   8 float autocvar_g_vehicle_raptor_pitchspeed;
   9 float autocvar_g_vehicle_raptor_pitchlimit;
  10
  11 float autocvar_g_vehicle_raptor_speed_forward;
  12 float autocvar_g_vehicle_raptor_speed_strafe;
  13 float autocvar_g_vehicle_raptor_speed_up;
  14 float autocvar_g_vehicle_raptor_speed_down;
  15 float autocvar_g_vehicle_raptor_friction;
  16
  17 float autocvar_g_vehicle_raptor_bomblets;
  18 float autocvar_g_vehicle_raptor_bomblet_alt;
  19 float autocvar_g_vehicle_raptor_bomblet_time;
  20 float autocvar_g_vehicle_raptor_bomblet_damage;
  21 float autocvar_g_vehicle_raptor_bomblet_spread;
  22 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  23 float autocvar_g_vehicle_raptor_bomblet_radius;
  24 float autocvar_g_vehicle_raptor_bomblet_force;
  25 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  26 float autocvar_g_vehicle_raptor_bombs_refire;
  27
  28 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  29 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  30 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  32
  33 float autocvar_g_vehicle_raptor_cannon_locktarget;
  34 float autocvar_g_vehicle_raptor_cannon_locking_time;
  35 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  36 float autocvar_g_vehicle_raptor_cannon_locked_time;
  37 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  38
  39 float autocvar_g_vehicle_raptor_cannon_cost;
  40 float autocvar_g_vehicle_raptor_cannon_damage;
  41 float autocvar_g_vehicle_raptor_cannon_radius;
  42 float autocvar_g_vehicle_raptor_cannon_refire;
  43 float autocvar_g_vehicle_raptor_cannon_speed;
  44 float autocvar_g_vehicle_raptor_cannon_spread;
  45 float autocvar_g_vehicle_raptor_cannon_force;
  46
  47 float autocvar_g_vehicle_raptor_energy;
  48 float autocvar_g_vehicle_raptor_energy_regen;
  49 float autocvar_g_vehicle_raptor_energy_regen_pause;
  50
  51 float autocvar_g_vehicle_raptor_health;
  52 float autocvar_g_vehicle_raptor_health_regen;
  53 float autocvar_g_vehicle_raptor_health_regen_pause;
  54
  55 float autocvar_g_vehicle_raptor_shield;
  56 float autocvar_g_vehicle_raptor_shield_regen;
  57 float autocvar_g_vehicle_raptor_shield_regen_pause;
  58
  59 void raptor_spawn();
  60 float raptor_frame();
  61 float raptor_takeoff();
  62
  63 .entity bomb1;
  64 .entity bomb2;
  65
  66 //#define RAPTOR_RETARDCAMERA
  67
  68 float raptor_altitude(float amax)
  69 {
  70         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  71     return vlen(self.origin - trace_endpos);
  72 }
  73
  74
  75 void raptor_bomblet_boom()
  76 {
  77     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
  78     pointparticles(particleeffectnum("raptor_bomb_impact"), self.origin, trace_plane_normal * 1000, 1);
  79     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  80                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  81                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  82                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_SBROCKET, world);
  83     remove(self);
  84 }
  85
  86 void raptor_bomblet_touch()
  87 {
  88     if(other == self.owner)
  89         return;
  90
  91     PROJECTILE_TOUCH;
  92     self.think = raptor_bomblet_boom;
  93     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  94 }
  95
  96 void raptor_bomb_burst()
  97 {
  98     if(self.cnt > time)
  99     if(autocvar_g_vehicle_raptor_bomblet_alt)
 100     {
 101         self.nextthink = time;
 102         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 103         if(trace_fraction == 1.0)
 104             return;
 105
 106         if(vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius)
 107             return;
 108     }
 109
 110     entity bomblet;
 111     float i;
 112
 113     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 114     pointparticles(particleeffectnum("rocket_explode"), self.origin, self.velocity, 1);
 115
 116     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 117     {
 118         bomblet = spawn();
 119         setorigin(bomblet, self.origin);
 120
 121         //bomblet.solid       = SOLID_TRIGGER;
 122         bomblet.movetype    = MOVETYPE_TOSS;
 123         bomblet.touch       = raptor_bomblet_touch;
 124         bomblet.think       = raptor_bomblet_boom;
 125         bomblet.nextthink   = time + 5;
 126         bomblet.owner       = self.owner;
 127         bomblet.realowner   = self.realowner;
 128         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 129         PROJECTILE_MAKETRIGGER(bomblet);
 130         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 131     }
 132
 133     remove(self);
 134 }
 135
 136 void raptor_bomb_touch()
 137 {
 138     raptor_bomb_burst();
 139 }
 140
 141 void raptor_bombdrop()
 142 {
 143     entity bomb_1, bomb_2;
 144
 145     //self.bomb1.alpha = 0;
 146     //self.bomb2.alpha = 0;
 147
 148     bomb_1 = spawn();
 149     bomb_2 = spawn();
 150
 151     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 152     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 153
 154     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_TOSS;
 155     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 156     bomb_1.touch        = bomb_2.touch      = raptor_bomb_touch;
 157     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 158     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 159
 160     if(autocvar_g_vehicle_raptor_bomblet_alt)
 161         bomb_1.nextthink = bomb_2.nextthink  = time;
 162     else
 163         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 164
 165     bomb_1.owner     = bomb_2.owner      = self;
 166     bomb_1.realowner = bomb_2.realowner  = self.owner;
 167     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 168     bomb_1.gravity   = bomb_2.gravity    = 1;
 169
 170     PROJECTILE_MAKETRIGGER(bomb_1);
 171     PROJECTILE_MAKETRIGGER(bomb_2);
 172
 173     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 174     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 175
 176 }
 177
 178
 179 void raptor_fire_cannon(entity gun, string tagname)
 180 {
 181     entity bolt;
 182     vector b_org;
 183     b_org = gettaginfo(gun, gettagindex(gun, tagname));
 184     bolt = vehicles_projectile("raptor_cannon_impact", "weapons/laserimpact.wav", "raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 185                            b_org, normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 186                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 187                            DEATH_WAKIGUN, PROJECTILE_RAPTORCANNON, 0);
 188 }
 189
 190 void raptor_think()
 191 {
 192 }
 193
 194 void raptor_enter()
 195 {
 196     self.owner.PlayerPhysplug = raptor_takeoff;
 197     self.movetype       = MOVETYPE_FLY;
 198     self.solid          = SOLID_BBOX;
 199     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 200     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 201     self.velocity_z = 1;
 202
 203 #ifdef RAPTOR_RETARDCAMERA
 204     setorigin(self.vehicle_viewport, self.origin);
 205 #endif
 206 }
 207
 208 void raptor_land()
 209 {
 210     float hgt;
 211
 212     hgt = raptor_altitude(512);
 213     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 214     self.angles_x *= 0.95;
 215     self.angles_z *= 0.95;
 216
 217     if(hgt < 128)
 218         if(self.frame != 0)
 219             self.frame = max(self.frame - 0.25, 0);
 220
 221     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 222     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 223
 224     if(hgt < 16)
 225     {
 226         self.movetype   = MOVETYPE_TOSS;
 227         self.think      = raptor_think;
 228     }
 229
 230     self.nextthink  = time;
 231 }
 232
 233 void raptor_exit(float eject)
 234 {
 235
 236     if(self.deadflag == DEAD_NO)
 237     {
 238         self.think      = raptor_land;
 239         self.nextthink  = time;
 240     }
 241
 242     if not (self.owner)
 243         return;
 244
 245         makevectors(self.angles);
 246         if(eject)
 247         {
 248             setorigin(self.owner,self.origin + v_forward * 100 + '0 0 64');
 249             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 250         }
 251         else
 252         setorigin(self.owner,self.origin - v_forward * 200 + '0 0 64');
 253
 254     self.owner = world;
 255 }
 256
 257 float raptor_takeoff()
 258 {
 259     entity player, raptor;
 260
 261     player = self;
 262     raptor = self.vehicle;
 263     self   = raptor;
 264
 265     // Takeoff sequense
 266     if(raptor.frame < 25)
 267     {
 268         raptor.frame += 0.25;
 269         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 270         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 271         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 272         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 273
 274         setorigin(player, raptor.origin + '0 0 32');
 275     }
 276     else
 277         player.PlayerPhysplug = raptor_frame;
 278
 279     self = player;
 280     return 1;
 281 }
 282
 283 float raptor_frame()
 284 {
 285     entity player, raptor;
 286     float ftmp, ftmp2;
 287     vector df;
 288
 289     player = self;
 290     raptor = self.vehicle;
 291     self   = raptor;
 292
 293     if(player.BUTTON_USE && raptor.deadflag == DEAD_NO)
 294     {
 295         self = raptor;
 296         vehicles_exit(VHEF_NORMAL);
 297         self = player;
 298         return 0;
 299     }
 300
 301     if(raptor.deadflag != DEAD_NO)
 302     {
 303         self = player;
 304         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 305         return 1;
 306     }
 307
 308
 309
 310     crosshair_trace(player);
 311
 312 #if VEHICLES_VIEWROTATE_CROSSHAIR
 313     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 314     if(df_x > 180)  df_x -= 360;
 315     if(df_x < -180) df_x += 360;
 316     if(df_y > 180)  df_y -= 360;
 317     if(df_y < -180) df_y += 360;
 318
 319     // Rotate Body
 320     ftmp = autocvar_g_vehicle_raptor_turnspeed * sys_frametime;
 321     ftmp = bound(-ftmp, shortangle_f(df_y - raptor.angles_y, raptor.angles_y), ftmp);
 322
 323     // Turn
 324     //raptor.angles_y = anglemods(raptor.angles_y + ftmp);
 325     raptor.avelocity_y = anglemods(raptor.angles_y + ftmp);
 326
 327     // Pitch Body
 328     ftmp = autocvar_g_vehicle_raptor_pitchspeed  * sys_frametime;
 329     ftmp = bound(-ftmp, shortangle_f(df_x - raptor.angles_x, raptor.angles_x), ftmp);
 330
 331     //raptor.angles_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 332     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 333 #else
 334     vector vang;
 335     vang = raptor.angles;
 336     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 337     vang_x *= -1;
 338     df_x *= -1;
 339     if(df_x > 180)  df_x -= 360;
 340     if(df_x < -180) df_x += 360;
 341     if(df_y > 180)  df_y -= 360;
 342     if(df_y < -180) df_y += 360;
 343
 344     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 345     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 346     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 347
 348     // Pitch
 349     ftmp = 0;
 350     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 351     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 352
 353     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 354     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 355     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 356
 357     raptor.angles_x = anglemods(raptor.angles_x);
 358     raptor.angles_y = anglemods(raptor.angles_y);
 359     raptor.angles_z = anglemods(raptor.angles_z);
 360
 361 #endif
 362
 363     if(autocvar_g_vehicle_raptor_movestyle == 1)
 364         makevectors('0 1 0' * raptor.angles_y);
 365     else
 366         makevectors(player.v_angle);
 367
 368 #ifdef RAPTOR_RETARDCAMERA
 369     float spd, back, up;
 370     spd = vlen(self.velocity) + 0.01;
 371     back = spd / autocvar_g_vehicle_raptor_speed_forward;
 372     up = 1 - back;
 373     back = back;
 374     back = back * 1250;
 375     back += 150;
 376     up = up * 200;
 377     up = up + 100;
 378
 379     setorigin(self.vehicle_viewport, self.origin + (v_up * up) + (v_forward * -back));
 380 #endif
 381
 382     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 383
 384     if(player.movement_x != 0)
 385     {
 386         if(player.movement_x > 0)
 387             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 388         else if(player.movement_x < 0)
 389             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 390     }
 391
 392     if(player.movement_y != 0)
 393     {
 394         if(player.movement_y < 0)
 395             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 396         else if(player.movement_y > 0)
 397             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 398
 399         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 400     }
 401     else
 402     {
 403         raptor.angles_z *= 0.95;
 404         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 405             raptor.angles_z = 0;
 406     }
 407
 408     if(player.BUTTON_CROUCH)
 409         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 410     else if (player.BUTTON_JUMP)
 411         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 412
 413     raptor.velocity  += df * frametime;
 414     player.velocity = player.movement  = raptor.velocity;
 415     setorigin(player,raptor.origin + '0 0 32');
 416
 417     vector vf, ad;
 418     // Target lock & predict
 419     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 420     {
 421
 422         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 423                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 424                              autocvar_g_vehicle_raptor_cannon_locked_time);
 425
 426         if(self.lock_target != world)
 427         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 428         if(self.lock_strength == 1)
 429         {
 430             float i, distance, impact_time;
 431
 432             vf = real_origin(raptor.lock_target);
 433             ad = vf;
 434             for(i = 0; i < 4; ++i)
 435             {
 436                 distance = vlen(ad - raptor.origin);
 437                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 438                 ad = vf + raptor.lock_target.velocity * impact_time;
 439             }
 440             trace_endpos = ad;
 441             //UpdateAuxiliaryXhair(player, trace_endpos, '1 1 1', 0);
 442         }
 443
 444         if(self.lock_target)
 445         {
 446             if(raptor.lock_strength == 1)
 447                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 448             else if(self.lock_strength > 0.5)
 449                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 450             else if(self.lock_strength < 0.5)
 451                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 452         }
 453     }
 454
 455     // Aim the gunz
 456     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 457     ftmp = -ftmp2;
 458
 459     // Gun1
 460     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 461     //ad = df;
 462     //vf = v_forward;
 463     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 464     df = shortangle_vxy(df - (raptor.angles + raptor.gun1.angles), raptor.angles + raptor.gun1.angles);     // Find aim offset
 465     // Bind to aimspeed
 466     df_x = bound(ftmp, df_x, ftmp2);
 467     df_y = bound(ftmp, df_y, ftmp2);
 468     // Bind to limts
 469     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 470     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 471
 472     //df = vectoangles(normalize(trace_endpos - df));
 473
 474     //Gun 2
 475     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 476     //ad += df;
 477     //vf += v_forward;
 478     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 479     df = shortangle_vxy(df - (raptor.angles + raptor.gun2.angles), raptor.angles + raptor.gun2.angles);     // Find aim offset
 480     // Bind to aimspeed
 481     df_x = bound(ftmp, df_x, ftmp2);
 482     df_y = bound(ftmp, df_y, ftmp2);
 483     // Bind to limts
 484     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 485     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 486
 487     /*
 488     ad = ad * 0.5;
 489     v_forward = vf * 0.5;
 490     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 491     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 492     */
 493
 494     if(player.BUTTON_ATCK)
 495     if(raptor.attack_finished_single <= time)
 496     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 497     {
 498         raptor.misc_bulletcounter += 1;
 499         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 500         if(raptor.misc_bulletcounter <= 2)
 501             raptor_fire_cannon(self.gun1, "fire1");
 502         else if(raptor.misc_bulletcounter == 3)
 503             raptor_fire_cannon(self.gun2, "fire1");
 504         else
 505         {
 506             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 507             raptor_fire_cannon(self.gun2, "fire1");
 508             raptor.misc_bulletcounter = 0;
 509         }
 510         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 511         self.cnt = time;
 512     }
 513
 514     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 515         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 516
 517     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 518         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 519
 520     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 521         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 522
 523
 524     if(time > raptor.delay)
 525     if(player.BUTTON_ATCK2)
 526     {
 527         raptor_bombdrop();
 528         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 529         raptor.lip   = time;
 530     }
 531
 532     player.vehicle_reload1 = (time - raptor.lip) / (raptor.delay - raptor.lip);
 533     raptor.bomb1.alpha = raptor.bomb2.alpha = player.vehicle_reload1;
 534
 535     VEHICLE_UPDATE_PLAYER(health, raptor);
 536     VEHICLE_UPDATE_PLAYER(energy, raptor);
 537     if(self.vehicle_flags & VHF_HASSHIELD)
 538         VEHICLE_UPDATE_PLAYER(shield, raptor);
 539
 540
 541
 542     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 543     return 1;
 544 }
 545
 546 void raptor_blowup()
 547 {
 548     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 549     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 550
 551     self.deadflag    = DEAD_DEAD;
 552     self.vehicle_exit(VHEF_NORMAL);
 553     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 554
 555     self.alpha          = -1;
 556     self.movetype       = MOVETYPE_NONE;
 557     self.effects        = EF_NODRAW;
 558     self.colormod       = '0 0 0';
 559     self.avelocity      = '0 0 0';
 560     self.velocity       = '0 0 0';
 561
 562     setorigin(self, self.pos1);
 563     self.touch = SUB_Null;
 564 }
 565
 566 void raptor_die()
 567 {
 568     self.health       = 0;
 569     self.event_damage = SUB_Null;
 570     self.iscreature   = FALSE;
 571     self.solid        = SOLID_CORPSE;
 572     self.takedamage   = DAMAGE_NO;
 573     self.deadflag     = DEAD_DYING;
 574     self.movetype     = MOVETYPE_BOUNCE;
 575
 576     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 577
 578     self.velocity_z += 128;
 579
 580     if(random() < 0.5)
 581         self.avelocity_z  = 45 + random() * 270;
 582     else
 583         self.avelocity_z  = -45 + random() * -270;
 584
 585     self.colormod = '-0.5 -0.5 -0.5';
 586         self.touch     = raptor_blowup;
 587 }
 588
 589 void raptor_spawn()
 590 {
 591     self.frame          = 0;
 592     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 593     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 594     self.movetype       = MOVETYPE_TOSS;
 595     self.solid          = SOLID_BBOX;
 596     self.vehicle_energy = 1;
 597
 598     self.bomb1.gun1.avelocity_y = 90;
 599     self.bomb1.gun2.avelocity_y = -90;
 600
 601     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 602     self.delay = time;
 603 }
 604
 605 void raptor_dinit()
 606 {
 607     entity spinner;
 608     vector ofs;
 609
 610     if not (vehicle_initialize(
 611              "Raptor",
 612              "models/vehicles/raptor.dpm",
 613              "",
 614              "models/vehicles/raptor_cockpit.dpm",
 615              "", "tag_hud", "tag_camera",
 616              HUD_RAPTOR,
 617              RAPTOR_MIN, RAPTOR_MAX,
 618              FALSE,
 619              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 620              raptor_frame,
 621              raptor_enter, raptor_exit,
 622              raptor_die,   raptor_think))
 623     {
 624         remove(self);
 625         return;
 626     }
 627     //FIXME: Camera is in a bad place in HUD model.
 628     setorigin(self.vehicle_viewport, '25 0 5');
 629
 630     self.frame = 0;
 631
 632     self.bomb1 = spawn();
 633     self.bomb2 = spawn();
 634     self.gun1  = spawn();
 635     self.gun2  = spawn();
 636
 637 #ifdef RAPTOR_RETARDCAMERA
 638     setattachment(self.vehicle_viewport, world, "");
 639 #endif
 640
 641     setmodel(self.bomb1,"models/vehicles/clusterbomb.md3");
 642     setmodel(self.bomb2,"models/vehicles/clusterbomb.md3");
 643     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 644     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 645
 646     setattachment(self.bomb1, self,"bombmount_left");
 647     setattachment(self.bomb2, self,"bombmount_right");
 648
 649
 650     // FIXME Guns mounts to angled bones
 651     self.bomb1.angles = self.angles;
 652     self.angles = '0 0 0';
 653     // This messes up gun-aim, so work arround it.
 654     //setattachment(self.gun1, self, "gunmount_left");
 655     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 656     ofs -= self.origin;
 657     setattachment(self.gun1, self, "");
 658     setorigin(self.gun1, ofs);
 659
 660     //setattachment(self.gun2, self, "gunmount_right");
 661     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 662     ofs -= self.origin;
 663     setattachment(self.gun2, self, "");
 664     setorigin(self.gun2, ofs);
 665
 666     self.angles = self.bomb1.angles;
 667     self.bomb1.angles = '0 0 0';
 668
 669
 670     spinner = spawn();
 671     spinner.owner = self;
 672     setmodel(spinner,"models/vehicles/spinner.dpm");
 673     setattachment(spinner, self, "engine_left");
 674     spinner.movetype = MOVETYPE_NOCLIP;
 675     spinner.avelocity = '0 90 0';
 676     self.bomb1.gun1 = spinner;
 677
 678     spinner = spawn();
 679     spinner.owner = self;
 680     setmodel(spinner,"models/vehicles/spinner.dpm");
 681     setattachment(spinner, self, "engine_right");
 682     spinner.movetype = MOVETYPE_NOCLIP;
 683     spinner.avelocity = '0 -90 0';
 684     self.bomb1.gun2 = spinner;
 685
 686     self.mass               = 1 ;
 687 }
 688
 689 void spawnfunc_vehicle_raptor()
 690 {
 691     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 692
 693     if(autocvar_g_vehicle_raptor_shield)
 694         self.vehicle_flags |= VHF_HASSHIELD;
 695
 696     if(autocvar_g_vehicle_raptor_shield_regen)
 697         self.vehicle_flags |= VHF_SHIELDREGEN;
 698
 699     if(autocvar_g_vehicle_raptor_health_regen)
 700         self.vehicle_flags |= VHF_HEALTHREGEN;
 701
 702     if(autocvar_g_vehicle_raptor_energy_regen)
 703         self.vehicle_flags |= VHF_ENERGYREGEN;
 704
 705     precache_model ("models/vehicles/raptor.dpm");
 706     precache_model ("models/vehicles/raptor_gun.dpm");
 707     precache_model ("models/vehicles/spinner.dpm");
 708     precache_model ("models/vehicles/raptor_cockpit.dpm");
 709     precache_model ("models/vehicles/clusterbomb.md3");
 710
 711     self.think = raptor_dinit;
 712     self.nextthink = time + 1;
 713 }