qcsrc/server/vehicles/raptor.qc

   1 #ifdef SVQC
   2 #define RAPTOR_MIN '-80 -80 0'
   3 #define RAPTOR_MAX '80 80 70'
   4 //#define RAPTOR_ENGINE "sound/vehicles/raptor.wav"
   5 float autocvar_g_vehicle_raptor_respawntime;
   6
   7 float autocvar_g_vehicle_raptor_movestyle;
   8 float autocvar_g_vehicle_raptor_turnspeed;
   9 float autocvar_g_vehicle_raptor_pitchspeed;
  10 float autocvar_g_vehicle_raptor_pitchlimit;
  11
  12 float autocvar_g_vehicle_raptor_speed_forward;
  13 float autocvar_g_vehicle_raptor_speed_strafe;
  14 float autocvar_g_vehicle_raptor_speed_up;
  15 float autocvar_g_vehicle_raptor_speed_down;
  16 float autocvar_g_vehicle_raptor_friction;
  17
  18 float autocvar_g_vehicle_raptor_bomblets;
  19 float autocvar_g_vehicle_raptor_bomblet_alt;
  20 float autocvar_g_vehicle_raptor_bomblet_time;
  21 float autocvar_g_vehicle_raptor_bomblet_damage;
  22 float autocvar_g_vehicle_raptor_bomblet_spread;
  23 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  24 float autocvar_g_vehicle_raptor_bomblet_radius;
  25 float autocvar_g_vehicle_raptor_bomblet_force;
  26 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  27 float autocvar_g_vehicle_raptor_bombs_refire;
  28
  29 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  30 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  32 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  33
  34 float autocvar_g_vehicle_raptor_cannon_locktarget;
  35 float autocvar_g_vehicle_raptor_cannon_locking_time;
  36 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  37 float autocvar_g_vehicle_raptor_cannon_locked_time;
  38 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  39
  40 float autocvar_g_vehicle_raptor_cannon_cost;
  41 float autocvar_g_vehicle_raptor_cannon_damage;
  42 float autocvar_g_vehicle_raptor_cannon_radius;
  43 float autocvar_g_vehicle_raptor_cannon_refire;
  44 float autocvar_g_vehicle_raptor_cannon_speed;
  45 float autocvar_g_vehicle_raptor_cannon_spread;
  46 float autocvar_g_vehicle_raptor_cannon_force;
  47
  48 float autocvar_g_vehicle_raptor_energy;
  49 float autocvar_g_vehicle_raptor_energy_regen;
  50 float autocvar_g_vehicle_raptor_energy_regen_pause;
  51
  52 float autocvar_g_vehicle_raptor_health;
  53 float autocvar_g_vehicle_raptor_health_regen;
  54 float autocvar_g_vehicle_raptor_health_regen_pause;
  55
  56 float autocvar_g_vehicle_raptor_shield;
  57 float autocvar_g_vehicle_raptor_shield_regen;
  58 float autocvar_g_vehicle_raptor_shield_regen_pause;
  59
  60 void raptor_spawn();
  61 float raptor_frame();
  62 float raptor_takeoff();
  63
  64 .entity bomb1;
  65 .entity bomb2;
  66
  67 float raptor_altitude(float amax)
  68 {
  69         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  70     return vlen(self.origin - trace_endpos);
  71 }
  72
  73
  74 void raptor_bomblet_boom()
  75 {
  76     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  77                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  78                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  79                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_RAPTOR_BOMB, world);
  80     remove(self);
  81 }
  82
  83 void raptor_bomblet_touch()
  84 {
  85     if(other == self.owner)
  86         return;
  87
  88     PROJECTILE_TOUCH;
  89     self.think = raptor_bomblet_boom;
  90     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  91 }
  92
  93 void raptor_bomb_burst()
  94 {
  95     if(self.cnt > time)
  96     if(autocvar_g_vehicle_raptor_bomblet_alt)
  97     {
  98         self.nextthink = time;
  99         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 100         if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 101         {
 102             UpdateCSQCProjectile(self);
 103             return;
 104         }
 105     }
 106
 107     entity bomblet;
 108     float i;
 109
 110     Damage_DamageInfo(self.origin, 0, 0, 0, '0 0 0', DEATH_RAPTOR_BOMB_SPLIT, self);
 111
 112     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 113     {
 114         bomblet = spawn();
 115         setorigin(bomblet, self.origin);
 116
 117         bomblet.movetype    = MOVETYPE_TOSS;
 118         bomblet.touch       = raptor_bomblet_touch;
 119         bomblet.think       = raptor_bomblet_boom;
 120         bomblet.nextthink   = time + 5;
 121         bomblet.owner       = self.owner;
 122         bomblet.realowner   = self.realowner;
 123         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 124
 125         PROJECTILE_MAKETRIGGER(bomblet);
 126         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 127     }
 128
 129     remove(self);
 130 }
 131
 132 void raptor_bomb_touch()
 133 {
 134     raptor_bomb_burst();
 135 }
 136
 137 void raptor_bombdrop()
 138 {
 139     entity bomb_1, bomb_2;
 140
 141     bomb_1 = spawn();
 142     bomb_2 = spawn();
 143
 144     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 145     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 146
 147     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_BOUNCE;
 148     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 149     bomb_1.touch        = bomb_2.touch      = raptor_bomb_touch;
 150     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 151     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 152
 153     if(autocvar_g_vehicle_raptor_bomblet_alt)
 154         bomb_1.nextthink = bomb_2.nextthink  = time;
 155     else
 156         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 157
 158     bomb_1.owner     = bomb_2.owner      = self;
 159     bomb_1.realowner = bomb_2.realowner  = self.owner;
 160     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 161     bomb_1.gravity   = bomb_2.gravity    = 1;
 162
 163     PROJECTILE_MAKETRIGGER(bomb_1);
 164     PROJECTILE_MAKETRIGGER(bomb_2);
 165
 166     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 167     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 168
 169 }
 170
 171
 172 void raptor_fire_cannon(entity gun, string tagname)
 173 {
 174     entity bolt;
 175     vector b_org;
 176     b_org = gettaginfo(gun, gettagindex(gun, tagname));
 177     bolt = vehicles_projectile("raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 178                            b_org, normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 179                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 180                            DEATH_RAPTOR_CANNON, PROJECTILE_RAPTORCANNON, 0, TRUE, TRUE);
 181 }
 182
 183 void raptor_think()
 184 {
 185 }
 186
 187 void raptor_enter()
 188 {
 189     self.owner.PlayerPhysplug = raptor_takeoff;
 190     self.movetype       = MOVETYPE_BOUNCEMISSILE;
 191     self.solid          = SOLID_SLIDEBOX;
 192     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 193     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 194     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 195     self.tur_head.exteriormodeltoclient = self.owner;
 196
 197     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 198     self.lip   = time;
 199
 200     if(self.owner.flagcarried)
 201        setorigin(self.owner.flagcarried, '-20 0 96');
 202
 203 }
 204
 205 void raptor_land()
 206 {
 207
 208     float hgt;
 209
 210     hgt = raptor_altitude(512);
 211     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 212     self.angles_x *= 0.95;
 213     self.angles_z *= 0.95;
 214
 215     if(hgt < 128)
 216         if(self.frame != 0)
 217             self.frame = max(self.frame - 0.25, 0);
 218
 219     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 220     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 221
 222     if(hgt < 16)
 223     {
 224         self.movetype   = MOVETYPE_TOSS;
 225         self.think      = raptor_think;
 226     }
 227
 228     self.nextthink  = time;
 229 }
 230
 231 void raptor_exit(float eject)
 232 {
 233     vector spot;
 234     self.tur_head.exteriormodeltoclient = world;
 235
 236     if(self.deadflag == DEAD_NO)
 237     {
 238         self.think      = raptor_land;
 239         self.nextthink  = time;
 240     }
 241
 242     if not (self.owner)
 243         return;
 244
 245         makevectors(self.angles);
 246         if(eject)
 247         {
 248             spot = self.origin + v_forward * 100 + '0 0 64';
 249             spot = vehicles_findgoodexit(spot);
 250             setorigin(self.owner , spot);
 251             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 252         }
 253         else
 254         {
 255             spot = self.origin - v_forward * 200 + '0 0 64';
 256             spot = vehicles_findgoodexit(spot);
 257             setorigin(self.owner , spot);
 258         }
 259
 260     self.owner = world;
 261 }
 262
 263 float raptor_takeoff()
 264 {
 265     entity player, raptor;
 266
 267     player = self;
 268     raptor = self.vehicle;
 269     self   = raptor;
 270
 271     if(self.sound_nexttime < time)
 272     {
 273         self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 274         sound (self, CHAN_TRIGGER, "vehicles/raptor_speed.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 275     }
 276
 277     // Takeoff sequense
 278     if(raptor.frame < 25)
 279     {
 280         raptor.frame += 0.25;
 281         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 282         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 283         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 284         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 285
 286         setorigin(player, raptor.origin + '0 0 32');
 287     }
 288     else
 289         player.PlayerPhysplug = raptor_frame;
 290
 291     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 292         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 293
 294     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 295         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 296
 297     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 298         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 299
 300
 301     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 302     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 303
 304     VEHICLE_UPDATE_PLAYER(health, raptor);
 305     VEHICLE_UPDATE_PLAYER(energy, raptor);
 306     if(self.vehicle_flags & VHF_HASSHIELD)
 307         VEHICLE_UPDATE_PLAYER(shield, raptor);
 308
 309     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 310     self = player;
 311     return 1;
 312 }
 313
 314 float raptor_frame()
 315 {
 316     entity player, raptor;
 317     float ftmp, ftmp2;
 318     vector df;
 319
 320         if(intermission_running)
 321                 return 1;
 322
 323     player = self;
 324     raptor = self.vehicle;
 325     self   = raptor;
 326
 327     vehicles_painframe();
 328     /*
 329     ftmp = vlen(self.velocity);
 330     if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 331         ftmp = 1;
 332     else
 333         ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 334     */
 335
 336     if(self.sound_nexttime < time)
 337     {
 338         self.sound_nexttime = time + 7.955812;
 339         //sound (self.tur_head, CHAN_TRIGGER, "vehicles/raptor_fly.wav", 1 - ftmp,   ATTN_NORM );
 340         sound (self, CHAN_TRIGGER, "vehicles/raptor_speed.wav", 1, ATTN_NORM);
 341         self.wait = ftmp;
 342     }
 343     /*
 344     else if(fabs(ftmp - self.wait) > 0.2)
 345     {
 346         sound (self.tur_head, CHAN_TRIGGER, "", 1 - ftmp,   ATTN_NORM );
 347         sound (self, CHAN_TRIGGER, "", ftmp, ATTN_NORM);
 348         self.wait = ftmp;
 349     }
 350     */
 351
 352     if(raptor.deadflag != DEAD_NO)
 353     {
 354         self = player;
 355         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 356         return 1;
 357     }
 358     crosshair_trace(player);
 359
 360     vector vang;
 361     vang = raptor.angles;
 362     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 363     vang_x *= -1;
 364     df_x *= -1;
 365     if(df_x > 180)  df_x -= 360;
 366     if(df_x < -180) df_x += 360;
 367     if(df_y > 180)  df_y -= 360;
 368     if(df_y < -180) df_y += 360;
 369
 370     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 371     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 372     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 373
 374     // Pitch
 375     ftmp = 0;
 376     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 377     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 378
 379     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 380     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 381     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 382
 383     raptor.angles_x = anglemods(raptor.angles_x);
 384     raptor.angles_y = anglemods(raptor.angles_y);
 385     raptor.angles_z = anglemods(raptor.angles_z);
 386
 387
 388     if(autocvar_g_vehicle_raptor_movestyle == 1)
 389         makevectors('0 1 0' * raptor.angles_y);
 390     else
 391         makevectors(player.v_angle);
 392
 393     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 394
 395     if(player.movement_x != 0)
 396     {
 397         if(player.movement_x > 0)
 398             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 399         else if(player.movement_x < 0)
 400             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 401     }
 402
 403     if(player.movement_y != 0)
 404     {
 405         if(player.movement_y < 0)
 406             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 407         else if(player.movement_y > 0)
 408             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 409
 410         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 411     }
 412     else
 413     {
 414         raptor.angles_z *= 0.95;
 415         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 416             raptor.angles_z = 0;
 417     }
 418
 419     if(player.BUTTON_CROUCH)
 420         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 421     else if (player.BUTTON_JUMP)
 422         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 423
 424     raptor.velocity  += df * frametime;
 425     //player.velocity = raptor.velocity;
 426     player.velocity = player.movement  = raptor.velocity;
 427     setorigin(player, raptor.origin + '0 0 32');
 428
 429     vector vf, ad;
 430     // Target lock & predict
 431     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 432     {
 433
 434         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 435                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 436                              autocvar_g_vehicle_raptor_cannon_locked_time);
 437
 438         if(self.lock_target != world)
 439         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 440         if(self.lock_strength == 1)
 441         {
 442             float i, distance, impact_time;
 443
 444             vf = real_origin(raptor.lock_target);
 445             ad = vf;
 446             for(i = 0; i < 4; ++i)
 447             {
 448                 distance = vlen(ad - raptor.origin);
 449                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 450                 ad = vf + raptor.lock_target.velocity * impact_time;
 451             }
 452             trace_endpos = ad;
 453         }
 454
 455         if(self.lock_target)
 456         {
 457             if(raptor.lock_strength == 1)
 458                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 459             else if(self.lock_strength > 0.5)
 460                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 461             else if(self.lock_strength < 0.5)
 462                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 463         }
 464     }
 465
 466     // Aim the gunz
 467     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 468     ftmp = -ftmp2;
 469
 470     // Gun1
 471     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 472     //ad = df;
 473     //vf = v_forward;
 474     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 475     df = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(raptor.angles), AnglesTransform_FromAngles(df))) - raptor.gun1.angles;
 476     df = shortangle_vxy(df, raptor.gun1.angles);
 477
 478     // Bind to aimspeed
 479     df_x = bound(ftmp, df_x, ftmp2);
 480     df_y = bound(ftmp, df_y, ftmp2);
 481     // Bind to limts
 482     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 483     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 484
 485     // Gun2
 486     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 487     //ad += df;
 488     //vf += v_forward;
 489     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 490     df = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(raptor.angles), AnglesTransform_FromAngles(df))) - raptor.gun2.angles;
 491     df = shortangle_vxy(df, raptor.gun2.angles);
 492
 493     // Bind to aimspeed
 494     df_x = bound(ftmp, df_x, ftmp2);
 495     df_y = bound(ftmp, df_y, ftmp2);
 496     // Bind to limts
 497     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 498     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 499
 500     /*
 501     ad = ad * 0.5;
 502     v_forward = vf * 0.5;
 503     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 504     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 505     */
 506
 507     if(player.BUTTON_ATCK)
 508     if(raptor.attack_finished_single <= time)
 509     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 510     {
 511         raptor.misc_bulletcounter += 1;
 512         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 513         if(raptor.misc_bulletcounter <= 2)
 514             raptor_fire_cannon(self.gun1, "fire1");
 515         else if(raptor.misc_bulletcounter == 3)
 516             raptor_fire_cannon(self.gun2, "fire1");
 517         else
 518         {
 519             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 520             raptor_fire_cannon(self.gun2, "fire1");
 521             raptor.misc_bulletcounter = 0;
 522         }
 523         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 524         self.cnt = time;
 525     }
 526
 527     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 528         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 529
 530     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 531         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 532
 533     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 534         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 535
 536
 537     if(time > raptor.delay)
 538     if(player.BUTTON_ATCK2)
 539     {
 540         raptor_bombdrop();
 541         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 542         raptor.lip   = time;
 543     }
 544
 545     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 546     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 547
 548     VEHICLE_UPDATE_PLAYER(health, raptor);
 549     VEHICLE_UPDATE_PLAYER(energy, raptor);
 550     if(self.vehicle_flags & VHF_HASSHIELD)
 551         VEHICLE_UPDATE_PLAYER(shield, raptor);
 552
 553     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 554     return 1;
 555 }
 556
 557 void raptor_blowup()
 558 {
 559     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 560     pointparticles(particleeffectnum("explosion_big"), self.origin, '0 0 0', 1);
 561
 562     self.deadflag    = DEAD_DEAD;
 563     self.vehicle_exit(VHEF_NORMAL);
 564     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 565
 566     self.alpha          = -1;
 567     self.movetype       = MOVETYPE_NONE;
 568     self.effects        = EF_NODRAW;
 569     self.colormod       = '0 0 0';
 570     self.avelocity      = '0 0 0';
 571     self.velocity       = '0 0 0';
 572
 573     setorigin(self, self.pos1);
 574     self.touch = SUB_Null;
 575     self.nextthink = 0;
 576 }
 577
 578 void raptor_diethink()
 579 {
 580     //self.avelocity += '0 0.5 1' * (random() * 5);
 581     //self.avelocity -= '0 0.5 1' * (random() * 5);
 582
 583     if(random() < 0.1)
 584     {
 585         sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 586         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 587     }
 588     self.nextthink = time + 0.1;
 589 }
 590
 591 void raptor_die()
 592 {
 593     self.health       = 0;
 594     self.event_damage = SUB_Null;
 595     self.iscreature   = FALSE;
 596     self.solid        = SOLID_CORPSE;
 597     self.takedamage   = DAMAGE_NO;
 598     self.deadflag     = DEAD_DYING;
 599     self.movetype     = MOVETYPE_BOUNCE;
 600     self.think        = raptor_diethink;
 601     self.nextthink    = time;
 602
 603     pointparticles(particleeffectnum("explosion_medium"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 604
 605     self.velocity_z += 600;
 606
 607     self.avelocity = '0 0.5 1' * (random() * 400);
 608     self.avelocity -= '0 0.5 1' * (random() * 400);
 609
 610     self.colormod = '-0.5 -0.5 -0.5';
 611         self.touch     = raptor_blowup;
 612 }
 613
 614 void raptor_spawn()
 615 {
 616     self.frame          = 0;
 617     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 618     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 619     self.movetype       = MOVETYPE_TOSS;
 620     self.solid          = SOLID_SLIDEBOX;
 621     self.vehicle_energy = 1;
 622
 623     self.bomb1.gun1.avelocity_y = 90;
 624     self.bomb1.gun2.avelocity_y = -90;
 625
 626     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 627     self.delay = time;
 628 }
 629
 630 // If we dont do this ever now and then, the raptors rotors
 631 // stop working, presumably due to angle overflow. cute.
 632 void raptor_rotor_anglefix()
 633 {
 634     self.gun1.angles_y = anglemods(self.gun1.angles_y);
 635     self.gun2.angles_y = anglemods(self.gun2.angles_y);
 636     self.nextthink = time + 15;
 637 }
 638
 639 void raptor_dinit()
 640 {
 641     entity spinner;
 642     vector ofs;
 643
 644     if not (vehicle_initialize(
 645              "Raptor",
 646              "models/vehicles/raptor.dpm",
 647              "",
 648              "models/vehicles/raptor_cockpit.dpm",
 649              "", "tag_hud", "tag_camera",
 650              HUD_RAPTOR,
 651              RAPTOR_MIN, RAPTOR_MAX,
 652              FALSE,
 653              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 654              raptor_frame,
 655              raptor_enter, raptor_exit,
 656              raptor_die,   raptor_think,
 657              FALSE))
 658     {
 659         remove(self);
 660         return;
 661     }
 662
 663     //FIXME: Camera is in a bad place in HUD model.
 664     //setorigin(self.vehicle_viewport, '25 0 5');
 665
 666     self.frame = 0;
 667
 668     self.bomb1 = spawn();
 669     self.bomb2 = spawn();
 670     self.gun1  = spawn();
 671     self.gun2  = spawn();
 672
 673     setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 674     setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 675     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 676     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 677     setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 678
 679     setattachment(self.bomb1, self,"bombmount_left");
 680     setattachment(self.bomb2, self,"bombmount_right");
 681     setattachment(self.tur_head, self,"root");
 682
 683
 684     // FIXME Guns mounts to angled bones
 685     self.bomb1.angles = self.angles;
 686     self.angles = '0 0 0';
 687     // This messes up gun-aim, so work arround it.
 688     //setattachment(self.gun1, self, "gunmount_left");
 689     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 690     ofs -= self.origin;
 691     setattachment(self.gun1, self, "");
 692     setorigin(self.gun1, ofs);
 693
 694     //setattachment(self.gun2, self, "gunmount_right");
 695     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 696     ofs -= self.origin;
 697     setattachment(self.gun2, self, "");
 698     setorigin(self.gun2, ofs);
 699
 700     self.angles = self.bomb1.angles;
 701     self.bomb1.angles = '0 0 0';
 702
 703     spinner = spawn();
 704     spinner.owner = self;
 705     setmodel(spinner,"models/vehicles/spinner.dpm");
 706     setattachment(spinner, self, "engine_left");
 707     spinner.movetype = MOVETYPE_NOCLIP;
 708     spinner.avelocity = '0 90 0';
 709     self.bomb1.gun1 = spinner;
 710
 711     spinner = spawn();
 712     spinner.owner = self;
 713     setmodel(spinner,"models/vehicles/spinner.dpm");
 714     setattachment(spinner, self, "engine_right");
 715     spinner.movetype = MOVETYPE_NOCLIP;
 716     spinner.avelocity = '0 -90 0';
 717     self.bomb1.gun2 = spinner;
 718
 719     // Sigh.
 720     self.bomb1.think = raptor_rotor_anglefix;
 721     self.bomb1.nextthink = time;
 722
 723     self.mass               = 1 ;
 724 }
 725
 726 void spawnfunc_vehicle_raptor()
 727 {
 728     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 729
 730     self.vehicle_flags |= VHF_DMGSHAKE;
 731     self.vehicle_flags |= VHF_DMGROLL;
 732
 733     if(autocvar_g_vehicle_raptor_shield)
 734         self.vehicle_flags |= VHF_HASSHIELD;
 735
 736     if(autocvar_g_vehicle_raptor_shield_regen)
 737         self.vehicle_flags |= VHF_SHIELDREGEN;
 738
 739     if(autocvar_g_vehicle_raptor_health_regen)
 740         self.vehicle_flags |= VHF_HEALTHREGEN;
 741
 742     if(autocvar_g_vehicle_raptor_energy_regen)
 743         self.vehicle_flags |= VHF_ENERGYREGEN;
 744
 745     precache_model ("models/vehicles/raptor.dpm");
 746     precache_model ("models/vehicles/raptor_gun.dpm");
 747     precache_model ("models/vehicles/spinner.dpm");
 748     precache_model ("models/vehicles/raptor_cockpit.dpm");
 749     precache_model ("models/vehicles/clusterbomb.md3");
 750     precache_model ("models/vehicles/clusterbomb_folded.md3");
 751     precache_model ("models/vehicles/raptor_body.dpm");
 752
 753     precache_sound ("vehicles/raptor_fly.wav");
 754     precache_sound ("vehicles/raptor_speed.wav");
 755     precache_sound ("");
 756
 757     self.think = raptor_dinit;
 758     self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_raptor_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 759 }
 760 #endif // SVQC