qcsrc/server/vehicles/raptor.qc

   1 #define RAPTOR_MIN '-80 -80 0'
   2 #define RAPTOR_MAX '80 80 70'
   3
   4 float autocvar_g_vehicle_raptor_respawntime;
   5
   6 float autocvar_g_vehicle_raptor_movestyle;
   7 float autocvar_g_vehicle_raptor_turnspeed;
   8 float autocvar_g_vehicle_raptor_pitchspeed;
   9 float autocvar_g_vehicle_raptor_pitchlimit;
  10
  11 float autocvar_g_vehicle_raptor_speed_forward;
  12 float autocvar_g_vehicle_raptor_speed_strafe;
  13 float autocvar_g_vehicle_raptor_speed_up;
  14 float autocvar_g_vehicle_raptor_speed_down;
  15 float autocvar_g_vehicle_raptor_friction;
  16
  17 float autocvar_g_vehicle_raptor_bomblets;
  18 float autocvar_g_vehicle_raptor_bomblet_alt;
  19 float autocvar_g_vehicle_raptor_bomblet_time;
  20 float autocvar_g_vehicle_raptor_bomblet_damage;
  21 float autocvar_g_vehicle_raptor_bomblet_spread;
  22 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  23 float autocvar_g_vehicle_raptor_bomblet_radius;
  24 float autocvar_g_vehicle_raptor_bomblet_force;
  25 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  26 float autocvar_g_vehicle_raptor_bombs_refire;
  27
  28 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  29 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  30 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  32
  33 float autocvar_g_vehicle_raptor_cannon_locktarget;
  34 float autocvar_g_vehicle_raptor_cannon_locking_time;
  35 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  36 float autocvar_g_vehicle_raptor_cannon_locked_time;
  37 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  38
  39 float autocvar_g_vehicle_raptor_cannon_cost;
  40 float autocvar_g_vehicle_raptor_cannon_damage;
  41 float autocvar_g_vehicle_raptor_cannon_radius;
  42 float autocvar_g_vehicle_raptor_cannon_refire;
  43 float autocvar_g_vehicle_raptor_cannon_speed;
  44 float autocvar_g_vehicle_raptor_cannon_spread;
  45
  46
  47 float autocvar_g_vehicle_raptor_energy;
  48 float autocvar_g_vehicle_raptor_energy_regen;
  49 float autocvar_g_vehicle_raptor_energy_regen_pause;
  50
  51 float autocvar_g_vehicle_raptor_health;
  52 float autocvar_g_vehicle_raptor_health_regen;
  53 float autocvar_g_vehicle_raptor_health_regen_pause;
  54
  55 float autocvar_g_vehicle_raptor_shield;
  56 float autocvar_g_vehicle_raptor_shield_regen;
  57 float autocvar_g_vehicle_raptor_shield_regen_pause;
  58
  59 void raptor_spawn();
  60 //void raptor_return();
  61 float raptor_frame();
  62 //float raptor_takeoff();
  63
  64 .entity bomb1;
  65 .entity bomb2;
  66 //.entity camera;
  67 //#define RAPTOR_RETARDCAMERA
  68
  69 float raptor_altitude(float amax)
  70 {
  71         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  72     return vlen(self.origin - trace_endpos);
  73 }
  74
  75
  76 void raptor_bomblet_boom()
  77 {
  78     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
  79     pointparticles(particleeffectnum("raptor_bomb_impact"), self.origin, trace_plane_normal * 1000, 1);
  80     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  81                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  82                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  83                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_SBROCKET, world);
  84     remove(self);
  85 }
  86
  87 void raptor_bomblet_touch()
  88 {
  89     if(other == self.owner)
  90         return;
  91
  92     PROJECTILE_TOUCH;
  93     self.think = raptor_bomblet_boom;
  94     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  95 }
  96
  97 void raptor_bomb_burst()
  98 {
  99     if(self.cnt > time)
 100     if(autocvar_g_vehicle_raptor_bomblet_alt)
 101     {
 102         self.nextthink = time;
 103         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 104         if(trace_fraction == 1.0)
 105             return;
 106
 107         if(vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius)
 108             return;
 109     }
 110
 111     entity bomblet;
 112     float i;
 113
 114     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 115     pointparticles(particleeffectnum("rocket_explode"), self.origin, self.velocity, 1);
 116
 117     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 118     {
 119         bomblet = spawn();
 120         setorigin(bomblet, self.origin);
 121
 122         bomblet.scale       = 0.5;
 123         bomblet.solid       = SOLID_TRIGGER;
 124         bomblet.movetype    = MOVETYPE_TOSS;
 125         bomblet.touch       = raptor_bomblet_touch;
 126         bomblet.think       = raptor_bomblet_boom;
 127         bomblet.nextthink   = time + 5;
 128         bomblet.owner   = self.owner;
 129         bomblet.realowner   = self.realowner;
 130         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 131         PROJECTILE_MAKETRIGGER(bomblet);
 132         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 133     }
 134
 135     remove(self);
 136 }
 137
 138 void raptor_bomb_touch()
 139 {
 140     raptor_bomb_burst();
 141 }
 142
 143 void raptor_bombdrop()
 144 {
 145     entity bomb_1, bomb_2;
 146
 147     //self.bomb1.alpha = 0;
 148     //self.bomb2.alpha = 0;
 149
 150     bomb_1 = spawn();
 151     bomb_2 = spawn();
 152
 153     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 154     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 155
 156     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_TOSS;
 157     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 158     bomb_1.touch        = bomb_2.touch      = raptor_bomb_touch;
 159     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 160     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 161
 162     if(autocvar_g_vehicle_raptor_bomblet_alt)
 163         bomb_1.nextthink = bomb_2.nextthink  = time;
 164     else
 165         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 166
 167     bomb_1.owner     = bomb_2.owner      = self;
 168     bomb_1.realowner = bomb_2.realowner  = self.owner;
 169     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 170
 171     PROJECTILE_MAKETRIGGER(bomb_1);
 172     PROJECTILE_MAKETRIGGER(bomb_2);
 173
 174     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 175     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 176
 177 }
 178
 179 void raptor_bolt_explode()
 180 {
 181         PROJECTILE_TOUCH;
 182     pointparticles(particleeffectnum("raptor_cannon_impact"), findbetterlocation (self.origin, 8), trace_plane_normal * 1000, 1);
 183     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_cannon_damage, 0, autocvar_g_vehicle_raptor_cannon_radius, world, 25, DEATH_WAKIGUN, world);
 184     sound (self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 185     remove (self);
 186 }
 187
 188 void raptor_fire_cannon(entity gun, string tagname)
 189 {
 190     entity bolt;
 191
 192     bolt = spawn();
 193
 194     PROJECTILE_MAKETRIGGER(bolt);
 195     sound (gun, CHAN_WEAPON, "weapons/lasergun_fire.wav", VOL_BASE, ATTN_NORM);
 196     setorigin(bolt, gettaginfo(gun, gettagindex(gun, tagname)));
 197
 198     bolt.movetype        = MOVETYPE_FLYMISSILE;
 199     bolt.flags           = FL_PROJECTILE | FL_NOTARGET;
 200     bolt.owner           = self;
 201     bolt.realowner       = self.owner;
 202     bolt.touch           = raptor_bolt_explode;
 203     bolt.think           = raptor_bolt_explode;
 204     bolt.nextthink       = time + 9;
 205     bolt.bot_dodge       = TRUE;
 206     bolt.bot_dodgerating = autocvar_g_vehicle_raptor_cannon_damage;
 207     bolt.velocity        = normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed;
 208
 209     pointparticles(particleeffectnum("raptor_cannon_muzzleflash"), bolt.origin, bolt.velocity, 1);
 210     //pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), bolt.origin, bolt.velocity, 1);
 211
 212     CSQCProjectile(bolt, TRUE, PROJECTILE_CRYLINK, TRUE);
 213 }
 214
 215 void raptor_think()
 216 {
 217 }
 218
 219 void raptor_enter()
 220 {
 221     self.movetype   = MOVETYPE_BOUNCEMISSILE;
 222     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 223     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 224     self.velocity_z = 1;
 225 #ifdef RAPTOR_RETARDCAMERA
 226     setorigin(self.vehicle_viewport, self.origin);
 227 #endif
 228 }
 229
 230 void raptor_land()
 231 {
 232     float hgt;
 233
 234     hgt = raptor_altitude(512);
 235     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 236     self.angles_x *= 0.95;
 237     self.angles_z *= 0.95;
 238
 239     if(hgt < 128)
 240         if(self.frame != 0)
 241             self.frame = max(self.frame - 0.25, 0);
 242
 243     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 244     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 245
 246     if(hgt < 16)
 247     {
 248         self.movetype   = MOVETYPE_BOUNCE;
 249         self.think      = raptor_think;
 250     }
 251
 252     self.nextthink  = time;
 253 }
 254
 255 void raptor_exit(float eject)
 256 {
 257
 258     if(self.deadflag == DEAD_NO)
 259     {
 260         vehicles_setreturn(autocvar_g_vehicle_raptor_respawntime, raptor_spawn);
 261         self.think      = raptor_land;
 262         self.nextthink  = time;
 263     }
 264
 265     if not (self.owner)
 266         return;
 267
 268         makevectors(self.angles);
 269         if(eject)
 270         {
 271             setorigin(self.owner,self.origin + v_forward * 100 + '0 0 64');
 272             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 273         }
 274         else
 275         setorigin(self.owner,self.origin - v_forward * 200 + '0 0 64');
 276
 277     self.owner = world;
 278 }
 279
 280 float raptor_frame()
 281 {
 282     entity player, raptor;
 283     float ftmp, ftmp2;
 284     vector df;
 285
 286     player = self;
 287     raptor   = self.vehicle;
 288     self    = raptor;
 289
 290     if(player.BUTTON_USE)
 291     {
 292         self = raptor;
 293         vehicles_exit(VHEF_NORMAL);
 294         self = player;
 295         return 0;
 296     }
 297
 298     if(raptor.deadflag != DEAD_NO)
 299     {
 300         self = player;
 301         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 302         return 1;
 303     }
 304
 305     // Takeoff sequense
 306     if(raptor.frame < 25)
 307     {
 308         raptor.frame += 0.25;
 309         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 310         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 2000);
 311         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 312         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 313         self = player;
 314         return 1;
 315     }
 316
 317     //collision_run();
 318
 319     crosshair_trace(player);
 320
 321 #if VEHICLES_VIEWROTATE_CROSSHAIR
 322     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 323     if(df_x > 180)  df_x -= 360;
 324     if(df_x < -180) df_x += 360;
 325     if(df_y > 180)  df_y -= 360;
 326     if(df_y < -180) df_y += 360;
 327
 328     // Rotate Body
 329     ftmp = autocvar_g_vehicle_raptor_turnspeed * sys_frametime;
 330     ftmp = bound(-ftmp, shortangle_f(df_y - raptor.angles_y, raptor.angles_y), ftmp);
 331
 332     // Turn
 333     raptor.angles_y = anglemods(raptor.angles_y + ftmp);
 334
 335     // Pitch Body
 336     ftmp = autocvar_g_vehicle_raptor_pitchspeed  * sys_frametime;
 337     ftmp = bound(-ftmp, shortangle_f(df_x - raptor.angles_x, raptor.angles_x), ftmp);
 338
 339     raptor.angles_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 340 #else
 341     raptor.angles_x *= -1;
 342     // Rotate Body
 343     ftmp = autocvar_g_vehicle_raptor_turnspeed * sys_frametime;
 344     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - raptor.angles_y, raptor.angles_y), ftmp);
 345
 346     // Turn
 347     raptor.angles_y = anglemods(raptor.angles_y + ftmp);
 348
 349     // Pitch Body
 350     ftmp = autocvar_g_vehicle_raptor_pitchspeed  * sys_frametime;
 351     ftmp2 = shortangle_f(player.v_angle_x - raptor.angles_x, raptor.angles_x);
 352
 353     if(player.movement_x > 0)
 354         ftmp2 += 20 * ftmp;
 355     else if(player.movement_x < 0)
 356         ftmp2 -= 45 * ftmp;
 357
 358     ftmp = bound(-ftmp, ftmp2, ftmp);
 359     raptor.angles_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 360     raptor.angles_x *= -1;
 361 #endif
 362
 363     if(autocvar_g_vehicle_raptor_movestyle == 1)
 364         fixedmakevectors('0 1 0' * raptor.angles_y);
 365     else
 366         makevectors(player.v_angle);
 367
 368 #ifdef RAPTOR_RETARDCAMERA
 369     float spd, back, up;
 370     spd = vlen(self.velocity) + 0.01;
 371     back = spd / autocvar_g_vehicle_raptor_speed_forward;
 372     up = 1 - back;
 373     back = back;
 374     back = back * 1250;
 375     back += 150;
 376     up = up * 200;
 377     up = up + 100;
 378
 379     setorigin(self.vehicle_viewport, self.origin + (v_up * up) + (v_forward * -back));
 380 #endif
 381
 382     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 383
 384     if(player.movement_x != 0)
 385     {
 386         if(player.movement_x > 0)
 387             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 388         else if(player.movement_x < 0)
 389             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 390     }
 391
 392     if(player.movement_y != 0)
 393     {
 394         if(player.movement_y < 0)
 395             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 396         else if(player.movement_y > 0)
 397             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 398
 399         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 400     }
 401     else
 402     {
 403         raptor.angles_z *= 0.95;
 404         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 405             raptor.angles_z = 0;
 406     }
 407
 408     if(player.BUTTON_CROUCH)
 409         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 410     else if (player.BUTTON_JUMP)
 411         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 412
 413     raptor.velocity  += df * frametime;
 414     player.velocity = player.movement  = raptor.velocity;
 415     setorigin(player,raptor.origin + '0 0 32');
 416
 417     vector vf, ad;
 418     // Target lock & predict
 419     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 420     {
 421
 422         vehicles_locktarget2((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 423                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 424                              autocvar_g_vehicle_raptor_cannon_locked_time);
 425
 426         if(autocvar_g_vehicle_raptor_cannon_predicttarget && self.lock_strength == 1)
 427         {
 428             if(self.lock_target != world)
 429             {
 430                 float i, distance, impact_time;
 431
 432                 vf = real_origin(raptor.lock_target);
 433                 ad = vf;
 434                 for(i = 0; i < 4; ++i)
 435                 {
 436                     distance = vlen(ad - raptor.origin);
 437                     impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 438                     ad = vf + raptor.lock_target.velocity * impact_time;
 439                 }
 440                 trace_endpos = ad;
 441                 UpdateAuxiliaryXhair(player, trace_endpos, '1 1 1', 0);
 442             }
 443         }
 444
 445         if(self.lock_target)
 446         {
 447             if(raptor.lock_strength == 1)
 448                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 449             else if(self.lock_strength > 0.5)
 450                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 451             else if(self.lock_strength < 0.5)
 452                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 453         }
 454
 455         /*
 456         if(self.lock_target != world)
 457         if(self.lock_strength == 1)
 458             UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 1);
 459         else
 460             UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * (1 - self.lock_strength)) + '0 1 0' * self.lock_strength, 1);
 461         */
 462     }
 463
 464     // Aim the gunz
 465     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 466     ftmp = -ftmp2;
 467
 468     // Gun1
 469     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 470     ad = df;
 471     vf = v_forward;
 472     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 473     df = shortangle_vxy(df - (raptor.angles + raptor.gun1.angles), raptor.angles + raptor.gun1.angles);     // Find aim offset
 474     // Bind to aimspeed
 475     df_x = bound(ftmp, df_x, ftmp2);
 476     df_y = bound(ftmp, df_y, ftmp2);
 477     // Bind to limts
 478     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 479     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 480
 481     //df = vectoangles(normalize(trace_endpos - df));
 482
 483     //Gun 2
 484     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 485     ad += df;
 486     vf += v_forward;
 487     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 488     df = shortangle_vxy(df - (raptor.angles + raptor.gun2.angles), raptor.angles + raptor.gun2.angles);     // Find aim offset
 489     // Bind to aimspeed
 490     df_x = bound(ftmp, df_x, ftmp2);
 491     df_y = bound(ftmp, df_y, ftmp2);
 492     // Bind to limts
 493     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 494     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 495
 496
 497     /*
 498     ad = ad * 0.5;
 499     v_forward = vf * 0.5;
 500     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 501     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 502     */
 503
 504     if(player.BUTTON_ATCK)
 505     if(raptor.attack_finished_single <= time)
 506     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 507     {
 508         raptor.misc_bulletcounter += 1;
 509         if(mod(raptor.misc_bulletcounter, 2))
 510             raptor_fire_cannon(self.gun1, "fire1");
 511         else
 512             raptor_fire_cannon(self.gun2, "fire1");
 513
 514         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 515         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 516         self.cnt = time;
 517     }
 518
 519     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 520         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 521
 522     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 523         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 524
 525     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 526         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 527
 528     player.vehicle_energy = raptor.vehicle_energy / autocvar_g_vehicle_raptor_energy;
 529
 530
 531     if(time > raptor.delay)
 532     {
 533         if(player.BUTTON_ATCK2)
 534         {
 535             raptor_bombdrop();
 536             raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 537         }
 538         player.vehicle_reload1 = 1;
 539     }
 540     else
 541     {
 542         player.vehicle_reload1 = min(time / raptor.delay, 1);
 543         //raptor.bomb1.alpha = raptor.bomb2.alpha = player.vehicle_reload1;
 544     }
 545
 546     VEHICLE_UPDATE_PLAYER(health, raptor);
 547
 548     if(self.vehicle_flags & VHF_HASSHIELD)
 549         VEHICLE_UPDATE_PLAYER(shield, raptor);
 550
 551     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 552     return 1;
 553 }
 554
 555 void raptor_touch()
 556 {
 557     vehicles_touch();
 558     if(self.owner)
 559     {
 560         if(vlen(self.velocity) == 0)
 561             return;
 562
 563         if(other.classname != "player")
 564             return;
 565
 566         return;
 567     }
 568
 569     if(other.classname != "player")
 570         return;
 571
 572     if(other.deadflag != DEAD_NO)
 573         return;
 574
 575     if(other.vehicle != world)
 576         return;
 577
 578     vehicles_enter();
 579 }
 580
 581 void raptor_blowup()
 582 {
 583     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 584     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 585
 586     self.deadflag    = DEAD_DEAD;
 587     self.vehicle_exit(VHEF_NORMAL);
 588     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 589
 590     self.alpha          = -1;
 591     self.movetype       = MOVETYPE_NONE;
 592     self.effects        = EF_NODRAW;
 593     self.colormod       = '0 0 0';
 594     self.avelocity      = '0 0 0';
 595     self.velocity       = '0 0 0';
 596
 597     setorigin(self, self.pos1);
 598     self.touch = SUB_Null;
 599 }
 600
 601 void raptor_die()
 602 {
 603     self.health       = 0;
 604     self.event_damage = SUB_Null;
 605     self.iscreature   = FALSE;
 606     self.solid        = SOLID_CORPSE;
 607     self.takedamage   = DAMAGE_NO;
 608     self.deadflag     = DEAD_DYING;
 609     self.movetype     = MOVETYPE_BOUNCE;
 610     //self.wait         = time;
 611
 612     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 613
 614     self.velocity_z += 128;
 615
 616     if(random() < 0.5)
 617         self.avelocity_z  = 45 + random() * 270;
 618     else
 619         self.avelocity_z  = -45 + random() * -270;
 620
 621     self.colormod = '-0.5 -0.5 -0.5';
 622
 623         self.touch     = raptor_blowup;
 624         self.think     = raptor_spawn;
 625         self.nextthink = time + autocvar_g_vehicle_raptor_respawntime;
 626 }
 627
 628 void raptor_spawn()
 629 {
 630     self.flags     = FL_NOTARGET;
 631     self.effects   = 0;
 632
 633     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 634     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 635     self.event_damage   = vehicles_damage;
 636     self.touch          = raptor_touch;
 637     self.iscreature     = TRUE;
 638     self.movetype       = MOVETYPE_FLY;
 639     self.solid          = SOLID_BBOX;
 640     self.takedamage     = DAMAGE_AIM;
 641         self.deadflag       = DEAD_NO;
 642     self.bot_attack     = TRUE;
 643     self.vehicle_energy = 1;
 644     self.vehicle_hudmodel.viewmodelforclient = self;
 645
 646     self.bomb1.gun1.avelocity_y = 90;
 647     self.bomb1.gun2.avelocity_y = -90;
 648     self.frame = 0;
 649
 650     setorigin(self, self.pos1);
 651     self.angles = self.pos2;
 652
 653     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 654     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 655     self.delay = time;
 656
 657     vehicles_reset_colors();
 658 }
 659
 660 void raptor_dinit()
 661 {
 662     entity spinner;
 663     vector ofs;
 664
 665     if not (vehicle_initialize(
 666              "Raptor",
 667              "models/vehicles/raptor.dpm",
 668              "",
 669              "models/vehicles/raptor_cockpit.dpm",
 670              "", "tag_hud", "tag_camera",
 671              HUD_RAPTOR,
 672              RAPTOR_MIN, RAPTOR_MAX,
 673              FALSE,
 674              raptor_spawn, raptor_frame,
 675              raptor_enter, raptor_exit,
 676              raptor_die,   raptor_think))
 677     {
 678         remove(self);
 679         return;
 680     }
 681
 682     //FIXME: Camera is in a bad place in HUD model.
 683     setorigin(self.vehicle_viewport, '5 0 5');
 684
 685     self.frame = 0;
 686
 687     self.bomb1 = spawn();
 688     self.bomb2 = spawn();
 689     self.gun1  = spawn();
 690     self.gun2  = spawn();
 691
 692 #ifdef RAPTOR_RETARDCAMERA
 693     setattachment(self.vehicle_viewport, world, "");
 694 #endif
 695
 696     setmodel(self.bomb1,"models/vehicles/raptor_bomb.dpm");
 697     setmodel(self.bomb2,"models/vehicles/raptor_bomb.dpm");
 698     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 699     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 700
 701     setattachment(self.bomb1, self,"bombmount_left");
 702     setattachment(self.bomb2, self,"bombmount_right");
 703
 704
 705     // FIXME Guns mounts to angled bones
 706     self.bomb1.angles = self.angles;
 707     self.angles = '0 0 0';
 708     // This messes up gun-aim, so work arround it.
 709     //setattachment(self.gun1, self, "gunmount_left");
 710     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 711     ofs -= self.origin;
 712     setattachment(self.gun1, self, "");
 713     setorigin(self.gun1, ofs);
 714
 715     //setattachment(self.gun2, self, "gunmount_right");
 716     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 717     ofs -= self.origin;
 718     setattachment(self.gun2, self, "");
 719     setorigin(self.gun2, ofs);
 720
 721     self.angles = self.bomb1.angles;
 722     self.bomb1.angles = '0 0 0';
 723
 724
 725     spinner = spawn();
 726     spinner.owner = self;
 727     setmodel(spinner,"models/vehicles/spinner.dpm");
 728     setattachment(spinner, self, "engine_left");
 729     spinner.movetype = MOVETYPE_NOCLIP;
 730     spinner.avelocity = '0 90 0';
 731     self.bomb1.gun1 = spinner;
 732
 733     spinner = spawn();
 734     spinner.owner = self;
 735     setmodel(spinner,"models/vehicles/spinner.dpm");
 736     setattachment(spinner, self, "engine_right");
 737     spinner.movetype = MOVETYPE_NOCLIP;
 738     spinner.avelocity = '0 -90 0';
 739     self.bomb1.gun2 = spinner;
 740
 741     self.mass               = 2200;
 742 }
 743
 744 void spawnfunc_vehicle_raptor()
 745 {
 746     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 747
 748     if(autocvar_g_vehicle_raptor_shield)
 749         self.vehicle_flags |= VHF_HASSHIELD;
 750
 751     if(autocvar_g_vehicle_raptor_shield_regen)
 752         self.vehicle_flags |= VHF_SHIELDREGEN;
 753
 754     if(autocvar_g_vehicle_raptor_health_regen)
 755         self.vehicle_flags |= VHF_HEALTHREGEN;
 756
 757     if(autocvar_g_vehicle_raptor_energy_regen)
 758         self.vehicle_flags |= VHF_ENERGYREGEN;
 759
 760     precache_model ("models/vehicles/raptor.dpm");
 761     precache_model ("models/vehicles/raptor_gun.dpm");
 762     precache_model ("models/vehicles/spinner.dpm");
 763     precache_model ("models/vehicles/raptor_cockpit.dpm");
 764     precache_model ("models/vehicles/raptor_bomb.dpm");
 765
 766     self.think = raptor_dinit;
 767     self.nextthink = time + 1;
 768 }