qcsrc/server/w_hagar.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
   3 #else
   4 #ifdef SVQC
   5 // NO bounce protection, as bounces are limited!
   6
   7 void W_Hagar_Explode (void)
   8 {
   9         self.event_damage = SUB_Null;
  10         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
  11
  12         remove (self);
  13 }
  14
  15 void W_Hagar_Explode2 (void)
  16 {
  17         self.event_damage = SUB_Null;
  18         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
  19
  20         remove (self);
  21 }
  22
  23 void W_Hagar_Touch (void)
  24 {
  25         PROJECTILE_TOUCH;
  26         self.use ();
  27 }
  28
  29 void W_Hagar_Touch2 (void)
  30 {
  31         PROJECTILE_TOUCH;
  32
  33         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  34                 self.use();
  35         } else {
  36                 self.cnt++;
  37                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  38                 self.angles = vectoangles (self.velocity);
  39                 self.owner = world;
  40                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  41         }
  42 }
  43
  44 void W_Hagar_Attack (void)
  45 {
  46         local entity missile;
  47
  48         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
  49
  50         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_primary_damage);
  51
  52         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  53
  54         missile = spawn ();
  55         missile.owner = missile.realowner = self;
  56         missile.classname = "missile";
  57         missile.bot_dodge = TRUE;
  58         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
  59         missile.touch = W_Hagar_Touch;
  60         missile.use = W_Hagar_Explode;
  61         missile.think = adaptor_think2use_hittype_splash;
  62         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
  63         PROJECTILE_MAKETRIGGER(missile);
  64         missile.projectiledeathtype = WEP_HAGAR;
  65         setorigin (missile, w_shotorg);
  66         setsize(missile, '0 0 0', '0 0 0');
  67
  68         missile.movetype = MOVETYPE_FLY;
  69         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
  70
  71         missile.angles = vectoangles (missile.velocity);
  72         missile.flags = FL_PROJECTILE;
  73
  74         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
  75
  76         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  77 }
  78
  79 void W_Hagar_Attack2 (void)
  80 {
  81         local entity missile;
  82
  83         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
  84
  85         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
  86
  87         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  88
  89         missile = spawn ();
  90         missile.owner = missile.realowner = self;
  91         missile.classname = "missile";
  92         missile.bot_dodge = TRUE;
  93         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
  94         missile.touch = W_Hagar_Touch2;
  95         missile.cnt = 0;
  96         missile.use = W_Hagar_Explode2;
  97         missile.think = adaptor_think2use_hittype_splash;
  98         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
  99         PROJECTILE_MAKETRIGGER(missile);
 100         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 101         setorigin (missile, w_shotorg);
 102         setsize(missile, '0 0 0', '0 0 0');
 103
 104         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 105         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
 106
 107         missile.angles = vectoangles (missile.velocity);
 108         missile.flags = FL_PROJECTILE;
 109
 110         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 111
 112         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 113 }
 114
 115 .float hagar_loadstep, hagar_loadblock;
 116 void W_Hagar_Attack2_Load (void)
 117 {
 118         // loadable hagar secondary attack, must always run each frame
 119
 120         if not(weapon_action(self.weapon, WR_CHECKAMMO2))
 121         {
 122                 W_SwitchToOtherWeapon(self);
 123                 return;
 124         }
 125
 126         local entity missile;
 127         local float counter, shots, loaded;
 128         local float used_ammo, enough_ammo;
 129         local vector s;
 130         vector forward, right, up;
 131
 132         loaded = self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max;
 133
 134         // check if we have enough ammo for another rocket
 135         used_ammo = autocvar_g_balance_hagar_secondary_ammo;
 136         if(autocvar_g_balance_hagar_reload_ammo)
 137                 enough_ammo = self.weapon_load[WEP_HAGAR] >= used_ammo + (used_ammo * self.hagar_load);
 138         else
 139                 enough_ammo = self.ammo_rockets >= used_ammo + (used_ammo * self.hagar_load);
 140
 141         if(self.BUTTON_ATCK2)
 142         {
 143                 if(self.BUTTON_ATCK)
 144                 {
 145                         if(self.hagar_load)
 146                         {
 147                                 // if we pressed primary fire while loading, unload all rockets and abort
 148                                 self.hagar_load = 0;
 149                                 sound(self, CHAN_WEAPON2, "weapons/hagar_load.wav", VOL_BASE, ATTN_NORM);
 150
 151                                 // require letting go of the alt fire button before we can load again
 152                                 self.hagar_loadblock = TRUE;
 153                         }
 154                 }
 155                 else
 156                 {
 157                         // check if we can attempt to load another rocket
 158                         if(!self.hagar_loadblock && !loaded && enough_ammo)
 159                         if(self.hagar_loadstep < time)
 160                         {
 161                                 self.hagar_load += 1;
 162                                 sound(self, CHAN_WEAPON2, "weapons/hagar_load.wav", VOL_BASE, ATTN_NORM);
 163
 164                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed;
 165                         }
 166                 }
 167         }
 168         else if(self.hagar_loadblock)
 169         {
 170                 // the alt fire button was released, so re-enable loading if blocked
 171                 self.hagar_loadblock = FALSE;
 172         }
 173
 174         if(self.hagar_load)
 175         if(!self.BUTTON_ATCK2 || ((loaded || !enough_ammo) && self.hagar_loadstep < time && !autocvar_g_balance_hagar_secondary_load_hold))
 176         if(weapon_prepareattack(0, autocvar_g_balance_hagar_secondary_refire))
 177         {
 178                 // time to release the rockets we've loaded
 179
 180                 W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load, autocvar_g_balance_hagar_reload_ammo);
 181
 182                 W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
 183                 pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 184
 185                 forward = v_forward;
 186                 right = v_right;
 187                 up = v_up;
 188
 189                 shots = self.hagar_load;
 190                 missile = world;
 191                 while (counter < shots)
 192                 {
 193                         missile = spawn ();
 194                         missile.owner = missile.realowner = self;
 195                         missile.classname = "missile";
 196                         missile.bot_dodge = TRUE;
 197                         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 198
 199                         missile.touch = W_Hagar_Touch; // not bouncy
 200                         missile.use = W_Hagar_Explode2;
 201                         missile.think = adaptor_think2use_hittype_splash;
 202                         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 203                         PROJECTILE_MAKETRIGGER(missile);
 204                         missile.projectiledeathtype = WEP_HAGAR;
 205                         setorigin (missile, w_shotorg);
 206                         setsize(missile, '0 0 0', '0 0 0');
 207                         missile.movetype = MOVETYPE_FLY;
 208
 209                         s = '0 0 0';
 210                         if (counter == 0)
 211                                 s = '0 0 0';
 212                         else
 213                         {
 214                                 makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 215                                 s_y = v_forward_x;
 216                                 s_z = v_forward_y;
 217                         }
 218                         s = s * cvar("g_balance_hagar_secondary_spread") * g_weaponspreadfactor;
 219                         W_SetupProjectileVelocityEx(missile, w_shotdir + right * s_y + up * s_z, v_up, cvar("g_balance_hagar_secondary_speed"), 0, 0, 0, FALSE);
 220
 221                         missile.angles = vectoangles (missile.velocity);
 222                         missile.flags = FL_PROJECTILE;
 223
 224                         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
 225
 226                         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 227
 228                         counter = counter + 1;
 229                 }
 230
 231                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 232                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_refire;
 233                 self.hagar_load = 0;
 234         }
 235 }
 236
 237 void spawnfunc_weapon_hagar (void)
 238 {
 239         weapon_defaultspawnfunc(WEP_HAGAR);
 240 }
 241
 242 float w_hagar(float req)
 243 {
 244         float ammo_amount;
 245         if (req == WR_AIM)
 246                 if (random()>0.15)
 247                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 248                 else
 249                 {
 250                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 251                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 252                 }
 253         else if (req == WR_THINK)
 254         {
 255                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
 256                         weapon_action(self.weapon, WR_RELOAD);
 257                 else
 258                 {
 259                         local float loadable_secondary;
 260                         loadable_secondary = autocvar_g_balance_hagar_secondary_load && autocvar_g_balance_hagar_secondary;
 261
 262                         if (loadable_secondary)
 263                                 W_Hagar_Attack2_Load(); // must run each frame, even when no firing buttons are pressed
 264                         if (self.BUTTON_ATCK && !self.hagar_load && !self.hagar_loadblock) // not while secondary is loaded or awaiting reset
 265                         {
 266                                 if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
 267                                 {
 268                                         W_Hagar_Attack();
 269                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
 270                                 }
 271                         }
 272                         else if (self.BUTTON_ATCK2 && !loadable_secondary && autocvar_g_balance_hagar_secondary)
 273                         {
 274                                 if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
 275                                 {
 276                                         W_Hagar_Attack2();
 277                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 278                                 }
 279                         }
 280                 }
 281         }
 282         else if (req == WR_PRECACHE)
 283         {
 284                 precache_model ("models/weapons/g_hagar.md3");
 285                 precache_model ("models/weapons/v_hagar.md3");
 286                 precache_model ("models/weapons/h_hagar.iqm");
 287                 precache_sound ("weapons/hagar_fire.wav");
 288                 precache_sound ("weapons/hagar_load.wav");
 289                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 290         }
 291         else if (req == WR_SETUP)
 292         {
 293                 weapon_setup(WEP_HAGAR);
 294                 self.current_ammo = ammo_rockets;
 295                 self.hagar_load = 0;
 296         }
 297         else if (req == WR_CHECKAMMO1)
 298         {
 299                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
 300                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_primary_ammo;
 301                 return ammo_amount;
 302         }
 303         else if (req == WR_CHECKAMMO2)
 304         {
 305                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 306                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 307                 return ammo_amount;
 308         }
 309         else if (req == WR_RELOAD)
 310         {
 311                 W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
 312         }
 313         return TRUE;
 314 };
 315 #endif
 316 #ifdef CSQC
 317 float w_hagar(float req)
 318 {
 319         if(req == WR_IMPACTEFFECT)
 320         {
 321                 vector org2;
 322                 org2 = w_org + w_backoff * 6;
 323                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 324                 if(!w_issilent)
 325                 {
 326                         if (w_random<0.15)
 327                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 328                         else if (w_random<0.7)
 329                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 330                         else
 331                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 332                 }
 333         }
 334         else if(req == WR_PRECACHE)
 335         {
 336                 precache_sound("weapons/hagexp1.wav");
 337                 precache_sound("weapons/hagexp2.wav");
 338                 precache_sound("weapons/hagexp3.wav");
 339         }
 340         else if (req == WR_SUICIDEMESSAGE)
 341                 w_deathtypestring = _("%s played with tiny rockets");
 342         else if (req == WR_KILLMESSAGE)
 343         {
 344                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 345                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
 346                 else // unchecked: SPLASH, SECONDARY
 347                         w_deathtypestring = _("%s was pummeled by %s");
 348         }
 349         return TRUE;
 350 }
 351 #endif
 352 #endif