qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, mine_explodeanyway;
   7 .float mine_time;
   8
   9 /*
  10 void spawnfunc_weapon_minelayer (void)
  11 {
  12         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  13 }
  14 */
  15
  16 void W_Mine_Stick (entity to)
  17 {
  18         spamsound (self, CH_SHOTS, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  19
  20         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  21
  22         entity newmine;
  23         newmine = spawn();
  24         newmine.classname = self.classname;
  25
  26         newmine.bot_dodge = self.bot_dodge;
  27         newmine.bot_dodgerating = self.bot_dodgerating;
  28
  29         newmine.owner = self.owner;
  30         newmine.realowner = self.realowner;
  31         setsize(newmine, '-4 -4 -4', '4 4 4');
  32         setorigin(newmine, self.origin);
  33         setmodel(newmine, "models/mine.md3");
  34         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  35
  36         newmine.oldvelocity = self.velocity;
  37
  38         newmine.takedamage = self.takedamage;
  39         newmine.damageforcescale = self.damageforcescale;
  40         newmine.health = self.health;
  41         newmine.event_damage = self.event_damage;
  42         newmine.spawnshieldtime = self.spawnshieldtime;
  43         newmine.damagedbycontents = TRUE;
  44
  45         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  46         newmine.projectiledeathtype = self.projectiledeathtype;
  47
  48         newmine.mine_time = self.mine_time;
  49
  50         newmine.touch = SUB_Null;
  51         newmine.think = W_Mine_Think;
  52         newmine.nextthink = time;
  53         newmine.cnt = self.cnt;
  54         newmine.flags = self.flags;
  55
  56         remove(self);
  57         self = newmine;
  58
  59         if(to)
  60                 SetMovetypeFollow(self, to);
  61 }
  62
  63 void W_Mine_Explode ()
  64 {
  65         if(other.takedamage == DAMAGE_AIM)
  66                 if(other.classname == "player")
  67                         if(IsDifferentTeam(self.realowner, other))
  68                                 if(other.deadflag == DEAD_NO)
  69                                         if(IsFlying(other))
  70                                                 AnnounceTo(self.realowner, "airshot");
  71
  72         self.event_damage = SUB_Null;
  73         self.takedamage = DAMAGE_NO;
  74
  75         RadiusDamage (self, self.realowner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  76
  77         if (self.realowner.weapon == WEP_MINE_LAYER)
  78         {
  79                 entity oldself;
  80                 oldself = self;
  81                 self = self.realowner;
  82                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
  83                 {
  84                         self.cnt = WEP_MINE_LAYER;
  85                         ATTACK_FINISHED(self) = time;
  86                         self.switchweapon = w_getbestweapon(self);
  87                 }
  88                 self = oldself;
  89         }
  90         self.realowner.minelayer_mines -= 1;
  91         remove (self);
  92 }
  93
  94 void W_Mine_DoRemoteExplode ()
  95 {
  96         self.event_damage = SUB_Null;
  97         self.takedamage = DAMAGE_NO;
  98
  99         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 100                 self.velocity = self.oldvelocity;
 101
 102         RadiusDamage (self, self.realowner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
 103
 104         if (self.realowner.weapon == WEP_MINE_LAYER)
 105         {
 106                 entity oldself;
 107                 oldself = self;
 108                 self = self.realowner;
 109                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
 110                 {
 111                         self.cnt = WEP_MINE_LAYER;
 112                         ATTACK_FINISHED(self) = time;
 113                         self.switchweapon = w_getbestweapon(self);
 114                 }
 115                 self = oldself;
 116         }
 117         self.realowner.minelayer_mines -= 1;
 118         remove (self);
 119 }
 120
 121 void W_Mine_RemoteExplode ()
 122 {
 123         if(self.realowner.deadflag == DEAD_NO)
 124                 if((self.spawnshieldtime >= 0)
 125                         ? (time >= self.spawnshieldtime) // timer
 126                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 127                 )
 128                 {
 129                         W_Mine_DoRemoteExplode();
 130                 }
 131 }
 132
 133 void W_Mine_ProximityExplode ()
 134 {
 135         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 136         if(autocvar_g_balance_minelayer_protection && self.mine_explodeanyway == 0)
 137         {
 138                 entity head;
 139                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 140                 while(head)
 141                 {
 142                         if(head == self.realowner || !IsDifferentTeam(head, self.realowner))
 143                                 return;
 144                         head = head.chain;
 145                 }
 146         }
 147
 148         self.mine_time = 0;
 149         W_Mine_Explode();
 150 }
 151
 152 float W_Mine_Count(entity e)
 153 {
 154         float minecount;
 155         entity mine;
 156         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 157                 minecount += 1;
 158
 159         return minecount;
 160 }
 161
 162 void W_Mine_Think (void)
 163 {
 164         entity head;
 165
 166         self.nextthink = time;
 167
 168         if(self.movetype == MOVETYPE_FOLLOW)
 169         {
 170                 if(LostMovetypeFollow(self))
 171                 {
 172                         UnsetMovetypeFollow(self);
 173                         self.movetype = MOVETYPE_NONE;
 174                 }
 175         }
 176
 177         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 178         // TODO: replace this mine_trigger.wav sound with a real countdown
 179         if ((time > self.cnt) && (!self.mine_time))
 180         {
 181                 if(autocvar_g_balance_minelayer_lifetime_countdown > 0)
 182                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 183                 self.mine_time = time + autocvar_g_balance_minelayer_lifetime_countdown;
 184                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 185         }
 186
 187         // a player's mines shall explode if he disconnects or dies
 188         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 189         if(self.realowner.classname != "player" || self.realowner.deadflag != DEAD_NO)
 190         {
 191                 other = world;
 192                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 193                 W_Mine_Explode();
 194                 return;
 195         }
 196
 197         // set the mine for detonation when a foe gets close enough
 198         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 199         while(head)
 200         {
 201                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 202                 if(head != self.realowner && IsDifferentTeam(head, self.realowner)) // don't trigger for team mates
 203                 if(!self.mine_time)
 204                 {
 205                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 206                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 207                 }
 208                 head = head.chain;
 209         }
 210
 211         // explode if it's time to
 212         if(self.mine_time && time >= self.mine_time)
 213         {
 214                 W_Mine_ProximityExplode();
 215                 return;
 216         }
 217
 218         // remote detonation
 219         if (self.realowner.weapon == WEP_MINE_LAYER)
 220         if (self.realowner.deadflag == DEAD_NO)
 221         if (self.minelayer_detonate)
 222                 W_Mine_RemoteExplode();
 223 }
 224
 225 void W_Mine_Touch (void)
 226 {
 227         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 228                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 229
 230         PROJECTILE_TOUCH;
 231
 232         if(other && other.classname == "player" && other.deadflag == DEAD_NO)
 233         {
 234                 // hit a player
 235                 // don't stick
 236         }
 237         else
 238         {
 239                 W_Mine_Stick(other);
 240         }
 241 }
 242
 243 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 244 {
 245         if (self.health <= 0)
 246                 return;
 247
 248         float is_from_enemy = (inflictor.realowner != self.realowner);
 249
 250         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 251                 return; // g_projectiles_damage says to halt
 252
 253         self.health = self.health - damage;
 254         self.angles = vectoangles(self.velocity);
 255
 256         if (self.health <= 0)
 257                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 258 }
 259
 260 void W_Mine_Attack (void)
 261 {
 262         entity mine;
 263         entity flash;
 264
 265         // scan how many mines we placed, and return if we reached our limit
 266         if(autocvar_g_balance_minelayer_limit)
 267         {
 268
 269                 if(W_Mine_Count(self) >= autocvar_g_balance_minelayer_limit)
 270                 {
 271                         // the refire delay keeps this message from being spammed
 272                         sprint(self, strcat("minelayer: You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 273                         play2(self, "weapons/unavailable.wav");
 274                         return;
 275                 }
 276         }
 277
 278         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo);
 279
 280         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CH_WEAPON_A, autocvar_g_balance_minelayer_damage);
 281         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 282
 283         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 284         mine.owner = mine.realowner = self;
 285         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 286                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 287         else
 288                 mine.spawnshieldtime = -1;
 289         mine.classname = "mine";
 290         mine.bot_dodge = TRUE;
 291         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 292
 293         mine.takedamage = DAMAGE_YES;
 294         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 295         mine.health = autocvar_g_balance_minelayer_health;
 296         mine.event_damage = W_Mine_Damage;
 297         mine.damagedbycontents = TRUE;
 298
 299         mine.movetype = MOVETYPE_TOSS;
 300         PROJECTILE_MAKETRIGGER(mine);
 301         mine.projectiledeathtype = WEP_MINE_LAYER;
 302         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 303
 304         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 305         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 306         mine.angles = vectoangles (mine.velocity);
 307
 308         mine.touch = W_Mine_Touch;
 309         mine.think = W_Mine_Think;
 310         mine.nextthink = time;
 311         mine.cnt = time + (autocvar_g_balance_minelayer_lifetime - autocvar_g_balance_minelayer_lifetime_countdown);
 312         mine.flags = FL_PROJECTILE;
 313
 314         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 315
 316         // muzzle flash for 1st person view
 317         flash = spawn ();
 318         setmodel (flash, "models/flash.md3"); // precision set below
 319         SUB_SetFade (flash, time, 0.1);
 320         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 321         W_AttachToShotorg(flash, '5 0 0');
 322
 323         // common properties
 324
 325         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 326
 327         self.minelayer_mines = W_Mine_Count(self);
 328 }
 329
 330 float W_PlacedMines(float detonate)
 331 {
 332         entity mine;
 333         float minfound;
 334
 335         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 336         {
 337                 if(detonate)
 338                 {
 339                         if(!mine.minelayer_detonate)
 340                         {
 341                                 mine.minelayer_detonate = TRUE;
 342                                 minfound = 1;
 343                         }
 344                 }
 345                 else
 346                         minfound = 1;
 347         }
 348         return minfound;
 349 }
 350
 351 float w_minelayer(float req)
 352 {
 353         entity mine;
 354         float ammo_amount;
 355
 356         if (req == WR_AIM)
 357         {
 358                 // aim and decide to fire if appropriate
 359                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 360                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 361                 {
 362                         // decide whether to detonate mines
 363                         entity targetlist, targ;
 364                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 365                         float selfdamage, teamdamage, enemydamage;
 366                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 367                         coredamage = autocvar_g_balance_minelayer_damage;
 368                         edgeradius = autocvar_g_balance_minelayer_radius;
 369                         recipricoledgeradius = 1 / edgeradius;
 370                         selfdamage = 0;
 371                         teamdamage = 0;
 372                         enemydamage = 0;
 373                         targetlist = findchainfloat(bot_attack, TRUE);
 374                         mine = find(world, classname, "mine");
 375                         while (mine)
 376                         {
 377                                 if (mine.realowner != self)
 378                                 {
 379                                         mine = find(mine, classname, "mine");
 380                                         continue;
 381                                 }
 382                                 targ = targetlist;
 383                                 while (targ)
 384                                 {
 385                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 386                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 387                                         // count potential damage according to type of target
 388                                         if (targ == self)
 389                                                 selfdamage = selfdamage + d;
 390                                         else if (targ.team == self.team && teamplay)
 391                                                 teamdamage = teamdamage + d;
 392                                         else if (bot_shouldattack(targ))
 393                                                 enemydamage = enemydamage + d;
 394                                         targ = targ.chain;
 395                                 }
 396                                 mine = find(mine, classname, "mine");
 397                         }
 398                         float desirabledamage;
 399                         desirabledamage = enemydamage;
 400                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 401                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 402                         if (teamplay && self.team)
 403                                 desirabledamage = desirabledamage - teamdamage;
 404
 405                         mine = find(world, classname, "mine");
 406                         while (mine)
 407                         {
 408                                 if (mine.realowner != self)
 409                                 {
 410                                         mine = find(mine, classname, "mine");
 411                                         continue;
 412                                 }
 413                                 makevectors(mine.v_angle);
 414                                 targ = targetlist;
 415                                 if (skill > 9) // normal players only do this for the target they are tracking
 416                                 {
 417                                         targ = targetlist;
 418                                         while (targ)
 419                                         {
 420                                                 if (
 421                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 422                                                         && desirabledamage > 0.1*coredamage
 423                                                 )self.BUTTON_ATCK2 = TRUE;
 424                                                 targ = targ.chain;
 425                                         }
 426                                 }else{
 427                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 428                                         //As the distance gets larger, a correct detonation gets near imposible
 429                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 430                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 431                                                 if(self.enemy.classname == "player")
 432                                                         if(desirabledamage >= 0.1*coredamage)
 433                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 434                                                                         self.BUTTON_ATCK2 = TRUE;
 435                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 436                                 }
 437
 438                                 mine = find(mine, classname, "mine");
 439                         }
 440                         // if we would be doing at X percent of the core damage, detonate it
 441                         // but don't fire a new shot at the same time!
 442                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 443                                 self.BUTTON_ATCK2 = TRUE;
 444                         if ((skill > 6.5) && (selfdamage > self.health))
 445                                 self.BUTTON_ATCK2 = FALSE;
 446                         //if(self.BUTTON_ATCK2 == TRUE)
 447                         //      dprint(ftos(desirabledamage),"\n");
 448                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 449                 }
 450         }
 451         else if (req == WR_THINK)
 452         {
 453                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 454                 {
 455                         // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 456                         if not (W_PlacedMines(FALSE) && self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 457                                 weapon_action(self.weapon, WR_RELOAD);
 458                 }
 459                 else if (self.BUTTON_ATCK)
 460                 {
 461                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 462                         {
 463                                 W_Mine_Attack();
 464                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 465                         }
 466                 }
 467
 468                 if (self.BUTTON_ATCK2)
 469                 {
 470                         if(W_PlacedMines(TRUE))
 471                                 sound (self, CH_WEAPON_B, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 472                 }
 473         }
 474         else if (req == WR_PRECACHE)
 475         {
 476                 precache_model ("models/flash.md3");
 477                 precache_model ("models/mine.md3");
 478                 precache_model ("models/weapons/g_minelayer.md3");
 479                 precache_model ("models/weapons/v_minelayer.md3");
 480                 precache_model ("models/weapons/h_minelayer.iqm");
 481                 precache_sound ("weapons/mine_det.wav");
 482                 precache_sound ("weapons/mine_fire.wav");
 483                 precache_sound ("weapons/mine_stick.wav");
 484                 precache_sound ("weapons/mine_trigger.wav");
 485                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 486         }
 487         else if (req == WR_SETUP)
 488         {
 489                 weapon_setup(WEP_MINE_LAYER);
 490                 self.current_ammo = ammo_rockets;
 491         }
 492         else if (req == WR_CHECKAMMO1)
 493         {
 494                 // don't switch while placing a mine
 495                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 496                 {
 497                         ammo_amount = self.ammo_rockets >= autocvar_g_balance_minelayer_ammo;
 498                         ammo_amount += self.(weapon_load[WEP_MINE_LAYER]) >= autocvar_g_balance_minelayer_ammo;
 499                         return ammo_amount;
 500                 }
 501         }
 502         else if (req == WR_CHECKAMMO2)
 503         {
 504                 if (W_PlacedMines(FALSE))
 505                         return TRUE;
 506                 else
 507                         return FALSE;
 508         }
 509         else if (req == WR_RELOAD)
 510         {
 511                 W_Reload(autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo, autocvar_g_balance_minelayer_reload_time, "weapons/reload.wav");
 512         }
 513         return TRUE;
 514 }
 515 #endif
 516 #ifdef CSQC
 517 float w_minelayer(float req)
 518 {
 519         if(req == WR_IMPACTEFFECT)
 520         {
 521                 vector org2;
 522                 org2 = w_org + w_backoff * 12;
 523                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 524                 if(!w_issilent)
 525                         sound(self, CH_SHOTS, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 526         }
 527         else if(req == WR_PRECACHE)
 528         {
 529                 precache_sound("weapons/mine_exp.wav");
 530         }
 531         else if (req == WR_SUICIDEMESSAGE)
 532                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 533                         w_deathtypestring = _("%s blew themself up with their minelayer");
 534                 else
 535                         w_deathtypestring = _("%s forgot about their mine");
 536         else if (req == WR_KILLMESSAGE)
 537         {
 538                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 539                         w_deathtypestring = _("%s got too close to %s's mine");
 540                 else if(w_deathtype & HITTYPE_SPLASH)
 541                         w_deathtypestring = _("%s almost dodged %s's mine");
 542                 else
 543                         w_deathtypestring = _("%s stepped on %s's mine");
 544         }
 545         return TRUE;
 546 }
 547 #endif
 548 #endif