qcsrc/server/vehicles/spiderbot.qc

   1 const vector SPIDERBOT_MIN = '-75 -75 10';
   2 const vector SPIDERBOT_MAX  = '75 75 125';
   3
   4 float autocvar_g_vehicle_spiderbot_respawntime;
   5
   6 //float autocvar_g_vehicle_spiderbot_crush_dmg;
   7 //float autocvar_g_vehicle_spiderbot_crush_force;
   8
   9 float autocvar_g_vehicle_spiderbot_speed_stop;
  10 float autocvar_g_vehicle_spiderbot_speed_strafe;
  11 float autocvar_g_vehicle_spiderbot_speed_walk;
  12 float autocvar_g_vehicle_spiderbot_turnspeed;
  13 float autocvar_g_vehicle_spiderbot_movement_inertia;
  14
  15 float autocvar_g_vehicle_spiderbot_springlength;
  16 float autocvar_g_vehicle_spiderbot_springup;
  17 float autocvar_g_vehicle_spiderbot_springblend;
  18
  19 float autocvar_g_vehicle_spiderbot_head_pitchlimit_down;
  20 float autocvar_g_vehicle_spiderbot_head_pitchlimit_up;
  21 float autocvar_g_vehicle_spiderbot_head_pitchspeed;
  22 float autocvar_g_vehicle_spiderbot_head_turnlimit;
  23 float autocvar_g_vehicle_spiderbot_head_turnspeed;
  24
  25 //float autocvar_g_vehicle_spiderbot_energy;
  26 //float autocvar_g_vehicle_spiderbot_energy_regen;
  27 //float autocvar_g_vehicle_spiderbot_energy_regen_pause;
  28
  29 float autocvar_g_vehicle_spiderbot_health;
  30 float autocvar_g_vehicle_spiderbot_health_regen;
  31 float autocvar_g_vehicle_spiderbot_health_regen_pause;
  32
  33 float autocvar_g_vehicle_spiderbot_shield;
  34 float autocvar_g_vehicle_spiderbot_shield_regen;
  35 float autocvar_g_vehicle_spiderbot_shield_regen_pause;
  36
  37 float autocvar_g_vehicle_spiderbot_minigun_damage;
  38 float autocvar_g_vehicle_spiderbot_minigun_refire;
  39 float autocvar_g_vehicle_spiderbot_minigun_spread;
  40 float autocvar_g_vehicle_spiderbot_minigun_cooldown;
  41 float autocvar_g_vehicle_spiderbot_minigun_heat;
  42
  43 float autocvar_g_vehicle_spiderbot_rocket_damage;
  44 float autocvar_g_vehicle_spiderbot_rocket_edgedamage;
  45 float autocvar_g_vehicle_spiderbot_rocket_force;
  46 float autocvar_g_vehicle_spiderbot_rocket_health;
  47 float autocvar_g_vehicle_spiderbot_rocket_lifetime;
  48 float autocvar_g_vehicle_spiderbot_rocket_noise;
  49 float autocvar_g_vehicle_spiderbot_rocket_radius;
  50 float autocvar_g_vehicle_spiderbot_rocket_refire;
  51 float autocvar_g_vehicle_spiderbot_rocket_reload;
  52 float autocvar_g_vehicle_spiderbot_rocket_speed;
  53 float autocvar_g_vehicle_spiderbot_rocket_turnrate;
  54
  55
  56 void spiderbot_exit(float eject);
  57 void spiderbot_enter();
  58 void spiderbot_spawn();
  59
  60 void spiderbot_rocket_unguided()
  61 {
  62     vector newdir, olddir;
  63
  64     self.nextthink  = time;
  65
  66     olddir = normalize(self.velocity);
  67     newdir = normalize(self.pos1 - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  68     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  69
  70     UpdateCSQCProjectile(self);
  71
  72     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
  73         self.use();
  74 }
  75
  76 void spiderbot_rocket_guided()
  77 {
  78     vector newdir, olddir;
  79
  80     self.nextthink  = time;
  81
  82     if not (self.realowner.vehicle)
  83         self.think = spiderbot_rocket_unguided;
  84
  85     crosshair_trace(self.realowner);
  86     olddir = normalize(self.velocity);
  87     newdir = normalize(trace_endpos - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  88     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  89
  90     UpdateCSQCProjectile(self);
  91
  92     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
  93         self.use();
  94 }
  95
  96 void spiderbot_guide_release()
  97 {
  98     entity rkt;
  99     rkt = findchainentity(realowner, self.owner);
 100     if not (rkt)
 101         return;
 102
 103     crosshair_trace(self.owner);
 104     while(rkt)
 105     {
 106         if(rkt.think == spiderbot_rocket_guided)
 107         {
 108             rkt.pos1 = trace_endpos;
 109             rkt.think = spiderbot_rocket_unguided;
 110         }
 111         rkt = rkt.chain;
 112     }
 113 }
 114
 115 void spiderbot_rocket_do()
 116 {
 117
 118     vector v;
 119     entity rocket;
 120
 121     if (self.owner.BUTTON_ATCK2)
 122     {
 123         if (self.wait == 1)
 124         if (self.tur_head.frame == 9 || self.tur_head.frame == 1)
 125         {
 126             if(self.gun2.cnt < time && self.tur_head.frame == 9)
 127                 self.tur_head.frame = 1;
 128
 129             return;
 130         }
 131         self.wait = 1;
 132     }
 133     else
 134     {
 135         if(self.wait)
 136             spiderbot_guide_release();
 137
 138         self.wait = 0;
 139     }
 140
 141     if(self.gun2.cnt > time)
 142         return;
 143
 144     if (self.tur_head.frame >= 9)
 145         self.tur_head.frame = 1;
 146
 147     if not (self.owner.BUTTON_ATCK2)
 148         return;
 149
 150     crosshair_trace(self.owner);
 151
 152     v = gettaginfo(self.tur_head,gettagindex(self.tur_head,"tag_fire"));
 153     rocket = vehicles_projectile("rocket_explode", "weapons/rocket_impact.wav", "", "weapons/rocket_fire.wav",
 154                            v, normalize(v_forward + (v_up * 0.5) + randomvec() * 0.25) * autocvar_g_vehicle_spiderbot_rocket_speed,
 155                            autocvar_g_vehicle_spiderbot_rocket_damage, autocvar_g_vehicle_spiderbot_rocket_radius, autocvar_g_vehicle_spiderbot_rocket_force, 1,
 156                            DEATH_SBROCKET, PROJECTILE_SPIDERROCKET, autocvar_g_vehicle_spiderbot_rocket_health);
 157
 158     rocket.cnt        = time + 15;
 159     rocket.classname  = "spiderbot_rocket";
 160     rocket.pos1       = trace_endpos;
 161     rocket.think      = spiderbot_rocket_guided;
 162     rocket.nextthink  = time;
 163     rocket.cnt        = time + autocvar_g_vehicle_spiderbot_rocket_lifetime;
 164     te_explosion (rocket.origin);
 165
 166     self.tur_head.frame += 1;
 167     if (self.tur_head.frame == 9)
 168         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_reload;
 169     else
 170         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_refire;
 171
 172     self.gun2.cnt = time + self.attack_finished_single;
 173 }
 174
 175 void spiderbot_minigun_fire(entity gun, float trail)
 176 {
 177     vector v;
 178
 179     v = gettaginfo(gun, gettagindex(gun,"barrels"));
 180     v_forward = normalize(v_forward);
 181     v += v_forward * 50;
 182
 183     fireBullet (v, v_forward, autocvar_g_vehicle_spiderbot_minigun_spread, autocvar_g_vehicle_spiderbot_minigun_damage,
 184         autocvar_g_vehicle_spiderbot_minigun_spread, DEATH_SBMINIGUN, 0);
 185
 186     if(trail)
 187     {
 188         sound (gun, CHAN_WEAPON, "weapons/uzi_fire.wav", VOL_BASE, ATTN_NORM);
 189         trailparticles(self, particleeffectnum("spiderbot_minigun_trail"), v, trace_endpos);
 190         pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), v, v_forward * 2500, 1);
 191         pointparticles(particleeffectnum("spiderbot_minigun_impact"), trace_endpos, trace_plane_normal * 2500,1);
 192     }
 193 }
 194
 195 void spiderbot_miniguns_do()
 196 {
 197     float ftmp;
 198
 199     if((self.vehicle_reload1 == 1) || (!self.owner.BUTTON_ATCK))
 200     {
 201         ftmp = 1 / autocvar_g_vehicle_spiderbot_minigun_cooldown * sys_frametime;
 202         self.owner.vehicle_reload1 = max(self.owner.vehicle_reload1 - ftmp, 0);
 203         if(self.owner.vehicle_reload1 <= 0)
 204             self.vehicle_reload1 = 0;
 205
 206         return;
 207     }
 208
 209     if (self.owner.BUTTON_ATCK)
 210     {
 211
 212         // Animate miniguns
 213         self.gun1.angles_z += (1440 * sys_frametime);
 214         self.gun2.angles_z -= (1440 * sys_frametime);
 215         if(self.gun1.angles_z >= 360)
 216         {
 217             self.gun1.angles_z = 0;
 218             self.gun2.angles_z = 360;
 219         }
 220
 221         if (self.tur_head.attack_finished_single < time)
 222         {
 223             // Fire bullets, alternating trails left<->right
 224             self = self.owner;
 225             if(self.misc_bulletcounter == 1)
 226             {
 227                 spiderbot_minigun_fire(self.vehicle.gun1, 0);
 228                 spiderbot_minigun_fire(self.vehicle.gun2, 1);
 229                 self.misc_bulletcounter = 0;
 230             }
 231             else
 232             {
 233                 spiderbot_minigun_fire(self.vehicle.gun1, 1);
 234                 spiderbot_minigun_fire(self.vehicle.gun2, 0);
 235                 self.misc_bulletcounter += 1;
 236             }
 237             self = self.vehicle;
 238
 239             ftmp = autocvar_g_vehicle_spiderbot_minigun_refire / autocvar_g_vehicle_spiderbot_minigun_heat;
 240             self.owner.vehicle_reload1 +=  ftmp;
 241
 242             if(self.owner.vehicle_reload1 >= 1)
 243             {
 244                 self.vehicle_reload1 = 1;
 245                 self.owner.vehicle_reload1 = 1;
 246                 self.tur_head.attack_finished_single = autocvar_g_vehicle_spiderbot_minigun_cooldown + time;
 247             }
 248             else
 249                 self.tur_head.attack_finished_single = autocvar_g_vehicle_spiderbot_minigun_refire + time;
 250         }
 251         return;
 252     }
 253 }
 254
 255 float spiderbot_frame()
 256 {
 257     vector ad;
 258     entity player, spider;
 259     float ftmp;
 260
 261     player = self;
 262     spider = self.vehicle;
 263
 264     player.BUTTON_ZOOM      = 0;
 265     player.BUTTON_CROUCH    = 0;
 266     player.switchweapon     = 0;
 267
 268     if(player.BUTTON_USE)
 269     {
 270         self = spider;
 271         vehicles_exit(VHEF_NORMAL);
 272         self = player;
 273         return 0;
 274     }
 275
 276     self = spider;
 277
 278     crosshair_trace(player);
 279     //UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload2) + ('0 1 0' * (1 - player.vehicle_reload2)), 2);
 280
 281 #if VEHICLES_VIEWROTATE_CROSSHAIR
 282     ad = vectoangles(normalize(trace_endpos - gettaginfo(spider.tur_head,gettagindex(spider.tur_head,"tag_hud")))) - (spider.tur_head.angles + spider.angles);
 283     if(ad_x > 180) ad_x -= 360;
 284     if(ad_x < -180) ad_x += 360;
 285     if(ad_y > 180) ad_y -= 360;
 286     if(ad_y < -180) ad_y += 360;
 287
 288     // Rotate head
 289     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 290     ad_y = bound(-ftmp, ad_y, ftmp);
 291     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 292
 293     // Pitch head
 294     ftmp = autocvar_g_vehicle_spiderbot_head_pitchspeed * sys_frametime;
 295     //ad_x = bound(-ftmp, ad_x, ftmp);
 296     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 297
 298     // Turn Body
 299     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 300     ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 301 #else
 302
 303     player.v_angle_x *= -1;
 304     ad = player.v_angle - (spider.tur_head.angles + spider.angles);
 305     player.v_angle_x *= -1;
 306     if(ad_x > 180)  ad_x -= 360;
 307     if(ad_x < -180) ad_x += 360;
 308     if(ad_y > 180)  ad_y -= 360;
 309     if(ad_y < -180) ad_y += 360;
 310
 311     // Rotate head
 312     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 313     ad_y = bound(-ftmp, ad_y, ftmp);
 314     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 315
 316
 317     // Pitch head
 318     ad = vectoangles(normalize(trace_endpos - gettaginfo(spider.tur_head,gettagindex(spider.tur_head,"tag_hud")))) - (spider.tur_head.angles + spider.angles);
 319     if(ad_x > 180) ad_x -= 360;
 320     if(ad_x < -180) ad_x += 360;
 321
 322
 323     ftmp = autocvar_g_vehicle_spiderbot_head_pitchspeed * sys_frametime;
 324     ad_x = bound(ftmp * -1, ad_x, ftmp);
 325     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 326
 327
 328
 329     // Turn Body
 330     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 331     ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 332
 333
 334 #endif
 335     makevectors(spider.angles + '-1 0 0' * spider.angles_x);
 336
 337     /*
 338     vector ofs;
 339     ofs = self.origin + v_up * 128;
 340     te_lightning1(world, ofs, ofs + v_up * 32);
 341     te_lightning1(world, ofs, ofs + v_right * 128);
 342     te_lightning1(world, ofs, ofs + v_forward * 256);
 343     */
 344
 345     movelib_groundalign4point(autocvar_g_vehicle_spiderbot_springlength, autocvar_g_vehicle_spiderbot_springup, autocvar_g_vehicle_spiderbot_springblend);
 346
 347     if(spider.flags & FL_ONGROUND)
 348     {
 349         if(player.BUTTON_JUMP && self.tur_head.wait < time)
 350         {
 351             self.tur_head.wait = time + 2;
 352             player.BUTTON_JUMP = 0;
 353             spider.velocity   = v_forward * 700 + v_up * 600;
 354             spider.frame = 4;
 355         }
 356         else
 357         {
 358             if(vlen(player.movement) == 0)
 359             {
 360                 movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 361                 spider.frame = 5;
 362             }
 363             else
 364             {
 365                 spider.angles_y = anglemods(spider.angles_y + ftmp);
 366                 spider.tur_head.angles_y -= ftmp;
 367
 368                 if(player.movement_x != 0)
 369                 {
 370                     if(player.movement_x > 0)
 371                     {
 372                         player.movement_x = 1;
 373                         spider.frame = 0;
 374                     }
 375                     else if(player.movement_x < 0)
 376                     {
 377                         player.movement_x = -1;
 378                         spider.frame = 1;
 379                     }
 380                     player.movement_y = 0;
 381                     movelib_move_simple(normalize(v_forward * player.movement_x),autocvar_g_vehicle_spiderbot_speed_walk,autocvar_g_vehicle_spiderbot_movement_inertia);
 382                 }
 383                 else if(player.movement_y != 0)
 384                 {
 385                     if(player.movement_y < 0)
 386                     {
 387                         player.movement_y = -1;
 388                         spider.frame = 2;
 389                     }
 390                     else if(player.movement_y > 0)
 391                     {
 392                         player.movement_y = 1;
 393                         spider.frame = 3;
 394                     }
 395                     movelib_move_simple(normalize(v_right * player.movement_y),autocvar_g_vehicle_spiderbot_speed_strafe,autocvar_g_vehicle_spiderbot_movement_inertia);
 396                 }
 397             }
 398         }
 399     }
 400
 401     self.angles_x = bound(-45, self.angles_x, 45);
 402     self.angles_z = bound(-45, self.angles_z, 45);
 403
 404     spiderbot_miniguns_do();
 405     spiderbot_rocket_do();
 406
 407     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 408         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_spiderbot_shield, autocvar_g_vehicle_spiderbot_shield_regen_pause, autocvar_g_vehicle_spiderbot_shield_regen, frametime);
 409
 410     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 411         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_spiderbot_health, autocvar_g_vehicle_spiderbot_health_regen_pause, autocvar_g_vehicle_spiderbot_health_regen, frametime);
 412
 413     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 414     player.vehicle_ammo2 = spider.tur_head.frame;
 415
 416     if(spider.gun2.cnt <= time)
 417         player.vehicle_reload2 = 1;
 418     else
 419         player.vehicle_reload2 = 1 - ((spider.gun2.cnt - time) / spider.attack_finished_single);
 420
 421     setorigin(player, spider.origin + '0 0 1' * SPIDERBOT_MAX_z);
 422     player.velocity = spider.velocity;
 423
 424     VEHICLE_UPDATE_PLAYER(health, spiderbot);
 425
 426     if(self.vehicle_flags & VHF_HASSHIELD)
 427         VEHICLE_UPDATE_PLAYER(shield, spiderbot);
 428
 429 #if 1 // 0 to enable per-gun impact aux crosshairs
 430     // Avarage gun impact point's -> aux cross
 431     vector vf;
 432     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 433     vf = v_forward;
 434     ad += gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 435     vf += v_forward;
 436     ad = ad * 0.5;
 437     v_forward = vf * 0.5;
 438     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 439     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 440
 441 #else
 442     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 443     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 444     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 445
 446     ad = gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 447     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 448     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 1);
 449 #endif
 450
 451     self = player;
 452     return 1;
 453 }
 454
 455 void spiderbot_think()
 456 {
 457     if(self.flags & FL_ONGROUND)
 458         movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 459
 460     self.nextthink = time;
 461 }
 462
 463 void spiderbot_enter()
 464 {
 465     self.movetype   = MOVETYPE_WALK;
 466     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_spiderbot_health);
 467     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_spiderbot_shield);
 468 }
 469
 470 void spiderbot_exit(float eject)
 471 {
 472     entity e;
 473
 474     e = findchain(classname,"spiderbot_rocket");
 475     while(e)
 476     {
 477         if(e.owner == self.owner)
 478         {
 479             e.realowner = self.owner;
 480             e.owner = world;
 481         }
 482         e = e.chain;
 483     }
 484
 485     self.velocity   = '0 0 0';
 486     self.think      = spiderbot_think;
 487     self.nextthink  = time;
 488     self.frame      = 5;
 489     self.movetype   = MOVETYPE_WALK;
 490
 491     if not (self.owner)
 492         return;
 493
 494         makevectors(self.angles);
 495         if(eject)
 496         {
 497             setorigin(self.owner ,self.origin + v_forward * 100 + '0 0 64');
 498             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 499         }
 500         else
 501         setorigin(self.owner, self.origin - v_forward * 200 + '0 0 64');
 502
 503     self.owner = world;
 504 }
 505
 506 // Better way of determening whats crushable needed! (fl_crushable?)
 507 float spiderbot_crushable(entity e)
 508 {
 509     if(e.classname == "corpse")
 510         return 1;
 511
 512     if(e.classname == "player")
 513         return 1;
 514
 515     if(e.classname == "monster_zombie")
 516         return 1;
 517
 518     return 0;
 519 }
 520
 521 /*void spiderbot_touch(
 522 {
 523     //vehicles_touch();
 524     if(self.owner)
 525     {
 526         if(vlen(self.velocity) == 0)
 527             return;
 528
 529         if not (spiderbot_crushable(other))
 530             return;
 531
 532         //todo: add check for velocity/angle here (so we dont cush players runing into us from behind)
 533
 534         Damage(other, self, self.owner,autocvar_g_vehicle_spiderbot_crush_dmg,DEATH_SBCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicle_spiderbot_crush_force);
 535         return;
 536     }
 537
 538     if(other.classname != "player")
 539         return;
 540
 541     if(other.deadflag != DEAD_NO)
 542         return;
 543
 544     if(other.vehicle != world)
 545         return;
 546
 547     vehicles_enter();
 548 }*/
 549
 550
 551 void spiderbot_spawn()
 552 {
 553     self.frame              = 5;
 554     self.tur_head.frame     = 1;
 555     self.think              = spiderbot_think;
 556     self.nextthink          = time;
 557     self.vehicle_health     = autocvar_g_vehicle_spiderbot_health;
 558     self.vehicle_shield     = autocvar_g_vehicle_spiderbot_shield;
 559     self.movetype           = MOVETYPE_WALK;
 560     self.solid              = SOLID_SLIDEBOX;
 561     self.alpha              = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = 1;
 562     self.tur_head.angles    = '0 0 0';
 563
 564     setorigin(self, self.pos1 + '0 0 128');
 565     self.angles = self.pos2;
 566 }
 567
 568 void spiderbot_headfade()
 569 {
 570         self.think = spiderbot_headfade;
 571         self.nextthink = self.fade_time;
 572         self.alpha = 1 - (time - self.fade_time) * self.fade_rate;
 573
 574     if(self.cnt < time || self.alpha < 0.1)
 575     {
 576         if(self.alpha > 0.1)
 577         {
 578             sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 579             pointparticles(particleeffectnum("rocket_explode"), self.origin + '0 0 100', '0 0 0', 1);
 580         }
 581         remove(self);
 582     }
 583 }
 584
 585 void spiderbot_blowup()
 586 {
 587     float i;
 588     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 589
 590     for(i = 0; i < 5; ++i)
 591         pointparticles(particleeffectnum("rocket_explode"), self.origin + (randomvec() * 100) + '0 0 100', '0 0 0', 1);
 592
 593     entity h, g1, g2, b;
 594     b = spawn();
 595     h = spawn();
 596     g1 = spawn();
 597     g2 = spawn();
 598
 599     setmodel(b,  "models/vehicles/spiderbot.dpm");
 600     setmodel(h,  "models/vehicles/spiderbot_top.dpm");
 601     setmodel(g1, "models/vehicles/spiderbot_barrels.dpm");
 602     setmodel(g2, "models/vehicles/spiderbot_barrels.dpm");
 603
 604     setorigin(b, self.origin);
 605     b.frame         = 11;
 606     b.angles        = self.angles;
 607     setsize(b, self.mins, self.maxs);
 608
 609     setorigin(h, gettaginfo(self, gettagindex(self, "tag_head")));
 610     h.movetype      = MOVETYPE_BOUNCE;
 611     h.solid         = SOLID_BBOX;
 612     h.velocity      = v_up * (500 + random() * 500) + randomvec() * 128;
 613     h.modelflags    = MF_ROCKET;
 614     h.effects       = EF_FLAME | EF_LOWPRECISION;
 615     h.avelocity     = randomvec() * 360;
 616
 617     h.alpha         = 1;
 618     h.cnt           = time + (3.5 * random());
 619     h.fade_rate     = 1 / min(autocvar_g_vehicle_spiderbot_respawntime, 10);
 620     h.fade_time     = time;
 621     h.think         = spiderbot_headfade;
 622     h.nextthink     = time;
 623
 624     setorigin(g1, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint01")));
 625     g1.movetype     = MOVETYPE_TOSS;
 626     g1.solid        = SOLID_CORPSE;
 627     g1.velocity     = v_forward * 700 + (randomvec() * 32);
 628     g1.avelocity    = randomvec() * 180;
 629
 630     setorigin(g2, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint02")));
 631     g2.movetype     = MOVETYPE_TOSS;
 632     g2.solid        = SOLID_CORPSE;
 633     g2.velocity     = v_forward * 700 + (randomvec() * 32);
 634     g2.avelocity    = randomvec() * 180;
 635
 636     h.colormod = b.colormod = g1.colormod = g2.colormod = '-2 -2 -2';
 637
 638     SUB_SetFade(b,  time + 5, min(autocvar_g_vehicle_spiderbot_respawntime, 1));
 639     //SUB_SetFade(h,  time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 640     SUB_SetFade(g1, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 641     SUB_SetFade(g2, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 642
 643     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_SBBLOWUP, world);
 644
 645     self.alpha = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = -1;
 646     self.movetype   = MOVETYPE_NONE;
 647     self.deadflag   = DEAD_DEAD;
 648     self.solid      = SOLID_NOT;
 649     self.tur_head.effects  &~=  EF_FLAME;
 650         self.vehicle_hudmodel.viewmodelforclient = self;
 651
 652     //self.nextthink  = time + autocvar_g_vehicle_spiderbot_respawntime;
 653     //self.think      = spiderbot_spawn;
 654
 655     //setorigin(self, self.tur_aimpos);
 656 }
 657
 658 void spiderbot_die()
 659 {
 660     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 661     pointparticles(particleeffectnum("rocket_explode"), self.origin + '0 0 100', '0 0 0', 1);
 662
 663     self.health         = 0;
 664     self.event_damage   = SUB_Null;
 665     self.takedamage     = DAMAGE_NO;
 666     self.touch          = SUB_Null;
 667     self.nextthink      = 3.4 + time + random() * 2;
 668     self.think          = spiderbot_blowup;
 669     self.deadflag       = DEAD_DYING;
 670         self.frame          = 5;
 671         self.tur_head.effects        |= EF_FLAME;
 672         self.colormod = self.tur_head.colormod = '-1 -1 -1';
 673         self.frame = 10;
 674         self.movetype = MOVETYPE_TOSS;
 675
 676 }
 677
 678 void vewhicle_spiderbot_dinit()
 679 {
 680     if not (vehicle_initialize(
 681              "Spiderbot",
 682              "models/vehicles/spiderbot.dpm",
 683              "models/vehicles/spiderbot_top.dpm",
 684              "models/vehicles/spiderbot_cockpit.dpm",
 685              "tag_head", "tag_hud", "",
 686              HUD_SPIDERBOT,
 687              SPIDERBOT_MIN, SPIDERBOT_MAX,
 688              FALSE,
 689              spiderbot_spawn, autocvar_g_vehicle_spiderbot_respawntime,
 690              spiderbot_frame,
 691              spiderbot_enter, spiderbot_exit,
 692              spiderbot_die,   spiderbot_think))
 693     {
 694         remove(self);
 695         return;
 696     }
 697
 698     self.gun1               = spawn();
 699     self.gun2               = spawn();
 700
 701     setmodel(self.gun1, "models/vehicles/spiderbot_barrels.dpm");
 702     setmodel(self.gun2, "models/vehicles/spiderbot_barrels.dpm");
 703
 704     setattachment(self.gun1, self.tur_head, "tag_hardpoint01");
 705     setattachment(self.gun2, self.tur_head, "tag_hardpoint02");
 706
 707     self.gravity            = 2;
 708     self.mass               = 5000;
 709 }
 710
 711 void spawnfunc_vehicle_spiderbot()
 712 {
 713     precache_model ( "models/vhshield.md3");
 714     precache_model ( "models/vehicles/spiderbot.dpm");
 715     precache_model ( "models/vehicles/spiderbot_top.dpm");
 716     precache_model ( "models/vehicles/spiderbot_barrels.dpm");
 717     precache_model ( "models/vehicles/spiderbot_cockpit.dpm");
 718     precache_model ( "models/uziflash.md3");
 719
 720     precache_sound ( "weapons/rocket_impact.wav" );
 721     precache_sound ( "weapons/uzi_fire.wav" );
 722     precache_sound ( "weapons/rocket_impact.wav" );
 723
 724     vehicles_configcheck("vehicle_spiderbot.cfg", autocvar_g_vehicle_spiderbot_health);
 725     if(autocvar_g_vehicle_spiderbot_shield)
 726         self.vehicle_flags |= VHF_HASSHIELD;
 727
 728     if(autocvar_g_vehicle_spiderbot_shield_regen)
 729         self.vehicle_flags |= VHF_SHIELDREGEN;
 730
 731     if(autocvar_g_vehicle_spiderbot_health_regen)
 732         self.vehicle_flags |= VHF_HEALTHREGEN;
 733
 734     self.think = vewhicle_spiderbot_dinit;
 735     self.nextthink = time + 0.5;
 736 }