qcsrc/server/vehicles/spiderbot.qc

   1 const vector SPIDERBOT_MIN = '-75 -75 10';
   2 const vector SPIDERBOT_MAX  = '75 75 125';
   3
   4 float autocvar_g_vehicle_spiderbot_respawntime;
   5
   6 float autocvar_g_vehicle_spiderbot_speed_stop;
   7 float autocvar_g_vehicle_spiderbot_speed_strafe;
   8 float autocvar_g_vehicle_spiderbot_speed_walk;
   9 float autocvar_g_vehicle_spiderbot_turnspeed;
  10 float autocvar_g_vehicle_spiderbot_movement_inertia;
  11
  12 float autocvar_g_vehicle_spiderbot_springlength;
  13 float autocvar_g_vehicle_spiderbot_springup;
  14 float autocvar_g_vehicle_spiderbot_springblend;
  15
  16 float autocvar_g_vehicle_spiderbot_head_pitchlimit_down;
  17 float autocvar_g_vehicle_spiderbot_head_pitchlimit_up;
  18 float autocvar_g_vehicle_spiderbot_head_pitchspeed;
  19 float autocvar_g_vehicle_spiderbot_head_turnlimit;
  20 float autocvar_g_vehicle_spiderbot_head_turnspeed;
  21
  22 //float autocvar_g_vehicle_spiderbot_energy;
  23 //float autocvar_g_vehicle_spiderbot_energy_regen;
  24 //float autocvar_g_vehicle_spiderbot_energy_regen_pause;
  25
  26 float autocvar_g_vehicle_spiderbot_health;
  27 float autocvar_g_vehicle_spiderbot_health_regen;
  28 float autocvar_g_vehicle_spiderbot_health_regen_pause;
  29
  30 float autocvar_g_vehicle_spiderbot_shield;
  31 float autocvar_g_vehicle_spiderbot_shield_regen;
  32 float autocvar_g_vehicle_spiderbot_shield_regen_pause;
  33
  34 float autocvar_g_vehicle_spiderbot_minigun_damage;
  35 float autocvar_g_vehicle_spiderbot_minigun_refire;
  36 float autocvar_g_vehicle_spiderbot_minigun_spread;
  37 float autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
  38 float autocvar_g_vehicle_spiderbot_minigun_ammo_max;
  39 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen;
  40 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause;
  41
  42
  43 float autocvar_g_vehicle_spiderbot_rocket_damage;
  44 float autocvar_g_vehicle_spiderbot_rocket_edgedamage;
  45 float autocvar_g_vehicle_spiderbot_rocket_force;
  46 float autocvar_g_vehicle_spiderbot_rocket_health;
  47 float autocvar_g_vehicle_spiderbot_rocket_lifetime;
  48 float autocvar_g_vehicle_spiderbot_rocket_noise;
  49 float autocvar_g_vehicle_spiderbot_rocket_radius;
  50 float autocvar_g_vehicle_spiderbot_rocket_refire;
  51 float autocvar_g_vehicle_spiderbot_rocket_reload;
  52 float autocvar_g_vehicle_spiderbot_rocket_speed;
  53 float autocvar_g_vehicle_spiderbot_rocket_turnrate;
  54
  55
  56 void spiderbot_exit(float eject);
  57 void spiderbot_enter();
  58 void spiderbot_spawn();
  59
  60 void spiderbot_rocket_unguided()
  61 {
  62     vector newdir, olddir;
  63
  64     self.nextthink  = time;
  65
  66     olddir = normalize(self.velocity);
  67     newdir = normalize(self.pos1 - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  68     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  69
  70     UpdateCSQCProjectile(self);
  71
  72     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
  73         self.use();
  74 }
  75
  76 void spiderbot_rocket_guided()
  77 {
  78     vector newdir, olddir;
  79
  80     self.nextthink  = time;
  81
  82     if not (self.realowner.vehicle)
  83         self.think = spiderbot_rocket_unguided;
  84
  85     crosshair_trace(self.realowner);
  86     olddir = normalize(self.velocity);
  87     newdir = normalize(trace_endpos - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  88     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  89
  90     UpdateCSQCProjectile(self);
  91
  92     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
  93         self.use();
  94 }
  95
  96 void spiderbot_guide_release()
  97 {
  98     entity rkt;
  99     rkt = findchainentity(realowner, self.owner);
 100     if not (rkt)
 101         return;
 102
 103     crosshair_trace(self.owner);
 104     while(rkt)
 105     {
 106         if(rkt.think == spiderbot_rocket_guided)
 107         {
 108             rkt.pos1 = trace_endpos;
 109             rkt.think = spiderbot_rocket_unguided;
 110         }
 111         rkt = rkt.chain;
 112     }
 113 }
 114
 115 void spiderbot_rocket_do()
 116 {
 117
 118     vector v;
 119     entity rocket;
 120
 121     if (self.owner.BUTTON_ATCK2)
 122     {
 123         if (self.wait == 1)
 124         if (self.tur_head.frame == 9 || self.tur_head.frame == 1)
 125         {
 126             if(self.gun2.cnt < time && self.tur_head.frame == 9)
 127                 self.tur_head.frame = 1;
 128
 129             return;
 130         }
 131         self.wait = 1;
 132     }
 133     else
 134     {
 135         if(self.wait)
 136             spiderbot_guide_release();
 137
 138         self.wait = 0;
 139     }
 140
 141     if(self.gun2.cnt > time)
 142         return;
 143
 144     if (self.tur_head.frame >= 9)
 145         self.tur_head.frame = 1;
 146
 147     if not (self.owner.BUTTON_ATCK2)
 148         return;
 149
 150     crosshair_trace(self.owner);
 151
 152     v = gettaginfo(self.tur_head,gettagindex(self.tur_head,"tag_fire"));
 153     rocket = vehicles_projectile("spiderbot_rocket_launch", "weapons/rocket_fire.wav",
 154                            v, normalize(v_forward) * autocvar_g_vehicle_spiderbot_rocket_speed,
 155                            autocvar_g_vehicle_spiderbot_rocket_damage, autocvar_g_vehicle_spiderbot_rocket_radius, autocvar_g_vehicle_spiderbot_rocket_force, 1,
 156                            DEATH_SBROCKET, PROJECTILE_SPIDERROCKET, autocvar_g_vehicle_spiderbot_rocket_health, FALSE, FALSE);
 157
 158     rocket.cnt        = time + 15;
 159     rocket.classname  = "spiderbot_rocket";
 160     rocket.pos1       = trace_endpos;
 161     rocket.think      = spiderbot_rocket_guided;
 162     rocket.nextthink  = time;
 163     rocket.cnt        = time + autocvar_g_vehicle_spiderbot_rocket_lifetime;
 164
 165     self.tur_head.frame += 1;
 166     if (self.tur_head.frame == 9)
 167         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_reload;
 168     else
 169         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_refire;
 170
 171     self.gun2.cnt = time + self.attack_finished_single;
 172 }
 173
 174 float spiderbot_frame()
 175 {
 176     vector ad;
 177     entity player, spider;
 178     float ftmp;
 179
 180     player = self;
 181     spider = self.vehicle;
 182
 183     player.BUTTON_ZOOM      = 0;
 184     player.BUTTON_CROUCH    = 0;
 185     player.switchweapon     = 0;
 186
 187     if(player.BUTTON_USE)
 188     {
 189         self = spider;
 190         vehicles_exit(VHEF_NORMAL);
 191         self = player;
 192         return 0;
 193     }
 194
 195     self = spider;
 196
 197     crosshair_trace(player);
 198     //UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload2) + ('0 1 0' * (1 - player.vehicle_reload2)), 2);
 199
 200 #if VEHICLES_VIEWROTATE_CROSSHAIR
 201     ad = vectoangles(normalize(trace_endpos - gettaginfo(spider.tur_head,gettagindex(spider.tur_head,"tag_hud")))) - (spider.tur_head.angles + spider.angles);
 202     if(ad_x > 180) ad_x -= 360;
 203     if(ad_x < -180) ad_x += 360;
 204     if(ad_y > 180) ad_y -= 360;
 205     if(ad_y < -180) ad_y += 360;
 206
 207     // Rotate head
 208     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 209     ad_y = bound(-ftmp, ad_y, ftmp);
 210     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 211
 212     // Pitch head
 213     ftmp = autocvar_g_vehicle_spiderbot_head_pitchspeed * sys_frametime;
 214     //ad_x = bound(-ftmp, ad_x, ftmp);
 215     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 216
 217     // Turn Body
 218     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 219     ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 220 #else
 221
 222     player.v_angle_x *= -1;
 223     ad = player.v_angle - (spider.tur_head.angles + spider.angles);
 224     player.v_angle_x *= -1;
 225     if(ad_x > 180)  ad_x -= 360;
 226     if(ad_x < -180) ad_x += 360;
 227     if(ad_y > 180)  ad_y -= 360;
 228     if(ad_y < -180) ad_y += 360;
 229
 230     // Rotate head
 231     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 232     ad_y = bound(-ftmp, ad_y, ftmp);
 233     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 234
 235     // Pitch head
 236     ad = vectoangles(normalize(trace_endpos - gettaginfo(spider.tur_head,gettagindex(spider.tur_head,"tag_hud")))) - (spider.tur_head.angles + spider.angles);
 237     if(ad_x > 180) ad_x -= 360;
 238     if(ad_x < -180) ad_x += 360;
 239
 240     ftmp = autocvar_g_vehicle_spiderbot_head_pitchspeed * sys_frametime;
 241     ad_x = bound(ftmp * -1, ad_x, ftmp);
 242     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 243
 244     // Turn Body
 245     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 246     ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 247
 248 #endif
 249     makevectors(spider.angles + '-1 0 0' * spider.angles_x);
 250
 251     /*
 252     vector ofs;
 253     ofs = self.origin + v_up * 128;
 254     te_lightning1(world, ofs, ofs + v_up * 32);
 255     te_lightning1(world, ofs, ofs + v_right * 128);
 256     te_lightning1(world, ofs, ofs + v_forward * 256);
 257     */
 258
 259     movelib_groundalign4point(autocvar_g_vehicle_spiderbot_springlength, autocvar_g_vehicle_spiderbot_springup, autocvar_g_vehicle_spiderbot_springblend);
 260
 261     if(spider.flags & FL_ONGROUND)
 262     {
 263         if(player.BUTTON_JUMP && self.tur_head.wait < time)
 264         {
 265             self.tur_head.wait = time + 2;
 266             player.BUTTON_JUMP = 0;
 267             spider.velocity   = v_forward * 700 + v_up * 600;
 268             spider.frame = 4;
 269         }
 270         else
 271         {
 272             if(vlen(player.movement) == 0)
 273             {
 274                 movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 275                 spider.frame = 5;
 276             }
 277             else
 278             {
 279                 spider.angles_y = anglemods(spider.angles_y + ftmp);
 280                 spider.tur_head.angles_y -= ftmp;
 281
 282                 if(player.movement_x != 0)
 283                 {
 284                     if(player.movement_x > 0)
 285                     {
 286                         player.movement_x = 1;
 287                         spider.frame = 0;
 288                     }
 289                     else if(player.movement_x < 0)
 290                     {
 291                         player.movement_x = -1;
 292                         spider.frame = 1;
 293                     }
 294                     player.movement_y = 0;
 295                     movelib_move_simple(normalize(v_forward * player.movement_x),autocvar_g_vehicle_spiderbot_speed_walk,autocvar_g_vehicle_spiderbot_movement_inertia);
 296                 }
 297                 else if(player.movement_y != 0)
 298                 {
 299                     if(player.movement_y < 0)
 300                     {
 301                         player.movement_y = -1;
 302                         spider.frame = 2;
 303                     }
 304                     else if(player.movement_y > 0)
 305                     {
 306                         player.movement_y = 1;
 307                         spider.frame = 3;
 308                     }
 309                     movelib_move_simple(normalize(v_right * player.movement_y),autocvar_g_vehicle_spiderbot_speed_strafe,autocvar_g_vehicle_spiderbot_movement_inertia);
 310                 }
 311             }
 312         }
 313     }
 314
 315     self.angles_x = bound(-45, self.angles_x, 45);
 316     self.angles_z = bound(-45, self.angles_z, 45);
 317
 318     if(player.BUTTON_ATCK)
 319     {
 320         spider.cnt = time;
 321         if(spider.vehicle_ammo1 >= autocvar_g_vehicle_spiderbot_minigun_ammo_cost && spider.tur_head.attack_finished_single <= time)
 322         {
 323             entity gun;
 324             vector v;
 325             spider.misc_bulletcounter += 1;
 326
 327             self = player;
 328
 329             mod(spider.misc_bulletcounter, 2) ? gun = spider.gun1 : gun = spider.gun2;
 330             v = gettaginfo(gun, gettagindex(gun, "barrels"));
 331             v_forward = normalize(v_forward);
 332             v += v_forward * 50;
 333
 334             fireBullet (v, v_forward, autocvar_g_vehicle_spiderbot_minigun_spread, autocvar_g_vehicle_spiderbot_minigun_damage,
 335                 autocvar_g_vehicle_spiderbot_minigun_spread, DEATH_SBMINIGUN, 0);
 336
 337             sound (gun, CHAN_WEAPON, "weapons/uzi_fire.wav", VOL_BASE, ATTN_NORM);
 338             trailparticles(self, particleeffectnum("spiderbot_minigun_trail"), v, trace_endpos);
 339             pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), v, v_forward * 2500, 1);
 340
 341             self = spider;
 342
 343             spider.vehicle_ammo1 -= autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
 344             spider.tur_head.attack_finished_single = time + autocvar_g_vehicle_spiderbot_minigun_refire;
 345             player.vehicle_ammo1 = (spider.vehicle_ammo1 / autocvar_g_vehicle_spiderbot_minigun_ammo_max) * 100;
 346         }
 347     }
 348     else
 349         vehicles_regen(cnt, vehicle_ammo1, autocvar_g_vehicle_spiderbot_minigun_ammo_max,
 350                                            autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause,
 351                                            autocvar_g_vehicle_spiderbot_minigun_ammo_regen, frametime);
 352
 353     dprint("1: ammo1:", ftos(spider.vehicle_ammo1), "\n");
 354
 355     spiderbot_rocket_do();
 356
 357     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 358         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_spiderbot_shield, autocvar_g_vehicle_spiderbot_shield_regen_pause, autocvar_g_vehicle_spiderbot_shield_regen, frametime);
 359
 360     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 361         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_spiderbot_health, autocvar_g_vehicle_spiderbot_health_regen_pause, autocvar_g_vehicle_spiderbot_health_regen, frametime);
 362
 363     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 364     player.vehicle_ammo2 = spider.tur_head.frame;
 365
 366     if(spider.gun2.cnt <= time)
 367         player.vehicle_reload2 = 1;
 368     else
 369         player.vehicle_reload2 = 1 - ((spider.gun2.cnt - time) / spider.attack_finished_single);
 370
 371     setorigin(player, spider.origin + '0 0 1' * SPIDERBOT_MAX_z);
 372     player.velocity = spider.velocity;
 373
 374     VEHICLE_UPDATE_PLAYER(health, spiderbot);
 375
 376     if(self.vehicle_flags & VHF_HASSHIELD)
 377         VEHICLE_UPDATE_PLAYER(shield, spiderbot);
 378
 379 #if 1 // 0 to enable per-gun impact aux crosshairs
 380     // Avarage gun impact point's -> aux cross
 381     vector vf;
 382     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 383     vf = v_forward;
 384     ad += gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 385     vf += v_forward;
 386     ad = ad * 0.5;
 387     v_forward = vf * 0.5;
 388     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 389     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 390
 391 #else
 392     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 393     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 394     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 395
 396     ad = gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 397     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 398     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 1);
 399 #endif
 400
 401     self = player;
 402     return 1;
 403 }
 404
 405 void spiderbot_think()
 406 {
 407     if(self.flags & FL_ONGROUND)
 408         movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 409
 410     self.nextthink = time;
 411 }
 412
 413 void spiderbot_enter()
 414 {
 415     self.movetype   = MOVETYPE_WALK;
 416     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_spiderbot_health);
 417     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_spiderbot_shield);
 418 }
 419
 420 void spiderbot_exit(float eject)
 421 {
 422     entity e;
 423
 424     e = findchain(classname,"spiderbot_rocket");
 425     while(e)
 426     {
 427         if(e.owner == self.owner)
 428         {
 429             e.realowner = self.owner;
 430             e.owner = world;
 431         }
 432         e = e.chain;
 433     }
 434
 435     self.velocity   = '0 0 0';
 436     self.think      = spiderbot_think;
 437     self.nextthink  = time;
 438     self.frame      = 5;
 439     self.movetype   = MOVETYPE_WALK;
 440
 441     if not (self.owner)
 442         return;
 443
 444         makevectors(self.angles);
 445         if(eject)
 446         {
 447             setorigin(self.owner ,self.origin + v_forward * 100 + '0 0 64');
 448             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 449         }
 450         else
 451         setorigin(self.owner, self.origin - v_forward * 200 + '0 0 64');
 452
 453     self.owner = world;
 454 }
 455
 456 void spiderbot_spawn()
 457 {
 458     self.frame              = 5;
 459     self.tur_head.frame     = 1;
 460     self.think              = spiderbot_think;
 461     self.nextthink          = time;
 462     self.vehicle_health     = autocvar_g_vehicle_spiderbot_health;
 463     self.vehicle_shield     = autocvar_g_vehicle_spiderbot_shield;
 464     self.movetype           = MOVETYPE_WALK;
 465     self.solid              = SOLID_SLIDEBOX;
 466     self.alpha              = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = 1;
 467     self.tur_head.angles    = '0 0 0';
 468
 469     setorigin(self, self.pos1 + '0 0 128');
 470     self.angles = self.pos2;
 471 }
 472
 473 void spiderbot_headfade()
 474 {
 475         self.think = spiderbot_headfade;
 476         self.nextthink = self.fade_time;
 477         self.alpha = 1 - (time - self.fade_time) * self.fade_rate;
 478
 479     if(self.cnt < time || self.alpha < 0.1)
 480     {
 481         if(self.alpha > 0.1)
 482         {
 483             sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 484             pointparticles(particleeffectnum("rocket_explode"), self.origin + '0 0 100', '0 0 0', 1);
 485         }
 486         remove(self);
 487     }
 488 }
 489
 490 void spiderbot_blowup()
 491 {
 492     float i;
 493     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 494
 495     for(i = 0; i < 5; ++i)
 496         pointparticles(particleeffectnum("rocket_explode"), self.origin + (randomvec() * 100) + '0 0 100', '0 0 0', 1);
 497
 498     entity h, g1, g2, b;
 499     b = spawn();
 500     h = spawn();
 501     g1 = spawn();
 502     g2 = spawn();
 503
 504     setmodel(b,  "models/vehicles/spiderbot.dpm");
 505     setmodel(h,  "models/vehicles/spiderbot_top.dpm");
 506     setmodel(g1, "models/vehicles/spiderbot_barrels.dpm");
 507     setmodel(g2, "models/vehicles/spiderbot_barrels.dpm");
 508
 509     setorigin(b, self.origin);
 510     b.frame         = 11;
 511     b.angles        = self.angles;
 512     setsize(b, self.mins, self.maxs);
 513
 514     setorigin(h, gettaginfo(self, gettagindex(self, "tag_head")));
 515     h.movetype      = MOVETYPE_BOUNCE;
 516     h.solid         = SOLID_BBOX;
 517     h.velocity      = v_up * (500 + random() * 500) + randomvec() * 128;
 518     h.modelflags    = MF_ROCKET;
 519     h.effects       = EF_FLAME | EF_LOWPRECISION;
 520     h.avelocity     = randomvec() * 360;
 521
 522     h.alpha         = 1;
 523     h.cnt           = time + (3.5 * random());
 524     h.fade_rate     = 1 / min(autocvar_g_vehicle_spiderbot_respawntime, 10);
 525     h.fade_time     = time;
 526     h.think         = spiderbot_headfade;
 527     h.nextthink     = time;
 528
 529     setorigin(g1, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint01")));
 530     g1.movetype     = MOVETYPE_TOSS;
 531     g1.solid        = SOLID_CORPSE;
 532     g1.velocity     = v_forward * 700 + (randomvec() * 32);
 533     g1.avelocity    = randomvec() * 180;
 534
 535     setorigin(g2, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint02")));
 536     g2.movetype     = MOVETYPE_TOSS;
 537     g2.solid        = SOLID_CORPSE;
 538     g2.velocity     = v_forward * 700 + (randomvec() * 32);
 539     g2.avelocity    = randomvec() * 180;
 540
 541     h.colormod = b.colormod = g1.colormod = g2.colormod = '-2 -2 -2';
 542
 543     SUB_SetFade(b,  time + 5, min(autocvar_g_vehicle_spiderbot_respawntime, 1));
 544     //SUB_SetFade(h,  time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 545     SUB_SetFade(g1, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 546     SUB_SetFade(g2, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 547
 548     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_SBBLOWUP, world);
 549
 550     self.alpha = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = -1;
 551     self.movetype   = MOVETYPE_NONE;
 552     self.deadflag   = DEAD_DEAD;
 553     self.solid      = SOLID_NOT;
 554     self.tur_head.effects  &~=  EF_FLAME;
 555         self.vehicle_hudmodel.viewmodelforclient = self;
 556
 557     //self.nextthink  = time + autocvar_g_vehicle_spiderbot_respawntime;
 558     //self.think      = spiderbot_spawn;
 559
 560     //setorigin(self, self.tur_aimpos);
 561 }
 562
 563 void spiderbot_die()
 564 {
 565     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 566     pointparticles(particleeffectnum("rocket_explode"), self.origin + '0 0 100', '0 0 0', 1);
 567
 568     self.health         = 0;
 569     self.event_damage   = SUB_Null;
 570     self.takedamage     = DAMAGE_NO;
 571     self.touch          = SUB_Null;
 572     self.nextthink      = 3.4 + time + random() * 2;
 573     self.think          = spiderbot_blowup;
 574     self.deadflag       = DEAD_DYING;
 575         self.frame          = 5;
 576         self.tur_head.effects        |= EF_FLAME;
 577         self.colormod = self.tur_head.colormod = '-1 -1 -1';
 578         self.frame = 10;
 579         self.movetype = MOVETYPE_TOSS;
 580
 581 }
 582
 583 void vewhicle_spiderbot_dinit()
 584 {
 585     if not (vehicle_initialize(
 586              "Spiderbot",
 587              "models/vehicles/spiderbot.dpm",
 588              "models/vehicles/spiderbot_top.dpm",
 589              "models/vehicles/spiderbot_cockpit.dpm",
 590              "tag_head", "tag_hud", "",
 591              HUD_SPIDERBOT,
 592              SPIDERBOT_MIN, SPIDERBOT_MAX,
 593              FALSE,
 594              spiderbot_spawn, autocvar_g_vehicle_spiderbot_respawntime,
 595              spiderbot_frame,
 596              spiderbot_enter, spiderbot_exit,
 597              spiderbot_die,   spiderbot_think))
 598     {
 599         remove(self);
 600         return;
 601     }
 602
 603     self.gun1               = spawn();
 604     self.gun2               = spawn();
 605
 606     setmodel(self.gun1, "models/vehicles/spiderbot_barrels.dpm");
 607     setmodel(self.gun2, "models/vehicles/spiderbot_barrels.dpm");
 608
 609     setattachment(self.gun1, self.tur_head, "tag_hardpoint01");
 610     setattachment(self.gun2, self.tur_head, "tag_hardpoint02");
 611
 612     self.gravity            = 2;
 613     self.mass               = 5000;
 614 }
 615
 616 void spawnfunc_vehicle_spiderbot()
 617 {
 618     precache_model ( "models/vhshield.md3");
 619     precache_model ( "models/vehicles/spiderbot.dpm");
 620     precache_model ( "models/vehicles/spiderbot_top.dpm");
 621     precache_model ( "models/vehicles/spiderbot_barrels.dpm");
 622     precache_model ( "models/vehicles/spiderbot_cockpit.dpm");
 623     precache_model ( "models/uziflash.md3");
 624
 625     precache_sound ( "weapons/rocket_impact.wav" );
 626     precache_sound ( "weapons/uzi_fire.wav" );
 627     precache_sound ( "weapons/rocket_impact.wav" );
 628
 629     vehicles_configcheck("vehicle_spiderbot.cfg", autocvar_g_vehicle_spiderbot_health);
 630     if(autocvar_g_vehicle_spiderbot_shield)
 631         self.vehicle_flags |= VHF_HASSHIELD;
 632
 633     if(autocvar_g_vehicle_spiderbot_shield_regen)
 634         self.vehicle_flags |= VHF_SHIELDREGEN;
 635
 636     if(autocvar_g_vehicle_spiderbot_health_regen)
 637         self.vehicle_flags |= VHF_HEALTHREGEN;
 638
 639     self.think = vewhicle_spiderbot_dinit;
 640     self.nextthink = time + 0.5;
 641 }