qcsrc/server/vehicles/raptor.qc

   1 #define RAPTOR_MIN '-80 -80 0'
   2 #define RAPTOR_MAX '80 80 70'
   3
   4 float autocvar_g_vehicle_raptor_respawntime;
   5
   6 float autocvar_g_vehicle_raptor_movestyle;
   7 float autocvar_g_vehicle_raptor_turnspeed;
   8 float autocvar_g_vehicle_raptor_pitchspeed;
   9 float autocvar_g_vehicle_raptor_pitchlimit;
  10
  11 float autocvar_g_vehicle_raptor_speed_forward;
  12 float autocvar_g_vehicle_raptor_speed_strafe;
  13 float autocvar_g_vehicle_raptor_speed_up;
  14 float autocvar_g_vehicle_raptor_speed_down;
  15 float autocvar_g_vehicle_raptor_friction;
  16
  17 float autocvar_g_vehicle_raptor_bomblets;
  18 float autocvar_g_vehicle_raptor_bomblet_alt;
  19 float autocvar_g_vehicle_raptor_bomblet_time;
  20 float autocvar_g_vehicle_raptor_bomblet_damage;
  21 float autocvar_g_vehicle_raptor_bomblet_spread;
  22 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  23 float autocvar_g_vehicle_raptor_bomblet_radius;
  24 float autocvar_g_vehicle_raptor_bomblet_force;
  25 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  26 float autocvar_g_vehicle_raptor_bombs_refire;
  27
  28 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  29 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  30 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  32
  33 float autocvar_g_vehicle_raptor_cannon_locktarget;
  34 float autocvar_g_vehicle_raptor_cannon_locking_time;
  35 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  36 float autocvar_g_vehicle_raptor_cannon_locked_time;
  37 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  38
  39 float autocvar_g_vehicle_raptor_cannon_cost;
  40 float autocvar_g_vehicle_raptor_cannon_damage;
  41 float autocvar_g_vehicle_raptor_cannon_radius;
  42 float autocvar_g_vehicle_raptor_cannon_refire;
  43 float autocvar_g_vehicle_raptor_cannon_speed;
  44 float autocvar_g_vehicle_raptor_cannon_spread;
  45
  46
  47 float autocvar_g_vehicle_raptor_energy;
  48 float autocvar_g_vehicle_raptor_energy_regen;
  49 float autocvar_g_vehicle_raptor_energy_regen_pause;
  50
  51 float autocvar_g_vehicle_raptor_health;
  52 float autocvar_g_vehicle_raptor_health_regen;
  53 float autocvar_g_vehicle_raptor_health_regen_pause;
  54
  55 float autocvar_g_vehicle_raptor_shield;
  56 float autocvar_g_vehicle_raptor_shield_regen;
  57 float autocvar_g_vehicle_raptor_shield_regen_pause;
  58
  59 void raptor_spawn();
  60 float raptor_frame();
  61 float raptor_takeoff();
  62
  63 .entity bomb1;
  64 .entity bomb2;
  65
  66 //#define RAPTOR_RETARDCAMERA
  67
  68 float raptor_altitude(float amax)
  69 {
  70         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  71     return vlen(self.origin - trace_endpos);
  72 }
  73
  74
  75 void raptor_bomblet_boom()
  76 {
  77     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
  78     pointparticles(particleeffectnum("raptor_bomb_impact"), self.origin, trace_plane_normal * 1000, 1);
  79     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  80                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  81                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  82                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_SBROCKET, world);
  83     remove(self);
  84 }
  85
  86 void raptor_bomblet_touch()
  87 {
  88     if(other == self.owner)
  89         return;
  90
  91     PROJECTILE_TOUCH;
  92     self.think = raptor_bomblet_boom;
  93     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  94 }
  95
  96 void raptor_bomb_burst()
  97 {
  98     if(self.cnt > time)
  99     if(autocvar_g_vehicle_raptor_bomblet_alt)
 100     {
 101         self.nextthink = time;
 102         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 103         if(trace_fraction == 1.0)
 104             return;
 105
 106         if(vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius)
 107             return;
 108     }
 109
 110     entity bomblet;
 111     float i;
 112
 113     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 114     pointparticles(particleeffectnum("rocket_explode"), self.origin, self.velocity, 1);
 115
 116     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 117     {
 118         bomblet = spawn();
 119         setorigin(bomblet, self.origin);
 120
 121         //bomblet.solid       = SOLID_TRIGGER;
 122         bomblet.movetype    = MOVETYPE_TOSS;
 123         bomblet.touch       = raptor_bomblet_touch;
 124         bomblet.think       = raptor_bomblet_boom;
 125         bomblet.nextthink   = time + 5;
 126         bomblet.owner       = self.owner;
 127         bomblet.realowner   = self.realowner;
 128         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 129         PROJECTILE_MAKETRIGGER(bomblet);
 130         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 131     }
 132
 133     remove(self);
 134 }
 135
 136 void raptor_bomb_touch()
 137 {
 138     raptor_bomb_burst();
 139 }
 140
 141 void raptor_bombdrop()
 142 {
 143     entity bomb_1, bomb_2;
 144
 145     //self.bomb1.alpha = 0;
 146     //self.bomb2.alpha = 0;
 147
 148     bomb_1 = spawn();
 149     bomb_2 = spawn();
 150
 151     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 152     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 153
 154     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_TOSS;
 155     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 156     bomb_1.touch        = bomb_2.touch      = raptor_bomb_touch;
 157     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 158     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 159
 160     if(autocvar_g_vehicle_raptor_bomblet_alt)
 161         bomb_1.nextthink = bomb_2.nextthink  = time;
 162     else
 163         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 164
 165     bomb_1.owner     = bomb_2.owner      = self;
 166     bomb_1.realowner = bomb_2.realowner  = self.owner;
 167     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 168     bomb_1.gravity   = bomb_2.gravity    = 1;
 169
 170     PROJECTILE_MAKETRIGGER(bomb_1);
 171     PROJECTILE_MAKETRIGGER(bomb_2);
 172
 173     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 174     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 175
 176 }
 177
 178 void raptor_bolt_explode()
 179 {
 180         PROJECTILE_TOUCH;
 181     pointparticles(particleeffectnum("raptor_cannon_impact"), findbetterlocation (self.origin, 8), trace_plane_normal * 1000, 1);
 182     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_cannon_damage, 0, autocvar_g_vehicle_raptor_cannon_radius, world, 25, DEATH_WAKIGUN, world);
 183     sound (self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 184     remove (self);
 185 }
 186
 187 void raptor_fire_cannon(entity gun, string tagname)
 188 {
 189     entity bolt;
 190
 191     bolt = spawn();
 192
 193     PROJECTILE_MAKETRIGGER(bolt);
 194     sound (gun, CHAN_WEAPON, "weapons/lasergun_fire.wav", VOL_BASE, ATTN_NORM);
 195     setorigin(bolt, gettaginfo(gun, gettagindex(gun, tagname)));
 196
 197     bolt.movetype        = MOVETYPE_FLYMISSILE;
 198     bolt.flags           = FL_PROJECTILE | FL_NOTARGET;
 199     bolt.owner           = self;
 200     bolt.realowner       = self.owner;
 201     bolt.touch           = raptor_bolt_explode;
 202     bolt.think           = raptor_bolt_explode;
 203     bolt.nextthink       = time + 9;
 204     bolt.bot_dodge       = TRUE;
 205     bolt.bot_dodgerating = autocvar_g_vehicle_raptor_cannon_damage;
 206     bolt.velocity        = normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed;
 207
 208     pointparticles(particleeffectnum("raptor_cannon_muzzleflash"), bolt.origin, bolt.velocity, 1);
 209     //pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), bolt.origin, bolt.velocity, 1);
 210
 211     CSQCProjectile(bolt, TRUE, PROJECTILE_RAPTORCANNON, TRUE);
 212 }
 213
 214 void raptor_think()
 215 {
 216 }
 217
 218 void raptor_enter()
 219 {
 220     self.owner.PlayerPhysplug = raptor_takeoff;
 221     self.movetype       = MOVETYPE_FLY;
 222     self.solid          = SOLID_BBOX;
 223     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 224     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 225     self.velocity_z = 1;
 226
 227 #ifdef RAPTOR_RETARDCAMERA
 228     setorigin(self.vehicle_viewport, self.origin);
 229 #endif
 230 }
 231
 232 void raptor_land()
 233 {
 234     float hgt;
 235
 236     hgt = raptor_altitude(512);
 237     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 238     self.angles_x *= 0.95;
 239     self.angles_z *= 0.95;
 240
 241     if(hgt < 128)
 242         if(self.frame != 0)
 243             self.frame = max(self.frame - 0.25, 0);
 244
 245     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 246     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 247
 248     if(hgt < 16)
 249     {
 250         self.movetype   = MOVETYPE_TOSS;
 251         self.think      = raptor_think;
 252     }
 253
 254     self.nextthink  = time;
 255 }
 256
 257 void raptor_exit(float eject)
 258 {
 259
 260     if(self.deadflag == DEAD_NO)
 261     {
 262         self.think      = raptor_land;
 263         self.nextthink  = time;
 264     }
 265
 266     if not (self.owner)
 267         return;
 268
 269         makevectors(self.angles);
 270         if(eject)
 271         {
 272             setorigin(self.owner,self.origin + v_forward * 100 + '0 0 64');
 273             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 274         }
 275         else
 276         setorigin(self.owner,self.origin - v_forward * 200 + '0 0 64');
 277
 278     self.owner = world;
 279 }
 280
 281 float raptor_takeoff()
 282 {
 283     entity player, raptor;
 284     float ftmp, ftmp2;
 285     vector df;
 286
 287     player = self;
 288     raptor = self.vehicle;
 289     self   = raptor;
 290
 291     // Takeoff sequense
 292     if(raptor.frame < 25)
 293     {
 294         raptor.frame += 0.25;
 295         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 296         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 297         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 298         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 299
 300         setorigin(player, raptor.origin + '0 0 32');
 301     }
 302     else
 303         player.PlayerPhysplug = raptor_frame;
 304
 305     self = player;
 306     return 1;
 307 }
 308
 309 float raptor_frame()
 310 {
 311     entity player, raptor;
 312     float ftmp, ftmp2;
 313     vector df;
 314
 315     player = self;
 316     raptor = self.vehicle;
 317     self   = raptor;
 318
 319     if(player.BUTTON_USE && raptor.deadflag == DEAD_NO)
 320     {
 321         self = raptor;
 322         vehicles_exit(VHEF_NORMAL);
 323         self = player;
 324         return 0;
 325     }
 326
 327     if(raptor.deadflag != DEAD_NO)
 328     {
 329         self = player;
 330         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 331         return 1;
 332     }
 333
 334
 335
 336     crosshair_trace(player);
 337
 338 #if VEHICLES_VIEWROTATE_CROSSHAIR
 339     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 340     if(df_x > 180)  df_x -= 360;
 341     if(df_x < -180) df_x += 360;
 342     if(df_y > 180)  df_y -= 360;
 343     if(df_y < -180) df_y += 360;
 344
 345     // Rotate Body
 346     ftmp = autocvar_g_vehicle_raptor_turnspeed * sys_frametime;
 347     ftmp = bound(-ftmp, shortangle_f(df_y - raptor.angles_y, raptor.angles_y), ftmp);
 348
 349     // Turn
 350     //raptor.angles_y = anglemods(raptor.angles_y + ftmp);
 351     raptor.avelocity_y = anglemods(raptor.angles_y + ftmp);
 352
 353     // Pitch Body
 354     ftmp = autocvar_g_vehicle_raptor_pitchspeed  * sys_frametime;
 355     ftmp = bound(-ftmp, shortangle_f(df_x - raptor.angles_x, raptor.angles_x), ftmp);
 356
 357     //raptor.angles_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 358     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 359 #else
 360     vector vang;
 361     vang = raptor.angles;
 362     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 363     vang_x *= -1;
 364     df_x *= -1;
 365     if(df_x > 180)  df_x -= 360;
 366     if(df_x < -180) df_x += 360;
 367     if(df_y > 180)  df_y -= 360;
 368     if(df_y < -180) df_y += 360;
 369
 370     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 371     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 372     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 373
 374     // Pitch
 375     ftmp = 0;
 376     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 377     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 378
 379     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 380     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 381     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 382
 383     raptor.angles_x = anglemods(raptor.angles_x);
 384     raptor.angles_y = anglemods(raptor.angles_y);
 385     raptor.angles_z = anglemods(raptor.angles_z);
 386
 387 #endif
 388
 389     if(autocvar_g_vehicle_raptor_movestyle == 1)
 390         makevectors('0 1 0' * raptor.angles_y);
 391     else
 392         makevectors(player.v_angle);
 393
 394 #ifdef RAPTOR_RETARDCAMERA
 395     float spd, back, up;
 396     spd = vlen(self.velocity) + 0.01;
 397     back = spd / autocvar_g_vehicle_raptor_speed_forward;
 398     up = 1 - back;
 399     back = back;
 400     back = back * 1250;
 401     back += 150;
 402     up = up * 200;
 403     up = up + 100;
 404
 405     setorigin(self.vehicle_viewport, self.origin + (v_up * up) + (v_forward * -back));
 406 #endif
 407
 408     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 409
 410     if(player.movement_x != 0)
 411     {
 412         if(player.movement_x > 0)
 413             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 414         else if(player.movement_x < 0)
 415             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 416     }
 417
 418     if(player.movement_y != 0)
 419     {
 420         if(player.movement_y < 0)
 421             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 422         else if(player.movement_y > 0)
 423             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 424
 425         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 426     }
 427     else
 428     {
 429         raptor.angles_z *= 0.95;
 430         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 431             raptor.angles_z = 0;
 432     }
 433
 434     if(player.BUTTON_CROUCH)
 435         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 436     else if (player.BUTTON_JUMP)
 437         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 438
 439     raptor.velocity  += df * frametime;
 440     player.velocity = player.movement  = raptor.velocity;
 441     setorigin(player,raptor.origin + '0 0 32');
 442
 443     vector vf, ad;
 444     // Target lock & predict
 445     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 446     {
 447
 448         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 449                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 450                              autocvar_g_vehicle_raptor_cannon_locked_time);
 451
 452         if(self.lock_target != world)
 453         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 454         if(self.lock_strength == 1)
 455         {
 456             float i, distance, impact_time;
 457
 458             vf = real_origin(raptor.lock_target);
 459             ad = vf;
 460             for(i = 0; i < 4; ++i)
 461             {
 462                 distance = vlen(ad - raptor.origin);
 463                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 464                 ad = vf + raptor.lock_target.velocity * impact_time;
 465             }
 466             trace_endpos = ad;
 467             //UpdateAuxiliaryXhair(player, trace_endpos, '1 1 1', 0);
 468         }
 469
 470         if(self.lock_target)
 471         {
 472             if(raptor.lock_strength == 1)
 473                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 474             else if(self.lock_strength > 0.5)
 475                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 476             else if(self.lock_strength < 0.5)
 477                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 478         }
 479     }
 480
 481     // Aim the gunz
 482     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 483     ftmp = -ftmp2;
 484
 485     // Gun1
 486     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 487     //ad = df;
 488     //vf = v_forward;
 489     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 490     df = shortangle_vxy(df - (raptor.angles + raptor.gun1.angles), raptor.angles + raptor.gun1.angles);     // Find aim offset
 491     // Bind to aimspeed
 492     df_x = bound(ftmp, df_x, ftmp2);
 493     df_y = bound(ftmp, df_y, ftmp2);
 494     // Bind to limts
 495     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 496     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 497
 498     //df = vectoangles(normalize(trace_endpos - df));
 499
 500     //Gun 2
 501     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 502     //ad += df;
 503     //vf += v_forward;
 504     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 505     df = shortangle_vxy(df - (raptor.angles + raptor.gun2.angles), raptor.angles + raptor.gun2.angles);     // Find aim offset
 506     // Bind to aimspeed
 507     df_x = bound(ftmp, df_x, ftmp2);
 508     df_y = bound(ftmp, df_y, ftmp2);
 509     // Bind to limts
 510     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 511     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 512
 513     /*
 514     ad = ad * 0.5;
 515     v_forward = vf * 0.5;
 516     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 517     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 518     */
 519
 520     if(player.BUTTON_ATCK)
 521     if(raptor.attack_finished_single <= time)
 522     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 523     {
 524         raptor.misc_bulletcounter += 1;
 525         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 526         if(raptor.misc_bulletcounter <= 2)
 527             raptor_fire_cannon(self.gun1, "fire1");
 528         else if(raptor.misc_bulletcounter == 3)
 529             raptor_fire_cannon(self.gun2, "fire1");
 530         else
 531         {
 532             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 533             raptor_fire_cannon(self.gun2, "fire1");
 534             raptor.misc_bulletcounter = 0;
 535         }
 536         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 537         self.cnt = time;
 538     }
 539
 540     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 541         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 542
 543     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 544         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 545
 546     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 547         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 548
 549
 550     if(time > raptor.delay)
 551     if(player.BUTTON_ATCK2)
 552     {
 553         raptor_bombdrop();
 554         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 555         raptor.lip   = time;
 556     }
 557
 558     player.vehicle_reload1 = (time - raptor.lip) / (raptor.delay - raptor.lip);
 559     raptor.bomb1.alpha = raptor.bomb2.alpha = player.vehicle_reload1;
 560
 561     VEHICLE_UPDATE_PLAYER(health, raptor);
 562     VEHICLE_UPDATE_PLAYER(energy, raptor);
 563     if(self.vehicle_flags & VHF_HASSHIELD)
 564         VEHICLE_UPDATE_PLAYER(shield, raptor);
 565
 566
 567
 568     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 569     return 1;
 570 }
 571
 572 void raptor_blowup()
 573 {
 574     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 575     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 576
 577     self.deadflag    = DEAD_DEAD;
 578     self.vehicle_exit(VHEF_NORMAL);
 579     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 580
 581     self.alpha          = -1;
 582     self.movetype       = MOVETYPE_NONE;
 583     self.effects        = EF_NODRAW;
 584     self.colormod       = '0 0 0';
 585     self.avelocity      = '0 0 0';
 586     self.velocity       = '0 0 0';
 587
 588     setorigin(self, self.pos1);
 589     self.touch = SUB_Null;
 590 }
 591
 592 void raptor_die()
 593 {
 594     self.health       = 0;
 595     self.event_damage = SUB_Null;
 596     self.iscreature   = FALSE;
 597     self.solid        = SOLID_CORPSE;
 598     self.takedamage   = DAMAGE_NO;
 599     self.deadflag     = DEAD_DYING;
 600     self.movetype     = MOVETYPE_BOUNCE;
 601
 602     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 603
 604     self.velocity_z += 128;
 605
 606     if(random() < 0.5)
 607         self.avelocity_z  = 45 + random() * 270;
 608     else
 609         self.avelocity_z  = -45 + random() * -270;
 610
 611     self.colormod = '-0.5 -0.5 -0.5';
 612         self.touch     = raptor_blowup;
 613 }
 614
 615 void raptor_spawn()
 616 {
 617     self.frame          = 0;
 618     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 619     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 620     self.movetype       = MOVETYPE_TOSS;
 621     self.solid          = SOLID_BBOX;
 622     self.vehicle_energy = 1;
 623
 624     self.bomb1.gun1.avelocity_y = 90;
 625     self.bomb1.gun2.avelocity_y = -90;
 626
 627     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 628     self.delay = time;
 629 }
 630
 631 void raptor_dinit()
 632 {
 633     entity spinner;
 634     vector ofs;
 635
 636     if not (vehicle_initialize(
 637              "Raptor",
 638              "models/vehicles/raptor.dpm",
 639              "",
 640              "models/vehicles/raptor_cockpit.dpm",
 641              "", "tag_hud", "tag_camera",
 642              HUD_RAPTOR,
 643              RAPTOR_MIN, RAPTOR_MAX,
 644              FALSE,
 645              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 646              raptor_frame,
 647              raptor_enter, raptor_exit,
 648              raptor_die,   raptor_think))
 649     {
 650         remove(self);
 651         return;
 652     }
 653     setorigin(self, self.origin + '0 0 50');
 654     //FIXME: Camera is in a bad place in HUD model.
 655     setorigin(self.vehicle_viewport, '5 0 5');
 656
 657     self.frame = 0;
 658
 659     self.bomb1 = spawn();
 660     self.bomb2 = spawn();
 661     self.gun1  = spawn();
 662     self.gun2  = spawn();
 663
 664 #ifdef RAPTOR_RETARDCAMERA
 665     setattachment(self.vehicle_viewport, world, "");
 666 #endif
 667
 668     setmodel(self.bomb1,"models/vehicles/clusterbomb.md3");
 669     setmodel(self.bomb2,"models/vehicles/clusterbomb.md3");
 670     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 671     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 672
 673     setattachment(self.bomb1, self,"bombmount_left");
 674     setattachment(self.bomb2, self,"bombmount_right");
 675
 676
 677     // FIXME Guns mounts to angled bones
 678     self.bomb1.angles = self.angles;
 679     self.angles = '0 0 0';
 680     // This messes up gun-aim, so work arround it.
 681     //setattachment(self.gun1, self, "gunmount_left");
 682     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 683     ofs -= self.origin;
 684     setattachment(self.gun1, self, "");
 685     setorigin(self.gun1, ofs);
 686
 687     //setattachment(self.gun2, self, "gunmount_right");
 688     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 689     ofs -= self.origin;
 690     setattachment(self.gun2, self, "");
 691     setorigin(self.gun2, ofs);
 692
 693     self.angles = self.bomb1.angles;
 694     self.bomb1.angles = '0 0 0';
 695
 696
 697     spinner = spawn();
 698     spinner.owner = self;
 699     setmodel(spinner,"models/vehicles/spinner.dpm");
 700     setattachment(spinner, self, "engine_left");
 701     spinner.movetype = MOVETYPE_NOCLIP;
 702     spinner.avelocity = '0 90 0';
 703     self.bomb1.gun1 = spinner;
 704
 705     spinner = spawn();
 706     spinner.owner = self;
 707     setmodel(spinner,"models/vehicles/spinner.dpm");
 708     setattachment(spinner, self, "engine_right");
 709     spinner.movetype = MOVETYPE_NOCLIP;
 710     spinner.avelocity = '0 -90 0';
 711     self.bomb1.gun2 = spinner;
 712
 713     self.mass               = 1 ;
 714 }
 715
 716 void spawnfunc_vehicle_raptor()
 717 {
 718     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 719
 720     if(autocvar_g_vehicle_raptor_shield)
 721         self.vehicle_flags |= VHF_HASSHIELD;
 722
 723     if(autocvar_g_vehicle_raptor_shield_regen)
 724         self.vehicle_flags |= VHF_SHIELDREGEN;
 725
 726     if(autocvar_g_vehicle_raptor_health_regen)
 727         self.vehicle_flags |= VHF_HEALTHREGEN;
 728
 729     if(autocvar_g_vehicle_raptor_energy_regen)
 730         self.vehicle_flags |= VHF_ENERGYREGEN;
 731
 732     precache_model ("models/vehicles/raptor.dpm");
 733     precache_model ("models/vehicles/raptor_gun.dpm");
 734     precache_model ("models/vehicles/spinner.dpm");
 735     precache_model ("models/vehicles/raptor_cockpit.dpm");
 736     precache_model ("models/vehicles/clusterbomb.md3");
 737
 738     self.think = raptor_dinit;
 739     self.nextthink = time + 1;
 740 }