qcsrc/server/w_hmg.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id      */ HMG,
   4 /* function      */ w_hmg,
   5 /* ammotype      */ IT_NAILS,
   6 /* impulse       */ 3,
   7 /* flags         */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN | WEP_FLAG_SUPERWEAPON,
   8 /* rating        */ BOT_PICKUP_RATING_HIGH,
   9 /* model         */ "ok_hmg",
  10 /* shortname */ "hmg",
  11 /* fullname      */ _("Heavy Machine Gun")
  12 );
  13 #else
  14 #ifdef SVQC
  15
  16 // weapon frames
  17
  18 void hmg_fire_auto()
  19 {
  20         float uzi_spread;
  21
  22         if (!self.BUTTON_ATCK)
  23         {
  24                 w_ready();
  25                 return;
  26         }
  27
  28         if(autocvar_g_balance_hmg_reload_ammo)
  29         if(!weapon_action(self.weapon, WR_CHECKAMMO1))
  30         if(!(self.items & IT_UNLIMITED_WEAPON_AMMO))
  31         {
  32                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
  33                 w_ready();
  34                 return;
  35         }
  36
  37         W_DecreaseAmmo(ammo_nails, autocvar_g_balance_hmg_sustained_ammo, autocvar_g_balance_hmg_reload_ammo);
  38
  39         W_SetupShot (self, TRUE, 0, "weapons/uzi_fire.wav", CH_WEAPON_A, autocvar_g_balance_hmg_sustained_damage);
  40
  41         if(!autocvar_g_norecoil)
  42         {
  43                 self.punchangle_x = random () - 0.5;
  44                 self.punchangle_y = random () - 0.5;
  45         }
  46
  47         uzi_spread = bound(autocvar_g_balance_hmg_spread_min, autocvar_g_balance_hmg_spread_min + (autocvar_g_balance_hmg_spread_add * self.misc_bulletcounter), autocvar_g_balance_hmg_spread_max);
  48         fireBullet(w_shotorg, w_shotdir, uzi_spread, autocvar_g_balance_hmg_solidpenetration, autocvar_g_balance_hmg_sustained_damage, autocvar_g_balance_hmg_sustained_force, WEP_HMG, 0);
  49
  50         self.misc_bulletcounter = self.misc_bulletcounter + 1;
  51
  52         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  53
  54         UziFlash();
  55         W_AttachToShotorg(self.muzzle_flash, '5 0 0');
  56
  57         if (autocvar_g_casings >= 2) // casing code
  58                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
  59
  60         ATTACK_FINISHED(self) = time + autocvar_g_balance_hmg_sustained_refire * W_WeaponRateFactor();
  61         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hmg_sustained_refire, hmg_fire_auto);
  62 }
  63
  64 void spawnfunc_weapon_hmg()
  65 {
  66         weapon_defaultspawnfunc(WEP_HMG);
  67 }
  68
  69 float w_hmg(float req)
  70 {
  71         float ammo_amount;
  72         if (req == WR_AIM)
  73                 if(vlen(self.origin-self.enemy.origin) < 3000 - bound(0, skill, 10) * 200)
  74                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
  75                 else
  76                 {
  77                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
  78                 }
  79         else if (req == WR_THINK)
  80         {
  81                 if(autocvar_g_balance_hmg_reload_ammo && self.clip_load < autocvar_g_balance_hmg_sustained_ammo) // forced reload
  82                         weapon_action(self.weapon, WR_RELOAD);
  83                 else
  84                 {
  85                         if (self.BUTTON_ATCK)
  86                         if (weapon_prepareattack(0, 0))
  87                         {
  88                                 self.misc_bulletcounter = 0;
  89                                 hmg_fire_auto();
  90                         }
  91                 }
  92         }
  93         else if (req == WR_PRECACHE)
  94         {
  95                 precache_model ("models/uziflash.md3");
  96                 precache_model ("models/weapons/g_ok_hmg.md3");
  97                 precache_model ("models/weapons/v_ok_hmg.md3");
  98                 precache_model ("models/weapons/h_ok_hmg.iqm");
  99                 precache_sound ("weapons/uzi_fire.wav");
 100         }
 101         else if (req == WR_SETUP)
 102         {
 103                 weapon_setup(WEP_HMG);
 104                 self.current_ammo = ammo_nails;
 105         }
 106         else if (req == WR_CHECKAMMO1)
 107         {
 108                 ammo_amount = self.ammo_nails >= autocvar_g_balance_hmg_sustained_ammo;
 109
 110                 if(autocvar_g_balance_hmg_reload_ammo)
 111                         ammo_amount += self.(weapon_load[WEP_HMG]) >= autocvar_g_balance_hmg_sustained_ammo;
 112
 113                 return ammo_amount;
 114         }
 115         else if (req == WR_CHECKAMMO2)
 116         {
 117                 ammo_amount = self.ammo_nails >= autocvar_g_balance_hmg_sustained_ammo;
 118
 119                 if(autocvar_g_balance_hmg_reload_ammo)
 120                         ammo_amount += self.(weapon_load[WEP_HMG]) >= autocvar_g_balance_hmg_sustained_ammo;
 121
 122                 return ammo_amount;
 123         }
 124         else if (req == WR_RELOAD)
 125         {
 126                 W_Reload(autocvar_g_balance_hmg_sustained_ammo, autocvar_g_balance_hmg_reload_ammo, autocvar_g_balance_hmg_reload_time, "weapons/reload.wav");
 127         }
 128         else if (req == WR_SUICIDEMESSAGE)
 129         {
 130                 return WEAPON_THINKING_WITH_PORTALS;
 131         }
 132         else if (req == WR_KILLMESSAGE)
 133         {
 134                 if(w_deathtype & HITTYPE_SECONDARY)
 135                         return WEAPON_HMG_MURDER_SNIPE;
 136                 else
 137                         return WEAPON_HMG_MURDER_SPRAY;
 138         }
 139         return TRUE;
 140 }
 141 #endif
 142 #ifdef CSQC
 143 float w_hmg(float req)
 144 {
 145         if(req == WR_IMPACTEFFECT)
 146         {
 147                 vector org2;
 148                 org2 = w_org + w_backoff * 2;
 149                 pointparticles(particleeffectnum("machinegun_impact"), org2, w_backoff * 1000, 1);
 150                 if(!w_issilent)
 151                         if(w_random < 0.05)
 152                                 sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTEN_NORM);
 153                         else if(w_random < 0.1)
 154                                 sound(self, CH_SHOTS, "weapons/ric2.wav", VOL_BASE, ATTEN_NORM);
 155                         else if(w_random < 0.2)
 156                                 sound(self, CH_SHOTS, "weapons/ric3.wav", VOL_BASE, ATTEN_NORM);
 157         }
 158         else if(req == WR_PRECACHE)
 159         {
 160                 precache_sound("weapons/ric1.wav");
 161                 precache_sound("weapons/ric2.wav");
 162                 precache_sound("weapons/ric3.wav");
 163         }
 164         return TRUE;
 165 }
 166 #endif
 167 #endif