qcsrc/server/w_grenadelauncher.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(GRENADE_LAUNCHER, w_glauncher, IT_ROCKETS, 4, WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "gl", "grenadelauncher", _("Mortar"))
   3 #else
   4 #ifdef SVQC
   5 .float gl_detonate_later;
   6 .float gl_bouncecnt;
   7
   8 .float grenadelauncher_load;
   9
  10 void W_GrenadeLauncher_SetAmmoCounter()
  11 {
  12         // set clip_load to the weapon we have switched to, if the gun uses reloading
  13         if(!autocvar_g_balance_grenadelauncher_reload_ammo)
  14                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  15         else
  16         {
  17                 self.clip_load = self.grenadelauncher_load;
  18                 self.clip_size = autocvar_g_balance_grenadelauncher_reload_ammo; // for the crosshair ammo display
  19         }
  20 }
  21
  22 void W_GrenadeLauncher_ReloadedAndReady()
  23 {
  24         float t;
  25
  26         // now do the ammo transfer
  27         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  28         while(self.clip_load < autocvar_g_balance_grenadelauncher_reload_ammo && self.ammo_rockets) // make sure we don't add more ammo than we have
  29         {
  30                 self.clip_load += 1;
  31                 self.ammo_rockets -= 1;
  32         }
  33         self.grenadelauncher_load = self.clip_load;
  34
  35         t = ATTACK_FINISHED(self) - autocvar_g_balance_grenadelauncher_reload_time - 1;
  36         ATTACK_FINISHED(self) = t;
  37         w_ready();
  38 }
  39
  40 void W_GrenadeLauncher_Reload()
  41 {
  42         // return if reloading is disabled for this weapon
  43         if(!autocvar_g_balance_grenadelauncher_reload_ammo)
  44                 return;
  45
  46         if(!W_ReloadCheck(self.ammo_rockets, min(autocvar_g_balance_grenadelauncher_primary_ammo, autocvar_g_balance_grenadelauncher_secondary_ammo)))
  47                 return;
  48
  49         float t;
  50
  51         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  52
  53         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_grenadelauncher_reload_time + 1;
  54         ATTACK_FINISHED(self) = t;
  55
  56         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_grenadelauncher_reload_time, W_GrenadeLauncher_ReloadedAndReady);
  57
  58         self.old_clip_load = self.clip_load;
  59         self.clip_load = -1;
  60 }
  61
  62 void W_Grenade_Explode (void)
  63 {
  64         if(other.takedamage == DAMAGE_AIM)
  65                 if(other.classname == "player")
  66                         if(IsDifferentTeam(self.owner, other))
  67                                 if(other.deadflag == DEAD_NO)
  68                                         if(IsFlying(other))
  69                                                 AnnounceTo(self.owner, "airshot");
  70
  71         self.event_damage = SUB_Null;
  72         self.takedamage = DAMAGE_NO;
  73
  74         if(self.movetype == MOVETYPE_NONE)
  75                 self.velocity = self.oldvelocity;
  76
  77         RadiusDamage (self, self.owner, autocvar_g_balance_grenadelauncher_primary_damage, autocvar_g_balance_grenadelauncher_primary_edgedamage, autocvar_g_balance_grenadelauncher_primary_radius, world, autocvar_g_balance_grenadelauncher_primary_force, self.projectiledeathtype, other);
  78
  79         remove (self);
  80 }
  81
  82 void W_Grenade_Explode2 (void)
  83 {
  84         if(other.takedamage == DAMAGE_AIM)
  85                 if(other.classname == "player")
  86                         if(IsDifferentTeam(self.owner, other))
  87                                 if(IsFlying(other))
  88                                         AnnounceTo(self.owner, "airshot");
  89
  90         self.event_damage = SUB_Null;
  91         self.takedamage = DAMAGE_NO;
  92
  93         if(self.movetype == MOVETYPE_NONE)
  94                 self.velocity = self.oldvelocity;
  95
  96         RadiusDamage (self, self.owner, autocvar_g_balance_grenadelauncher_secondary_damage, autocvar_g_balance_grenadelauncher_secondary_edgedamage, autocvar_g_balance_grenadelauncher_secondary_radius, world, autocvar_g_balance_grenadelauncher_secondary_force, self.projectiledeathtype, other);
  97
  98         remove (self);
  99 }
 100
 101 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 102 {
 103         if (self.health <= 0)
 104                 return;
 105         self.health = self.health - damage;
 106         if (self.health <= 0)
 107         {
 108                 W_PrepareExplosionByDamage(attacker, self.think);
 109         }
 110 }
 111
 112 void W_Grenade_Think1 (void)
 113 {
 114         self.nextthink = time;
 115         if (time > self.cnt)
 116         {
 117                 other = world;
 118                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 119                 W_Grenade_Explode ();
 120                 return;
 121         }
 122         if(self.gl_detonate_later && self.gl_bouncecnt >= autocvar_g_balance_grenadelauncher_primary_remote_minbouncecnt)
 123                 W_Grenade_Explode();
 124 }
 125
 126 void W_Grenade_Touch1 (void)
 127 {
 128         PROJECTILE_TOUCH;
 129         if (other.takedamage == DAMAGE_AIM || autocvar_g_balance_grenadelauncher_primary_type == 0) // always explode when hitting a player, or if normal mortar projectile
 130         {
 131                 self.use ();
 132         }
 133         else if (autocvar_g_balance_grenadelauncher_primary_type == 1) // bounce
 134         {
 135                 float r;
 136                 r = random() * 6;
 137                 if(r < 1)
 138                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
 139                 else if(r < 2)
 140                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
 141                 else if(r < 3)
 142                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
 143                 else if(r < 4)
 144                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
 145                 else if(r < 5)
 146                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
 147                 else
 148                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
 149                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 150                 self.gl_bouncecnt += 1;
 151         }
 152         else if(autocvar_g_balance_grenadelauncher_primary_type == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
 153         {
 154                 spamsound (self, CHAN_PROJECTILE, "weapons/grenade_stick.wav", VOL_BASE, ATTN_NORM);
 155
 156                 // let it stick whereever it is
 157                 self.oldvelocity = self.velocity;
 158                 self.velocity = '0 0 0';
 159                 self.movetype = MOVETYPE_NONE; // also disables gravity
 160                 self.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
 161                 UpdateCSQCProjectile(self);
 162
 163                 // do not respond to any more touches
 164                 self.solid = SOLID_NOT;
 165
 166                 self.nextthink = min(self.nextthink, time + autocvar_g_balance_grenadelauncher_primary_lifetime2);
 167         }
 168 }
 169
 170 void W_Grenade_Touch2 (void)
 171 {
 172         PROJECTILE_TOUCH;
 173         if (other.takedamage == DAMAGE_AIM || autocvar_g_balance_grenadelauncher_secondary_type == 0) // always explode when hitting a player, or if normal mortar projectile
 174         {
 175                 self.use ();
 176         }
 177         else if (autocvar_g_balance_grenadelauncher_secondary_type == 1) // bounce
 178         {
 179                 float r;
 180                 r = random() * 6;
 181                 if(r < 1)
 182                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
 183                 else if(r < 2)
 184                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
 185                 else if(r < 3)
 186                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
 187                 else if(r < 4)
 188                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
 189                 else if(r < 5)
 190                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
 191                 else
 192                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
 193                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 194                 self.gl_bouncecnt += 1;
 195         }
 196         else if(autocvar_g_balance_grenadelauncher_secondary_type == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
 197         {
 198                 spamsound (self, CHAN_PROJECTILE, "weapons/grenade_stick.wav", VOL_BASE, ATTN_NORM);
 199
 200                 // let it stick whereever it is
 201                 self.oldvelocity = self.velocity;
 202                 self.velocity = '0 0 0';
 203                 self.movetype = MOVETYPE_NONE; // also disables gravity
 204                 self.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
 205                 UpdateCSQCProjectile(self);
 206
 207                 // do not respond to any more touches
 208                 self.solid = SOLID_NOT;
 209
 210                 self.nextthink = min(self.nextthink, time + autocvar_g_balance_grenadelauncher_secondary_lifetime2);
 211         }
 212 }
 213
 214 void W_Grenade_Attack (void)
 215 {
 216         local entity gren;
 217
 218         // if there's not enough ammo for this attack (but we still have the weapon), reload
 219         if(autocvar_g_balance_grenadelauncher_reload_ammo && self.clip_load < autocvar_g_balance_grenadelauncher_primary_ammo)
 220         {
 221                 W_GrenadeLauncher_Reload();
 222                 return;
 223         }
 224
 225         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 226         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 227         {
 228                 if(autocvar_g_balance_grenadelauncher_reload_ammo)
 229                 {
 230                         self.clip_load -= autocvar_g_balance_grenadelauncher_primary_ammo;
 231                         self.grenadelauncher_load = self.clip_load;
 232                 }
 233                 else
 234                         self.ammo_rockets -= autocvar_g_balance_grenadelauncher_primary_ammo;
 235         }
 236
 237         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 4, "weapons/grenade_fire.wav", CHAN_WEAPON, autocvar_g_balance_grenadelauncher_primary_damage);
 238         w_shotdir = v_forward; // no TrueAim for grenades please
 239
 240         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 241
 242         gren = spawn ();
 243         gren.owner = self;
 244         gren.classname = "grenade";
 245         gren.bot_dodge = TRUE;
 246         gren.bot_dodgerating = autocvar_g_balance_grenadelauncher_primary_damage;
 247         gren.movetype = MOVETYPE_BOUNCE;
 248         gren.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 249         gren.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 250         PROJECTILE_MAKETRIGGER(gren);
 251         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER;
 252         setorigin(gren, w_shotorg);
 253         setsize(gren, '-3 -3 -3', '3 3 3');
 254
 255         gren.cnt = time + autocvar_g_balance_grenadelauncher_primary_lifetime;
 256         gren.nextthink = time;
 257         gren.think = W_Grenade_Think1;
 258         gren.use = W_Grenade_Explode;
 259         gren.touch = W_Grenade_Touch1;
 260
 261         gren.takedamage = DAMAGE_YES;
 262         gren.health = autocvar_g_balance_grenadelauncher_primary_health;
 263         gren.damageforcescale = autocvar_g_balance_grenadelauncher_primary_damageforcescale;
 264         gren.event_damage = W_Grenade_Damage;
 265         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_primary);
 266
 267         gren.angles = vectoangles (gren.velocity);
 268         gren.flags = FL_PROJECTILE;
 269
 270         if(autocvar_g_balance_grenadelauncher_primary_type == 0 || autocvar_g_balance_grenadelauncher_primary_type == 2)
 271                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 272         else
 273                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING, TRUE);
 274
 275         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 276 }
 277
 278 void W_Grenade_Attack2 (void)
 279 {
 280         local entity gren;
 281
 282         // if there's not enough ammo for this attack (but we still have the weapon), reload
 283         if(autocvar_g_balance_grenadelauncher_reload_ammo && self.clip_load < autocvar_g_balance_grenadelauncher_secondary_ammo)
 284         {
 285                 W_GrenadeLauncher_Reload();
 286                 return;
 287         }
 288
 289         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 290         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 291         {
 292                 if(autocvar_g_balance_grenadelauncher_reload_ammo)
 293                 {
 294                         self.clip_load -= autocvar_g_balance_grenadelauncher_secondary_ammo;
 295                         self.grenadelauncher_load = self.clip_load;
 296                 }
 297                 else
 298                         self.ammo_rockets -= autocvar_g_balance_grenadelauncher_secondary_ammo;
 299         }
 300
 301         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 4, "weapons/grenade_fire.wav", CHAN_WEAPON, autocvar_g_balance_grenadelauncher_secondary_damage);
 302         w_shotdir = v_forward; // no TrueAim for grenades please
 303
 304         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 305
 306         gren = spawn ();
 307         gren.owner = self;
 308         gren.classname = "grenade";
 309         gren.bot_dodge = TRUE;
 310         gren.bot_dodgerating = autocvar_g_balance_grenadelauncher_secondary_damage;
 311         gren.movetype = MOVETYPE_BOUNCE;
 312         gren.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 313         gren.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 314         PROJECTILE_MAKETRIGGER(gren);
 315         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER | HITTYPE_SECONDARY;
 316         setorigin(gren, w_shotorg);
 317         setsize(gren, '-3 -3 -3', '3 3 3');
 318
 319         gren.nextthink = time + autocvar_g_balance_grenadelauncher_secondary_lifetime;
 320         gren.think = adaptor_think2use_hittype_splash;
 321         gren.use = W_Grenade_Explode2;
 322         gren.touch = W_Grenade_Touch2;
 323
 324         gren.takedamage = DAMAGE_YES;
 325         gren.health = autocvar_g_balance_grenadelauncher_secondary_health;
 326         gren.damageforcescale = autocvar_g_balance_grenadelauncher_secondary_damageforcescale;
 327         gren.event_damage = W_Grenade_Damage;
 328         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_secondary);
 329
 330         gren.angles = vectoangles (gren.velocity);
 331         gren.flags = FL_PROJECTILE;
 332
 333         if(autocvar_g_balance_grenadelauncher_secondary_type == 0 || autocvar_g_balance_grenadelauncher_secondary_type == 2)
 334                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 335         else
 336                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING, TRUE);
 337
 338         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 339 }
 340
 341 void spawnfunc_weapon_grenadelauncher (void)
 342 {
 343         weapon_defaultspawnfunc(WEP_GRENADE_LAUNCHER);
 344 }
 345
 346 .float bot_secondary_grenademooth;
 347 float w_glauncher(float req)
 348 {
 349         entity nade;
 350         float nadefound;
 351
 352         if (req == WR_AIM)
 353         {
 354                 self.BUTTON_ATCK = FALSE;
 355                 self.BUTTON_ATCK2 = FALSE;
 356                 if (self.bot_secondary_grenademooth == 0)
 357                 {
 358                         if(bot_aim(autocvar_g_balance_grenadelauncher_primary_speed, autocvar_g_balance_grenadelauncher_primary_speed_up, autocvar_g_balance_grenadelauncher_primary_lifetime, TRUE))
 359                         {
 360                                 self.BUTTON_ATCK = TRUE;
 361                                 if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 362                         }
 363                 }
 364                 else
 365                 {
 366                         if(bot_aim(autocvar_g_balance_grenadelauncher_secondary_speed, autocvar_g_balance_grenadelauncher_secondary_speed_up, autocvar_g_balance_grenadelauncher_secondary_lifetime, TRUE))
 367                         {
 368                                 self.BUTTON_ATCK2 = TRUE;
 369                                 if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 370                         }
 371                 }
 372         }
 373         else if (req == WR_THINK)
 374         {
 375                 if(autocvar_g_balance_grenadelauncher_reload_ammo && self.clip_load < min(autocvar_g_balance_grenadelauncher_primary_ammo, autocvar_g_balance_grenadelauncher_secondary_ammo)) // forced reload
 376                         W_GrenadeLauncher_Reload();
 377                 else if (self.BUTTON_ATCK)
 378                 {
 379                         if (weapon_prepareattack(0, autocvar_g_balance_grenadelauncher_primary_refire))
 380                         {
 381                                 W_Grenade_Attack();
 382                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_grenadelauncher_primary_animtime, w_ready);
 383                         }
 384                 }
 385                 else if (self.BUTTON_ATCK2)
 386                 {
 387                         if (cvar("g_balance_grenadelauncher_secondary_remote_detonateprimary"))
 388                         {
 389                                 nadefound = 0;
 390                                 for(nade = world; (nade = find(nade, classname, "grenade")); ) if(nade.owner == self)
 391                                 {
 392                                         if(!nade.gl_detonate_later)
 393                                         {
 394                                                 nade.gl_detonate_later = TRUE;
 395                                                 nadefound = 1;
 396                                         }
 397                                 }
 398                                 if(nadefound)
 399                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 400                         }
 401                         else if (weapon_prepareattack(1, autocvar_g_balance_grenadelauncher_secondary_refire))
 402                         {
 403                                 W_Grenade_Attack2();
 404                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_grenadelauncher_secondary_animtime, w_ready);
 405                         }
 406                 }
 407         if(self.wish_reload)
 408         {
 409             if(self.switchweapon == self.weapon)
 410             {
 411                 if(self.weaponentity.state == WS_READY)
 412                 {
 413                     self.wish_reload = 0;
 414                     W_GrenadeLauncher_Reload();
 415                 }
 416             }
 417         }
 418         }
 419         else if (req == WR_PRECACHE)
 420         {
 421                 precache_model ("models/weapons/g_gl.md3");
 422                 precache_model ("models/weapons/v_gl.md3");
 423                 precache_model ("models/weapons/h_gl.iqm");
 424                 precache_sound ("weapons/grenade_bounce1.wav");
 425                 precache_sound ("weapons/grenade_bounce2.wav");
 426                 precache_sound ("weapons/grenade_bounce3.wav");
 427                 precache_sound ("weapons/grenade_bounce4.wav");
 428                 precache_sound ("weapons/grenade_bounce5.wav");
 429                 precache_sound ("weapons/grenade_bounce6.wav");
 430                 precache_sound ("weapons/grenade_stick.wav");
 431                 precache_sound ("weapons/grenade_fire.wav");
 432         }
 433         else if (req == WR_SETUP)
 434         {
 435                 weapon_setup(WEP_GRENADE_LAUNCHER);
 436                 W_GrenadeLauncher_SetAmmoCounter();
 437         }
 438         else if (req == WR_CHECKAMMO1)
 439         {
 440                 if(autocvar_g_balance_grenadelauncher_reload_ammo)
 441                         return self.grenadelauncher_load >= autocvar_g_balance_grenadelauncher_primary_ammo;
 442                 else
 443                         return self.ammo_rockets >= autocvar_g_balance_grenadelauncher_primary_ammo;
 444         }
 445         else if (req == WR_CHECKAMMO2)
 446         {
 447                 if(autocvar_g_balance_grenadelauncher_reload_ammo)
 448                         return self.grenadelauncher_load >= autocvar_g_balance_grenadelauncher_secondary_ammo;
 449                 else
 450                         return self.ammo_rockets >= autocvar_g_balance_grenadelauncher_secondary_ammo;
 451         }
 452         return TRUE;
 453 };
 454 #endif
 455 #ifdef CSQC
 456 float w_glauncher(float req)
 457 {
 458         if(req == WR_IMPACTEFFECT)
 459         {
 460                 vector org2;
 461                 org2 = w_org + w_backoff * 12;
 462                 pointparticles(particleeffectnum("grenade_explode"), org2, '0 0 0', 1);
 463                 if(!w_issilent)
 464                         sound(self, CHAN_PROJECTILE, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 465         }
 466         else if(req == WR_PRECACHE)
 467         {
 468                 precache_sound("weapons/grenade_impact.wav");
 469         }
 470         else if (req == WR_SUICIDEMESSAGE)
 471         {
 472                 if(w_deathtype & HITTYPE_SECONDARY)
 473                         w_deathtypestring = "%s tried out his own grenade";
 474                 else
 475                         w_deathtypestring = "%s detonated";
 476         }
 477         else if (req == WR_KILLMESSAGE)
 478         {
 479                 if(w_deathtype & HITTYPE_SPLASH)
 480                         if(w_deathtype & HITTYPE_BOUNCE) // (must be secondary then)
 481                                 w_deathtypestring = "%s didn't see %s's grenade";
 482                         else // unchecked: SECONDARY
 483                                 w_deathtypestring = "%s almost dodged %s's grenade";
 484                 else // unchecked: SECONDARY, BOUNCE
 485                         w_deathtypestring = "%s ate %s's grenade";
 486         }
 487         else if (req == WR_RELOAD)
 488         {
 489                 W_GrenadeLauncher_Reload();
 490         }
 491         return TRUE;
 492 }
 493 #endif
 494 #endif