qcsrc/server/vehicles/raptor.qc

   1 #define RSM_FIRST 0
   2 #define RSM_BOMB 0
   3 #define RSM_FLARE 1
   4 #define RSM_LAST 1
   5
   6 #define RAPTOR_MIN '-80 -80 0'
   7 #define RAPTOR_MAX '80 80 70'
   8
   9 #ifdef SVQC
  10 float autocvar_g_vehicle_raptor;
  11
  12 float autocvar_g_vehicle_raptor_respawntime;
  13 float autocvar_g_vehicle_raptor_takeofftime;
  14
  15 float autocvar_g_vehicle_raptor_movestyle;
  16 float autocvar_g_vehicle_raptor_turnspeed;
  17 float autocvar_g_vehicle_raptor_pitchspeed;
  18 float autocvar_g_vehicle_raptor_pitchlimit;
  19
  20 float autocvar_g_vehicle_raptor_speed_forward;
  21 float autocvar_g_vehicle_raptor_speed_strafe;
  22 float autocvar_g_vehicle_raptor_speed_up;
  23 float autocvar_g_vehicle_raptor_speed_down;
  24 float autocvar_g_vehicle_raptor_friction;
  25
  26 float autocvar_g_vehicle_raptor_bomblets;
  27 float autocvar_g_vehicle_raptor_bomblet_alt;
  28 float autocvar_g_vehicle_raptor_bomblet_time;
  29 float autocvar_g_vehicle_raptor_bomblet_damage;
  30 float autocvar_g_vehicle_raptor_bomblet_spread;
  31 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  32 float autocvar_g_vehicle_raptor_bomblet_radius;
  33 float autocvar_g_vehicle_raptor_bomblet_force;
  34 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  35 float autocvar_g_vehicle_raptor_bombs_refire;
  36
  37 float autocvar_g_vehicle_raptor_flare_refire;
  38 float autocvar_g_vehicle_raptor_flare_lifetime;
  39 float autocvar_g_vehicle_raptor_flare_chase;
  40 float autocvar_g_vehicle_raptor_flare_range;
  41
  42 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  43 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  44 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  45 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  46
  47 float autocvar_g_vehicle_raptor_cannon_locktarget;
  48 float autocvar_g_vehicle_raptor_cannon_locking_time;
  49 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  50 float autocvar_g_vehicle_raptor_cannon_locked_time;
  51 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  52
  53 float autocvar_g_vehicle_raptor_cannon_cost;
  54 float autocvar_g_vehicle_raptor_cannon_damage;
  55 float autocvar_g_vehicle_raptor_cannon_radius;
  56 float autocvar_g_vehicle_raptor_cannon_refire;
  57 float autocvar_g_vehicle_raptor_cannon_speed;
  58 float autocvar_g_vehicle_raptor_cannon_spread;
  59 float autocvar_g_vehicle_raptor_cannon_force;
  60
  61 float autocvar_g_vehicle_raptor_energy;
  62 float autocvar_g_vehicle_raptor_energy_regen;
  63 float autocvar_g_vehicle_raptor_energy_regen_pause;
  64
  65 float autocvar_g_vehicle_raptor_health;
  66 float autocvar_g_vehicle_raptor_health_regen;
  67 float autocvar_g_vehicle_raptor_health_regen_pause;
  68
  69 float autocvar_g_vehicle_raptor_shield;
  70 float autocvar_g_vehicle_raptor_shield_regen;
  71 float autocvar_g_vehicle_raptor_shield_regen_pause;
  72
  73 float autocvar_g_vehicle_raptor_bouncefactor;
  74 float autocvar_g_vehicle_raptor_bouncestop;
  75 vector autocvar_g_vehicle_raptor_bouncepain;
  76
  77 void raptor_spawn(float);
  78 float raptor_frame();
  79 float raptor_takeoff();
  80
  81 .entity bomb1;
  82 .entity bomb2;
  83
  84 float raptor_altitude(float amax)
  85 {
  86         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), MOVE_WORLDONLY, self);
  87     return vlen(self.origin - trace_endpos);
  88 }
  89
  90
  91 void raptor_bomblet_boom()
  92 {
  93     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  94                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  95                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  96                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_RAPTOR_BOMB, world);
  97     remove(self);
  98 }
  99
 100 void raptor_bomblet_touch()
 101 {
 102     if(other == self.owner)
 103         return;
 104
 105     PROJECTILE_TOUCH;
 106     self.think = raptor_bomblet_boom;
 107     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
 108 }
 109
 110 void raptor_bomb_burst()
 111 {
 112     if(self.cnt > time)
 113     if(autocvar_g_vehicle_raptor_bomblet_alt)
 114     {
 115         self.nextthink = time;
 116         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 117         if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 118         {
 119             UpdateCSQCProjectile(self);
 120             return;
 121         }
 122     }
 123
 124     entity bomblet;
 125     float i;
 126
 127     Damage_DamageInfo(self.origin, 0, 0, 0, '0 0 0', DEATH_RAPTOR_BOMB_SPLIT, 0, self);
 128
 129     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 130     {
 131         bomblet = spawn();
 132         setorigin(bomblet, self.origin);
 133
 134         bomblet.movetype    = MOVETYPE_TOSS;
 135         bomblet.touch       = raptor_bomblet_touch;
 136         bomblet.think       = raptor_bomblet_boom;
 137         bomblet.nextthink   = time + 5;
 138         bomblet.owner       = self.owner;
 139         bomblet.realowner   = self.realowner;
 140         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 141
 142         PROJECTILE_MAKETRIGGER(bomblet);
 143         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 144     }
 145
 146     remove(self);
 147 }
 148
 149 void raptor_bombdrop()
 150 {
 151     entity bomb_1, bomb_2;
 152
 153     bomb_1 = spawn();
 154     bomb_2 = spawn();
 155
 156     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 157     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 158
 159     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_BOUNCE;
 160     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 161     bomb_1.touch        = bomb_2.touch      = raptor_bomb_burst;
 162     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 163     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 164
 165     if(autocvar_g_vehicle_raptor_bomblet_alt)
 166         bomb_1.nextthink = bomb_2.nextthink  = time;
 167     else
 168         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 169
 170     bomb_1.owner     = bomb_2.owner      = self;
 171     bomb_1.realowner = bomb_2.realowner  = self.owner;
 172     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 173     bomb_1.gravity   = bomb_2.gravity    = 1;
 174
 175     PROJECTILE_MAKETRIGGER(bomb_1);
 176     PROJECTILE_MAKETRIGGER(bomb_2);
 177
 178     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 179     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 180 }
 181
 182
 183 void raptor_fire_cannon(entity gun, string tagname)
 184 {
 185     vehicles_projectile("raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 186                            gettaginfo(gun, gettagindex(gun, tagname)), normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 187                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 188                            DEATH_RAPTOR_CANNON, PROJECTILE_RAPTORCANNON, 0, TRUE, TRUE, self.owner);
 189 }
 190
 191 void raptor_think()
 192 {
 193 }
 194
 195 void raptor_enter()
 196 {
 197     self.owner.PlayerPhysplug = raptor_takeoff;
 198     self.movetype       = MOVETYPE_BOUNCEMISSILE;
 199     self.solid          = SOLID_SLIDEBOX;
 200     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health) * 100;
 201     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield) * 100;
 202     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 203     self.tur_head.exteriormodeltoclient = self.owner;
 204
 205     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 206     self.lip   = time;
 207
 208     if(self.owner.flagcarried)
 209        setorigin(self.owner.flagcarried, '-20 0 96');
 210
 211     CSQCVehicleSetup(self.owner, 0);
 212 }
 213
 214 void raptor_land()
 215 {
 216     float hgt;
 217
 218     hgt = raptor_altitude(512);
 219     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 220     self.angles_x *= 0.95;
 221     self.angles_z *= 0.95;
 222
 223     if(hgt < 128)
 224     if(hgt > 0)
 225         self.frame = (hgt / 128) * 25;
 226
 227     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 228     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 229
 230     if(hgt < 16)
 231     {
 232         self.movetype = MOVETYPE_TOSS;
 233         self.think    = raptor_think;
 234         self.frame    = 0;
 235     }
 236
 237     self.nextthink  = time;
 238 }
 239
 240 void raptor_exit(float eject)
 241 {
 242     vector spot;
 243     self.tur_head.exteriormodeltoclient = world;
 244
 245     if(self.deadflag == DEAD_NO)
 246     {
 247         self.think      = raptor_land;
 248         self.nextthink  = time;
 249     }
 250
 251     if not (self.owner)
 252         return;
 253
 254         makevectors(self.angles);
 255         if(eject)
 256         {
 257             spot = self.origin + v_forward * 100 + '0 0 64';
 258             spot = vehicles_findgoodexit(spot);
 259             setorigin(self.owner , spot);
 260             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 261             self.owner.oldvelocity = self.owner.velocity;
 262         }
 263         else
 264         {
 265             self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed;
 266             self.owner.oldvelocity = self.owner.velocity;
 267             spot = self.origin - v_forward * 200 + '0 0 64';
 268             spot = vehicles_findgoodexit(spot);
 269             setorigin(self.owner , spot);
 270         }
 271         antilag_clear(self.owner);
 272     self.owner = world;
 273 }
 274
 275 float raptor_takeoff()
 276 {
 277     entity player, raptor;
 278
 279     player = self;
 280     raptor = self.vehicle;
 281     self   = raptor;
 282     if(self.sound_nexttime < time)
 283     {
 284         self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 285         sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 286     }
 287
 288     // Takeoff sequense
 289     if(raptor.frame < 25)
 290     {
 291         raptor.frame += 25 / (autocvar_g_vehicle_raptor_takeofftime / sys_frametime);
 292         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 293         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 294         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 295         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 296
 297         setorigin(player, raptor.origin + '0 0 32');
 298     }
 299     else
 300         player.PlayerPhysplug = raptor_frame;
 301
 302     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 303         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, TRUE);
 304
 305     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 306         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, FALSE);
 307
 308     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 309         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, FALSE);
 310
 311
 312     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 313     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 314
 315     VEHICLE_UPDATE_PLAYER(player, health, raptor);
 316     VEHICLE_UPDATE_PLAYER(player, energy, raptor);
 317     if(self.vehicle_flags & VHF_HASSHIELD)
 318         VEHICLE_UPDATE_PLAYER(player, shield, raptor);
 319
 320     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 321     self = player;
 322     return 1;
 323 }
 324
 325 void raptor_flare_touch()
 326 {
 327     remove(self);
 328 }
 329
 330 void raptor_flare_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 331 {
 332     self.health -= damage;
 333     if(self.health <= 0)
 334         remove(self);
 335 }
 336
 337 void raptor_flare_think()
 338 {
 339     self.nextthink = time + 0.1;
 340     entity _missile = findchainentity(enemy, self.owner);
 341     while(_missile)
 342     {
 343         if(_missile.flags & FL_PROJECTILE)
 344         if(vlen(self.origin - _missile.origin) < autocvar_g_vehicle_raptor_flare_range)
 345         if(random() > autocvar_g_vehicle_raptor_flare_chase)
 346             _missile.enemy = self;
 347         _missile = _missile.chain;
 348     }
 349
 350     if(self.tur_impacttime < time)
 351         remove(self);
 352 }
 353
 354 float raptor_frame()
 355 {
 356     entity player, raptor;
 357     float ftmp = 0;
 358     vector df;
 359
 360         if(intermission_running)
 361                 return 1;
 362
 363     player = self;
 364     raptor = self.vehicle;
 365     self   = raptor;
 366     vehicles_painframe();
 367     /*
 368     ftmp = vlen(self.velocity);
 369     if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 370         ftmp = 1;
 371     else
 372         ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 373     */
 374
 375     if(self.sound_nexttime < time)
 376     {
 377         self.sound_nexttime = time + 7.955812;
 378         //sound (self.tur_head, CH_TRIGGER_SINGLE, "vehicles/raptor_fly.wav", 1 - ftmp,   ATTN_NORM );
 379         sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", 1, ATTN_NORM);
 380         self.wait = ftmp;
 381     }
 382     /*
 383     else if(fabs(ftmp - self.wait) > 0.2)
 384     {
 385         sound (self.tur_head, CH_TRIGGER_SINGLE, "", 1 - ftmp,   ATTN_NORM );
 386         sound (self, CH_TRIGGER_SINGLE, "", ftmp, ATTN_NORM);
 387         self.wait = ftmp;
 388     }
 389     */
 390
 391     if(raptor.deadflag != DEAD_NO)
 392     {
 393         self = player;
 394         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 395         return 1;
 396     }
 397     crosshair_trace(player);
 398
 399     vector vang;
 400     vang = raptor.angles;
 401     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 402     vang_x *= -1;
 403     df_x *= -1;
 404     if(df_x > 180)  df_x -= 360;
 405     if(df_x < -180) df_x += 360;
 406     if(df_y > 180)  df_y -= 360;
 407     if(df_y < -180) df_y += 360;
 408
 409     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 410     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 411     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 412
 413     // Pitch
 414     ftmp = 0;
 415     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 416     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 417
 418     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 419     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 420     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 421
 422     raptor.angles_x = anglemods(raptor.angles_x);
 423     raptor.angles_y = anglemods(raptor.angles_y);
 424     raptor.angles_z = anglemods(raptor.angles_z);
 425
 426     if(autocvar_g_vehicle_raptor_movestyle == 1)
 427         makevectors('0 1 0' * raptor.angles_y);
 428     else
 429         makevectors(player.v_angle);
 430
 431     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 432
 433     if(player.movement_x != 0)
 434     {
 435         if(player.movement_x > 0)
 436             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 437         else if(player.movement_x < 0)
 438             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 439     }
 440
 441     if(player.movement_y != 0)
 442     {
 443         if(player.movement_y < 0)
 444             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 445         else if(player.movement_y > 0)
 446             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 447
 448         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 449     }
 450     else
 451     {
 452         raptor.angles_z *= 0.95;
 453         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 454             raptor.angles_z = 0;
 455     }
 456
 457     if(player.BUTTON_CROUCH)
 458         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 459     else if (player.BUTTON_JUMP)
 460         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 461
 462     raptor.velocity  += df * frametime;
 463     player.velocity = player.movement  = raptor.velocity;
 464     setorigin(player, raptor.origin + '0 0 32');
 465
 466     vector vf, ad;
 467     // Target lock & predict
 468     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 469     {
 470
 471         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 472                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 473                              autocvar_g_vehicle_raptor_cannon_locked_time);
 474
 475         if(self.lock_target != world)
 476         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 477         if(self.lock_strength == 1)
 478         {
 479             float i, distance, impact_time;
 480
 481             vf = real_origin(raptor.lock_target);
 482             ad = vf;
 483             for(i = 0; i < 4; ++i)
 484             {
 485                 distance = vlen(ad - raptor.origin);
 486                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 487                 ad = vf + raptor.lock_target.velocity * impact_time;
 488             }
 489             trace_endpos = ad;
 490         }
 491
 492         if(self.lock_target)
 493         {
 494             if(raptor.lock_strength == 1)
 495                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 496             else if(self.lock_strength > 0.5)
 497                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 498             else if(self.lock_strength < 0.5)
 499                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 500         }
 501     }
 502
 503
 504     vehicle_aimturret(raptor, trace_endpos, raptor.gun1, "fire1",
 505                           autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 506                           autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 507
 508     vehicle_aimturret(raptor, trace_endpos, raptor.gun2, "fire1",
 509                           autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 510                           autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 511
 512     /*
 513     ad = ad * 0.5;
 514     v_forward = vf * 0.5;
 515     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 516     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 517     */
 518
 519     if(player.BUTTON_ATCK)
 520     if(raptor.attack_finished_single <= time)
 521     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 522     {
 523         raptor.misc_bulletcounter += 1;
 524         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 525         if(raptor.misc_bulletcounter <= 2)
 526             raptor_fire_cannon(self.gun1, "fire1");
 527         else if(raptor.misc_bulletcounter == 3)
 528             raptor_fire_cannon(self.gun2, "fire1");
 529         else
 530         {
 531             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 532             raptor_fire_cannon(self.gun2, "fire1");
 533             raptor.misc_bulletcounter = 0;
 534         }
 535         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 536         self.cnt = time;
 537     }
 538
 539     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 540         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, TRUE);
 541
 542     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 543         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, FALSE);
 544
 545     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 546         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, FALSE);
 547
 548     if(raptor.vehicle_weapon2mode == RSM_BOMB)
 549     {
 550         if(time > raptor.lip + autocvar_g_vehicle_raptor_bombs_refire)
 551         if(player.BUTTON_ATCK2)
 552         {
 553             raptor_bombdrop();
 554             raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 555             raptor.lip   = time;
 556         }
 557     }
 558     else
 559     {
 560         if(time > raptor.lip + autocvar_g_vehicle_raptor_flare_refire)
 561         if(player.BUTTON_ATCK2)
 562         {
 563             float i;
 564             entity _flare;
 565
 566             for(i = 0; i < 3; ++i)
 567             {
 568             _flare = spawn();
 569             setmodel(_flare, "models/runematch/rune.mdl");
 570             _flare.effects = EF_LOWPRECISION | EF_FLAME;
 571             _flare.scale = 0.5;
 572             setorigin(_flare, self.origin - '0 0 16');
 573             _flare.movetype = MOVETYPE_TOSS;
 574             _flare.gravity = 0.15;
 575             _flare.velocity = 0.25 * raptor.velocity + (v_forward + randomvec() * 0.25)* -500;
 576             _flare.think = raptor_flare_think;
 577             _flare.nextthink = time;
 578             _flare.owner = raptor;
 579             _flare.solid = SOLID_CORPSE;
 580             _flare.takedamage = DAMAGE_YES;
 581             _flare.event_damage = raptor_flare_damage;
 582             _flare.health = 20;
 583             _flare.tur_impacttime = time + autocvar_g_vehicle_raptor_flare_lifetime;
 584             _flare.touch = raptor_flare_touch;
 585             }
 586             raptor.delay = time + autocvar_g_vehicle_raptor_flare_refire;
 587             raptor.lip   = time;
 588         }
 589     }
 590
 591     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 592     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 593
 594     if(self.bomb1.cnt < time)
 595     {
 596         entity _missile = findchainentity(enemy, raptor);
 597         float _incomming = 0;
 598         while(_missile)
 599         {
 600             if(_missile.flags & FL_PROJECTILE)
 601             if(MISSILE_IS_TRACKING(_missile))
 602             if(vlen(self.origin - _missile.origin) < 2 * autocvar_g_vehicle_raptor_flare_range)
 603                 ++_incomming;
 604
 605             _missile = _missile.chain;
 606         }
 607
 608         if(_incomming)
 609             sound(self, CH_PAIN_SINGLE, "vehicles/missile_alarm.wav", VOL_BASE, ATTN_NONE);
 610
 611         self.bomb1.cnt = time + 1;
 612     }
 613
 614
 615     VEHICLE_UPDATE_PLAYER(player, health, raptor);
 616     VEHICLE_UPDATE_PLAYER(player, energy, raptor);
 617     if(self.vehicle_flags & VHF_HASSHIELD)
 618         VEHICLE_UPDATE_PLAYER(player, shield, raptor);
 619
 620     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 621
 622     self = player;
 623     return 1;
 624 }
 625
 626 void raptor_blowup()
 627 {
 628     self.deadflag    = DEAD_DEAD;
 629     self.vehicle_exit(VHEF_NORMAL);
 630     RadiusDamage (self, self.enemy, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 631
 632     self.alpha          = -1;
 633     self.movetype       = MOVETYPE_NONE;
 634     self.effects        = EF_NODRAW;
 635     self.colormod       = '0 0 0';
 636     self.avelocity      = '0 0 0';
 637     self.velocity       = '0 0 0';
 638
 639     setorigin(self, self.pos1);
 640     self.touch = SUB_Null;
 641     self.nextthink = 0;
 642 }
 643
 644 void raptor_diethink()
 645 {
 646     if(random() < 0.1)
 647     {
 648         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 649         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 650     }
 651     self.nextthink = time + 0.1;
 652 }
 653
 654 void raptor_die()
 655 {
 656     self.health       = 0;
 657     self.event_damage = SUB_Null;
 658     self.solid        = SOLID_CORPSE;
 659     self.takedamage   = DAMAGE_NO;
 660     self.deadflag     = DEAD_DYING;
 661     self.movetype     = MOVETYPE_BOUNCE;
 662     self.think        = raptor_diethink;
 663     self.nextthink    = time;
 664
 665     pointparticles(particleeffectnum("explosion_medium"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 666
 667     self.velocity_z += 600;
 668
 669     self.avelocity = '0 0.5 1' * (random() * 400);
 670     self.avelocity -= '0 0.5 1' * (random() * 400);
 671
 672     self.colormod = '-0.5 -0.5 -0.5';
 673         self.touch     = raptor_blowup;
 674 }
 675
 676 void raptor_impact()
 677 {
 678     if(autocvar_g_vehicle_raptor_bouncepain_x)
 679         vehilces_impact(autocvar_g_vehicle_raptor_bouncepain_x, autocvar_g_vehicle_raptor_bouncepain_y, autocvar_g_vehicle_raptor_bouncepain_z);
 680 }
 681
 682 void raptor_spawn(float _f)
 683 {
 684     self.frame          = 0;
 685     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 686     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 687     self.movetype       = MOVETYPE_TOSS;
 688     self.solid          = SOLID_SLIDEBOX;
 689     self.vehicle_energy = 1;
 690
 691     self.bomb1.gun1.avelocity_y = 90;
 692     self.bomb1.gun2.avelocity_y = -90;
 693
 694     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 695     self.delay = time;
 696
 697     self.bouncefactor = autocvar_g_vehicle_raptor_bouncefactor;
 698     self.bouncestop = autocvar_g_vehicle_raptor_bouncestop;
 699     self.vehicle_impact = raptor_impact;
 700 }
 701
 702 // If we dont do this ever now and then, the raptors rotors
 703 // stop working, presumably due to angle overflow. cute.
 704 void raptor_rotor_anglefix()
 705 {
 706     self.gun1.angles_y = anglemods(self.gun1.angles_y);
 707     self.gun2.angles_y = anglemods(self.gun2.angles_y);
 708     self.nextthink = time + 15;
 709 }
 710 float raptor_impulse(float _imp)
 711 {
 712     switch(_imp)
 713     {
 714         case 10:
 715         case 15:
 716         case 18:
 717             self.vehicle.vehicle_weapon2mode += 1;
 718             if(self.vehicle.vehicle_weapon2mode > RSM_LAST)
 719                 self.vehicle.vehicle_weapon2mode = RSM_FIRST;
 720
 721             CSQCVehicleSetup(self, 0);
 722             return TRUE;
 723         case 12:
 724         case 16:
 725         case 19:
 726             self.vehicle.vehicle_weapon2mode -= 1;
 727             if(self.vehicle.vehicle_weapon2mode < RSM_FIRST)
 728                 self.vehicle.vehicle_weapon2mode = RSM_LAST;
 729
 730             CSQCVehicleSetup(self, 0);
 731             return TRUE;
 732
 733         /*
 734         case 17: // toss gun, could be used to exit?
 735             break;
 736         case 20: // Manual minigun reload?
 737             break;
 738         */
 739     }
 740     return FALSE;
 741 }
 742
 743 void raptor_dinit()
 744 {
 745     entity spinner;
 746     vector ofs;
 747
 748     if not (vehicle_initialize(
 749              "Raptor",
 750              "models/vehicles/raptor.dpm",
 751              "",
 752              "models/vehicles/raptor_cockpit.dpm",
 753              "", "tag_hud", "tag_camera",
 754              HUD_RAPTOR,
 755              RAPTOR_MIN, RAPTOR_MAX,
 756              FALSE,
 757              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 758              raptor_frame,
 759              raptor_enter, raptor_exit,
 760              raptor_die,   raptor_think,
 761              FALSE,
 762              autocvar_g_vehicle_raptor_health))
 763     {
 764         remove(self);
 765         return;
 766     }
 767
 768     //FIXME: Camera is in a bad place in HUD model.
 769     //setorigin(self.vehicle_viewport, '25 0 5');
 770
 771     self.vehicles_impusle   = raptor_impulse;
 772
 773     self.frame = 0;
 774
 775     self.bomb1 = spawn();
 776     self.bomb2 = spawn();
 777     self.gun1  = spawn();
 778     self.gun2  = spawn();
 779
 780     setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 781     setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 782     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 783     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 784     setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 785
 786     setattachment(self.bomb1, self,"bombmount_left");
 787     setattachment(self.bomb2, self,"bombmount_right");
 788     setattachment(self.tur_head, self,"root");
 789
 790
 791     // FIXMODEL Guns mounts to angled bones
 792     self.bomb1.angles = self.angles;
 793     self.angles = '0 0 0';
 794     // This messes up gun-aim, so work arround it.
 795     //setattachment(self.gun1, self, "gunmount_left");
 796     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 797     ofs -= self.origin;
 798     setattachment(self.gun1, self, "");
 799     setorigin(self.gun1, ofs);
 800
 801     //setattachment(self.gun2, self, "gunmount_right");
 802     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 803     ofs -= self.origin;
 804     setattachment(self.gun2, self, "");
 805     setorigin(self.gun2, ofs);
 806
 807     self.angles = self.bomb1.angles;
 808     self.bomb1.angles = '0 0 0';
 809
 810     spinner = spawn();
 811     spinner.owner = self;
 812     setmodel(spinner,"models/vehicles/spinner.dpm");
 813     setattachment(spinner, self, "engine_left");
 814     spinner.movetype = MOVETYPE_NOCLIP;
 815     spinner.avelocity = '0 90 0';
 816     self.bomb1.gun1 = spinner;
 817
 818     spinner = spawn();
 819     spinner.owner = self;
 820     setmodel(spinner,"models/vehicles/spinner.dpm");
 821     setattachment(spinner, self, "engine_right");
 822     spinner.movetype = MOVETYPE_NOCLIP;
 823     spinner.avelocity = '0 -90 0';
 824     self.bomb1.gun2 = spinner;
 825
 826     // Sigh.
 827     self.bomb1.think = raptor_rotor_anglefix;
 828     self.bomb1.nextthink = time;
 829
 830     self.mass               = 1 ;
 831 }
 832
 833 void spawnfunc_vehicle_raptor()
 834 {
 835     if(!autocvar_g_vehicle_raptor)
 836     {
 837         remove(self);
 838         return;
 839     }
 840
 841     self.vehicle_flags |= VHF_DMGSHAKE;
 842     self.vehicle_flags |= VHF_DMGROLL;
 843
 844     if(autocvar_g_vehicle_raptor_shield)
 845         self.vehicle_flags |= VHF_HASSHIELD;
 846
 847     if(autocvar_g_vehicle_raptor_shield_regen)
 848         self.vehicle_flags |= VHF_SHIELDREGEN;
 849
 850     if(autocvar_g_vehicle_raptor_health_regen)
 851         self.vehicle_flags |= VHF_HEALTHREGEN;
 852
 853     if(autocvar_g_vehicle_raptor_energy_regen)
 854         self.vehicle_flags |= VHF_ENERGYREGEN;
 855
 856     precache_model ("models/vehicles/raptor.dpm");
 857     precache_model ("models/vehicles/raptor_gun.dpm");
 858     precache_model ("models/vehicles/spinner.dpm");
 859     precache_model ("models/vehicles/raptor_cockpit.dpm");
 860     //precache_model ("models/vehicles/clusterbomb.md3");
 861     precache_model ("models/vehicles/clusterbomb_folded.md3");
 862     precache_model ("models/vehicles/raptor_body.dpm");
 863
 864     precache_sound ("vehicles/raptor_fly.wav");
 865     precache_sound ("vehicles/raptor_speed.wav");
 866     precache_sound ("vehicles/missile_alarm.wav");
 867
 868     self.think = raptor_dinit;
 869
 870     if(g_assault)
 871         self.nextthink = time + 0.5;
 872     else
 873         self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_raptor_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 874 }
 875 #endif // SVQC