qcsrc/server/w_nex.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(NEX, w_nex, IT_CELLS, 7, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "nex", "nex", _("Nex"))
   3 #else
   4 #ifdef SVQC
   5
   6 void W_Nex_SetAmmoCounter()
   7 {
   8         // set clip_load to the weapon we have switched to, if the gun uses reloading
   9         if(!autocvar_g_balance_nex_reload_ammo)
  10                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  11         else
  12         {
  13                 self.clip_load = self.weapon_load[WEP_NEX];
  14                 self.clip_size = autocvar_g_balance_nex_reload_ammo; // for the crosshair ammo display
  15         }
  16 }
  17
  18 void W_Nex_Reload()
  19 {
  20         self.reload_ammo_player = ammo_cells;
  21         self.reload_ammo_min = min(autocvar_g_balance_nex_primary_ammo, autocvar_g_balance_nex_secondary_ammo);
  22         self.reload_ammo_amount = autocvar_g_balance_nex_reload_ammo;
  23         self.reload_time = autocvar_g_balance_nex_reload_time;
  24         self.reload_sound = "weapons/reload.wav";
  25
  26         W_Reload();
  27 }
  28
  29 void SendCSQCNexBeamParticle(float charge) {
  30         vector v;
  31         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  32         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  33         WriteByte(MSG_BROADCAST, TE_CSQC_NEXGUNBEAMPARTICLE);
  34         WriteCoord(MSG_BROADCAST, w_shotorg_x);
  35         WriteCoord(MSG_BROADCAST, w_shotorg_y);
  36         WriteCoord(MSG_BROADCAST, w_shotorg_z);
  37         WriteCoord(MSG_BROADCAST, v_x);
  38         WriteCoord(MSG_BROADCAST, v_y);
  39         WriteCoord(MSG_BROADCAST, v_z);
  40         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
  41 }
  42
  43 void W_Nex_Attack (float issecondary)
  44 {
  45         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
  46         if(issecondary)
  47         {
  48                 mydmg = autocvar_g_balance_nex_secondary_damage;
  49                 myforce = autocvar_g_balance_nex_secondary_force;
  50                 mymindist = autocvar_g_balance_nex_secondary_damagefalloff_mindist;
  51                 mymaxdist = autocvar_g_balance_nex_secondary_damagefalloff_maxdist;
  52                 myhalflife = autocvar_g_balance_nex_secondary_damagefalloff_halflife;
  53                 myforcehalflife = autocvar_g_balance_nex_secondary_damagefalloff_forcehalflife;
  54                 myammo = autocvar_g_balance_nex_secondary_ammo;
  55         }
  56         else
  57         {
  58                 mydmg = autocvar_g_balance_nex_primary_damage;
  59                 myforce = autocvar_g_balance_nex_primary_force;
  60                 mymindist = autocvar_g_balance_nex_primary_damagefalloff_mindist;
  61                 mymaxdist = autocvar_g_balance_nex_primary_damagefalloff_maxdist;
  62                 myhalflife = autocvar_g_balance_nex_primary_damagefalloff_halflife;
  63                 myforcehalflife = autocvar_g_balance_nex_primary_damagefalloff_forcehalflife;
  64                 myammo = autocvar_g_balance_nex_primary_ammo;
  65         }
  66
  67         float flying;
  68         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  69
  70         if(autocvar_g_balance_nex_charge)
  71         {
  72                 charge = autocvar_g_balance_nex_charge_mindmg / mydmg + (1 - autocvar_g_balance_nex_charge_mindmg / mydmg) * self.nex_charge;
  73                 self.nex_charge *= autocvar_g_balance_nex_charge_shot_multiplier; // do this AFTER setting mydmg/myforce
  74                 // O RLY? -- divVerent
  75                 // YA RLY -- FruitieX
  76         }
  77         else
  78                 charge = 1;
  79         mydmg *= charge;
  80         myforce *= charge;
  81
  82         W_SetupShot (self, TRUE, 5, "weapons/nexfire.wav", CHAN_WEAPON, mydmg);
  83         if(charge > autocvar_g_balance_nex_charge_limit && autocvar_g_balance_nex_charge_limit) // if the Nex is overcharged, we play an extra sound
  84         {
  85                 sound (self, CHAN_WEAPON2, "weapons/nexcharge.wav", VOL_BASE * (charge - 0.5 * autocvar_g_balance_nex_charge_limit) / (1 - 0.5 * autocvar_g_balance_nex_charge_limit), ATTN_NORM);
  86         }
  87
  88         yoda = 0;
  89         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_NEX);
  90
  91         if(yoda && flying)
  92                 AnnounceTo(self, "yoda");
  93
  94         //beam and muzzle flash done on client
  95         SendCSQCNexBeamParticle(charge);
  96
  97         // flash and burn the wall
  98         if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  99                 Damage_DamageInfo(trace_endpos, mydmg, 0, 0, myforce * w_shotdir, WEP_NEX, self);
 100
 101         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 102         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 103         {
 104                 if(autocvar_g_balance_nex_reload_ammo)
 105                 {
 106                         self.clip_load -= myammo;
 107                         self.weapon_load[WEP_NEX] = self.clip_load;
 108                 }
 109                 else
 110                         self.ammo_cells -= myammo;
 111         }
 112 }
 113
 114 void spawnfunc_weapon_nex (void); // defined in t_items.qc
 115
 116 .float nex_chargepool_pauseregen_finished;
 117 float w_nex(float req)
 118 {
 119         float dt;
 120         float ammo_amount;
 121         if (req == WR_AIM)
 122         {
 123                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
 124                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 1, FALSE);
 125         }
 126         else if (req == WR_THINK)
 127         {
 128                 if(autocvar_g_balance_nex_charge && self.nex_charge < autocvar_g_balance_nex_charge_limit)
 129                         self.nex_charge = min(1, self.nex_charge + autocvar_g_balance_nex_charge_rate * frametime / W_TICSPERFRAME);
 130
 131                 if(autocvar_g_balance_nex_secondary_chargepool)
 132                         if(self.nex_chargepool_ammo < 1)
 133                         {
 134                                 if(self.nex_chargepool_pauseregen_finished < time)
 135                                         self.nex_chargepool_ammo = min(1, self.nex_chargepool_ammo + autocvar_g_balance_nex_secondary_chargepool_regen * frametime / W_TICSPERFRAME);
 136                                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_nex_secondary_chargepool_pause_health_regen);
 137                         }
 138
 139                 if(autocvar_g_balance_nex_reload_ammo && self.clip_load < min(autocvar_g_balance_nex_primary_ammo, autocvar_g_balance_nex_secondary_ammo)) // forced reload
 140                         W_Nex_Reload();
 141                 else
 142                 {
 143                         if (self.BUTTON_ATCK)
 144                         {
 145                                 if (weapon_prepareattack(0, autocvar_g_balance_nex_primary_refire))
 146                                 {
 147                                         W_Nex_Attack(0);
 148                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_nex_primary_animtime, w_ready);
 149                                 }
 150                         }
 151                         if ((autocvar_g_balance_nex_secondary_charge && !autocvar_g_balance_nex_secondary) ? self.BUTTON_ZOOM : self.BUTTON_ATCK2)
 152                         {
 153                                 if(autocvar_g_balance_nex_secondary_charge)
 154                                 {
 155                                         self.nex_charge_rottime = time + autocvar_g_balance_nex_charge_rot_pause;
 156                                         dt = frametime / W_TICSPERFRAME;
 157
 158                                         if(self.nex_charge < 1)
 159                                         {
 160                                                 if(autocvar_g_balance_nex_secondary_chargepool)
 161                                                 {
 162                                                         if(autocvar_g_balance_nex_secondary_ammo)
 163                                                         {
 164                                                                 // always deplete if secondary is held
 165                                                                 self.nex_chargepool_ammo = max(0, self.nex_chargepool_ammo - autocvar_g_balance_nex_secondary_ammo * dt);
 166
 167                                                                 dt = min(dt, (1 - self.nex_charge) / autocvar_g_balance_nex_secondary_charge_rate);
 168                                                                 self.nex_chargepool_pauseregen_finished = time + autocvar_g_balance_nex_secondary_chargepool_pause_regen;
 169                                                                 dt = min(dt, self.nex_chargepool_ammo);
 170                                                                 dt = max(0, dt);
 171
 172                                                                 self.nex_charge += dt * autocvar_g_balance_nex_secondary_charge_rate;
 173                                                         }
 174                                                 }
 175
 176                                                 else if(autocvar_g_balance_nex_secondary_ammo)
 177                                                 {
 178                                                         if(self.BUTTON_ATCK2) // only eat ammo when the button is pressed
 179                                                         {
 180                                                                 dt = min(dt, (1 - self.nex_charge) / autocvar_g_balance_nex_secondary_charge_rate);
 181                                                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 182                                                                 {
 183                                                                         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 184                                                                         if(autocvar_g_balance_nex_reload_ammo)
 185                                                                         {
 186                                                                                 dt = min(dt, (self.clip_load - autocvar_g_balance_nex_primary_ammo) / autocvar_g_balance_nex_secondary_ammo);
 187                                                                                 dt = max(0, dt);
 188                                                                                 if(dt > 0)
 189                                                                                 {
 190                                                                                         self.clip_load = max(autocvar_g_balance_nex_secondary_ammo, self.clip_load - autocvar_g_balance_nex_secondary_ammo * dt);
 191                                                                                 }
 192                                                                                 self.weapon_load[WEP_NEX] = self.clip_load;
 193                                                                         }
 194                                                                         else
 195                                                                         {
 196                                                                                 dt = min(dt, (self.ammo_cells - autocvar_g_balance_nex_primary_ammo) / autocvar_g_balance_nex_secondary_ammo);
 197                                                                                 dt = max(0, dt);
 198                                                                                 if(dt > 0)
 199                                                                                 {
 200                                                                                         self.ammo_cells = max(autocvar_g_balance_nex_secondary_ammo, self.ammo_cells - autocvar_g_balance_nex_secondary_ammo * dt);
 201                                                                                 }
 202                                                                         }
 203                                                                 }
 204                                                                 self.nex_charge += dt * autocvar_g_balance_nex_secondary_charge_rate;
 205                                                         }
 206                                                 }
 207
 208                                                 else
 209                                                 {
 210                                                         dt = min(dt, (1 - self.nex_charge) / autocvar_g_balance_nex_secondary_charge_rate);
 211                                                         self.nex_charge += dt * autocvar_g_balance_nex_secondary_charge_rate;
 212                                                 }
 213                                         }
 214                                 }
 215                                 else if(autocvar_g_balance_nex_secondary)
 216                                 {
 217                                         if (weapon_prepareattack(0, autocvar_g_balance_nex_secondary_refire))
 218                                         {
 219                                                 W_Nex_Attack(1);
 220                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_nex_secondary_animtime, w_ready);
 221                                         }
 222                                 }
 223                         }
 224                 }
 225
 226                 if(autocvar_g_balance_nex_charge)
 227                 {
 228                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_limit);
 229                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_limit);
 230                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_limit);
 231
 232                         if(self.nex_charge > autocvar_g_balance_nex_charge_limit)
 233                         {
 234                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_limit) / (1 - autocvar_g_balance_nex_charge_limit);
 235                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_limit) / (1 - autocvar_g_balance_nex_charge_limit);
 236                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_limit) / (1 - autocvar_g_balance_nex_charge_limit);
 237                         }
 238                 }
 239         }
 240         else if (req == WR_PRECACHE)
 241         {
 242                 precache_model ("models/nexflash.md3");
 243                 precache_model ("models/weapons/g_nex.md3");
 244                 precache_model ("models/weapons/v_nex.md3");
 245                 precache_model ("models/weapons/h_nex.iqm");
 246                 precache_sound ("weapons/nexfire.wav");
 247                 precache_sound ("weapons/nexcharge.wav");
 248                 precache_sound ("weapons/nexwhoosh1.wav");
 249                 precache_sound ("weapons/nexwhoosh2.wav");
 250                 precache_sound ("weapons/nexwhoosh3.wav");
 251                 precache_sound ("weapons/reload.wav");
 252         }
 253         else if (req == WR_SETUP)
 254         {
 255                 weapon_setup(WEP_NEX);
 256                 W_Nex_SetAmmoCounter();
 257         }
 258         else if (req == WR_CHECKAMMO1)
 259         {
 260                 ammo_amount = self.ammo_cells >= autocvar_g_balance_nex_primary_ammo;
 261                 ammo_amount += (autocvar_g_balance_nex_reload_ammo && self.weapon_load[WEP_NEX] >= autocvar_g_balance_nex_primary_ammo);
 262                 return ammo_amount;
 263         }
 264         else if (req == WR_CHECKAMMO2)
 265         {
 266                 // don't allow charging if we don't have enough ammo
 267                 ammo_amount = self.ammo_cells >= autocvar_g_balance_nex_secondary_ammo;
 268                 ammo_amount += self.weapon_load[WEP_NEX] >= autocvar_g_balance_nex_secondary_ammo;
 269                 return ammo_amount;
 270         }
 271         else if (req == WR_RELOAD)
 272         {
 273                 W_Nex_Reload();
 274         }
 275
 276         return TRUE;
 277 };
 278 #endif
 279 #ifdef CSQC
 280 float w_nex(float req)
 281 {
 282         if(req == WR_IMPACTEFFECT)
 283         {
 284                 vector org2;
 285                 org2 = w_org + w_backoff * 6;
 286                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 287                 if(!w_issilent)
 288                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 289         }
 290         else if(req == WR_PRECACHE)
 291         {
 292                 precache_sound("weapons/neximpact.wav");
 293         }
 294         else if (req == WR_SUICIDEMESSAGE)
 295                 w_deathtypestring = _("%s did the impossible");
 296         else if (req == WR_KILLMESSAGE)
 297                 w_deathtypestring = _("%s has been vaporized by %s");
 298         return TRUE;
 299 }
 300 #endif
 301 #endif