qcsrc/server/vehicles/raptor.qc

   1 #define RAPTOR_MIN '-80 -80 0'
   2 #define RAPTOR_MAX '80 80 70'
   3
   4 float autocvar_g_vehicle_raptor_respawntime;
   5
   6 float autocvar_g_vehicle_raptor_movestyle;
   7 float autocvar_g_vehicle_raptor_turnspeed;
   8 float autocvar_g_vehicle_raptor_pitchspeed;
   9 float autocvar_g_vehicle_raptor_pitchlimit;
  10
  11 float autocvar_g_vehicle_raptor_speed_forward;
  12 float autocvar_g_vehicle_raptor_speed_strafe;
  13 float autocvar_g_vehicle_raptor_speed_up;
  14 float autocvar_g_vehicle_raptor_speed_down;
  15 float autocvar_g_vehicle_raptor_friction;
  16
  17 float autocvar_g_vehicle_raptor_bomblets;
  18 float autocvar_g_vehicle_raptor_bomblet_alt;
  19 float autocvar_g_vehicle_raptor_bomblet_time;
  20 float autocvar_g_vehicle_raptor_bomblet_damage;
  21 float autocvar_g_vehicle_raptor_bomblet_spread;
  22 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  23 float autocvar_g_vehicle_raptor_bomblet_radius;
  24 float autocvar_g_vehicle_raptor_bomblet_force;
  25 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  26 float autocvar_g_vehicle_raptor_bombs_refire;
  27
  28 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  29 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  30 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  32
  33 float autocvar_g_vehicle_raptor_cannon_locktarget;
  34 float autocvar_g_vehicle_raptor_cannon_locking_time;
  35 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  36 float autocvar_g_vehicle_raptor_cannon_locked_time;
  37 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  38
  39 float autocvar_g_vehicle_raptor_cannon_cost;
  40 float autocvar_g_vehicle_raptor_cannon_damage;
  41 float autocvar_g_vehicle_raptor_cannon_radius;
  42 float autocvar_g_vehicle_raptor_cannon_refire;
  43 float autocvar_g_vehicle_raptor_cannon_speed;
  44 float autocvar_g_vehicle_raptor_cannon_spread;
  45 float autocvar_g_vehicle_raptor_cannon_force;
  46
  47 float autocvar_g_vehicle_raptor_energy;
  48 float autocvar_g_vehicle_raptor_energy_regen;
  49 float autocvar_g_vehicle_raptor_energy_regen_pause;
  50
  51 float autocvar_g_vehicle_raptor_health;
  52 float autocvar_g_vehicle_raptor_health_regen;
  53 float autocvar_g_vehicle_raptor_health_regen_pause;
  54
  55 float autocvar_g_vehicle_raptor_shield;
  56 float autocvar_g_vehicle_raptor_shield_regen;
  57 float autocvar_g_vehicle_raptor_shield_regen_pause;
  58
  59 void raptor_spawn();
  60 float raptor_frame();
  61 float raptor_takeoff();
  62
  63 .entity bomb1;
  64 .entity bomb2;
  65
  66 //#define RAPTOR_RETARDCAMERA
  67
  68 float raptor_altitude(float amax)
  69 {
  70         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  71     return vlen(self.origin - trace_endpos);
  72 }
  73
  74
  75 void raptor_bomblet_boom()
  76 {
  77     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
  78     pointparticles(particleeffectnum("raptor_bomb_impact"), self.origin, trace_plane_normal * 1000, 1);
  79     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  80                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  81                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  82                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_SBROCKET, world);
  83     remove(self);
  84 }
  85
  86 void raptor_bomblet_touch()
  87 {
  88     if(other == self.owner)
  89         return;
  90
  91     PROJECTILE_TOUCH;
  92     self.think = raptor_bomblet_boom;
  93     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  94 }
  95
  96 void raptor_bomb_burst()
  97 {
  98     if(self.cnt > time)
  99     if(autocvar_g_vehicle_raptor_bomblet_alt)
 100     {
 101         self.nextthink = time;
 102         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 103         if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 104         {
 105             UpdateCSQCProjectile(self);
 106             return;
 107         }
 108     }
 109
 110     entity bomblet;
 111     float i;
 112
 113     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 114     pointparticles(particleeffectnum("raptor_bomb_spread"), self.origin, self.velocity, 1);
 115
 116     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 117     {
 118         bomblet = spawn();
 119         setorigin(bomblet, self.origin);
 120
 121         bomblet.movetype    = MOVETYPE_TOSS;
 122         bomblet.touch       = raptor_bomblet_touch;
 123         bomblet.think       = raptor_bomblet_boom;
 124         bomblet.nextthink   = time + 5;
 125         bomblet.owner       = self.owner;
 126         bomblet.realowner   = self.realowner;
 127         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 128
 129         PROJECTILE_MAKETRIGGER(bomblet);
 130         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 131     }
 132
 133     remove(self);
 134 }
 135
 136 void raptor_bomb_touch()
 137 {
 138     raptor_bomb_burst();
 139 }
 140
 141 void raptor_bombdrop()
 142 {
 143     entity bomb_1, bomb_2;
 144
 145     //self.bomb1.alpha = 0;
 146     //self.bomb2.alpha = 0;
 147
 148     bomb_1 = spawn();
 149     bomb_2 = spawn();
 150
 151     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 152     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 153
 154     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_BOUNCE;
 155     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 156     bomb_1.touch        = bomb_2.touch      = raptor_bomb_touch;
 157     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 158     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 159
 160     if(autocvar_g_vehicle_raptor_bomblet_alt)
 161         bomb_1.nextthink = bomb_2.nextthink  = time;
 162     else
 163         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 164
 165     bomb_1.owner     = bomb_2.owner      = self;
 166     bomb_1.realowner = bomb_2.realowner  = self.owner;
 167     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 168     bomb_1.gravity   = bomb_2.gravity    = 1;
 169
 170     PROJECTILE_MAKETRIGGER(bomb_1);
 171     PROJECTILE_MAKETRIGGER(bomb_2);
 172
 173     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 174     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 175
 176 }
 177
 178
 179 void raptor_fire_cannon(entity gun, string tagname)
 180 {
 181     entity bolt;
 182     vector b_org;
 183     b_org = gettaginfo(gun, gettagindex(gun, tagname));
 184     bolt = vehicles_projectile("raptor_cannon_impact", "weapons/laserimpact.wav", "raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 185                            b_org, normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 186                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 187                            DEATH_WAKIGUN, PROJECTILE_RAPTORCANNON, 0);
 188 }
 189
 190 void raptor_think()
 191 {
 192 }
 193
 194 void raptor_enter()
 195 {
 196     self.owner.PlayerPhysplug = raptor_takeoff;
 197     self.movetype       = MOVETYPE_FLY;
 198     self.solid          = SOLID_BBOX;
 199     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 200     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 201     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 202     self.tur_head.exteriormodeltoclient = self.owner;
 203
 204 #ifdef RAPTOR_RETARDCAMERA
 205     setorigin(self.vehicle_viewport, self.origin);
 206 #endif
 207 }
 208
 209 void raptor_land()
 210 {
 211     float hgt;
 212
 213     hgt = raptor_altitude(512);
 214     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 215     self.angles_x *= 0.95;
 216     self.angles_z *= 0.95;
 217
 218     if(hgt < 128)
 219         if(self.frame != 0)
 220             self.frame = max(self.frame - 0.25, 0);
 221
 222     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 223     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 224
 225     if(hgt < 16)
 226     {
 227         self.movetype   = MOVETYPE_TOSS;
 228         self.think      = raptor_think;
 229     }
 230
 231     self.nextthink  = time;
 232 }
 233
 234 void raptor_exit(float eject)
 235 {
 236     self.tur_head.exteriormodeltoclient = world;
 237
 238     if(self.deadflag == DEAD_NO)
 239     {
 240         self.think      = raptor_land;
 241         self.nextthink  = time;
 242     }
 243
 244     if not (self.owner)
 245         return;
 246
 247         makevectors(self.angles);
 248         if(eject)
 249         {
 250             setorigin(self.owner,self.origin + v_forward * 100 + '0 0 64');
 251             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 252         }
 253         else
 254         setorigin(self.owner,self.origin - v_forward * 200 + '0 0 64');
 255
 256     self.owner = world;
 257 }
 258
 259 float raptor_takeoff()
 260 {
 261     entity player, raptor;
 262
 263     player = self;
 264     raptor = self.vehicle;
 265     self   = raptor;
 266
 267     // Takeoff sequense
 268     if(raptor.frame < 25)
 269     {
 270         raptor.frame += 0.25;
 271         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 272         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 273         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 274         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 275
 276         setorigin(player, raptor.origin + '0 0 32');
 277     }
 278     else
 279         player.PlayerPhysplug = raptor_frame;
 280
 281     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 282     self = player;
 283     return 1;
 284 }
 285
 286 float raptor_frame()
 287 {
 288     entity player, raptor;
 289     float ftmp, ftmp2;
 290     vector df;
 291
 292     player = self;
 293     raptor = self.vehicle;
 294     self   = raptor;
 295
 296     if(player.BUTTON_USE && raptor.deadflag == DEAD_NO)
 297     {
 298         self = raptor;
 299         vehicles_exit(VHEF_NORMAL);
 300         self = player;
 301         return 0;
 302     }
 303
 304     if(raptor.deadflag != DEAD_NO)
 305     {
 306         self = player;
 307         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 308         return 1;
 309     }
 310
 311
 312
 313     crosshair_trace(player);
 314
 315 #if VEHICLES_VIEWROTATE_CROSSHAIR
 316     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 317     if(df_x > 180)  df_x -= 360;
 318     if(df_x < -180) df_x += 360;
 319     if(df_y > 180)  df_y -= 360;
 320     if(df_y < -180) df_y += 360;
 321
 322     // Rotate Body
 323     ftmp = autocvar_g_vehicle_raptor_turnspeed * sys_frametime;
 324     ftmp = bound(-ftmp, shortangle_f(df_y - raptor.angles_y, raptor.angles_y), ftmp);
 325
 326     // Turn
 327     //raptor.angles_y = anglemods(raptor.angles_y + ftmp);
 328     raptor.avelocity_y = anglemods(raptor.angles_y + ftmp);
 329
 330     // Pitch Body
 331     ftmp = autocvar_g_vehicle_raptor_pitchspeed  * sys_frametime;
 332     ftmp = bound(-ftmp, shortangle_f(df_x - raptor.angles_x, raptor.angles_x), ftmp);
 333
 334     //raptor.angles_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 335     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 336 #else
 337     vector vang;
 338     vang = raptor.angles;
 339     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 340     vang_x *= -1;
 341     df_x *= -1;
 342     if(df_x > 180)  df_x -= 360;
 343     if(df_x < -180) df_x += 360;
 344     if(df_y > 180)  df_y -= 360;
 345     if(df_y < -180) df_y += 360;
 346
 347     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 348     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 349     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 350
 351     // Pitch
 352     ftmp = 0;
 353     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 354     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 355
 356     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 357     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 358     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 359
 360     raptor.angles_x = anglemods(raptor.angles_x);
 361     raptor.angles_y = anglemods(raptor.angles_y);
 362     raptor.angles_z = anglemods(raptor.angles_z);
 363
 364 #endif
 365
 366     if(autocvar_g_vehicle_raptor_movestyle == 1)
 367         makevectors('0 1 0' * raptor.angles_y);
 368     else
 369         makevectors(player.v_angle);
 370
 371 #ifdef RAPTOR_RETARDCAMERA
 372     float spd, back, up;
 373     spd = vlen(self.velocity) + 0.01;
 374     back = spd / autocvar_g_vehicle_raptor_speed_forward;
 375     up = 1 - back;
 376     back = back;
 377     back = back * 1250;
 378     back += 150;
 379     up = up * 200;
 380     up = up + 100;
 381
 382     setorigin(self.vehicle_viewport, self.origin + (v_up * up) + (v_forward * -back));
 383 #endif
 384
 385     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 386
 387     if(player.movement_x != 0)
 388     {
 389         if(player.movement_x > 0)
 390             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 391         else if(player.movement_x < 0)
 392             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 393     }
 394
 395     if(player.movement_y != 0)
 396     {
 397         if(player.movement_y < 0)
 398             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 399         else if(player.movement_y > 0)
 400             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 401
 402         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 403     }
 404     else
 405     {
 406         raptor.angles_z *= 0.95;
 407         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 408             raptor.angles_z = 0;
 409     }
 410
 411     if(player.BUTTON_CROUCH)
 412         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 413     else if (player.BUTTON_JUMP)
 414         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 415
 416     raptor.velocity  += df * frametime;
 417     player.velocity = player.movement  = raptor.velocity;
 418     setorigin(player,raptor.origin + '0 0 32');
 419
 420     vector vf, ad;
 421     // Target lock & predict
 422     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 423     {
 424
 425         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 426                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 427                              autocvar_g_vehicle_raptor_cannon_locked_time);
 428
 429         if(self.lock_target != world)
 430         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 431         if(self.lock_strength == 1)
 432         {
 433             float i, distance, impact_time;
 434
 435             vf = real_origin(raptor.lock_target);
 436             ad = vf;
 437             for(i = 0; i < 4; ++i)
 438             {
 439                 distance = vlen(ad - raptor.origin);
 440                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 441                 ad = vf + raptor.lock_target.velocity * impact_time;
 442             }
 443             trace_endpos = ad;
 444             //UpdateAuxiliaryXhair(player, trace_endpos, '1 1 1', 0);
 445         }
 446
 447         if(self.lock_target)
 448         {
 449             if(raptor.lock_strength == 1)
 450                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 451             else if(self.lock_strength > 0.5)
 452                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 453             else if(self.lock_strength < 0.5)
 454                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 455         }
 456     }
 457
 458     // Aim the gunz
 459     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 460     ftmp = -ftmp2;
 461
 462     // Gun1
 463     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 464     //ad = df;
 465     //vf = v_forward;
 466     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 467     df = shortangle_vxy(df - (raptor.angles + raptor.gun1.angles), raptor.angles + raptor.gun1.angles);     // Find aim offset
 468     // Bind to aimspeed
 469     df_x = bound(ftmp, df_x, ftmp2);
 470     df_y = bound(ftmp, df_y, ftmp2);
 471     // Bind to limts
 472     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 473     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 474
 475     //df = vectoangles(normalize(trace_endpos - df));
 476
 477     //Gun 2
 478     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 479     //ad += df;
 480     //vf += v_forward;
 481     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 482     df = shortangle_vxy(df - (raptor.angles + raptor.gun2.angles), raptor.angles + raptor.gun2.angles);     // Find aim offset
 483     // Bind to aimspeed
 484     df_x = bound(ftmp, df_x, ftmp2);
 485     df_y = bound(ftmp, df_y, ftmp2);
 486     // Bind to limts
 487     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 488     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 489
 490     /*
 491     ad = ad * 0.5;
 492     v_forward = vf * 0.5;
 493     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 494     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 495     */
 496
 497     if(player.BUTTON_ATCK)
 498     if(raptor.attack_finished_single <= time)
 499     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 500     {
 501         raptor.misc_bulletcounter += 1;
 502         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 503         if(raptor.misc_bulletcounter <= 2)
 504             raptor_fire_cannon(self.gun1, "fire1");
 505         else if(raptor.misc_bulletcounter == 3)
 506             raptor_fire_cannon(self.gun2, "fire1");
 507         else
 508         {
 509             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 510             raptor_fire_cannon(self.gun2, "fire1");
 511             raptor.misc_bulletcounter = 0;
 512         }
 513         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 514         self.cnt = time;
 515     }
 516
 517     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 518         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 519
 520     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 521         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 522
 523     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 524         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 525
 526
 527     if(time > raptor.delay)
 528     if(player.BUTTON_ATCK2)
 529     {
 530         raptor_bombdrop();
 531         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 532         raptor.lip   = time;
 533     }
 534
 535     player.vehicle_reload1 = (time - raptor.lip) / (raptor.delay - raptor.lip);
 536     raptor.bomb1.alpha = raptor.bomb2.alpha = player.vehicle_reload1;
 537
 538     VEHICLE_UPDATE_PLAYER(health, raptor);
 539     VEHICLE_UPDATE_PLAYER(energy, raptor);
 540     if(self.vehicle_flags & VHF_HASSHIELD)
 541         VEHICLE_UPDATE_PLAYER(shield, raptor);
 542
 543
 544
 545     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 546     return 1;
 547 }
 548
 549 void raptor_blowup()
 550 {
 551     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 552     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 553
 554     self.deadflag    = DEAD_DEAD;
 555     self.vehicle_exit(VHEF_NORMAL);
 556     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 557
 558     self.alpha          = -1;
 559     self.movetype       = MOVETYPE_NONE;
 560     self.effects        = EF_NODRAW;
 561     self.colormod       = '0 0 0';
 562     self.avelocity      = '0 0 0';
 563     self.velocity       = '0 0 0';
 564
 565     setorigin(self, self.pos1);
 566     self.touch = SUB_Null;
 567 }
 568
 569 void raptor_die()
 570 {
 571     self.health       = 0;
 572     self.event_damage = SUB_Null;
 573     self.iscreature   = FALSE;
 574     self.solid        = SOLID_CORPSE;
 575     self.takedamage   = DAMAGE_NO;
 576     self.deadflag     = DEAD_DYING;
 577     self.movetype     = MOVETYPE_BOUNCE;
 578
 579     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 580
 581     self.velocity_z += 128;
 582
 583     if(random() < 0.5)
 584         self.avelocity_z  = 45 + random() * 270;
 585     else
 586         self.avelocity_z  = -45 + random() * -270;
 587
 588     self.colormod = '-0.5 -0.5 -0.5';
 589         self.touch     = raptor_blowup;
 590 }
 591
 592 void raptor_spawn()
 593 {
 594     self.frame          = 0;
 595     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 596     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 597     self.movetype       = MOVETYPE_TOSS;
 598     self.solid          = SOLID_BBOX;
 599     self.vehicle_energy = 1;
 600
 601     self.bomb1.gun1.avelocity_y = 90;
 602     self.bomb1.gun2.avelocity_y = -90;
 603
 604     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 605     self.delay = time;
 606 }
 607
 608 // If we dont do this ever now and then, the raptors rotors
 609 // stop working, presumably due to angle overflow. cute.
 610 void raptor_rotor_anglefix()
 611 {
 612     self.gun1.angles_y = anglemods(self.gun1.angles_y);
 613     self.gun2.angles_y = anglemods(self.gun2.angles_y);
 614     self.nextthink = time + 15;
 615 }
 616
 617 void raptor_dinit()
 618 {
 619     entity spinner;
 620     vector ofs;
 621
 622     if not (vehicle_initialize(
 623              "Raptor",
 624              "models/vehicles/raptor.dpm",
 625              "",
 626              "models/vehicles/raptor_cockpit.dpm",
 627              "", "tag_hud", "tag_camera",
 628              HUD_RAPTOR,
 629              RAPTOR_MIN, RAPTOR_MAX,
 630              FALSE,
 631              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 632              raptor_frame,
 633              raptor_enter, raptor_exit,
 634              raptor_die,   raptor_think))
 635     {
 636         remove(self);
 637         return;
 638     }
 639
 640     //FIXME: Camera is in a bad place in HUD model.
 641     //setorigin(self.vehicle_viewport, '25 0 5');
 642
 643     self.frame = 0;
 644
 645     self.bomb1 = spawn();
 646     self.bomb2 = spawn();
 647     self.gun1  = spawn();
 648     self.gun2  = spawn();
 649
 650 #ifdef RAPTOR_RETARDCAMERA
 651     setattachment(self.vehicle_viewport, world, "");
 652 #endif
 653
 654     setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 655     setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 656     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 657     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 658     setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 659
 660     setattachment(self.bomb1, self,"bombmount_left");
 661     setattachment(self.bomb2, self,"bombmount_right");
 662     setattachment(self.tur_head, self,"root");
 663
 664
 665     // FIXME Guns mounts to angled bones
 666     self.bomb1.angles = self.angles;
 667     self.angles = '0 0 0';
 668     // This messes up gun-aim, so work arround it.
 669     //setattachment(self.gun1, self, "gunmount_left");
 670     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 671     ofs -= self.origin;
 672     setattachment(self.gun1, self, "");
 673     setorigin(self.gun1, ofs);
 674
 675     //setattachment(self.gun2, self, "gunmount_right");
 676     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 677     ofs -= self.origin;
 678     setattachment(self.gun2, self, "");
 679     setorigin(self.gun2, ofs);
 680
 681     self.angles = self.bomb1.angles;
 682     self.bomb1.angles = '0 0 0';
 683
 684     spinner = spawn();
 685     spinner.owner = self;
 686     setmodel(spinner,"models/vehicles/spinner.dpm");
 687     setattachment(spinner, self, "engine_left");
 688     spinner.movetype = MOVETYPE_NOCLIP;
 689     spinner.avelocity = '0 90 0';
 690     self.bomb1.gun1 = spinner;
 691
 692     spinner = spawn();
 693     spinner.owner = self;
 694     setmodel(spinner,"models/vehicles/spinner.dpm");
 695     setattachment(spinner, self, "engine_right");
 696     spinner.movetype = MOVETYPE_NOCLIP;
 697     spinner.avelocity = '0 -90 0';
 698     self.bomb1.gun2 = spinner;
 699
 700     // Sigh.
 701     self.bomb1.think = raptor_rotor_anglefix;
 702     self.bomb1.nextthink = time;
 703
 704     self.mass               = 1 ;
 705 }
 706
 707 void spawnfunc_vehicle_raptor()
 708 {
 709     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 710
 711     if(autocvar_g_vehicle_raptor_shield)
 712         self.vehicle_flags |= VHF_HASSHIELD;
 713
 714     if(autocvar_g_vehicle_raptor_shield_regen)
 715         self.vehicle_flags |= VHF_SHIELDREGEN;
 716
 717     if(autocvar_g_vehicle_raptor_health_regen)
 718         self.vehicle_flags |= VHF_HEALTHREGEN;
 719
 720     if(autocvar_g_vehicle_raptor_energy_regen)
 721         self.vehicle_flags |= VHF_ENERGYREGEN;
 722
 723     precache_model ("models/vehicles/raptor.dpm");
 724     precache_model ("models/vehicles/raptor_gun.dpm");
 725     precache_model ("models/vehicles/spinner.dpm");
 726     precache_model ("models/vehicles/raptor_cockpit.dpm");
 727     precache_model ("models/vehicles/clusterbomb.md3");
 728     precache_model ("models/vehicles/clusterbomb_folded.md3");
 729     precache_model ("models/vehicles/raptor_body.dpm");
 730
 731     self.think = raptor_dinit;
 732     self.nextthink = time + 1;
 733 }