qcsrc/server/vehicles/raptor.qc

   1 #ifdef SVQC
   2 #define RAPTOR_MIN '-80 -80 0'
   3 #define RAPTOR_MAX '80 80 70'
   4 //#define RAPTOR_ENGINE "sound/vehicles/raptor.wav"
   5 float autocvar_g_vehicle_raptor_respawntime;
   6
   7 float autocvar_g_vehicle_raptor_movestyle;
   8 float autocvar_g_vehicle_raptor_turnspeed;
   9 float autocvar_g_vehicle_raptor_pitchspeed;
  10 float autocvar_g_vehicle_raptor_pitchlimit;
  11
  12 float autocvar_g_vehicle_raptor_speed_forward;
  13 float autocvar_g_vehicle_raptor_speed_strafe;
  14 float autocvar_g_vehicle_raptor_speed_up;
  15 float autocvar_g_vehicle_raptor_speed_down;
  16 float autocvar_g_vehicle_raptor_friction;
  17
  18 float autocvar_g_vehicle_raptor_bomblets;
  19 float autocvar_g_vehicle_raptor_bomblet_alt;
  20 float autocvar_g_vehicle_raptor_bomblet_time;
  21 float autocvar_g_vehicle_raptor_bomblet_damage;
  22 float autocvar_g_vehicle_raptor_bomblet_spread;
  23 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  24 float autocvar_g_vehicle_raptor_bomblet_radius;
  25 float autocvar_g_vehicle_raptor_bomblet_force;
  26 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  27 float autocvar_g_vehicle_raptor_bombs_refire;
  28
  29 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  30 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  32 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  33
  34 float autocvar_g_vehicle_raptor_cannon_locktarget;
  35 float autocvar_g_vehicle_raptor_cannon_locking_time;
  36 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  37 float autocvar_g_vehicle_raptor_cannon_locked_time;
  38 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  39
  40 float autocvar_g_vehicle_raptor_cannon_cost;
  41 float autocvar_g_vehicle_raptor_cannon_damage;
  42 float autocvar_g_vehicle_raptor_cannon_radius;
  43 float autocvar_g_vehicle_raptor_cannon_refire;
  44 float autocvar_g_vehicle_raptor_cannon_speed;
  45 float autocvar_g_vehicle_raptor_cannon_spread;
  46 float autocvar_g_vehicle_raptor_cannon_force;
  47
  48 float autocvar_g_vehicle_raptor_energy;
  49 float autocvar_g_vehicle_raptor_energy_regen;
  50 float autocvar_g_vehicle_raptor_energy_regen_pause;
  51
  52 float autocvar_g_vehicle_raptor_health;
  53 float autocvar_g_vehicle_raptor_health_regen;
  54 float autocvar_g_vehicle_raptor_health_regen_pause;
  55
  56 float autocvar_g_vehicle_raptor_shield;
  57 float autocvar_g_vehicle_raptor_shield_regen;
  58 float autocvar_g_vehicle_raptor_shield_regen_pause;
  59
  60 void raptor_spawn();
  61 float raptor_frame();
  62 float raptor_takeoff();
  63
  64 .entity bomb1;
  65 .entity bomb2;
  66
  67 float raptor_altitude(float amax)
  68 {
  69         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  70     return vlen(self.origin - trace_endpos);
  71 }
  72
  73
  74 void raptor_bomblet_boom()
  75 {
  76     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  77                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  78                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  79                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_RAPTOR_BOMB, world);
  80     remove(self);
  81 }
  82
  83 void raptor_bomblet_touch()
  84 {
  85     if(other == self.owner)
  86         return;
  87
  88     PROJECTILE_TOUCH;
  89     self.think = raptor_bomblet_boom;
  90     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  91 }
  92
  93 void raptor_bomb_burst()
  94 {
  95     if(self.cnt > time)
  96     if(autocvar_g_vehicle_raptor_bomblet_alt)
  97     {
  98         self.nextthink = time;
  99         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 100         if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 101         {
 102             UpdateCSQCProjectile(self);
 103             return;
 104         }
 105     }
 106
 107     entity bomblet;
 108     float i;
 109
 110     Damage_DamageInfo(self.origin, 0, 0, 0, '0 0 0', DEATH_RAPTOR_BOMB_SPLIT, self);
 111
 112     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 113     {
 114         bomblet = spawn();
 115         setorigin(bomblet, self.origin);
 116
 117         bomblet.movetype    = MOVETYPE_TOSS;
 118         bomblet.touch       = raptor_bomblet_touch;
 119         bomblet.think       = raptor_bomblet_boom;
 120         bomblet.nextthink   = time + 5;
 121         bomblet.owner       = self.owner;
 122         bomblet.realowner   = self.realowner;
 123         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 124
 125         PROJECTILE_MAKETRIGGER(bomblet);
 126         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 127     }
 128
 129     remove(self);
 130 }
 131
 132 void raptor_bomb_touch()
 133 {
 134     raptor_bomb_burst();
 135 }
 136
 137 void raptor_bombdrop()
 138 {
 139     entity bomb_1, bomb_2;
 140
 141     bomb_1 = spawn();
 142     bomb_2 = spawn();
 143
 144     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 145     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 146
 147     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_BOUNCE;
 148     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 149     bomb_1.touch        = bomb_2.touch      = raptor_bomb_touch;
 150     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 151     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 152
 153     if(autocvar_g_vehicle_raptor_bomblet_alt)
 154         bomb_1.nextthink = bomb_2.nextthink  = time;
 155     else
 156         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 157
 158     bomb_1.owner     = bomb_2.owner      = self;
 159     bomb_1.realowner = bomb_2.realowner  = self.owner;
 160     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 161     bomb_1.gravity   = bomb_2.gravity    = 1;
 162
 163     PROJECTILE_MAKETRIGGER(bomb_1);
 164     PROJECTILE_MAKETRIGGER(bomb_2);
 165
 166     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 167     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 168
 169 }
 170
 171
 172 void raptor_fire_cannon(entity gun, string tagname)
 173 {
 174     entity bolt;
 175     vector b_org;
 176     b_org = gettaginfo(gun, gettagindex(gun, tagname));
 177     bolt = vehicles_projectile("raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 178                            b_org, normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 179                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 180                            DEATH_RAPTOR_CANNON, PROJECTILE_RAPTORCANNON, 0, TRUE, TRUE);
 181 }
 182
 183 void raptor_think()
 184 {
 185 }
 186
 187 void raptor_enter()
 188 {
 189     self.owner.PlayerPhysplug = raptor_takeoff;
 190     self.movetype       = MOVETYPE_BOUNCEMISSILE;
 191     self.solid          = SOLID_SLIDEBOX;
 192     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 193     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 194     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 195     self.tur_head.exteriormodeltoclient = self.owner;
 196
 197     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 198     self.lip   = time;
 199
 200 }
 201
 202 void raptor_land()
 203 {
 204
 205     float hgt;
 206
 207     hgt = raptor_altitude(512);
 208     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 209     self.angles_x *= 0.95;
 210     self.angles_z *= 0.95;
 211
 212     if(hgt < 128)
 213         if(self.frame != 0)
 214             self.frame = max(self.frame - 0.25, 0);
 215
 216     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 217     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 218
 219     if(hgt < 16)
 220     {
 221         self.movetype   = MOVETYPE_TOSS;
 222         self.think      = raptor_think;
 223     }
 224
 225     self.nextthink  = time;
 226 }
 227
 228 void raptor_exit(float eject)
 229 {
 230     vector spot;
 231     self.tur_head.exteriormodeltoclient = world;
 232
 233     if(self.deadflag == DEAD_NO)
 234     {
 235         self.think      = raptor_land;
 236         self.nextthink  = time;
 237     }
 238
 239     if not (self.owner)
 240         return;
 241
 242         makevectors(self.angles);
 243         if(eject)
 244         {
 245             spot = self.origin + v_forward * 100 + '0 0 64';
 246             spot = vehicles_findgoodexit(spot);
 247             setorigin(self.owner , spot);
 248             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 249         }
 250         else
 251         {
 252             spot = self.origin - v_forward * 200 + '0 0 64';
 253             spot = vehicles_findgoodexit(spot);
 254             setorigin(self.owner , spot);
 255         }
 256
 257     self.owner = world;
 258 }
 259
 260 float raptor_takeoff()
 261 {
 262     entity player, raptor;
 263
 264     player = self;
 265     raptor = self.vehicle;
 266     self   = raptor;
 267
 268     if(self.sound_nexttime < time)
 269     {
 270         self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 271         sound (self, CHAN_TRIGGER, "vehicles/raptor_speed.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 272     }
 273
 274     // Takeoff sequense
 275     if(raptor.frame < 25)
 276     {
 277         raptor.frame += 0.25;
 278         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 279         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 280         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 281         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 282
 283         setorigin(player, raptor.origin + '0 0 32');
 284     }
 285     else
 286         player.PlayerPhysplug = raptor_frame;
 287
 288     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 289         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 290
 291     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 292         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 293
 294     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 295         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 296
 297
 298     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 299     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 300
 301     VEHICLE_UPDATE_PLAYER(health, raptor);
 302     VEHICLE_UPDATE_PLAYER(energy, raptor);
 303     if(self.vehicle_flags & VHF_HASSHIELD)
 304         VEHICLE_UPDATE_PLAYER(shield, raptor);
 305
 306     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 307     self = player;
 308     return 1;
 309 }
 310
 311 float raptor_frame()
 312 {
 313     entity player, raptor;
 314     float ftmp, ftmp2;
 315     vector df, ra;
 316
 317     player = self;
 318     raptor = self.vehicle;
 319     self   = raptor;
 320
 321     /*
 322     ftmp = vlen(self.velocity);
 323     if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 324         ftmp = 1;
 325     else
 326         ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 327     */
 328
 329     if(self.sound_nexttime < time)
 330     {
 331         self.sound_nexttime = time + 7.955812;
 332         //sound (self.tur_head, CHAN_TRIGGER, "vehicles/raptor_fly.wav", 1 - ftmp,   ATTN_NORM );
 333         sound (self, CHAN_TRIGGER, "vehicles/raptor_speed.wav", 1, ATTN_NORM);
 334         self.wait = ftmp;
 335     }
 336     /*
 337     else if(fabs(ftmp - self.wait) > 0.2)
 338     {
 339         sound (self.tur_head, CHAN_TRIGGER, "", 1 - ftmp,   ATTN_NORM );
 340         sound (self, CHAN_TRIGGER, "", ftmp, ATTN_NORM);
 341         self.wait = ftmp;
 342     }
 343     */
 344
 345     if(player.BUTTON_USE && raptor.deadflag == DEAD_NO)
 346     {
 347         self = raptor;
 348         vehicles_exit(VHEF_NORMAL);
 349         self = player;
 350         return 0;
 351     }
 352
 353     if(raptor.deadflag != DEAD_NO)
 354     {
 355         self = player;
 356         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 357         return 1;
 358     }
 359     crosshair_trace(player);
 360
 361
 362     vector vang;
 363     vang = raptor.angles;
 364     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 365     vang_x *= -1;
 366     df_x *= -1;
 367     if(df_x > 180)  df_x -= 360;
 368     if(df_x < -180) df_x += 360;
 369     if(df_y > 180)  df_y -= 360;
 370     if(df_y < -180) df_y += 360;
 371
 372     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 373     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 374     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 375
 376     // Pitch
 377     ftmp = 0;
 378     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 379     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 380
 381     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 382     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 383     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 384
 385     raptor.angles_x = anglemods(raptor.angles_x);
 386     raptor.angles_y = anglemods(raptor.angles_y);
 387     raptor.angles_z = anglemods(raptor.angles_z);
 388
 389
 390     if(autocvar_g_vehicle_raptor_movestyle == 1)
 391         makevectors('0 1 0' * raptor.angles_y);
 392     else
 393         makevectors(player.v_angle);
 394
 395     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 396
 397     if(player.movement_x != 0)
 398     {
 399         if(player.movement_x > 0)
 400             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 401         else if(player.movement_x < 0)
 402             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 403     }
 404
 405     if(player.movement_y != 0)
 406     {
 407         if(player.movement_y < 0)
 408             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 409         else if(player.movement_y > 0)
 410             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 411
 412         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 413     }
 414     else
 415     {
 416         raptor.angles_z *= 0.95;
 417         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 418             raptor.angles_z = 0;
 419     }
 420
 421     if(player.BUTTON_CROUCH)
 422         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 423     else if (player.BUTTON_JUMP)
 424         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 425
 426     raptor.velocity  += df * frametime;
 427     //player.velocity = raptor.velocity;
 428     player.velocity = player.movement  = raptor.velocity;
 429     setorigin(player, raptor.origin + '0 0 32');
 430
 431     vector vf, ad;
 432     // Target lock & predict
 433     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 434     {
 435
 436         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 437                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 438                              autocvar_g_vehicle_raptor_cannon_locked_time);
 439
 440         if(self.lock_target != world)
 441         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 442         if(self.lock_strength == 1)
 443         {
 444             float i, distance, impact_time;
 445
 446             vf = real_origin(raptor.lock_target);
 447             ad = vf;
 448             for(i = 0; i < 4; ++i)
 449             {
 450                 distance = vlen(ad - raptor.origin);
 451                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 452                 ad = vf + raptor.lock_target.velocity * impact_time;
 453             }
 454             trace_endpos = ad;
 455             //UpdateAuxiliaryXhair(player, trace_endpos, '1 1 1', 0);
 456         }
 457
 458         if(self.lock_target)
 459         {
 460             if(raptor.lock_strength == 1)
 461                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 462             else if(self.lock_strength > 0.5)
 463                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 464             else if(self.lock_strength < 0.5)
 465                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 466         }
 467     }
 468
 469     ra = raptor.angles;
 470     ra_z = 0;
 471     // Aim the gunz
 472     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 473     ftmp = -ftmp2;
 474
 475     // Gun1
 476     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 477     ad = df;
 478     vf = v_forward;
 479     //if(self.lock_strength == 1)
 480     //{
 481         df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 482         df = shortangle_vxy(df - (ra + raptor.gun1.angles), ra + raptor.gun1.angles);     // Find aim offset
 483     //}
 484     //else
 485     //    df = '0 0 0';
 486
 487     // Bind to aimspeed
 488     df_x = bound(ftmp, df_x, ftmp2);
 489     df_y = bound(ftmp, df_y, ftmp2);
 490     // Bind to limts
 491     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 492     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 493
 494     // Gun2
 495     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 496     ad += df;
 497     vf += v_forward;
 498     //if(self.lock_strength == 1)
 499     //{
 500         df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 501         df = shortangle_vxy(df - (ra + raptor.gun2.angles), ra + raptor.gun2.angles);     // Find aim offset
 502     //}
 503     //else
 504     //    df = '0 0 0';
 505
 506     // Bind to aimspeed
 507     df_x = bound(ftmp, df_x, ftmp2);
 508     df_y = bound(ftmp, df_y, ftmp2);
 509     // Bind to limts
 510     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 511     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 512
 513     /*
 514     ad = ad * 0.5;
 515     v_forward = vf * 0.5;
 516     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 517     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 518     */
 519
 520     if(player.BUTTON_ATCK)
 521     if(raptor.attack_finished_single <= time)
 522     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 523     {
 524         raptor.misc_bulletcounter += 1;
 525         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 526         if(raptor.misc_bulletcounter <= 2)
 527             raptor_fire_cannon(self.gun1, "fire1");
 528         else if(raptor.misc_bulletcounter == 3)
 529             raptor_fire_cannon(self.gun2, "fire1");
 530         else
 531         {
 532             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 533             raptor_fire_cannon(self.gun2, "fire1");
 534             raptor.misc_bulletcounter = 0;
 535         }
 536         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 537         self.cnt = time;
 538     }
 539
 540     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 541         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 542
 543     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 544         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 545
 546     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 547         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 548
 549
 550     if(time > raptor.delay)
 551     if(player.BUTTON_ATCK2)
 552     {
 553         raptor_bombdrop();
 554         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 555         raptor.lip   = time;
 556     }
 557
 558     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 559     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 560
 561     VEHICLE_UPDATE_PLAYER(health, raptor);
 562     VEHICLE_UPDATE_PLAYER(energy, raptor);
 563     if(self.vehicle_flags & VHF_HASSHIELD)
 564         VEHICLE_UPDATE_PLAYER(shield, raptor);
 565
 566     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 567     return 1;
 568 }
 569
 570 void raptor_blowup()
 571 {
 572     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 573     pointparticles(particleeffectnum("explosion_big"), self.origin, '0 0 0', 1);
 574
 575     self.deadflag    = DEAD_DEAD;
 576     self.vehicle_exit(VHEF_NORMAL);
 577     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 578
 579     self.alpha          = -1;
 580     self.movetype       = MOVETYPE_NONE;
 581     self.effects        = EF_NODRAW;
 582     self.colormod       = '0 0 0';
 583     self.avelocity      = '0 0 0';
 584     self.velocity       = '0 0 0';
 585
 586     setorigin(self, self.pos1);
 587     self.touch = SUB_Null;
 588     self.nextthink = 0;
 589 }
 590
 591 void raptor_diethink()
 592 {
 593     //self.avelocity += '0 0.5 1' * (random() * 5);
 594     //self.avelocity -= '0 0.5 1' * (random() * 5);
 595
 596     if(random() < 0.1)
 597     {
 598         sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 599         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 600     }
 601     self.nextthink = time + 0.1;
 602 }
 603
 604 void raptor_die()
 605 {
 606     self.health       = 0;
 607     self.event_damage = SUB_Null;
 608     self.iscreature   = FALSE;
 609     self.solid        = SOLID_CORPSE;
 610     self.takedamage   = DAMAGE_NO;
 611     self.deadflag     = DEAD_DYING;
 612     self.movetype     = MOVETYPE_BOUNCE;
 613     self.think        = raptor_diethink;
 614     self.nextthink    = time;
 615
 616     pointparticles(particleeffectnum("explosion_medium"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 617
 618     self.velocity_z += 600;
 619
 620     self.avelocity = '0 0.5 1' * (random() * 400);
 621     self.avelocity -= '0 0.5 1' * (random() * 400);
 622
 623     self.colormod = '-0.5 -0.5 -0.5';
 624         self.touch     = raptor_blowup;
 625 }
 626
 627 void raptor_spawn()
 628 {
 629     self.frame          = 0;
 630     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 631     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 632     self.movetype       = MOVETYPE_TOSS;
 633     self.solid          = SOLID_SLIDEBOX;
 634     self.vehicle_energy = 1;
 635
 636     self.bomb1.gun1.avelocity_y = 90;
 637     self.bomb1.gun2.avelocity_y = -90;
 638
 639     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 640     self.delay = time;
 641 }
 642
 643 // If we dont do this ever now and then, the raptors rotors
 644 // stop working, presumably due to angle overflow. cute.
 645 void raptor_rotor_anglefix()
 646 {
 647     self.gun1.angles_y = anglemods(self.gun1.angles_y);
 648     self.gun2.angles_y = anglemods(self.gun2.angles_y);
 649     self.nextthink = time + 15;
 650 }
 651
 652 void raptor_dinit()
 653 {
 654     entity spinner;
 655     vector ofs;
 656
 657     if not (vehicle_initialize(
 658              "Raptor",
 659              "models/vehicles/raptor.dpm",
 660              "",
 661              "models/vehicles/raptor_cockpit.dpm",
 662              "", "tag_hud", "tag_camera",
 663              HUD_RAPTOR,
 664              RAPTOR_MIN, RAPTOR_MAX,
 665              FALSE,
 666              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 667              raptor_frame,
 668              raptor_enter, raptor_exit,
 669              raptor_die,   raptor_think,
 670              FALSE))
 671     {
 672         remove(self);
 673         return;
 674     }
 675
 676     //FIXME: Camera is in a bad place in HUD model.
 677     //setorigin(self.vehicle_viewport, '25 0 5');
 678
 679     self.frame = 0;
 680
 681     self.bomb1 = spawn();
 682     self.bomb2 = spawn();
 683     self.gun1  = spawn();
 684     self.gun2  = spawn();
 685
 686     setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 687     setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 688     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 689     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 690     setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 691
 692     setattachment(self.bomb1, self,"bombmount_left");
 693     setattachment(self.bomb2, self,"bombmount_right");
 694     setattachment(self.tur_head, self,"root");
 695
 696
 697     // FIXME Guns mounts to angled bones
 698     self.bomb1.angles = self.angles;
 699     self.angles = '0 0 0';
 700     // This messes up gun-aim, so work arround it.
 701     //setattachment(self.gun1, self, "gunmount_left");
 702     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 703     ofs -= self.origin;
 704     setattachment(self.gun1, self, "");
 705     setorigin(self.gun1, ofs);
 706
 707     //setattachment(self.gun2, self, "gunmount_right");
 708     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 709     ofs -= self.origin;
 710     setattachment(self.gun2, self, "");
 711     setorigin(self.gun2, ofs);
 712
 713     self.angles = self.bomb1.angles;
 714     self.bomb1.angles = '0 0 0';
 715
 716     spinner = spawn();
 717     spinner.owner = self;
 718     setmodel(spinner,"models/vehicles/spinner.dpm");
 719     setattachment(spinner, self, "engine_left");
 720     spinner.movetype = MOVETYPE_NOCLIP;
 721     spinner.avelocity = '0 90 0';
 722     self.bomb1.gun1 = spinner;
 723
 724     spinner = spawn();
 725     spinner.owner = self;
 726     setmodel(spinner,"models/vehicles/spinner.dpm");
 727     setattachment(spinner, self, "engine_right");
 728     spinner.movetype = MOVETYPE_NOCLIP;
 729     spinner.avelocity = '0 -90 0';
 730     self.bomb1.gun2 = spinner;
 731
 732     // Sigh.
 733     self.bomb1.think = raptor_rotor_anglefix;
 734     self.bomb1.nextthink = time;
 735
 736     self.mass               = 1 ;
 737 }
 738
 739 void spawnfunc_vehicle_raptor()
 740 {
 741     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 742
 743     if(autocvar_g_vehicle_raptor_shield)
 744         self.vehicle_flags |= VHF_HASSHIELD;
 745
 746     if(autocvar_g_vehicle_raptor_shield_regen)
 747         self.vehicle_flags |= VHF_SHIELDREGEN;
 748
 749     if(autocvar_g_vehicle_raptor_health_regen)
 750         self.vehicle_flags |= VHF_HEALTHREGEN;
 751
 752     if(autocvar_g_vehicle_raptor_energy_regen)
 753         self.vehicle_flags |= VHF_ENERGYREGEN;
 754
 755     precache_model ("models/vehicles/raptor.dpm");
 756     precache_model ("models/vehicles/raptor_gun.dpm");
 757     precache_model ("models/vehicles/spinner.dpm");
 758     precache_model ("models/vehicles/raptor_cockpit.dpm");
 759     precache_model ("models/vehicles/clusterbomb.md3");
 760     precache_model ("models/vehicles/clusterbomb_folded.md3");
 761     precache_model ("models/vehicles/raptor_body.dpm");
 762
 763     precache_sound ("vehicles/raptor_fly.wav");
 764     precache_sound ("vehicles/raptor_speed.wav");
 765     precache_sound ("");
 766
 767     self.think = raptor_dinit;
 768     self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_raptor_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 769 }
 770 #endif // SVQC