qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 9, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", "Mine Layer");
   3 #else
   4 #ifdef SVQC
   5 .float minelayer_detonate;
   6 .float mine_number, mine_time;
   7
   8 void spawnfunc_weapon_minelayer (void)
   9 {
  10         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  11 }
  12
  13 void W_Mine_Unregister()
  14 {
  15         if(self.owner && self.owner.lastmine == self)
  16                 self.owner.lastmine = world;
  17 }
  18
  19 void W_Mine_Explode ()
  20 {
  21         W_Mine_Unregister();
  22
  23         if(other.takedamage == DAMAGE_AIM)
  24                 if(other.classname == "player")
  25                         if(IsDifferentTeam(self.owner, other))
  26                                 if(IsFlying(other))
  27                                         AnnounceTo(self.owner, "airshot");
  28
  29         self.event_damage = SUB_Null;
  30         self.takedamage = DAMAGE_NO;
  31
  32         RadiusDamage (self, self.owner, cvar("g_balance_minelayer_damage"), cvar("g_balance_minelayer_edgedamage"), cvar("g_balance_minelayer_radius"), world, cvar("g_balance_minelayer_force"), self.projectiledeathtype, other);
  33
  34         if (self.owner.weapon == WEP_MINE_LAYER)
  35         {
  36                 if(self.owner.ammo_rockets < cvar("g_balance_minelayer_ammo"))
  37                 {
  38                         self.owner.cnt = WEP_MINE_LAYER;
  39                         ATTACK_FINISHED(self.owner) = time;
  40                         self.owner.switchweapon = w_getbestweapon(self.owner);
  41                 }
  42         }
  43         remove (self);
  44 }
  45
  46 void W_Mine_DoRemoteExplode ()
  47 {
  48         W_Mine_Unregister();
  49
  50         self.event_damage = SUB_Null;
  51         self.takedamage = DAMAGE_NO;
  52
  53         RadiusDamage (self, self.owner, cvar("g_balance_minelayer_remote_damage"), cvar("g_balance_minelayer_remote_edgedamage"), cvar("g_balance_minelayer_remote_radius"), world, cvar("g_balance_minelayer_remote_force"), self.projectiledeathtype | HITTYPE_BOUNCE, world);
  54
  55         if (self.owner.weapon == WEP_MINE_LAYER)
  56         {
  57                 if(self.owner.ammo_rockets < cvar("g_balance_minelayer_ammo"))
  58                 {
  59                         self.owner.cnt = WEP_MINE_LAYER;
  60                         ATTACK_FINISHED(self.owner) = time;
  61                         self.owner.switchweapon = w_getbestweapon(self.owner);
  62                 }
  63         }
  64         remove (self);
  65 }
  66
  67 void W_Mine_RemoteExplode()
  68 {
  69         if(self.owner.deadflag == DEAD_NO)
  70         if(self.owner.lastmine)
  71         {
  72                 if((self.spawnshieldtime >= 0)
  73                         ? (time >= self.spawnshieldtime) // timer
  74                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_minelayer_radius")) // safety device
  75                 )
  76                 {
  77                         W_Mine_DoRemoteExplode();
  78                 }
  79         }
  80 }
  81
  82 void W_Mine_Think (void)
  83 {
  84         self.nextthink = time;
  85         if (time > self.cnt)
  86         {
  87                 other = world;
  88                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  89                 W_Mine_Explode ();
  90                 return;
  91         }
  92
  93         // detect players who are close the mine and explode if the player should detonate it
  94         entity head;
  95         head = findradius(self.origin, cvar("g_balance_minelayer_detectionradius"));
  96
  97         while(head)
  98         {
  99                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 100                 if(head != self.owner)
 101                 if(IsDifferentTeam(head, self.owner)) // don't detonate for team mates
 102                 if(!self.mine_time)
 103                 {
 104                         self.mine_time = time + cvar("g_balance_minelayer_time");
 105                 }
 106                 head = head.chain;
 107         }
 108
 109         // explode if it's time
 110         if(self.mine_time && time >= self.mine_time)
 111         {
 112                 self.mine_time = 0;
 113                 W_Mine_Explode();
 114         }
 115
 116         // remote detonation
 117         if (self.owner.weapon == WEP_MINE_LAYER)
 118         if (self.owner.deadflag == DEAD_NO)
 119         if (self.minelayer_detonate)
 120                 W_Mine_RemoteExplode();
 121
 122         if(self.csqcprojectile_clientanimate == 0)
 123                 UpdateCSQCProjectile(self);
 124 }
 125
 126 void W_Mine_Touch (void)
 127 {
 128         PROJECTILE_TOUCH;
 129         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
 130         self.movetype = MOVETYPE_NONE; // lock the mine in place
 131         // TODO: make sure this doesn't cause the mine to get stuck in the air if it falls over a moving entity
 132 }
 133
 134 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 135 {
 136         if (self.health <= 0)
 137                 return;
 138         self.health = self.health - damage;
 139         self.angles = vectoangles(self.velocity);
 140         if (self.health <= 0)
 141                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 142 }
 143
 144 void W_Mine_Attack (void)
 145 {
 146         local entity mine;
 147         local entity flash;
 148
 149         // scan how many mines we placed, and return if we reached our limit
 150         if(cvar("g_balance_minelayer_limit"))
 151         {
 152                 entity mine;
 153                 self.mine_number = 0;
 154                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 155                         self.mine_number += 1;
 156
 157                 if(self.mine_number >= cvar("g_balance_minelayer_limit"))
 158                 {
 159                         // the refire delay keeps this message from being spammed
 160                         sprint(self, strcat("You cannot place more than ^2", cvar_string("g_balance_minelayer_limit"), " ^7mines at a time\n") );
 161                         play2(self, "weapons/unavailable.wav");
 162                         return;
 163                 }
 164         }
 165
 166         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 167                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_minelayer_ammo");
 168
 169         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", cvar("g_balance_minelayer_damage"));
 170         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 171
 172         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 173         mine.owner = self;
 174         self.lastmine = mine;
 175         if(cvar("g_balance_minelayer_detonatedelay") >= 0)
 176                 mine.spawnshieldtime = time + cvar("g_balance_minelayer_detonatedelay");
 177         else
 178                 mine.spawnshieldtime = -1;
 179         mine.classname = "mine";
 180         mine.bot_dodge = TRUE;
 181         mine.bot_dodgerating = cvar("g_balance_minelayer_damage") * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 182
 183         mine.takedamage = DAMAGE_YES;
 184         mine.damageforcescale = cvar("g_balance_minelayer_damageforcescale");
 185         mine.health = cvar("g_balance_minelayer_health");
 186         mine.event_damage = W_Mine_Damage;
 187
 188         mine.movetype = MOVETYPE_TOSS;
 189         PROJECTILE_MAKETRIGGER(mine);
 190         mine.projectiledeathtype = WEP_MINE_LAYER;
 191         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 192
 193         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 194         W_SetupProjectileVelocity(mine, cvar("g_balance_minelayer_speedstart"), 0);
 195         mine.angles = vectoangles (mine.velocity);
 196
 197         mine.touch = W_Mine_Touch;
 198         mine.think = W_Mine_Think;
 199         mine.nextthink = time;
 200         mine.cnt = time + cvar("g_balance_minelayer_lifetime");
 201         mine.flags = FL_PROJECTILE;
 202
 203         CSQCProjectile(mine, FALSE, PROJECTILE_MINE, TRUE);
 204
 205         // muzzle flash for 1st person view
 206         flash = spawn ();
 207         setmodel (flash, "models/flash.md3"); // precision set below
 208         SUB_SetFade (flash, time, 0.1);
 209         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 210         W_AttachToShotorg(flash, '5 0 0');
 211
 212         // common properties
 213 }
 214
 215 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 216
 217 float w_minelayer(float req)
 218 {
 219         entity mine;
 220         float minfound;
 221         if (req == WR_AIM)
 222         {
 223                 // aim and decide to fire if appropriate
 224                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_minelayer_speed"), 0, cvar("g_balance_minelayer_lifetime"), FALSE);
 225                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 226                 {
 227                         // decide whether to detonate mines
 228                         local entity mine, targetlist, targ;
 229                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 230                         local float selfdamage, teamdamage, enemydamage;
 231                         edgedamage = cvar("g_balance_minelayer_edgedamage");
 232                         coredamage = cvar("g_balance_minelayer_damage");
 233                         edgeradius = cvar("g_balance_minelayer_radius");
 234                         recipricoledgeradius = 1 / edgeradius;
 235                         selfdamage = 0;
 236                         teamdamage = 0;
 237                         enemydamage = 0;
 238                         targetlist = findchainfloat(bot_attack, TRUE);
 239                         mine = find(world, classname, "mine");
 240                         while (mine)
 241                         {
 242                                 if (mine.owner != self)
 243                                 {
 244                                         mine = find(mine, classname, "mine");
 245                                         continue;
 246                                 }
 247                                 targ = targetlist;
 248                                 while (targ)
 249                                 {
 250                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 251                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 252                                         // count potential damage according to type of target
 253                                         if (targ == self)
 254                                                 selfdamage = selfdamage + d;
 255                                         else if (targ.team == self.team && teams_matter)
 256                                                 teamdamage = teamdamage + d;
 257                                         else if (bot_shouldattack(targ))
 258                                                 enemydamage = enemydamage + d;
 259                                         targ = targ.chain;
 260                                 }
 261                                 mine = find(mine, classname, "mine");
 262                         }
 263                         local float desirabledamage;
 264                         desirabledamage = enemydamage;
 265                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 266                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 267                         if (self.team && teamplay != 1)
 268                                 desirabledamage = desirabledamage - teamdamage;
 269
 270                         mine = find(world, classname, "mine");
 271                         while (mine)
 272                         {
 273                                 if (mine.owner != self)
 274                                 {
 275                                         mine = find(mine, classname, "mine");
 276                                         continue;
 277                                 }
 278                                 makevectors(mine.v_angle);
 279                                 targ = targetlist;
 280                                 if (skill > 9) // normal players only do this for the target they are tracking
 281                                 {
 282                                         targ = targetlist;
 283                                         while (targ)
 284                                         {
 285                                                 if (
 286                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 287                                                         && desirabledamage > 0.1*coredamage
 288                                                 )self.BUTTON_ATCK2 = TRUE;
 289                                                 targ = targ.chain;
 290                                         }
 291                                 }else{
 292                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 293                                         //As the distance gets larger, a correct detonation gets near imposible
 294                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 295                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 296                                                 if(self.enemy.classname == "player")
 297                                                         if(desirabledamage >= 0.1*coredamage)
 298                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 299                                                                         self.BUTTON_ATCK2 = TRUE;
 300                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 301                                 }
 302
 303                                 mine = find(mine, classname, "mine");
 304                         }
 305                         // if we would be doing at X percent of the core damage, detonate it
 306                         // but don't fire a new shot at the same time!
 307                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 308                                 self.BUTTON_ATCK2 = TRUE;
 309                         if ((skill > 6.5) && (selfdamage > self.health))
 310                                 self.BUTTON_ATCK2 = FALSE;
 311                         //if(self.BUTTON_ATCK2 == TRUE)
 312                         //      dprint(ftos(desirabledamage),"\n");
 313                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 314                 }
 315         }
 316         else if (req == WR_THINK)
 317         {
 318                 if (self.BUTTON_ATCK)
 319                 {
 320                         if(weapon_prepareattack(0, cvar("g_balance_minelayer_refire")))
 321                         {
 322                                 W_Mine_Attack();
 323                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_minelayer_animtime"), w_ready);
 324                         }
 325                 }
 326
 327                 if (self.BUTTON_ATCK2)
 328                 {
 329                         minfound = 0;
 330                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 331                         {
 332                                 if(!mine.minelayer_detonate)
 333                                 {
 334                                         mine.minelayer_detonate = TRUE;
 335                                         minfound = 1;
 336                                 }
 337                         }
 338                         if(minfound)
 339                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 340                 }
 341         }
 342         else if (req == WR_PRECACHE)
 343         {
 344                 precache_model ("models/flash.md3");
 345                 precache_model ("models/weapons/g_minelayer.md3");
 346                 precache_model ("models/weapons/v_minelayer.md3");
 347                 precache_model ("models/weapons/h_minelayer.iqm");
 348                 precache_sound ("weapons/mine_det.wav");
 349                 precache_sound ("weapons/mine_fire.wav");
 350                 precache_sound ("weapons/mine_stick.wav");
 351         }
 352         else if (req == WR_SETUP)
 353         {
 354                 weapon_setup(WEP_MINE_LAYER);
 355         }
 356         else if (req == WR_CHECKAMMO1)
 357         {
 358                 // don't switch while placing a mine
 359                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 360                         && self.ammo_rockets < cvar("g_balance_minelayer_ammo"))
 361                         return FALSE;
 362         }
 363         else if (req == WR_CHECKAMMO2)
 364                 return FALSE;
 365         return TRUE;
 366 };
 367 #endif
 368 #ifdef CSQC
 369 float w_minelayer(float req)
 370 {
 371         if(req == WR_IMPACTEFFECT)
 372         {
 373                 vector org2;
 374                 org2 = w_org + w_backoff * 12;
 375                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 376                 if(!w_issilent)
 377                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 378         }
 379         else if(req == WR_PRECACHE)
 380         {
 381                 precache_sound("weapons/mine_exp.wav");
 382         }
 383         else if (req == WR_SUICIDEMESSAGE)
 384                 w_deathtypestring = "%s exploded";
 385         else if (req == WR_KILLMESSAGE)
 386         {
 387                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 388                         w_deathtypestring = "%s got too close to %s's mine";
 389                 else if(w_deathtype & HITTYPE_SPLASH)
 390                         w_deathtypestring = "%s almost dodged %s's mine";
 391                 else
 392                         w_deathtypestring = "%s stepped on %s's mine";
 393         }
 394         return TRUE;
 395 }
 396 #endif
 397 #endif