qcsrc/server/w_nex.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(NEX, w_nex, IT_CELLS, 7, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "nex", "nex", "Nex");
   3 #else
   4 #ifdef SVQC
   5 void SendCSQCNexBeamParticle() {
   6         vector v;
   7         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
   8         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   9         WriteByte(MSG_BROADCAST, TE_CSQC_NEXGUNBEAMPARTICLE);
  10
  11         WriteCoord(MSG_BROADCAST, w_shotorg_x);
  12         WriteCoord(MSG_BROADCAST, w_shotorg_y);
  13         WriteCoord(MSG_BROADCAST, w_shotorg_z);
  14         WriteCoord(MSG_BROADCAST, v_x);
  15         WriteCoord(MSG_BROADCAST, v_y);
  16         WriteCoord(MSG_BROADCAST, v_z);
  17 }
  18
  19 void W_Nex_Attack (float issecondary)
  20 {
  21         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, myvel;
  22         if(issecondary)
  23         {
  24                 mydmg = cvar("g_balance_nex_secondary_damage");
  25                 myforce = cvar("g_balance_nex_secondary_force");
  26                 mymindist = cvar("g_balance_nex_secondary_damagefalloff_mindist");
  27                 mymaxdist = cvar("g_balance_nex_secondary_damagefalloff_maxdist");
  28                 myhalflife = cvar("g_balance_nex_secondary_damagefalloff_halflife");
  29                 myforcehalflife = cvar("g_balance_nex_secondary_damagefalloff_forcehalflife");
  30                 myammo = cvar("g_balance_nex_secondary_ammo");
  31         }
  32         else
  33         {
  34                 mydmg = cvar("g_balance_nex_primary_damage");
  35                 myforce = cvar("g_balance_nex_primary_force");
  36                 mymindist = cvar("g_balance_nex_primary_damagefalloff_mindist");
  37                 mymaxdist = cvar("g_balance_nex_primary_damagefalloff_maxdist");
  38                 myhalflife = cvar("g_balance_nex_primary_damagefalloff_halflife");
  39                 myforcehalflife = cvar("g_balance_nex_primary_damagefalloff_forcehalflife");
  40                 myammo = cvar("g_balance_nex_primary_ammo");
  41         }
  42
  43         float flying;
  44         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  45
  46         if(cvar("g_balance_nex_velocitydependent")) // player velocity dependent damage and force
  47         {
  48                 myvel = vlen(self.velocity);
  49
  50                 if(myvel < cvar("g_balance_nex_velocitydependent_minspeed"))
  51                         myvel = bound(cvar("g_balance_nex_velocitydependent_minspeed"), myvel, cvar("g_balance_nex_velocitydependent_maxspeed"));
  52
  53                 // TODO: make it more obvious (through effects, indicator on weapon) that damage increases when speed increases
  54                 mydmg *= cvar("g_balance_nex_velocitydependent_maxspeed") / myvel;
  55                 myforce *= cvar("g_balance_nex_velocitydependent_maxspeed") / myvel;
  56         }
  57
  58         W_SetupShot (self, TRUE, 5, "weapons/nexfire.wav", mydmg);
  59
  60         yoda = 0;
  61         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_NEX);
  62
  63         if(yoda && flying)
  64                 AnnounceTo(self, "yoda");
  65
  66         //beam and muzzle flash done on client
  67         SendCSQCNexBeamParticle();
  68
  69         // flash and burn the wall
  70         if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  71                 Damage_DamageInfo(trace_endpos, mydmg, 0, 0, myforce * w_shotdir, WEP_NEX, self);
  72
  73         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  74                 self.ammo_cells = self.ammo_cells - myammo;
  75 }
  76
  77 void spawnfunc_weapon_nex (void); // defined in t_items.qc
  78
  79 float w_nex(float req)
  80 {
  81         if (req == WR_AIM)
  82         {
  83                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
  84                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 1, FALSE);
  85         }
  86         else if (req == WR_THINK)
  87         {
  88                 if (self.BUTTON_ATCK)
  89                 {
  90                         if (weapon_prepareattack(0, cvar("g_balance_nex_primary_refire")))
  91                         {
  92                                 W_Nex_Attack(0);
  93                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_primary_animtime"), w_ready);
  94                         }
  95                 }
  96                 if (self.BUTTON_ATCK2)
  97                 {
  98                         if(cvar("g_balance_nex_secondary"))
  99                         {
 100                                 if (weapon_prepareattack(0, cvar("g_balance_nex_secondary_refire")))
 101                                 {
 102                                         W_Nex_Attack(1);
 103                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_secondary_animtime"), w_ready);
 104                                 }
 105                         }
 106                 }
 107         }
 108         else if (req == WR_PRECACHE)
 109         {
 110                 precache_model ("models/nexflash.md3");
 111                 precache_model ("models/weapons/g_nex.md3");
 112                 precache_model ("models/weapons/v_nex.md3");
 113                 precache_model ("models/weapons/h_nex.iqm");
 114                 precache_sound ("weapons/nexfire.wav");
 115                 precache_sound ("weapons/nexwhoosh1.wav");
 116                 precache_sound ("weapons/nexwhoosh2.wav");
 117                 precache_sound ("weapons/nexwhoosh3.wav");
 118         }
 119         else if (req == WR_SETUP)
 120                 weapon_setup(WEP_NEX);
 121         else if (req == WR_CHECKAMMO1)
 122                 return self.ammo_cells >= cvar("g_balance_nex_primary_ammo");
 123         else if (req == WR_CHECKAMMO2)
 124                 return self.ammo_cells >= cvar("g_balance_nex_secondary_ammo");
 125         return TRUE;
 126 };
 127 #endif
 128 #ifdef CSQC
 129 float w_nex(float req)
 130 {
 131         if(req == WR_IMPACTEFFECT)
 132         {
 133                 vector org2;
 134                 org2 = w_org + w_backoff * 6;
 135                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 136                 if(!w_issilent)
 137                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 138         }
 139         else if(req == WR_PRECACHE)
 140         {
 141                 precache_sound("weapons/neximpact.wav");
 142         }
 143         else if (req == WR_SUICIDEMESSAGE)
 144                 w_deathtypestring = "%s did the impossible";
 145         else if (req == WR_KILLMESSAGE)
 146                 w_deathtypestring = "%s has been vaporized by %s";
 147         return TRUE;
 148 }
 149 #endif
 150 #endif