qcsrc/server/vehicles/raptor.qc

   1 #ifdef SVQC
   2 #define RAPTOR_MIN '-80 -80 0'
   3 #define RAPTOR_MAX '80 80 70'
   4 //#define RAPTOR_ENGINE "sound/vehicles/raptor.wav"
   5 float autocvar_g_vehicle_raptor_respawntime;
   6
   7 float autocvar_g_vehicle_raptor_movestyle;
   8 float autocvar_g_vehicle_raptor_turnspeed;
   9 float autocvar_g_vehicle_raptor_pitchspeed;
  10 float autocvar_g_vehicle_raptor_pitchlimit;
  11
  12 float autocvar_g_vehicle_raptor_speed_forward;
  13 float autocvar_g_vehicle_raptor_speed_strafe;
  14 float autocvar_g_vehicle_raptor_speed_up;
  15 float autocvar_g_vehicle_raptor_speed_down;
  16 float autocvar_g_vehicle_raptor_friction;
  17
  18 float autocvar_g_vehicle_raptor_bomblets;
  19 float autocvar_g_vehicle_raptor_bomblet_alt;
  20 float autocvar_g_vehicle_raptor_bomblet_time;
  21 float autocvar_g_vehicle_raptor_bomblet_damage;
  22 float autocvar_g_vehicle_raptor_bomblet_spread;
  23 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  24 float autocvar_g_vehicle_raptor_bomblet_radius;
  25 float autocvar_g_vehicle_raptor_bomblet_force;
  26 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  27 float autocvar_g_vehicle_raptor_bombs_refire;
  28
  29 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  30 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  32 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  33
  34 float autocvar_g_vehicle_raptor_cannon_locktarget;
  35 float autocvar_g_vehicle_raptor_cannon_locking_time;
  36 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  37 float autocvar_g_vehicle_raptor_cannon_locked_time;
  38 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  39
  40 float autocvar_g_vehicle_raptor_cannon_cost;
  41 float autocvar_g_vehicle_raptor_cannon_damage;
  42 float autocvar_g_vehicle_raptor_cannon_radius;
  43 float autocvar_g_vehicle_raptor_cannon_refire;
  44 float autocvar_g_vehicle_raptor_cannon_speed;
  45 float autocvar_g_vehicle_raptor_cannon_spread;
  46 float autocvar_g_vehicle_raptor_cannon_force;
  47
  48 float autocvar_g_vehicle_raptor_energy;
  49 float autocvar_g_vehicle_raptor_energy_regen;
  50 float autocvar_g_vehicle_raptor_energy_regen_pause;
  51
  52 float autocvar_g_vehicle_raptor_health;
  53 float autocvar_g_vehicle_raptor_health_regen;
  54 float autocvar_g_vehicle_raptor_health_regen_pause;
  55
  56 float autocvar_g_vehicle_raptor_shield;
  57 float autocvar_g_vehicle_raptor_shield_regen;
  58 float autocvar_g_vehicle_raptor_shield_regen_pause;
  59
  60 void raptor_spawn();
  61 float raptor_frame();
  62 float raptor_takeoff();
  63
  64 .entity bomb1;
  65 .entity bomb2;
  66
  67 //#define RAPTOR_RETARDCAMERA
  68
  69 float raptor_altitude(float amax)
  70 {
  71         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  72     return vlen(self.origin - trace_endpos);
  73 }
  74
  75
  76 void raptor_bomblet_boom()
  77 {
  78     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  79                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  80                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  81                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_RAPTOR_BOMB, world);
  82     remove(self);
  83 }
  84
  85 void raptor_bomblet_touch()
  86 {
  87     if(other == self.owner)
  88         return;
  89
  90     PROJECTILE_TOUCH;
  91     self.think = raptor_bomblet_boom;
  92     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  93 }
  94
  95 void raptor_bomb_burst()
  96 {
  97     if(self.cnt > time)
  98     if(autocvar_g_vehicle_raptor_bomblet_alt)
  99     {
 100         self.nextthink = time;
 101         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 102         if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 103         {
 104             UpdateCSQCProjectile(self);
 105             return;
 106         }
 107     }
 108
 109     entity bomblet;
 110     float i;
 111
 112     //sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 113     //pointparticles(particleeffectnum("raptor_bomb_spread"), self.origin, self.velocity, 1);
 114
 115     Damage_DamageInfo(self.origin, 0, 0, 0, '0 0 0', DEATH_RAPTOR_BOMB_SPLIT, self);
 116
 117     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 118     {
 119         bomblet = spawn();
 120         setorigin(bomblet, self.origin);
 121
 122         bomblet.movetype    = MOVETYPE_TOSS;
 123         bomblet.touch       = raptor_bomblet_touch;
 124         bomblet.think       = raptor_bomblet_boom;
 125         bomblet.nextthink   = time + 5;
 126         bomblet.owner       = self.owner;
 127         bomblet.realowner   = self.realowner;
 128         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 129
 130         PROJECTILE_MAKETRIGGER(bomblet);
 131         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 132     }
 133
 134     remove(self);
 135 }
 136
 137 void raptor_bomb_touch()
 138 {
 139     raptor_bomb_burst();
 140 }
 141
 142 void raptor_bombdrop()
 143 {
 144     entity bomb_1, bomb_2;
 145
 146     //self.bomb1.alpha = 0;
 147     //self.bomb2.alpha = 0;
 148
 149     bomb_1 = spawn();
 150     bomb_2 = spawn();
 151
 152     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 153     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 154
 155     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_BOUNCE;
 156     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 157     bomb_1.touch        = bomb_2.touch      = raptor_bomb_touch;
 158     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 159     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 160
 161     if(autocvar_g_vehicle_raptor_bomblet_alt)
 162         bomb_1.nextthink = bomb_2.nextthink  = time;
 163     else
 164         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 165
 166     bomb_1.owner     = bomb_2.owner      = self;
 167     bomb_1.realowner = bomb_2.realowner  = self.owner;
 168     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 169     bomb_1.gravity   = bomb_2.gravity    = 1;
 170
 171     PROJECTILE_MAKETRIGGER(bomb_1);
 172     PROJECTILE_MAKETRIGGER(bomb_2);
 173
 174     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 175     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 176
 177 }
 178
 179
 180 void raptor_fire_cannon(entity gun, string tagname)
 181 {
 182     entity bolt;
 183     vector b_org;
 184     b_org = gettaginfo(gun, gettagindex(gun, tagname));
 185     bolt = vehicles_projectile("raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 186                            b_org, normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 187                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 188                            DEATH_RAPTOR_CANNON, PROJECTILE_RAPTORCANNON, 0, TRUE, TRUE);
 189 }
 190
 191 void raptor_think()
 192 {
 193 }
 194
 195 void raptor_enter()
 196 {
 197     self.owner.PlayerPhysplug = raptor_takeoff;
 198     self.movetype       = MOVETYPE_BOUNCEMISSILE;
 199     self.solid          = SOLID_SLIDEBOX;
 200     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 201     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 202     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 203     self.tur_head.exteriormodeltoclient = self.owner;
 204
 205     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 206     self.lip   = time;
 207
 208 #ifdef RAPTOR_RETARDCAMERA
 209     setorigin(self.vehicle_viewport, self.origin);
 210 #endif
 211 }
 212
 213 void raptor_land()
 214 {
 215     float hgt;
 216
 217     hgt = raptor_altitude(512);
 218     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 219     self.angles_x *= 0.95;
 220     self.angles_z *= 0.95;
 221
 222     if(hgt < 128)
 223         if(self.frame != 0)
 224             self.frame = max(self.frame - 0.25, 0);
 225
 226     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 227     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 228
 229     if(hgt < 16)
 230     {
 231         self.movetype   = MOVETYPE_TOSS;
 232         self.think      = raptor_think;
 233     }
 234
 235     self.nextthink  = time;
 236 }
 237
 238 void raptor_exit(float eject)
 239 {
 240     self.tur_head.exteriormodeltoclient = world;
 241
 242     if(self.deadflag == DEAD_NO)
 243     {
 244         self.think      = raptor_land;
 245         self.nextthink  = time;
 246     }
 247
 248     if not (self.owner)
 249         return;
 250
 251         makevectors(self.angles);
 252         if(eject)
 253         {
 254             setorigin(self.owner,self.origin + v_forward * 100 + '0 0 64');
 255             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 256         }
 257         else
 258         setorigin(self.owner,self.origin - v_forward * 200 + '0 0 64');
 259
 260     self.owner = world;
 261 }
 262
 263 float raptor_takeoff()
 264 {
 265     entity player, raptor;
 266
 267     player = self;
 268     raptor = self.vehicle;
 269     self   = raptor;
 270
 271     if(self.sound_nexttime < time)
 272     {
 273         self.sound_nexttime = time + soundlength("vehicles/raptor_fly.wav");
 274         sound (self, CHAN_VOICE, "vehicles/raptor_fly.wav", VOL_BASE, ATTN_NORM);
 275     }
 276
 277     // Takeoff sequense
 278     if(raptor.frame < 25)
 279     {
 280         raptor.frame += 0.25;
 281         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 282         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 283         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 284         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 285
 286         setorigin(player, raptor.origin + '0 0 32');
 287     }
 288     else
 289         player.PlayerPhysplug = raptor_frame;
 290
 291     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 292         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 293
 294     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 295         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 296
 297     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 298         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 299
 300
 301     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 302     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 303
 304     VEHICLE_UPDATE_PLAYER(health, raptor);
 305     VEHICLE_UPDATE_PLAYER(energy, raptor);
 306     if(self.vehicle_flags & VHF_HASSHIELD)
 307         VEHICLE_UPDATE_PLAYER(shield, raptor);
 308
 309     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 310     self = player;
 311     return 1;
 312 }
 313
 314 float raptor_frame()
 315 {
 316     entity player, raptor;
 317     float ftmp, ftmp2;
 318     vector df, ra;
 319
 320     player = self;
 321     raptor = self.vehicle;
 322     self   = raptor;
 323
 324     ftmp = vlen(self.velocity);
 325     if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 326         ftmp = 1;
 327     else
 328         ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 329
 330     if(fabs(ftmp - self.wait) > 0.2 || self.sound_nexttime < time)
 331     {
 332         self.sound_nexttime = time + soundlength("vehicles/raptor_fly.wav");
 333         sound (self, CHAN_VOICE, "vehicles/raptor_fly.wav", 1 - ftmp,   ATTN_NORM );
 334         sound (self, CHAN_PLAYER, "vehicles/raptor_speed.wav", ftmp, ATTN_NORM);
 335         self.wait = ftmp;
 336     }
 337
 338     if(player.BUTTON_USE && raptor.deadflag == DEAD_NO)
 339     {
 340         self = raptor;
 341         vehicles_exit(VHEF_NORMAL);
 342         self = player;
 343         return 0;
 344     }
 345
 346     if(raptor.deadflag != DEAD_NO)
 347     {
 348         self = player;
 349         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 350         return 1;
 351     }
 352     crosshair_trace(player);
 353
 354 #if VEHICLES_VIEWROTATE_CROSSHAIR
 355     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 356     if(df_x > 180)  df_x -= 360;
 357     if(df_x < -180) df_x += 360;--
 358     if(df_y > 180)  df_y -= 360;
 359     if(df_y < -180) df_y += 360;
 360
 361     // Rotate Body
 362     ftmp = autocvar_g_vehicle_raptor_turnspeed * sys_frametime;
 363     ftmp = bound(-ftmp, shortangle_f(df_y - raptor.angles_y, raptor.angles_y), ftmp);
 364
 365     // Turn
 366     //raptor.angles_y = anglemods(raptor.angles_y + ftmp);
 367     raptor.avelocity_y = anglemods(raptor.angles_y + ftmp);
 368
 369     // Pitch Body
 370     ftmp = autocvar_g_vehicle_raptor_pitchspeed  * sys_frametime;
 371     ftmp = bound(-ftmp, shortangle_f(df_x - raptor.angles_x, raptor.angles_x), ftmp);
 372
 373     //raptor.angles_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 374     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 375 #else
 376     vector vang;
 377     vang = raptor.angles;
 378     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 379     vang_x *= -1;
 380     df_x *= -1;
 381     if(df_x > 180)  df_x -= 360;
 382     if(df_x < -180) df_x += 360;
 383     if(df_y > 180)  df_y -= 360;
 384     if(df_y < -180) df_y += 360;
 385
 386     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 387     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 388     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 389
 390     // Pitch
 391     ftmp = 0;
 392     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 393     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 394
 395     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 396     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 397     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 398
 399     raptor.angles_x = anglemods(raptor.angles_x);
 400     raptor.angles_y = anglemods(raptor.angles_y);
 401     raptor.angles_z = anglemods(raptor.angles_z);
 402
 403 #endif
 404
 405     if(autocvar_g_vehicle_raptor_movestyle == 1)
 406         makevectors('0 1 0' * raptor.angles_y);
 407     else
 408         makevectors(player.v_angle);
 409
 410 #ifdef RAPTOR_RETARDCAMERA
 411     float spd, back, up;
 412     spd = vlen(self.velocity) + 0.01;
 413     back = spd / autocvar_g_vehicle_raptor_speed_forward;
 414     up = 1 - back;
 415     back = back;
 416     back = back * 1250;
 417     back += 150;
 418     up = up * 200;
 419     up = up + 100;
 420
 421     setorigin(self.vehicle_viewport, self.origin + (v_up * up) + (v_forward * -back));
 422 #endif
 423
 424     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 425
 426     if(player.movement_x != 0)
 427     {
 428         if(player.movement_x > 0)
 429             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 430         else if(player.movement_x < 0)
 431             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 432     }
 433
 434     if(player.movement_y != 0)
 435     {
 436         if(player.movement_y < 0)
 437             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 438         else if(player.movement_y > 0)
 439             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 440
 441         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 442     }
 443     else
 444     {
 445         raptor.angles_z *= 0.95;
 446         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 447             raptor.angles_z = 0;
 448     }
 449
 450     if(player.BUTTON_CROUCH)
 451         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 452     else if (player.BUTTON_JUMP)
 453         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 454
 455     raptor.velocity  += df * frametime;
 456     //player.velocity = player.movement  = raptor.velocity;
 457     player.velocity = raptor.velocity;
 458     //setorigin(player,raptor.origin + '0 0 32');
 459
 460     vector vf, ad;
 461     // Target lock & predict
 462     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 463     {
 464
 465         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 466                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 467                              autocvar_g_vehicle_raptor_cannon_locked_time);
 468
 469         if(self.lock_target != world)
 470         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 471         if(self.lock_strength == 1)
 472         {
 473             float i, distance, impact_time;
 474
 475             vf = real_origin(raptor.lock_target);
 476             ad = vf;
 477             for(i = 0; i < 4; ++i)
 478             {
 479                 distance = vlen(ad - raptor.origin);
 480                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 481                 ad = vf + raptor.lock_target.velocity * impact_time;
 482             }
 483             trace_endpos = ad;
 484             //UpdateAuxiliaryXhair(player, trace_endpos, '1 1 1', 0);
 485         }
 486
 487         if(self.lock_target)
 488         {
 489             if(raptor.lock_strength == 1)
 490                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 491             else if(self.lock_strength > 0.5)
 492                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 493             else if(self.lock_strength < 0.5)
 494                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 495         }
 496     }
 497
 498     ra = raptor.angles;
 499     ra_z = 0;
 500     // Aim the gunz
 501     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 502     ftmp = -ftmp2;
 503
 504     // Gun1
 505     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 506     //ad = df;
 507     //vf = v_forward;
 508     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 509     df = shortangle_vxy(df - (ra + raptor.gun1.angles), ra + raptor.gun1.angles);     // Find aim offset
 510     // Bind to aimspeed
 511     df_x = bound(ftmp, df_x, ftmp2);
 512     df_y = bound(ftmp, df_y, ftmp2);
 513     // Bind to limts
 514     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 515     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 516
 517     //df = vectoangles(normalize(trace_endpos - df));
 518
 519     //Gun 2
 520     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 521     //ad += df;
 522     //vf += v_forward;
 523     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 524     df = shortangle_vxy(df - (ra + raptor.gun2.angles), ra + raptor.gun2.angles);     // Find aim offset
 525     // Bind to aimspeed
 526     df_x = bound(ftmp, df_x, ftmp2);
 527     df_y = bound(ftmp, df_y, ftmp2);
 528     // Bind to limts
 529     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 530     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 531
 532     /*
 533     ad = ad * 0.5;
 534     v_forward = vf * 0.5;
 535     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 536     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 537     */
 538
 539     if(player.BUTTON_ATCK)
 540     if(raptor.attack_finished_single <= time)
 541     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 542     {
 543         raptor.misc_bulletcounter += 1;
 544         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 545         if(raptor.misc_bulletcounter <= 2)
 546             raptor_fire_cannon(self.gun1, "fire1");
 547         else if(raptor.misc_bulletcounter == 3)
 548             raptor_fire_cannon(self.gun2, "fire1");
 549         else
 550         {
 551             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 552             raptor_fire_cannon(self.gun2, "fire1");
 553             raptor.misc_bulletcounter = 0;
 554         }
 555         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 556         self.cnt = time;
 557     }
 558
 559     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 560         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 561
 562     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 563         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 564
 565     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 566         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 567
 568
 569     if(time > raptor.delay)
 570     if(player.BUTTON_ATCK2)
 571     {
 572         raptor_bombdrop();
 573         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 574         raptor.lip   = time;
 575     }
 576
 577     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 578     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 579
 580     VEHICLE_UPDATE_PLAYER(health, raptor);
 581     VEHICLE_UPDATE_PLAYER(energy, raptor);
 582     if(self.vehicle_flags & VHF_HASSHIELD)
 583         VEHICLE_UPDATE_PLAYER(shield, raptor);
 584
 585     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 586     return 1;
 587 }
 588
 589 void raptor_blowup()
 590 {
 591     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 592     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 593
 594     self.deadflag    = DEAD_DEAD;
 595     self.vehicle_exit(VHEF_NORMAL);
 596     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 597
 598     self.alpha          = -1;
 599     self.movetype       = MOVETYPE_NONE;
 600     self.effects        = EF_NODRAW;
 601     self.colormod       = '0 0 0';
 602     self.avelocity      = '0 0 0';
 603     self.velocity       = '0 0 0';
 604
 605     setorigin(self, self.pos1);
 606     self.touch = SUB_Null;
 607 }
 608
 609 void raptor_die()
 610 {
 611     self.health       = 0;
 612     self.event_damage = SUB_Null;
 613     self.iscreature   = FALSE;
 614     self.solid        = SOLID_CORPSE;
 615     self.takedamage   = DAMAGE_NO;
 616     self.deadflag     = DEAD_DYING;
 617     self.movetype     = MOVETYPE_BOUNCE;
 618
 619     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 620
 621     self.velocity_z += 128;
 622
 623     if(random() < 0.5)
 624         self.avelocity_z  = 45 + random() * 270;
 625     else
 626         self.avelocity_z  = -45 + random() * -270;
 627
 628     self.colormod = '-0.5 -0.5 -0.5';
 629         self.touch     = raptor_blowup;
 630 }
 631
 632 void raptor_spawn()
 633 {
 634     self.frame          = 0;
 635     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 636     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 637     self.movetype       = MOVETYPE_TOSS;
 638     self.solid          = SOLID_SLIDEBOX;
 639     self.vehicle_energy = 1;
 640
 641     self.bomb1.gun1.avelocity_y = 90;
 642     self.bomb1.gun2.avelocity_y = -90;
 643
 644     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 645     self.delay = time;
 646 }
 647
 648 // If we dont do this ever now and then, the raptors rotors
 649 // stop working, presumably due to angle overflow. cute.
 650 void raptor_rotor_anglefix()
 651 {
 652     self.gun1.angles_y = anglemods(self.gun1.angles_y);
 653     self.gun2.angles_y = anglemods(self.gun2.angles_y);
 654     self.nextthink = time + 15;
 655 }
 656
 657 void raptor_dinit()
 658 {
 659     entity spinner;
 660     vector ofs;
 661
 662     if not (vehicle_initialize(
 663              "Raptor",
 664              "models/vehicles/raptor.dpm",
 665              "",
 666              "models/vehicles/raptor_cockpit.dpm",
 667              "", "tag_hud", "tag_camera",
 668              HUD_RAPTOR,
 669              RAPTOR_MIN, RAPTOR_MAX,
 670              FALSE,
 671              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 672              raptor_frame,
 673              raptor_enter, raptor_exit,
 674              raptor_die,   raptor_think,
 675              FALSE))
 676     {
 677         remove(self);
 678         return;
 679     }
 680
 681     //FIXME: Camera is in a bad place in HUD model.
 682     //setorigin(self.vehicle_viewport, '25 0 5');
 683
 684     self.frame = 0;
 685
 686     self.bomb1 = spawn();
 687     self.bomb2 = spawn();
 688     self.gun1  = spawn();
 689     self.gun2  = spawn();
 690
 691 #ifdef RAPTOR_RETARDCAMERA
 692     setattachment(self.vehicle_viewport, world, "");
 693 #endif
 694
 695     setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 696     setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 697     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 698     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 699     setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 700
 701     setattachment(self.bomb1, self,"bombmount_left");
 702     setattachment(self.bomb2, self,"bombmount_right");
 703     setattachment(self.tur_head, self,"root");
 704
 705
 706     // FIXME Guns mounts to angled bones
 707     self.bomb1.angles = self.angles;
 708     self.angles = '0 0 0';
 709     // This messes up gun-aim, so work arround it.
 710     //setattachment(self.gun1, self, "gunmount_left");
 711     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 712     ofs -= self.origin;
 713     setattachment(self.gun1, self, "");
 714     setorigin(self.gun1, ofs);
 715
 716     //setattachment(self.gun2, self, "gunmount_right");
 717     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 718     ofs -= self.origin;
 719     setattachment(self.gun2, self, "");
 720     setorigin(self.gun2, ofs);
 721
 722     self.angles = self.bomb1.angles;
 723     self.bomb1.angles = '0 0 0';
 724
 725     spinner = spawn();
 726     spinner.owner = self;
 727     setmodel(spinner,"models/vehicles/spinner.dpm");
 728     setattachment(spinner, self, "engine_left");
 729     spinner.movetype = MOVETYPE_NOCLIP;
 730     spinner.avelocity = '0 90 0';
 731     self.bomb1.gun1 = spinner;
 732
 733     spinner = spawn();
 734     spinner.owner = self;
 735     setmodel(spinner,"models/vehicles/spinner.dpm");
 736     setattachment(spinner, self, "engine_right");
 737     spinner.movetype = MOVETYPE_NOCLIP;
 738     spinner.avelocity = '0 -90 0';
 739     self.bomb1.gun2 = spinner;
 740
 741     // Sigh.
 742     self.bomb1.think = raptor_rotor_anglefix;
 743     self.bomb1.nextthink = time;
 744
 745     self.mass               = 1 ;
 746 }
 747
 748 void spawnfunc_vehicle_raptor()
 749 {
 750     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 751
 752
 753
 754     if(autocvar_g_vehicle_raptor_shield)
 755         self.vehicle_flags |= VHF_HASSHIELD;
 756
 757     if(autocvar_g_vehicle_raptor_shield_regen)
 758         self.vehicle_flags |= VHF_SHIELDREGEN;
 759
 760     if(autocvar_g_vehicle_raptor_health_regen)
 761         self.vehicle_flags |= VHF_HEALTHREGEN;
 762
 763     if(autocvar_g_vehicle_raptor_energy_regen)
 764         self.vehicle_flags |= VHF_ENERGYREGEN;
 765
 766     precache_model ("models/vehicles/raptor.dpm");
 767     precache_model ("models/vehicles/raptor_gun.dpm");
 768     precache_model ("models/vehicles/spinner.dpm");
 769     precache_model ("models/vehicles/raptor_cockpit.dpm");
 770     precache_model ("models/vehicles/clusterbomb.md3");
 771     precache_model ("models/vehicles/clusterbomb_folded.md3");
 772     precache_model ("models/vehicles/raptor_body.dpm");
 773     precache_sound ("vehicles/raptor_fly.wav");
 774     precache_sound ("vehicles/raptor_speed.wav");
 775
 776     self.think = raptor_dinit;
 777     self.nextthink = time + 1;
 778 }
 779 #endif // SVQC
 780
 781 #ifdef CSQC
 782 void raptor_draw()
 783 {
 784
 785 }
 786
 787 void raptor_draw2d()
 788 {
 789
 790 }
 791
 792 void raptor_read_extra()
 793 {
 794
 795 }
 796
 797 void vehicle_raptor_assemble()
 798 {
 799
 800 }
 801 #endif //CSQC