qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", "Mine Layer");
   3 #else
   4 #ifdef SVQC
   5 .float minelayer_detonate;
   6 .float mine_number, mine_time;
   7
   8 void spawnfunc_weapon_minelayer (void)
   9 {
  10         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  11 }
  12
  13 void W_Mine_RespawnEntity ()
  14 {
  15         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  16
  17         entity newmine;
  18         newmine = spawn();
  19         newmine.classname = self.classname;
  20
  21         newmine.bot_dodge = self.bot_dodge;
  22         newmine.bot_dodgerating = self.bot_dodgerating;
  23
  24         newmine.owner = self.owner;
  25         setsize(newmine, '-4 -4 -4', '4 4 4');
  26         setorigin(newmine, self.origin);
  27         setmodel(newmine, "models/mine.md3");
  28         newmine.angles = vectoangles(-trace_plane_normal);
  29
  30         newmine.takedamage = self.takedamage;
  31         newmine.damageforcescale = self.damageforcescale;
  32         newmine.health = self.health;
  33         newmine.event_damage = self.event_damage;
  34
  35         newmine.movetype = MOVETYPE_NONE;
  36         newmine.projectiledeathtype = self.projectiledeathtype;
  37
  38         newmine.mine_number = self.mine_number;
  39         newmine.mine_time = self.mine_time;
  40
  41         newmine.touch = SUB_Null;
  42         newmine.think = self.think;
  43         newmine.nextthink = time;
  44         newmine.cnt = self.cnt;
  45         newmine.flags = self.flags;
  46
  47         remove(self);
  48         self = newmine;
  49 }
  50
  51 void W_Mine_Explode ()
  52 {
  53         if(other.takedamage == DAMAGE_AIM)
  54                 if(other.classname == "player")
  55                         if(IsDifferentTeam(self.owner, other))
  56                                 if(IsFlying(other))
  57                                         AnnounceTo(self.owner, "airshot");
  58
  59         self.event_damage = SUB_Null;
  60         self.takedamage = DAMAGE_NO;
  61
  62         RadiusDamage (self, self.owner, cvar("g_balance_minelayer_damage"), cvar("g_balance_minelayer_edgedamage"), cvar("g_balance_minelayer_radius"), world, cvar("g_balance_minelayer_force"), self.projectiledeathtype, other);
  63
  64         if (self.owner.weapon == WEP_MINE_LAYER)
  65         {
  66                 if(self.owner.ammo_rockets < cvar("g_balance_minelayer_ammo"))
  67                 {
  68                         self.owner.cnt = WEP_MINE_LAYER;
  69                         ATTACK_FINISHED(self.owner) = time;
  70                         self.owner.switchweapon = w_getbestweapon(self.owner);
  71                 }
  72         }
  73         remove (self);
  74 }
  75
  76 void W_Mine_DoRemoteExplode ()
  77 {
  78         self.event_damage = SUB_Null;
  79         self.takedamage = DAMAGE_NO;
  80
  81         RadiusDamage (self, self.owner, cvar("g_balance_minelayer_remote_damage"), cvar("g_balance_minelayer_remote_edgedamage"), cvar("g_balance_minelayer_remote_radius"), world, cvar("g_balance_minelayer_remote_force"), self.projectiledeathtype | HITTYPE_BOUNCE, world);
  82
  83         if (self.owner.weapon == WEP_MINE_LAYER)
  84         {
  85                 if(self.owner.ammo_rockets < cvar("g_balance_minelayer_ammo"))
  86                 {
  87                         self.owner.cnt = WEP_MINE_LAYER;
  88                         ATTACK_FINISHED(self.owner) = time;
  89                         self.owner.switchweapon = w_getbestweapon(self.owner);
  90                 }
  91         }
  92         remove (self);
  93 }
  94
  95 void W_Mine_RemoteExplode()
  96 {
  97         if(self.owner.deadflag == DEAD_NO)
  98                 if((self.spawnshieldtime >= 0)
  99                         ? (time >= self.spawnshieldtime) // timer
 100                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_minelayer_radius")) // safety device
 101                 )
 102                 {
 103                         W_Mine_DoRemoteExplode();
 104                 }
 105 }
 106
 107 void W_Mine_ProximityExplode()
 108 {
 109         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 110         if(cvar("g_balance_minelayer_protection"))
 111         {
 112                 entity head;
 113                 head = findradius(self.origin, cvar("g_balance_minelayer_radius"));
 114                 while(head)
 115                 {
 116                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 117                                 return;
 118                         head = head.chain;
 119                 }
 120         }
 121
 122         self.mine_time = 0;
 123         W_Mine_Explode();
 124 }
 125
 126 void W_Mine_Think (void)
 127 {
 128         entity head;
 129
 130         self.nextthink = time;
 131         if (time > self.cnt)
 132         {
 133                 other = world;
 134                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 135                 W_Mine_Explode ();
 136                 return;
 137         }
 138
 139         // set the mine for detonation when a foe gets too close
 140         head = findradius(self.origin, cvar("g_balance_minelayer_detectionradius"));
 141         while(head)
 142         {
 143                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 144                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 145                 if(!self.mine_time)
 146                 {
 147                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 148                         self.mine_time = time + cvar("g_balance_minelayer_time");
 149                 }
 150                 head = head.chain;
 151         }
 152
 153         // explode if it's time to
 154         if(self.mine_time && time >= self.mine_time)
 155                 W_Mine_ProximityExplode();
 156
 157         // remote detonation
 158         if (self.owner.weapon == WEP_MINE_LAYER)
 159         if (self.owner.deadflag == DEAD_NO)
 160         if (self.minelayer_detonate)
 161                 W_Mine_RemoteExplode();
 162
 163         if(self.csqcprojectile_clientanimate == 0)
 164                 UpdateCSQCProjectile(self);
 165 }
 166
 167 void W_Mine_Touch (void)
 168 {
 169         PROJECTILE_TOUCH;
 170         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 171         {
 172                 spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
 173                 self.movetype = MOVETYPE_NONE; // lock the mine in place
 174
 175                 W_Mine_RespawnEntity();
 176         }
 177         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 178                 self.velocity = '0 0 0';
 179 }
 180
 181 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 182 {
 183         if (self.health <= 0)
 184                 return;
 185         self.health = self.health - damage;
 186         self.angles = vectoangles(self.velocity);
 187         if (self.health <= 0)
 188                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 189 }
 190
 191 void W_Mine_Attack (void)
 192 {
 193         local entity mine;
 194         local entity flash;
 195
 196         // scan how many mines we placed, and return if we reached our limit
 197         if(cvar("g_balance_minelayer_limit"))
 198         {
 199                 self.mine_number = 0;
 200                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 201                         self.mine_number += 1;
 202
 203                 if(self.mine_number >= cvar("g_balance_minelayer_limit"))
 204                 {
 205                         // the refire delay keeps this message from being spammed
 206                         sprint(self, strcat("You cannot place more than ^2", cvar_string("g_balance_minelayer_limit"), " ^7mines at a time\n") );
 207                         play2(self, "weapons/unavailable.wav");
 208                         return;
 209                 }
 210         }
 211
 212         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 213                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_minelayer_ammo");
 214
 215         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", cvar("g_balance_minelayer_damage"));
 216         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 217
 218         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 219         mine.owner = self;
 220         if(cvar("g_balance_minelayer_detonatedelay") >= 0)
 221                 mine.spawnshieldtime = time + cvar("g_balance_minelayer_detonatedelay");
 222         else
 223                 mine.spawnshieldtime = -1;
 224         mine.classname = "mine";
 225         mine.bot_dodge = TRUE;
 226         mine.bot_dodgerating = cvar("g_balance_minelayer_damage") * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 227
 228         mine.takedamage = DAMAGE_YES;
 229         mine.damageforcescale = cvar("g_balance_minelayer_damageforcescale");
 230         mine.health = cvar("g_balance_minelayer_health");
 231         mine.event_damage = W_Mine_Damage;
 232
 233         mine.movetype = MOVETYPE_TOSS;
 234         PROJECTILE_MAKETRIGGER(mine);
 235         mine.projectiledeathtype = WEP_MINE_LAYER;
 236         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 237
 238         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 239         W_SetupProjectileVelocity(mine, cvar("g_balance_minelayer_speed"), 0);
 240         mine.angles = vectoangles (mine.velocity);
 241
 242         mine.touch = W_Mine_Touch;
 243         mine.think = W_Mine_Think;
 244         mine.nextthink = time;
 245         mine.cnt = time + cvar("g_balance_minelayer_lifetime");
 246         mine.flags = FL_PROJECTILE;
 247
 248         CSQCProjectile(mine, FALSE, PROJECTILE_MINE, TRUE);
 249
 250         // muzzle flash for 1st person view
 251         flash = spawn ();
 252         setmodel (flash, "models/flash.md3"); // precision set below
 253         SUB_SetFade (flash, time, 0.1);
 254         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 255         W_AttachToShotorg(flash, '5 0 0');
 256
 257         // common properties
 258 }
 259
 260 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 261
 262 float w_minelayer(float req)
 263 {
 264         entity mine;
 265         float minfound;
 266         if (req == WR_AIM)
 267         {
 268                 // aim and decide to fire if appropriate
 269                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_minelayer_speed"), 0, cvar("g_balance_minelayer_lifetime"), FALSE);
 270                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 271                 {
 272                         // decide whether to detonate mines
 273                         local entity mine, targetlist, targ;
 274                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 275                         local float selfdamage, teamdamage, enemydamage;
 276                         edgedamage = cvar("g_balance_minelayer_edgedamage");
 277                         coredamage = cvar("g_balance_minelayer_damage");
 278                         edgeradius = cvar("g_balance_minelayer_radius");
 279                         recipricoledgeradius = 1 / edgeradius;
 280                         selfdamage = 0;
 281                         teamdamage = 0;
 282                         enemydamage = 0;
 283                         targetlist = findchainfloat(bot_attack, TRUE);
 284                         mine = find(world, classname, "mine");
 285                         while (mine)
 286                         {
 287                                 if (mine.owner != self)
 288                                 {
 289                                         mine = find(mine, classname, "mine");
 290                                         continue;
 291                                 }
 292                                 targ = targetlist;
 293                                 while (targ)
 294                                 {
 295                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 296                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 297                                         // count potential damage according to type of target
 298                                         if (targ == self)
 299                                                 selfdamage = selfdamage + d;
 300                                         else if (targ.team == self.team && teams_matter)
 301                                                 teamdamage = teamdamage + d;
 302                                         else if (bot_shouldattack(targ))
 303                                                 enemydamage = enemydamage + d;
 304                                         targ = targ.chain;
 305                                 }
 306                                 mine = find(mine, classname, "mine");
 307                         }
 308                         local float desirabledamage;
 309                         desirabledamage = enemydamage;
 310                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 311                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 312                         if (self.team && teamplay != 1)
 313                                 desirabledamage = desirabledamage - teamdamage;
 314
 315                         mine = find(world, classname, "mine");
 316                         while (mine)
 317                         {
 318                                 if (mine.owner != self)
 319                                 {
 320                                         mine = find(mine, classname, "mine");
 321                                         continue;
 322                                 }
 323                                 makevectors(mine.v_angle);
 324                                 targ = targetlist;
 325                                 if (skill > 9) // normal players only do this for the target they are tracking
 326                                 {
 327                                         targ = targetlist;
 328                                         while (targ)
 329                                         {
 330                                                 if (
 331                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 332                                                         && desirabledamage > 0.1*coredamage
 333                                                 )self.BUTTON_ATCK2 = TRUE;
 334                                                 targ = targ.chain;
 335                                         }
 336                                 }else{
 337                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 338                                         //As the distance gets larger, a correct detonation gets near imposible
 339                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 340                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 341                                                 if(self.enemy.classname == "player")
 342                                                         if(desirabledamage >= 0.1*coredamage)
 343                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 344                                                                         self.BUTTON_ATCK2 = TRUE;
 345                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 346                                 }
 347
 348                                 mine = find(mine, classname, "mine");
 349                         }
 350                         // if we would be doing at X percent of the core damage, detonate it
 351                         // but don't fire a new shot at the same time!
 352                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 353                                 self.BUTTON_ATCK2 = TRUE;
 354                         if ((skill > 6.5) && (selfdamage > self.health))
 355                                 self.BUTTON_ATCK2 = FALSE;
 356                         //if(self.BUTTON_ATCK2 == TRUE)
 357                         //      dprint(ftos(desirabledamage),"\n");
 358                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 359                 }
 360         }
 361         else if (req == WR_THINK)
 362         {
 363                 if (self.BUTTON_ATCK)
 364                 {
 365                         if(weapon_prepareattack(0, cvar("g_balance_minelayer_refire")))
 366                         {
 367                                 W_Mine_Attack();
 368                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_minelayer_animtime"), w_ready);
 369                         }
 370                 }
 371
 372                 if (self.BUTTON_ATCK2)
 373                 {
 374                         minfound = 0;
 375                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 376                         {
 377                                 if(!mine.minelayer_detonate)
 378                                 {
 379                                         mine.minelayer_detonate = TRUE;
 380                                         minfound = 1;
 381                                 }
 382                         }
 383                         if(minfound)
 384                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 385                 }
 386         }
 387         else if (req == WR_PRECACHE)
 388         {
 389                 precache_model ("models/flash.md3");
 390                 precache_model ("models/mine.md3");
 391                 precache_model ("models/weapons/g_minelayer.md3");
 392                 precache_model ("models/weapons/v_minelayer.md3");
 393                 precache_model ("models/weapons/h_minelayer.iqm");
 394                 precache_sound ("weapons/mine_det.wav");
 395                 precache_sound ("weapons/mine_fire.wav");
 396                 precache_sound ("weapons/mine_stick.wav");
 397                 precache_sound ("weapons/mine_trigger.wav");
 398         }
 399         else if (req == WR_SETUP)
 400         {
 401                 weapon_setup(WEP_MINE_LAYER);
 402         }
 403         else if (req == WR_CHECKAMMO1)
 404         {
 405                 // don't switch while placing a mine
 406                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 407                         && self.ammo_rockets < cvar("g_balance_minelayer_ammo"))
 408                         return FALSE;
 409         }
 410         else if (req == WR_CHECKAMMO2)
 411                 return FALSE;
 412         return TRUE;
 413 };
 414 #endif
 415 #ifdef CSQC
 416 float w_minelayer(float req)
 417 {
 418         if(req == WR_IMPACTEFFECT)
 419         {
 420                 vector org2;
 421                 org2 = w_org + w_backoff * 12;
 422                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 423                 if(!w_issilent)
 424                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 425         }
 426         else if(req == WR_PRECACHE)
 427         {
 428                 precache_sound("weapons/mine_exp.wav");
 429         }
 430         else if (req == WR_SUICIDEMESSAGE)
 431                 w_deathtypestring = "%s exploded";
 432         else if (req == WR_KILLMESSAGE)
 433         {
 434                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 435                         w_deathtypestring = "%s got too close to %s's mine";
 436                 else if(w_deathtype & HITTYPE_SPLASH)
 437                         w_deathtypestring = "%s almost dodged %s's mine";
 438                 else
 439                         w_deathtypestring = "%s stepped on %s's mine";
 440         }
 441         return TRUE;
 442 }
 443 #endif
 444 #endif